2 * linux/arch/x86_64/entry.S
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
6 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
10 * entry.S contains the system-call and fault low-level handling routines.
12 * Some of this is documented in Documentation/x86/entry_64.txt
14 * NOTE: This code handles signal-recognition, which happens every time
15 * after an interrupt and after each system call.
17 * A note on terminology:
18 * - iret frame: Architecture defined interrupt frame from SS to RIP
19 * at the top of the kernel process stack.
22 * - CFI macros are used to generate dwarf2 unwind information for better
23 * backtraces. They don't change any code.
24 * - ENTRY/END Define functions in the symbol table.
25 * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
26 * - idtentry - Define exception entry points.
29 #include <linux/linkage.h>
30 #include <asm/segment.h>
31 #include <asm/cache.h>
32 #include <asm/errno.h>
33 #include <asm/dwarf2.h>
34 #include <asm/calling.h>
35 #include <asm/asm-offsets.h>
37 #include <asm/unistd.h>
38 #include <asm/thread_info.h>
39 #include <asm/hw_irq.h>
40 #include <asm/page_types.h>
41 #include <asm/irqflags.h>
42 #include <asm/paravirt.h>
43 #include <asm/percpu.h>
45 #include <asm/context_tracking.h>
47 #include <asm/pgtable_types.h>
48 #include <linux/err.h>
50 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
51 #include <linux/elf-em.h>
52 #define AUDIT_ARCH_X86_64 (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
53 #define __AUDIT_ARCH_64BIT 0x80000000
54 #define __AUDIT_ARCH_LE 0x40000000
57 .section .entry.text, "ax"
60 #ifdef CONFIG_PARAVIRT
61 ENTRY(native_usergs_sysret64)
64 ENDPROC(native_usergs_sysret64)
65 #endif /* CONFIG_PARAVIRT */
68 .macro TRACE_IRQS_IRETQ
69 #ifdef CONFIG_TRACE_IRQFLAGS
70 bt $9,EFLAGS(%rsp) /* interrupts off? */
78 * When dynamic function tracer is enabled it will add a breakpoint
79 * to all locations that it is about to modify, sync CPUs, update
80 * all the code, sync CPUs, then remove the breakpoints. In this time
81 * if lockdep is enabled, it might jump back into the debug handler
82 * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
84 * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
85 * make sure the stack pointer does not get reset back to the top
86 * of the debug stack, and instead just reuses the current stack.
88 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
90 .macro TRACE_IRQS_OFF_DEBUG
91 call debug_stack_set_zero
93 call debug_stack_reset
96 .macro TRACE_IRQS_ON_DEBUG
97 call debug_stack_set_zero
99 call debug_stack_reset
102 .macro TRACE_IRQS_IRETQ_DEBUG
103 bt $9,EFLAGS(%rsp) /* interrupts off? */
110 # define TRACE_IRQS_OFF_DEBUG TRACE_IRQS_OFF
111 # define TRACE_IRQS_ON_DEBUG TRACE_IRQS_ON
112 # define TRACE_IRQS_IRETQ_DEBUG TRACE_IRQS_IRETQ
118 .macro EMPTY_FRAME start=1 offset=0
122 CFI_DEF_CFA rsp,8+\offset
124 CFI_DEF_CFA_OFFSET 8+\offset
129 * initial frame state for interrupts (and exceptions without error code)
131 .macro INTR_FRAME start=1 offset=0
132 EMPTY_FRAME \start, 5*8+\offset
133 /*CFI_REL_OFFSET ss, 4*8+\offset*/
134 CFI_REL_OFFSET rsp, 3*8+\offset
135 /*CFI_REL_OFFSET rflags, 2*8+\offset*/
136 /*CFI_REL_OFFSET cs, 1*8+\offset*/
137 CFI_REL_OFFSET rip, 0*8+\offset
141 * initial frame state for exceptions with error code (and interrupts
142 * with vector already pushed)
144 .macro XCPT_FRAME start=1 offset=0
145 INTR_FRAME \start, 1*8+\offset
149 * frame that enables passing a complete pt_regs to a C function.
151 .macro DEFAULT_FRAME start=1 offset=0
152 XCPT_FRAME \start, ORIG_RAX+\offset
153 CFI_REL_OFFSET rdi, RDI+\offset
154 CFI_REL_OFFSET rsi, RSI+\offset
155 CFI_REL_OFFSET rdx, RDX+\offset
156 CFI_REL_OFFSET rcx, RCX+\offset
157 CFI_REL_OFFSET rax, RAX+\offset
158 CFI_REL_OFFSET r8, R8+\offset
159 CFI_REL_OFFSET r9, R9+\offset
160 CFI_REL_OFFSET r10, R10+\offset
161 CFI_REL_OFFSET r11, R11+\offset
162 CFI_REL_OFFSET rbx, RBX+\offset
163 CFI_REL_OFFSET rbp, RBP+\offset
164 CFI_REL_OFFSET r12, R12+\offset
165 CFI_REL_OFFSET r13, R13+\offset
166 CFI_REL_OFFSET r14, R14+\offset
167 CFI_REL_OFFSET r15, R15+\offset
171 * 64bit SYSCALL instruction entry. Up to 6 arguments in registers.
173 * 64bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
174 * then loads new ss, cs, and rip from previously programmed MSRs.
175 * rflags gets masked by a value from another MSR (so CLD and CLAC
176 * are not needed). SYSCALL does not save anything on the stack
177 * and does not change rsp.
179 * Registers on entry:
180 * rax system call number
182 * r11 saved rflags (note: r11 is callee-clobbered register in C ABI)
186 * r10 arg3 (needs to be moved to rcx to conform to C ABI)
189 * (note: r12-r15,rbp,rbx are callee-preserved in C ABI)
191 * Only called from user space.
193 * When user can change pt_regs->foo always force IRET. That is because
194 * it deals with uncanonical addresses better. SYSRET has trouble
195 * with them due to bugs in both AMD and Intel CPUs.
203 /*CFI_REGISTER rflags,r11*/
206 * Interrupts are off on entry.
207 * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
208 * it is too small to ever cause noticeable irq latency.
212 * A hypervisor implementation might want to use a label
213 * after the swapgs, so that it can do the swapgs
214 * for the guest and jump here on syscall.
216 GLOBAL(system_call_after_swapgs)
218 movq %rsp,PER_CPU_VAR(rsp_scratch)
219 movq PER_CPU_VAR(kernel_stack),%rsp
221 /* Construct struct pt_regs on stack */
222 pushq_cfi $__USER_DS /* pt_regs->ss */
223 pushq_cfi PER_CPU_VAR(rsp_scratch) /* pt_regs->sp */
225 * Re-enable interrupts.
226 * We use 'rsp_scratch' as a scratch space, hence irq-off block above
227 * must execute atomically in the face of possible interrupt-driven
228 * task preemption. We must enable interrupts only after we're done
229 * with using rsp_scratch:
231 ENABLE_INTERRUPTS(CLBR_NONE)
232 pushq_cfi %r11 /* pt_regs->flags */
233 pushq_cfi $__USER_CS /* pt_regs->cs */
234 pushq_cfi %rcx /* pt_regs->ip */
236 pushq_cfi_reg rax /* pt_regs->orig_ax */
237 pushq_cfi_reg rdi /* pt_regs->di */
238 pushq_cfi_reg rsi /* pt_regs->si */
239 pushq_cfi_reg rdx /* pt_regs->dx */
240 pushq_cfi_reg rcx /* pt_regs->cx */
241 pushq_cfi $-ENOSYS /* pt_regs->ax */
242 pushq_cfi_reg r8 /* pt_regs->r8 */
243 pushq_cfi_reg r9 /* pt_regs->r9 */
244 pushq_cfi_reg r10 /* pt_regs->r10 */
245 pushq_cfi_reg r11 /* pt_regs->r11 */
246 sub $(6*8),%rsp /* pt_regs->bp,bx,r12-15 not saved */
247 CFI_ADJUST_CFA_OFFSET 6*8
249 testl $_TIF_WORK_SYSCALL_ENTRY, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
251 system_call_fastpath:
252 #if __SYSCALL_MASK == ~0
253 cmpq $__NR_syscall_max,%rax
255 andl $__SYSCALL_MASK,%eax
256 cmpl $__NR_syscall_max,%eax
258 ja 1f /* return -ENOSYS (already in pt_regs->ax) */
260 call *sys_call_table(,%rax,8)
264 * Syscall return path ending with SYSRET (fast path).
265 * Has incompletely filled pt_regs.
269 * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
270 * it is too small to ever cause noticeable irq latency.
272 DISABLE_INTERRUPTS(CLBR_NONE)
275 * We must check ti flags with interrupts (or at least preemption)
276 * off because we must *never* return to userspace without
277 * processing exit work that is enqueued if we're preempted here.
278 * In particular, returning to userspace with any of the one-shot
279 * flags (TIF_NOTIFY_RESUME, TIF_USER_RETURN_NOTIFY, etc) set is
282 testl $_TIF_ALLWORK_MASK, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
283 jnz int_ret_from_sys_call_irqs_off /* Go to the slow path */
287 RESTORE_C_REGS_EXCEPT_RCX_R11
290 movq EFLAGS(%rsp),%r11
291 /*CFI_REGISTER rflags,r11*/
294 * 64bit SYSRET restores rip from rcx,
295 * rflags from r11 (but RF and VM bits are forced to 0),
296 * cs and ss are loaded from MSRs.
297 * Restoration of rflags re-enables interrupts.
299 * NB: On AMD CPUs with the X86_BUG_SYSRET_SS_ATTRS bug, the ss
300 * descriptor is not reinitialized. This means that we should
301 * avoid SYSRET with SS == NULL, which could happen if we schedule,
302 * exit the kernel, and re-enter using an interrupt vector. (All
303 * interrupt entries on x86_64 set SS to NULL.) We prevent that
304 * from happening by reloading SS in __switch_to. (Actually
305 * detecting the failure in 64-bit userspace is tricky but can be
312 /* Do syscall entry tracing */
315 movl $AUDIT_ARCH_X86_64, %esi
316 call syscall_trace_enter_phase1
318 jnz tracesys_phase2 /* if needed, run the slow path */
319 RESTORE_C_REGS_EXCEPT_RAX /* else restore clobbered regs */
320 movq ORIG_RAX(%rsp), %rax
321 jmp system_call_fastpath /* and return to the fast path */
326 movl $AUDIT_ARCH_X86_64, %esi
328 call syscall_trace_enter_phase2
331 * Reload registers from stack in case ptrace changed them.
332 * We don't reload %rax because syscall_trace_entry_phase2() returned
333 * the value it wants us to use in the table lookup.
335 RESTORE_C_REGS_EXCEPT_RAX
337 #if __SYSCALL_MASK == ~0
338 cmpq $__NR_syscall_max,%rax
340 andl $__SYSCALL_MASK,%eax
341 cmpl $__NR_syscall_max,%eax
343 ja 1f /* return -ENOSYS (already in pt_regs->ax) */
344 movq %r10,%rcx /* fixup for C */
345 call *sys_call_table(,%rax,8)
348 /* Use IRET because user could have changed pt_regs->foo */
351 * Syscall return path ending with IRET.
352 * Has correct iret frame.
354 GLOBAL(int_ret_from_sys_call)
355 DISABLE_INTERRUPTS(CLBR_NONE)
356 int_ret_from_sys_call_irqs_off: /* jumps come here from the irqs-off SYSRET path */
358 movl $_TIF_ALLWORK_MASK,%edi
359 /* edi: mask to check */
360 GLOBAL(int_with_check)
362 GET_THREAD_INFO(%rcx)
363 movl TI_flags(%rcx),%edx
366 andl $~TS_COMPAT,TI_status(%rcx)
369 /* Either reschedule or signal or syscall exit tracking needed. */
370 /* First do a reschedule test. */
371 /* edx: work, edi: workmask */
373 testl $_TIF_NEED_RESCHED_MASK,%edx
376 ENABLE_INTERRUPTS(CLBR_NONE)
380 DISABLE_INTERRUPTS(CLBR_NONE)
384 /* handle signals and tracing -- both require a full pt_regs */
387 ENABLE_INTERRUPTS(CLBR_NONE)
389 /* Check for syscall exit trace */
390 testl $_TIF_WORK_SYSCALL_EXIT,%edx
393 leaq 8(%rsp),%rdi # &ptregs -> arg1
394 call syscall_trace_leave
396 andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
400 testl $_TIF_DO_NOTIFY_MASK,%edx
402 movq %rsp,%rdi # &ptregs -> arg1
403 xorl %esi,%esi # oldset -> arg2
404 call do_notify_resume
405 1: movl $_TIF_WORK_MASK,%edi
408 DISABLE_INTERRUPTS(CLBR_NONE)
413 /* The IRETQ could re-enable interrupts: */
414 DISABLE_INTERRUPTS(CLBR_ANY)
418 * Try to use SYSRET instead of IRET if we're returning to
419 * a completely clean 64-bit userspace context.
422 cmpq %rcx,RIP(%rsp) /* RCX == RIP */
423 jne opportunistic_sysret_failed
426 * On Intel CPUs, SYSRET with non-canonical RCX/RIP will #GP
427 * in kernel space. This essentially lets the user take over
428 * the kernel, since userspace controls RSP. It's not worth
429 * testing for canonicalness exactly -- this check detects any
430 * of the 17 high bits set, which is true for non-canonical
431 * or kernel addresses. (This will pessimize vsyscall=native.
434 * If virtual addresses ever become wider, this will need
435 * to be updated to remain correct on both old and new CPUs.
437 .ifne __VIRTUAL_MASK_SHIFT - 47
438 .error "virtual address width changed -- SYSRET checks need update"
440 shr $__VIRTUAL_MASK_SHIFT, %rcx
441 jnz opportunistic_sysret_failed
443 cmpq $__USER_CS,CS(%rsp) /* CS must match SYSRET */
444 jne opportunistic_sysret_failed
447 cmpq %r11,EFLAGS(%rsp) /* R11 == RFLAGS */
448 jne opportunistic_sysret_failed
451 * SYSRET can't restore RF. SYSRET can restore TF, but unlike IRET,
452 * restoring TF results in a trap from userspace immediately after
453 * SYSRET. This would cause an infinite loop whenever #DB happens
454 * with register state that satisfies the opportunistic SYSRET
455 * conditions. For example, single-stepping this user code:
457 * movq $stuck_here,%rcx
462 * would never get past 'stuck_here'.
464 testq $(X86_EFLAGS_RF|X86_EFLAGS_TF), %r11
465 jnz opportunistic_sysret_failed
467 /* nothing to check for RSP */
469 cmpq $__USER_DS,SS(%rsp) /* SS must match SYSRET */
470 jne opportunistic_sysret_failed
473 * We win! This label is here just for ease of understanding
474 * perf profiles. Nothing jumps here.
476 syscall_return_via_sysret:
478 /* r11 is already restored (see code above) */
479 RESTORE_C_REGS_EXCEPT_R11
484 opportunistic_sysret_failed:
486 jmp restore_c_regs_and_iret
491 .macro FORK_LIKE func
494 DEFAULT_FRAME 0, 8 /* offset 8: return address */
512 /* exec failed, can use fast SYSRET code path in this case */
515 /* must use IRET code path (pt_regs->cs may have changed) */
517 CFI_ADJUST_CFA_OFFSET -8
520 jmp int_ret_from_sys_call
524 * Remaining execve stubs are only 7 bytes long.
525 * ENTRY() often aligns to 16 bytes, which in this case has no benefits.
528 GLOBAL(stub_execveat)
532 jmp return_from_execve
536 #ifdef CONFIG_X86_X32_ABI
538 GLOBAL(stub_x32_execve)
541 call compat_sys_execve
542 jmp return_from_execve
546 GLOBAL(stub_x32_execveat)
549 call compat_sys_execveat
550 jmp return_from_execve
552 END(stub_x32_execveat)
555 #ifdef CONFIG_IA32_EMULATION
557 GLOBAL(stub32_execve)
559 call compat_sys_execve
560 jmp return_from_execve
564 GLOBAL(stub32_execveat)
566 call compat_sys_execveat
567 jmp return_from_execve
573 * sigreturn is special because it needs to restore all registers on return.
574 * This cannot be done with SYSRET, so use the IRET return path instead.
576 ENTRY(stub_rt_sigreturn)
580 * SAVE_EXTRA_REGS result is not normally needed:
581 * sigreturn overwrites all pt_regs->GPREGS.
582 * But sigreturn can fail (!), and there is no easy way to detect that.
583 * To make sure RESTORE_EXTRA_REGS doesn't restore garbage on error,
584 * we SAVE_EXTRA_REGS here.
587 call sys_rt_sigreturn
590 CFI_ADJUST_CFA_OFFSET -8
593 jmp int_ret_from_sys_call
595 END(stub_rt_sigreturn)
597 #ifdef CONFIG_X86_X32_ABI
598 ENTRY(stub_x32_rt_sigreturn)
602 call sys32_x32_rt_sigreturn
605 END(stub_x32_rt_sigreturn)
609 * A newly forked process directly context switches into this address.
611 * rdi: prev task we switched from
616 LOCK ; btr $TIF_FORK,TI_flags(%r8)
619 popfq_cfi # reset kernel eflags
621 call schedule_tail # rdi: 'prev' task parameter
625 testl $3,CS(%rsp) # from kernel_thread?
628 * By the time we get here, we have no idea whether our pt_regs,
629 * ti flags, and ti status came from the 64-bit SYSCALL fast path,
630 * the slow path, or one of the ia32entry paths.
631 * Use IRET code path to return, since it can safely handle
634 jnz int_ret_from_sys_call
636 /* We came from kernel_thread */
637 /* nb: we depend on RESTORE_EXTRA_REGS above */
642 jmp int_ret_from_sys_call
647 * Build the entry stubs with some assembler magic.
648 * We pack 1 stub into every 8-byte block.
651 ENTRY(irq_entries_start)
653 vector=FIRST_EXTERNAL_VECTOR
654 .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
655 pushq_cfi $(~vector+0x80) /* Note: always in signed byte range */
658 CFI_ADJUST_CFA_OFFSET -8
662 END(irq_entries_start)
665 * Interrupt entry/exit.
667 * Interrupt entry points save only callee clobbered registers in fast path.
669 * Entry runs with interrupts off.
672 /* 0(%rsp): ~(interrupt number) */
673 .macro interrupt func
676 * Since nothing in interrupt handling code touches r12...r15 members
677 * of "struct pt_regs", and since interrupts can nest, we can save
678 * four stack slots and simultaneously provide
679 * an unwind-friendly stack layout by saving "truncated" pt_regs
680 * exactly up to rbp slot, without these members.
682 ALLOC_PT_GPREGS_ON_STACK -RBP
684 /* this goes to 0(%rsp) for unwinder, not for saving the value: */
685 SAVE_EXTRA_REGS_RBP -RBP
687 leaq -RBP(%rsp),%rdi /* arg1 for \func (pointer to pt_regs) */
689 testl $3, CS-RBP(%rsp)
694 * Save previous stack pointer, optionally switch to interrupt stack.
695 * irq_count is used to check if a CPU is already on an interrupt stack
696 * or not. While this is essentially redundant with preempt_count it is
697 * a little cheaper to use a separate counter in the PDA (short of
698 * moving irq_enter into assembly, which would be too much work)
701 incl PER_CPU_VAR(irq_count)
702 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
703 CFI_DEF_CFA_REGISTER rsi
707 * "CFA (Current Frame Address) is the value on stack + offset"
709 CFI_ESCAPE 0x0f /* DW_CFA_def_cfa_expression */, 6, \
710 0x77 /* DW_OP_breg7 (rsp) */, 0, \
711 0x06 /* DW_OP_deref */, \
712 0x08 /* DW_OP_const1u */, SIZEOF_PTREGS-RBP, \
713 0x22 /* DW_OP_plus */
714 /* We entered an interrupt context - irqs are off: */
721 * The interrupt stubs push (~vector+0x80) onto the stack and
722 * then jump to common_interrupt.
724 .p2align CONFIG_X86_L1_CACHE_SHIFT
728 addq $-0x80,(%rsp) /* Adjust vector to [-256,-1] range */
730 /* 0(%rsp): old RSP */
732 DISABLE_INTERRUPTS(CLBR_NONE)
734 decl PER_CPU_VAR(irq_count)
736 /* Restore saved previous stack */
738 CFI_DEF_CFA rsi,SIZEOF_PTREGS-RBP /* reg/off reset after def_cfa_expr */
739 /* return code expects complete pt_regs - adjust rsp accordingly: */
741 CFI_DEF_CFA_REGISTER rsp
742 CFI_ADJUST_CFA_OFFSET RBP
746 /* Interrupt came from user space */
748 GET_THREAD_INFO(%rcx)
750 * %rcx: thread info. Interrupts off.
752 retint_with_reschedule:
753 movl $_TIF_WORK_MASK,%edi
756 movl TI_flags(%rcx),%edx
761 retint_swapgs: /* return to user-space */
763 * The iretq could re-enable interrupts:
765 DISABLE_INTERRUPTS(CLBR_ANY)
769 jmp restore_c_regs_and_iret
771 /* Returning to kernel space */
773 #ifdef CONFIG_PREEMPT
774 /* Interrupts are off */
775 /* Check if we need preemption */
776 bt $9,EFLAGS(%rsp) /* interrupts were off? */
778 0: cmpl $0,PER_CPU_VAR(__preempt_count)
779 #ifndef CONFIG_PREEMPT_LAZY
782 jz do_preempt_schedule_irq
784 # atleast preempt count == 0 ?
785 cmpl $_PREEMPT_ENABLED,PER_CPU_VAR(__preempt_count)
788 GET_THREAD_INFO(%rcx)
789 cmpl $0, TI_preempt_lazy_count(%rcx)
792 bt $TIF_NEED_RESCHED_LAZY,TI_flags(%rcx)
794 do_preempt_schedule_irq:
796 call preempt_schedule_irq
801 * The iretq could re-enable interrupts:
806 * At this label, code paths which return to kernel and to user,
807 * which come from interrupts/exception and from syscalls, merge.
809 restore_c_regs_and_iret:
811 REMOVE_PT_GPREGS_FROM_STACK 8
818 * Are we returning to a stack segment from the LDT? Note: in
819 * 64-bit mode SS:RSP on the exception stack is always valid.
821 #ifdef CONFIG_X86_ESPFIX64
822 testb $4,(SS-RIP)(%rsp)
823 jnz native_irq_return_ldt
826 .global native_irq_return_iret
827 native_irq_return_iret:
829 * This may fault. Non-paranoid faults on return to userspace are
830 * handled by fixup_bad_iret. These include #SS, #GP, and #NP.
831 * Double-faults due to espfix64 are handled in do_double_fault.
832 * Other faults here are fatal.
836 #ifdef CONFIG_X86_ESPFIX64
837 native_irq_return_ldt:
841 movq PER_CPU_VAR(espfix_waddr),%rdi
842 movq %rax,(0*8)(%rdi) /* RAX */
843 movq (2*8)(%rsp),%rax /* RIP */
844 movq %rax,(1*8)(%rdi)
845 movq (3*8)(%rsp),%rax /* CS */
846 movq %rax,(2*8)(%rdi)
847 movq (4*8)(%rsp),%rax /* RFLAGS */
848 movq %rax,(3*8)(%rdi)
849 movq (6*8)(%rsp),%rax /* SS */
850 movq %rax,(5*8)(%rdi)
851 movq (5*8)(%rsp),%rax /* RSP */
852 movq %rax,(4*8)(%rdi)
853 andl $0xffff0000,%eax
855 orq PER_CPU_VAR(espfix_stack),%rax
859 jmp native_irq_return_iret
862 /* edi: workmask, edx: work */
865 testl $_TIF_NEED_RESCHED_MASK,%edx
868 ENABLE_INTERRUPTS(CLBR_NONE)
872 GET_THREAD_INFO(%rcx)
873 DISABLE_INTERRUPTS(CLBR_NONE)
878 testl $_TIF_DO_NOTIFY_MASK,%edx
881 ENABLE_INTERRUPTS(CLBR_NONE)
883 movq $-1,ORIG_RAX(%rsp)
884 xorl %esi,%esi # oldset
885 movq %rsp,%rdi # &pt_regs
886 call do_notify_resume
888 DISABLE_INTERRUPTS(CLBR_NONE)
890 GET_THREAD_INFO(%rcx)
891 jmp retint_with_reschedule
894 END(common_interrupt)
899 .macro apicinterrupt3 num sym do_sym
911 #ifdef CONFIG_TRACING
912 #define trace(sym) trace_##sym
913 #define smp_trace(sym) smp_trace_##sym
915 .macro trace_apicinterrupt num sym
916 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
919 .macro trace_apicinterrupt num sym do_sym
923 .macro apicinterrupt num sym do_sym
924 apicinterrupt3 \num \sym \do_sym
925 trace_apicinterrupt \num \sym
929 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
930 irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
931 apicinterrupt3 REBOOT_VECTOR \
932 reboot_interrupt smp_reboot_interrupt
936 apicinterrupt3 UV_BAU_MESSAGE \
937 uv_bau_message_intr1 uv_bau_message_interrupt
939 apicinterrupt LOCAL_TIMER_VECTOR \
940 apic_timer_interrupt smp_apic_timer_interrupt
941 apicinterrupt X86_PLATFORM_IPI_VECTOR \
942 x86_platform_ipi smp_x86_platform_ipi
944 #ifdef CONFIG_HAVE_KVM
945 apicinterrupt3 POSTED_INTR_VECTOR \
946 kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
949 #ifdef CONFIG_X86_MCE_THRESHOLD
950 apicinterrupt THRESHOLD_APIC_VECTOR \
951 threshold_interrupt smp_threshold_interrupt
954 #ifdef CONFIG_X86_THERMAL_VECTOR
955 apicinterrupt THERMAL_APIC_VECTOR \
956 thermal_interrupt smp_thermal_interrupt
960 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
961 call_function_single_interrupt smp_call_function_single_interrupt
962 apicinterrupt CALL_FUNCTION_VECTOR \
963 call_function_interrupt smp_call_function_interrupt
964 apicinterrupt RESCHEDULE_VECTOR \
965 reschedule_interrupt smp_reschedule_interrupt
968 apicinterrupt ERROR_APIC_VECTOR \
969 error_interrupt smp_error_interrupt
970 apicinterrupt SPURIOUS_APIC_VECTOR \
971 spurious_interrupt smp_spurious_interrupt
973 #ifdef CONFIG_IRQ_WORK
974 apicinterrupt IRQ_WORK_VECTOR \
975 irq_work_interrupt smp_irq_work_interrupt
979 * Exception entry points.
981 #define CPU_TSS_IST(x) PER_CPU_VAR(cpu_tss) + (TSS_ist + ((x) - 1) * 8)
983 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
986 .if \shift_ist != -1 && \paranoid == 0
987 .error "using shift_ist requires paranoid=1"
997 PARAVIRT_ADJUST_EXCEPTION_FRAME
999 .ifeq \has_error_code
1000 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1003 ALLOC_PT_GPREGS_ON_STACK
1008 testl $3, CS(%rsp) /* If coming from userspace, switch */
1009 jnz 1f /* stacks. */
1015 /* returned flag: ebx=0: need swapgs on exit, ebx=1: don't need it */
1020 .if \shift_ist != -1
1021 TRACE_IRQS_OFF_DEBUG /* reload IDT in case of recursion */
1027 movq %rsp,%rdi /* pt_regs pointer */
1030 movq ORIG_RAX(%rsp),%rsi /* get error code */
1031 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1033 xorl %esi,%esi /* no error code */
1036 .if \shift_ist != -1
1037 subq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
1042 .if \shift_ist != -1
1043 addq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
1046 /* these procedures expect "no swapgs" flag in ebx */
1056 * Paranoid entry from userspace. Switch stacks and treat it
1057 * as a normal entry. This means that paranoid handlers
1058 * run in real process context if user_mode(regs).
1065 movq %rsp,%rdi /* pt_regs pointer */
1067 movq %rax,%rsp /* switch stack */
1069 movq %rsp,%rdi /* pt_regs pointer */
1072 movq ORIG_RAX(%rsp),%rsi /* get error code */
1073 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1075 xorl %esi,%esi /* no error code */
1080 jmp error_exit /* %ebx: no swapgs flag */
1087 #ifdef CONFIG_TRACING
1088 .macro trace_idtentry sym do_sym has_error_code:req
1089 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
1090 idtentry \sym \do_sym has_error_code=\has_error_code
1093 .macro trace_idtentry sym do_sym has_error_code:req
1094 idtentry \sym \do_sym has_error_code=\has_error_code
1098 idtentry divide_error do_divide_error has_error_code=0
1099 idtentry overflow do_overflow has_error_code=0
1100 idtentry bounds do_bounds has_error_code=0
1101 idtentry invalid_op do_invalid_op has_error_code=0
1102 idtentry device_not_available do_device_not_available has_error_code=0
1103 idtentry double_fault do_double_fault has_error_code=1 paranoid=2
1104 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
1105 idtentry invalid_TSS do_invalid_TSS has_error_code=1
1106 idtentry segment_not_present do_segment_not_present has_error_code=1
1107 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
1108 idtentry coprocessor_error do_coprocessor_error has_error_code=0
1109 idtentry alignment_check do_alignment_check has_error_code=1
1110 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
1113 /* Reload gs selector with exception handling */
1114 /* edi: new selector */
1115 ENTRY(native_load_gs_index)
1118 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1122 2: mfence /* workaround */
1127 END(native_load_gs_index)
1129 _ASM_EXTABLE(gs_change,bad_gs)
1130 .section .fixup,"ax"
1131 /* running with kernelgs */
1133 SWAPGS /* switch back to user gs */
1139 #ifndef CONFIG_PREEMPT_RT_FULL
1140 /* Call softirq on interrupt stack. Interrupts are off. */
1141 ENTRY(do_softirq_own_stack)
1144 CFI_REL_OFFSET rbp,0
1146 CFI_DEF_CFA_REGISTER rbp
1147 incl PER_CPU_VAR(irq_count)
1148 cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1149 push %rbp # backlink for old unwinder
1153 CFI_DEF_CFA_REGISTER rsp
1154 CFI_ADJUST_CFA_OFFSET -8
1155 decl PER_CPU_VAR(irq_count)
1158 END(do_softirq_own_stack)
1162 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
1165 * A note on the "critical region" in our callback handler.
1166 * We want to avoid stacking callback handlers due to events occurring
1167 * during handling of the last event. To do this, we keep events disabled
1168 * until we've done all processing. HOWEVER, we must enable events before
1169 * popping the stack frame (can't be done atomically) and so it would still
1170 * be possible to get enough handler activations to overflow the stack.
1171 * Although unlikely, bugs of that kind are hard to track down, so we'd
1172 * like to avoid the possibility.
1173 * So, on entry to the handler we detect whether we interrupted an
1174 * existing activation in its critical region -- if so, we pop the current
1175 * activation and restart the handler using the previous one.
1177 ENTRY(xen_do_hypervisor_callback) # do_hypervisor_callback(struct *pt_regs)
1180 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1181 * see the correct pointer to the pt_regs
1183 movq %rdi, %rsp # we don't return, adjust the stack frame
1186 11: incl PER_CPU_VAR(irq_count)
1188 CFI_DEF_CFA_REGISTER rbp
1189 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1190 pushq %rbp # backlink for old unwinder
1191 call xen_evtchn_do_upcall
1193 CFI_DEF_CFA_REGISTER rsp
1194 decl PER_CPU_VAR(irq_count)
1195 #ifndef CONFIG_PREEMPT
1196 call xen_maybe_preempt_hcall
1200 END(xen_do_hypervisor_callback)
1203 * Hypervisor uses this for application faults while it executes.
1204 * We get here for two reasons:
1205 * 1. Fault while reloading DS, ES, FS or GS
1206 * 2. Fault while executing IRET
1207 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1208 * registers that could be reloaded and zeroed the others.
1209 * Category 2 we fix up by killing the current process. We cannot use the
1210 * normal Linux return path in this case because if we use the IRET hypercall
1211 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1212 * We distinguish between categories by comparing each saved segment register
1213 * with its current contents: any discrepancy means we in category 1.
1215 ENTRY(xen_failsafe_callback)
1217 /*CFI_REL_OFFSET gs,GS*/
1218 /*CFI_REL_OFFSET fs,FS*/
1219 /*CFI_REL_OFFSET es,ES*/
1220 /*CFI_REL_OFFSET ds,DS*/
1221 CFI_REL_OFFSET r11,8
1222 CFI_REL_OFFSET rcx,0
1236 /* All segments match their saved values => Category 2 (Bad IRET). */
1242 CFI_ADJUST_CFA_OFFSET -0x30
1243 pushq_cfi $0 /* RIP */
1246 jmp general_protection
1248 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1254 CFI_ADJUST_CFA_OFFSET -0x30
1255 pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1256 ALLOC_PT_GPREGS_ON_STACK
1261 END(xen_failsafe_callback)
1263 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1264 xen_hvm_callback_vector xen_evtchn_do_upcall
1266 #endif /* CONFIG_XEN */
1268 #if IS_ENABLED(CONFIG_HYPERV)
1269 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1270 hyperv_callback_vector hyperv_vector_handler
1271 #endif /* CONFIG_HYPERV */
1273 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1274 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1275 idtentry stack_segment do_stack_segment has_error_code=1
1277 idtentry xen_debug do_debug has_error_code=0
1278 idtentry xen_int3 do_int3 has_error_code=0
1279 idtentry xen_stack_segment do_stack_segment has_error_code=1
1281 idtentry general_protection do_general_protection has_error_code=1
1282 trace_idtentry page_fault do_page_fault has_error_code=1
1283 #ifdef CONFIG_KVM_GUEST
1284 idtentry async_page_fault do_async_page_fault has_error_code=1
1286 #ifdef CONFIG_X86_MCE
1287 idtentry machine_check has_error_code=0 paranoid=1 do_sym=*machine_check_vector(%rip)
1291 * Save all registers in pt_regs, and switch gs if needed.
1292 * Use slow, but surefire "are we in kernel?" check.
1293 * Return: ebx=0: need swapgs on exit, ebx=1: otherwise
1295 ENTRY(paranoid_entry)
1301 movl $MSR_GS_BASE,%ecx
1304 js 1f /* negative -> in kernel */
1312 * "Paranoid" exit path from exception stack. This is invoked
1313 * only on return from non-NMI IST interrupts that came
1314 * from kernel space.
1316 * We may be returning to very strange contexts (e.g. very early
1317 * in syscall entry), so checking for preemption here would
1318 * be complicated. Fortunately, we there's no good reason
1319 * to try to handle preemption here.
1321 /* On entry, ebx is "no swapgs" flag (1: don't need swapgs, 0: need it) */
1322 ENTRY(paranoid_exit)
1324 DISABLE_INTERRUPTS(CLBR_NONE)
1325 TRACE_IRQS_OFF_DEBUG
1326 testl %ebx,%ebx /* swapgs needed? */
1327 jnz paranoid_exit_no_swapgs
1330 jmp paranoid_exit_restore
1331 paranoid_exit_no_swapgs:
1332 TRACE_IRQS_IRETQ_DEBUG
1333 paranoid_exit_restore:
1336 REMOVE_PT_GPREGS_FROM_STACK 8
1342 * Save all registers in pt_regs, and switch gs if needed.
1343 * Return: ebx=0: need swapgs on exit, ebx=1: otherwise
1352 je error_kernelspace
1360 * There are two places in the kernel that can potentially fault with
1361 * usergs. Handle them here. B stepping K8s sometimes report a
1362 * truncated RIP for IRET exceptions returning to compat mode. Check
1363 * for these here too.
1366 CFI_REL_OFFSET rcx, RCX+8
1368 leaq native_irq_return_iret(%rip),%rcx
1369 cmpq %rcx,RIP+8(%rsp)
1371 movl %ecx,%eax /* zero extend */
1372 cmpq %rax,RIP+8(%rsp)
1374 cmpq $gs_change,RIP+8(%rsp)
1379 /* Fix truncated RIP */
1380 movq %rcx,RIP+8(%rsp)
1388 decl %ebx /* Return to usergs */
1394 /* On entry, ebx is "no swapgs" flag (1: don't need swapgs, 0: need it) */
1399 DISABLE_INTERRUPTS(CLBR_NONE)
1401 GET_THREAD_INFO(%rcx)
1404 LOCKDEP_SYS_EXIT_IRQ
1405 movl TI_flags(%rcx),%edx
1406 movl $_TIF_WORK_MASK,%edi
1413 /* Runs on exception stack */
1416 PARAVIRT_ADJUST_EXCEPTION_FRAME
1418 * We allow breakpoints in NMIs. If a breakpoint occurs, then
1419 * the iretq it performs will take us out of NMI context.
1420 * This means that we can have nested NMIs where the next
1421 * NMI is using the top of the stack of the previous NMI. We
1422 * can't let it execute because the nested NMI will corrupt the
1423 * stack of the previous NMI. NMI handlers are not re-entrant
1426 * To handle this case we do the following:
1427 * Check the a special location on the stack that contains
1428 * a variable that is set when NMIs are executing.
1429 * The interrupted task's stack is also checked to see if it
1431 * If the variable is not set and the stack is not the NMI
1433 * o Set the special variable on the stack
1434 * o Copy the interrupt frame into a "saved" location on the stack
1435 * o Copy the interrupt frame into a "copy" location on the stack
1436 * o Continue processing the NMI
1437 * If the variable is set or the previous stack is the NMI stack:
1438 * o Modify the "copy" location to jump to the repeate_nmi
1439 * o return back to the first NMI
1441 * Now on exit of the first NMI, we first clear the stack variable
1442 * The NMI stack will tell any nested NMIs at that point that it is
1443 * nested. Then we pop the stack normally with iret, and if there was
1444 * a nested NMI that updated the copy interrupt stack frame, a
1445 * jump will be made to the repeat_nmi code that will handle the second
1449 /* Use %rdx as our temp variable throughout */
1451 CFI_REL_OFFSET rdx, 0
1454 * If %cs was not the kernel segment, then the NMI triggered in user
1455 * space, which means it is definitely not nested.
1457 cmpl $__KERNEL_CS, 16(%rsp)
1461 * Check the special variable on the stack to see if NMIs are
1468 * Now test if the previous stack was an NMI stack.
1469 * We need the double check. We check the NMI stack to satisfy the
1470 * race when the first NMI clears the variable before returning.
1471 * We check the variable because the first NMI could be in a
1472 * breakpoint routine using a breakpoint stack.
1475 /* Compare the NMI stack (rdx) with the stack we came from (4*8(%rsp)) */
1476 cmpq %rdx, 4*8(%rsp)
1477 /* If the stack pointer is above the NMI stack, this is a normal NMI */
1479 subq $EXCEPTION_STKSZ, %rdx
1480 cmpq %rdx, 4*8(%rsp)
1481 /* If it is below the NMI stack, it is a normal NMI */
1483 /* Ah, it is within the NMI stack, treat it as nested */
1489 * Do nothing if we interrupted the fixup in repeat_nmi.
1490 * It's about to repeat the NMI handler, so we are fine
1491 * with ignoring this one.
1493 movq $repeat_nmi, %rdx
1496 movq $end_repeat_nmi, %rdx
1501 /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1502 leaq -1*8(%rsp), %rdx
1504 CFI_ADJUST_CFA_OFFSET 1*8
1505 leaq -10*8(%rsp), %rdx
1506 pushq_cfi $__KERNEL_DS
1509 pushq_cfi $__KERNEL_CS
1510 pushq_cfi $repeat_nmi
1512 /* Put stack back */
1514 CFI_ADJUST_CFA_OFFSET -6*8
1520 /* No need to check faults here */
1526 * Because nested NMIs will use the pushed location that we
1527 * stored in rdx, we must keep that space available.
1528 * Here's what our stack frame will look like:
1529 * +-------------------------+
1531 * | original Return RSP |
1532 * | original RFLAGS |
1535 * +-------------------------+
1536 * | temp storage for rdx |
1537 * +-------------------------+
1538 * | NMI executing variable |
1539 * +-------------------------+
1541 * | copied Return RSP |
1545 * +-------------------------+
1547 * | Saved Return RSP |
1551 * +-------------------------+
1553 * +-------------------------+
1555 * The saved stack frame is used to fix up the copied stack frame
1556 * that a nested NMI may change to make the interrupted NMI iret jump
1557 * to the repeat_nmi. The original stack frame and the temp storage
1558 * is also used by nested NMIs and can not be trusted on exit.
1560 /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1564 /* Set the NMI executing variable on the stack. */
1568 * Leave room for the "copied" frame
1571 CFI_ADJUST_CFA_OFFSET 5*8
1573 /* Copy the stack frame to the Saved frame */
1575 pushq_cfi 11*8(%rsp)
1577 CFI_DEF_CFA_OFFSET 5*8
1579 /* Everything up to here is safe from nested NMIs */
1582 * If there was a nested NMI, the first NMI's iret will return
1583 * here. But NMIs are still enabled and we can take another
1584 * nested NMI. The nested NMI checks the interrupted RIP to see
1585 * if it is between repeat_nmi and end_repeat_nmi, and if so
1586 * it will just return, as we are about to repeat an NMI anyway.
1587 * This makes it safe to copy to the stack frame that a nested
1592 * Update the stack variable to say we are still in NMI (the update
1593 * is benign for the non-repeat case, where 1 was pushed just above
1594 * to this very stack slot).
1598 /* Make another copy, this one may be modified by nested NMIs */
1600 CFI_ADJUST_CFA_OFFSET -10*8
1602 pushq_cfi -6*8(%rsp)
1605 CFI_DEF_CFA_OFFSET 5*8
1609 * Everything below this point can be preempted by a nested
1610 * NMI if the first NMI took an exception and reset our iret stack
1611 * so that we repeat another NMI.
1613 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1614 ALLOC_PT_GPREGS_ON_STACK
1617 * Use paranoid_entry to handle SWAPGS, but no need to use paranoid_exit
1618 * as we should not be calling schedule in NMI context.
1619 * Even with normal interrupts enabled. An NMI should not be
1620 * setting NEED_RESCHED or anything that normal interrupts and
1621 * exceptions might do.
1627 * Save off the CR2 register. If we take a page fault in the NMI then
1628 * it could corrupt the CR2 value. If the NMI preempts a page fault
1629 * handler before it was able to read the CR2 register, and then the
1630 * NMI itself takes a page fault, the page fault that was preempted
1631 * will read the information from the NMI page fault and not the
1632 * origin fault. Save it off and restore it if it changes.
1633 * Use the r12 callee-saved register.
1637 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1642 /* Did the NMI take a page fault? Restore cr2 if it did */
1649 testl %ebx,%ebx /* swapgs needed? */
1656 /* Pop the extra iret frame at once */
1657 REMOVE_PT_GPREGS_FROM_STACK 6*8
1659 /* Clear the NMI executing stack variable */
1665 ENTRY(ignore_sysret)