qemu/roms/openbios/arch/ppc/qemu/ldscript

   1 OUTPUT_FORMAT(elf32-powerpc)
   2 OUTPUT_ARCH(powerpc:common)
   3
   4 /* Initial load address
   5  */
   6 BASE_ADDR = 0xfff00000;
   7
   8 /* As NVRAM is at 0xfff04000, the .text needs to be after that
   9  */
  10 TEXT_ADDR = 0xfff08000;
  11
  12 /* Hard reset vector address
  13  */
  14 HRESET_ADDR = 0xfffffffc;
  15
  16 CSTACK_SIZE = 32768;    /* client stack size */
  17
  18 SECTIONS
  19 {
  20     . = BASE_ADDR;
  21
  22     _start = BASE_ADDR + 0x0100;
  23     .text.vectors ALIGN(4096): {
  24         *(.text.vectors)
  25     }
  26
  27     . = TEXT_ADDR;
  28     /* Normal sections */
  29     .text ALIGN(4096): {
  30         *(.text)
  31         *(.text.*)
  32     }
  33
  34     .rodata ALIGN(4096): {
  35         _rodata = .;
  36         *(.rodata)
  37         *(.rodata.*)
  38         *(.note.ELFBoot)
  39     }
  40     .data ALIGN(4096): {
  41         _data = .;
  42         *(.data)
  43         *(.data.*)
  44         _edata = .;
  45     }
  46
  47     .bss ALIGN(4096): {
  48         _bss = .;
  49         *(.sbss)
  50         *(.sbss.*)
  51         *(.bss)
  52         *(.bss.*)
  53         *(COMMON)
  54         _ebss = .;
  55     }
  56
  57     . = HRESET_ADDR;
  58
  59     .romentry : { *(.romentry) }
  60
  61     . = ALIGN(4096);
  62     _end = .;
  63
  64     /* We discard .note sections other than .note.ELFBoot,
  65      * because some versions of GCC generates useless ones. */
  66
  67     /DISCARD/ : { *(.comment*) *(.note.*) }
  68 }