qemu/roms/openbios/arch/sparc64/ldscript

   1 OUTPUT_FORMAT(elf64-sparc)
   2 OUTPUT_ARCH(sparc:v9)
   3
   4 /* QEMU ELF loader can't handle very complex files, so we put ELFBoot
   5 info to rodata and put initctx to data.*/
   6
   7 ENTRY(trap_table)
   8
   9 /* Initial load address
  10  */
  11 BASE_ADDR = 0x00000000ffd00000;
  12
  13 /* 16KB stack */
  14 STACK_SIZE = 16384;
  15 IOMEM_SIZE = 256 * 1024 + 768 * 1024;
  16
  17 SECTIONS
  18 {
  19     . = BASE_ADDR;
  20
  21     /* Start of the program.
  22      * Now the version string is in the note, we must include it
  23      * in the program. Otherwise we lose the string after relocation. */
  24     _start = .;
  25
  26     /* Normal sections */
  27     .text ALIGN(524288): {
  28         *(.text.vectors)
  29         *(.text)
  30         *(.text.*)
  31     }
  32     .rodata ALIGN(524288): {
  33         _rodata = .;
  34         sound_drivers_start = .;
  35         *(.rodata.sound_drivers)
  36         sound_drivers_end = .;
  37         *(.rodata)
  38         *(.rodata.*)
  39         *(.note.ELFBoot)
  40     }
  41     .data ALIGN(524288): {
  42         _data = .;
  43         *(.data)
  44         *(.data.*)
  45     }
  46
  47     .bss ALIGN(4096): {
  48         _bss = .;
  49         *(.bss)
  50         *(.bss.*)
  51         *(COMMON)
  52
  53         _stack = .;
  54         . += STACK_SIZE;
  55         . = ALIGN(16);
  56         _estack = .;
  57     }
  58
  59     . = ALIGN(4096);
  60     _end = .;
  61     _iomem = _end + IOMEM_SIZE;
  62
  63     /* We discard .note sections other than .note.ELFBoot,
  64      * because some versions of GCC generates useless ones. */
  65
  66     /DISCARD/ : { *(.comment*) *(.note.*) }
  67 }