qemu/roms/openbios/arch/ppc64/qemu/ldscript

   1 OUTPUT_FORMAT(elf64-powerpc)
   2 OUTPUT_ARCH(powerpc:common64)
   3
   4 /* Initial load address
   5  */
   6 BASE_ADDR = 0xfff00000;
   7
   8 /* As NVRAM is at 0xfff04000, the .text needs to be after that
   9  * The value in arch/ppc/qemu/kernel.c must match this value!
  10  */
  11 TEXT_ADDR = 0xfff08000;
  12
  13 /* Hard reset vector address
  14  */
  15 HRESET_ADDR = 0xfffffffc;
  16
  17 CSTACK_SIZE = 32768;    /* client stack size */
  18
  19 SECTIONS
  20 {
  21     . = BASE_ADDR;
  22
  23     _start = BASE_ADDR + 0x0100;
  24     .text.vectors ALIGN(4096): {
  25         *(.text.vectors)
  26     }
  27
  28     . = TEXT_ADDR;
  29     /* Normal sections */
  30     .data.dict ALIGN(4096): {
  31         _dict_start = .;
  32         *(.data.dict)
  33         _dict_end = .;
  34     }
  35
  36     .text ALIGN(4096): {
  37         *(.text)
  38         *(.text.*)
  39     }
  40
  41     .rodata ALIGN(4096): {
  42         _rodata = .;
  43         *(.rodata)
  44         *(.rodata.*)
  45         *(.note.ELFBoot)
  46     }
  47     .data ALIGN(4096): {
  48         _data = .;
  49         *(.data)
  50         *(.data.*)
  51         *(.toc1)
  52         *(.branch_lt)
  53         _edata = .;
  54     }
  55     .opd : {
  56         *(.opd)
  57     }
  58     .got : {
  59         __toc_start = .;
  60         *(.got)
  61         *(.toc)
  62     }
  63
  64     .bss ALIGN(4096): {
  65         _bss = .;
  66         *(.sbss)
  67         *(.sbss.*)
  68         *(.bss)
  69         *(.bss.*)
  70         *(COMMON)
  71         _ebss = .;
  72     }
  73
  74     . = HRESET_ADDR;
  75
  76     .romentry : { *(.romentry) }
  77
  78     . = ALIGN(4096);
  79     _end = .;
  80
  81     /* We discard .note sections other than .note.ELFBoot,
  82      * because some versions of GCC generates useless ones. */
  83
  84     /DISCARD/ : { *(.comment*) *(.note.*) }
  85 }