qemu/roms/SLOF/clients/takeover/client.lds

   1 /******************************************************************************
   2  * Copyright (c) 2004, 2008 IBM Corporation
   3  * All rights reserved.
   4  * This program and the accompanying materials
   5  * are made available under the terms of the BSD License
   6  * which accompanies this distribution, and is available at
   7  * http://www.opensource.org/licenses/bsd-license.php
   8  *
   9  * Contributors:
  10  *     IBM Corporation - initial implementation
  11  *****************************************************************************/
  12
  13 OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
  14 OUTPUT_ARCH(powerpc:common64)
  15 ENTRY(_entry)
  16
  17 SECTIONS {
  18         .client 0x400100:
  19         {
  20         __client_start = .;
  21           *(.start)
  22           *(.text .stub .text.* .gnu.linkonce.t.*)
  23           *(.sfpr .glink)
  24           *(.rodata .rodata.* .gnu.linkonce.r.*)
  25           KEEP (*(.opd))
  26           . = ALIGN(256);
  27           *(.data .data.* .gnu.linkonce.d.*)
  28           . = ALIGN(256);
  29         } =0x60000000
  30
  31         .diag_table :
  32         {
  33           _diag_init_start = .;
  34           *(.diag_init)
  35           _diag_init_end = .;
  36         }
  37         .lowmem :
  38         {
  39           _lowmem_start = .;
  40           *(.lowmem)
  41           _lowmem_end = .;
  42         }
  43
  44         .got :
  45         {
  46           . = ALIGN(8);
  47           _got = .;
  48           *(.got .toc)
  49           _got_end = .;
  50         }
  51         .comment : { *(.comment) }
  52         .branch_lt : { *(.branch_lt) }
  53         .bss :
  54         {
  55         __bssStart = .;
  56           *(*COM* .bss .gnu.linkonce.b.*)
  57         __client_end = .;
  58         __bssSize = . - __bssStart;
  59         }
  60 }