qemu/roms/u-boot/board/sandburst/metrobox/u-boot.lds.debug

   1 /*
   2  * (C) Copyright 2002-2005
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  * Travis B. Sawyer, Sandburst Corporation, tsawyer@sandburst.com
   5  *
   6  * SPDX-License-Identifier:     GPL-2.0+
   7  */
   8
   9 OUTPUT_ARCH(powerpc)
  10 /* Do we need any of these for elf?
  11    __DYNAMIC = 0;    */
  12 SECTIONS
  13 {
  14   /* Read-only sections, merged into text segment: */
  15   . = + SIZEOF_HEADERS;
  16   .interp : { *(.interp) }
  17   .hash          : { *(.hash)           }
  18   .dynsym        : { *(.dynsym)         }
  19   .dynstr        : { *(.dynstr)         }
  20   .rel.text      : { *(.rel.text)       }
  21   .rela.text     : { *(.rela.text)      }
  22   .rel.data      : { *(.rel.data)       }
  23   .rela.data     : { *(.rela.data)      }
  24   .rel.rodata    : { *(.rel.rodata)     }
  25   .rela.rodata   : { *(.rela.rodata)    }
  26   .rel.got       : { *(.rel.got)        }
  27   .rela.got      : { *(.rela.got)       }
  28   .rel.ctors     : { *(.rel.ctors)      }
  29   .rela.ctors    : { *(.rela.ctors)     }
  30   .rel.dtors     : { *(.rel.dtors)      }
  31   .rela.dtors    : { *(.rela.dtors)     }
  32   .rel.bss       : { *(.rel.bss)        }
  33   .rela.bss      : { *(.rela.bss)       }
  34   .rel.plt       : { *(.rel.plt)        }
  35   .rela.plt      : { *(.rela.plt)       }
  36   .init          : { *(.init)   }
  37   .plt : { *(.plt) }
  38   .text      :
  39   {
  40     /* WARNING - the following is hand-optimized to fit within  */
  41     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  42
  43     arch/powerpc/cpu/ppc4xx/start.o     (.text)
  44     board/sandburst/metrobox/init.o (.text)
  45     arch/powerpc/cpu/ppc4xx/kgdb.o      (.text)
  46     arch/powerpc/cpu/ppc4xx/traps.o     (.text)
  47     arch/powerpc/cpu/ppc4xx/interrupts.o        (.text)
  48     arch/powerpc/cpu/ppc4xx/4xx_uart.o  (.text)
  49     arch/powerpc/cpu/ppc4xx/cpu_init.o  (.text)
  50     arch/powerpc/cpu/ppc4xx/speed.o     (.text)
  51     drivers/net/4xx_enet.o      (.text)
  52     common/dlmalloc.o   (.text)
  53     lib/crc32.o         (.text)
  54     arch/powerpc/lib/extable.o  (.text)
  55     lib/zlib.o          (.text)
  56
  57 /*    common/env_embedded.o(.text) */
  58
  59     *(.text)
  60     *(.got1)
  61   }
  62   _etext = .;
  63   PROVIDE (etext = .);
  64   .rodata    :
  65   {
  66     *(.rodata)
  67     *(.rodata1)
  68     *(.rodata.str1.4)
  69     *(.eh_frame)
  70   }
  71   .fini      : { *(.fini)    } =0
  72   .ctors     : { *(.ctors)   }
  73   .dtors     : { *(.dtors)   }
  74
  75   /* Read-write section, merged into data segment: */
  76   . = (. + 0x0FFF) & 0xFFFFF000;
  77   _erotext = .;
  78   PROVIDE (erotext = .);
  79   .reloc   :
  80   {
  81     *(.got)
  82     _GOT2_TABLE_ = .;
  83     *(.got2)
  84     _FIXUP_TABLE_ = .;
  85     *(.fixup)
  86   }
  87   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  88   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  89
  90   .data    :
  91   {
  92     *(.data)
  93     *(.data1)
  94     *(.sdata)
  95     *(.sdata2)
  96     *(.dynamic)
  97     CONSTRUCTORS
  98   }
  99   _edata  =  .;
 100   PROVIDE (edata = .);
 101
 102
 103   . = ALIGN(4);
 104   .u_boot_list : {
 105         KEEP(*(SORT(.u_boot_list*)));
 106   }
 107
 108
 109   __start___ex_table = .;
 110   __ex_table : { *(__ex_table) }
 111   __stop___ex_table = .;
 112
 113   . = ALIGN(256);
 114   __init_begin = .;
 115   .text.init : { *(.text.init) }
 116   .data.init : { *(.data.init) }
 117   . = ALIGN(256);
 118   __init_end = .;
 119
 120   __bss_start = .;
 121   .bss       :
 122   {
 123    *(.sbss) *(.scommon)
 124    *(.dynbss)
 125    *(.bss)
 126    *(COMMON)
 127   }
 128   __bss_end = . ;
 129   PROVIDE (end = .);
 130 }