qemu/roms/SLOF/board-qemu/llfw/stage2.lds

   1 /******************************************************************************
   2  * Copyright (c) 2004, 2008 IBM Corporation
   3  * All rights reserved.
   4  * This program and the accompanying materials
   5  * are made available under the terms of the BSD License
   6  * which accompanies this distribution, and is available at
   7  * http://www.opensource.org/licenses/bsd-license.php
   8  *
   9  * Contributors:
  10  *     IBM Corporation - initial implementation
  11  *****************************************************************************/
  12
  13 OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
  14 OUTPUT_ARCH(powerpc:common64)
  15
  16 /* set the entry point */
  17 ENTRY ( __start )
  18
  19 SECTIONS {
  20         __executable_start = .;
  21
  22         .text : {
  23                 *(.text)
  24         }
  25
  26         __etext = .;
  27
  28         . = ALIGN(8);
  29
  30         .data : {
  31                 *(.data)
  32                 *(.rodata .rodata.*)
  33                 *(.got1)
  34                 *(.sdata)
  35                 *(.opd)
  36         }
  37
  38         /* FIXME bss at end ??? */
  39
  40         . = ALIGN(8);
  41         __bss_start = .;
  42         .bss : {
  43                 *(.sbss) *(.scommon)
  44                 *(.dynbss)
  45                 *(.bss)
  46         }
  47
  48         . = ALIGN(8);
  49         __bss_end = .;
  50         __bss_size = (__bss_end - __bss_start);
  51
  52         __toc_start = .;
  53         .got :
  54         {
  55                  *(.toc .got)
  56         }
  57         . = ALIGN(8);
  58         __toc_end = .;
  59 }