src/ceph/cmake/modules/FindLZ4.cmake

   1 # Try to find liblz4
   2 #
   3 # Once done, this will define
   4 #
   5 # LZ4_FOUND
   6 # LZ4_INCLUDE_DIR
   7 # LZ4_LIBRARY
   8 # LZ4_VERSION_STRING
   9 # LZ4_VERSION_MAJOR
  10 # LZ4_VERSION_MINOR
  11 # LZ4_VERSION_RELEASE
  12
  13 find_path(LZ4_INCLUDE_DIR NAMES lz4.h)
  14
  15 if(LZ4_INCLUDE_DIR AND EXISTS "${LZ4_INCLUDE_DIR}/lz4.h")
  16   foreach(ver "MAJOR" "MINOR" "RELEASE")
  17     file(STRINGS "${LZ4_INCLUDE_DIR}/lz4.h" LZ4_VER_${ver}_LINE
  18       REGEX "^#define[ \t]+LZ4_VERSION_${ver}[ \t]+[0-9]+[ \t]+.*$")
  19     string(REGEX REPLACE "^#define[ \t]+LZ4_VERSION_${ver}[ \t]+([0-9]+)[ \t]+.*$"
  20       "\\1" LZ4_VERSION_${ver} "${LZ4_VER_${ver}_LINE}")
  21     unset(${LZ4_VER_${ver}_LINE})
  22   endforeach()
  23   set(LZ4_VERSION_STRING
  24     "${LZ4_VERSION_MAJOR}.${LZ4_VERSION_MINOR}.${LZ4_VERSION_RELEASE}")
  25 endif()
  26
  27 find_library(LZ4_LIBRARY NAMES lz4)
  28
  29 include(FindPackageHandleStandardArgs)
  30 find_package_handle_standard_args(LZ4
  31   REQUIRED_VARS LZ4_LIBRARY LZ4_INCLUDE_DIR
  32   VERSION_VAR LZ4_VERSION_STRING)
  33
  34 mark_as_advanced(LZ4_INCLUDE_DIR LZ4_LIBRARY)