qemu/roms/SLOF/rtas/rtas.lds

   1 /******************************************************************************
   2  * Copyright (c) 2004, 2008 IBM Corporation
   3  * All rights reserved.
   4  * This program and the accompanying materials
   5  * are made available under the terms of the BSD License
   6  * which accompanies this distribution, and is available at
   7  * http://www.opensource.org/licenses/bsd-license.php
   8  *
   9  * Contributors:
  10  *     IBM Corporation - initial implementation
  11  *****************************************************************************/
  12
  13 OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
  14 OUTPUT_ARCH(powerpc:common64)
  15
  16 SECTIONS {
  17         .text 0:
  18         {
  19           *(.rtasstart)
  20           *(.text .stub .text.* .gnu.linkonce.t.*)
  21           *(.sfpr .glink)
  22           *(.rodata .rodata.* .gnu.linkonce.r.*)
  23           *(.opd)
  24         } =0x60000000
  25         .data :
  26         {
  27           *(.data .data.* .gnu.linkonce.d.*)
  28         }
  29         .got :
  30         {
  31           . = ALIGN(256);
  32           _got = DEFINED (.TOC.) ? .TOC. : ADDR (.got) + 0x8000;
  33           *(.got .toc)
  34         }
  35         .reloc :
  36         {
  37           . = ALIGN(4);
  38           _reloc_table_start = .;
  39           *(.reloc)
  40           _reloc_table_end = .;
  41         }
  42         .bss :
  43         {
  44           __bss_start = .;
  45           *(*COM* .bss .sbss .gnu.linkonce.b.*)
  46           __bss_end = .;
  47         }
  48         __bss_size = (__bss_end - __bss_start);
  49         _rtas_end = .;
  50 }