kernel/arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Return to user mode is not as complex as all this looks,
 319  * but we want the default path for a system call return to
 320  * go as quickly as possible which is why some of this is
 321  * less clear than it otherwise should be.
 322  */
 323
 324         # userspace resumption stub bypassing syscall exit tracing
 325         ALIGN
 326         RING0_PTREGS_FRAME
 327 ret_from_exception:
 328         preempt_stop(CLBR_ANY)
 329 ret_from_intr:
 330         GET_THREAD_INFO(%ebp)
 331 #ifdef CONFIG_VM86
 332         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 333         movb PT_CS(%esp), %al
 334         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 335 #else
 336         /*
 337          * We can be coming here from child spawned by kernel_thread().
 338          */
 339         movl PT_CS(%esp), %eax
 340         andl $SEGMENT_RPL_MASK, %eax
 341 #endif
 342         cmpl $USER_RPL, %eax
 343         jb resume_kernel                # not returning to v8086 or userspace
 344
 345 ENTRY(resume_userspace)
 346         LOCKDEP_SYS_EXIT
 347         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 348                                         # setting need_resched or sigpending
 349                                         # between sampling and the iret
 350         TRACE_IRQS_OFF
 351         movl TI_flags(%ebp), %ecx
 352         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 353                                         # int/exception return?
 354         jne work_pending
 355         jmp restore_all
 356 END(ret_from_exception)
 357
 358 #ifdef CONFIG_PREEMPT
 359 ENTRY(resume_kernel)
 360         DISABLE_INTERRUPTS(CLBR_ANY)
 361 need_resched:
 362         # preempt count == 0 + NEED_RS set?
 363         cmpl $0,PER_CPU_VAR(__preempt_count)
 364 #ifndef CONFIG_PREEMPT_LAZY
 365         jnz restore_all
 366 #else
 367         jz test_int_off
 368
 369         # atleast preempt count == 0 ?
 370         cmpl $_PREEMPT_ENABLED,PER_CPU_VAR(__preempt_count)
 371         jne restore_all
 372
 373         cmpl $0,TI_preempt_lazy_count(%ebp)     # non-zero preempt_lazy_count ?
 374         jnz restore_all
 375
 376         testl $_TIF_NEED_RESCHED_LAZY, TI_flags(%ebp)
 377         jz restore_all
 378 test_int_off:
 379 #endif
 380         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 381         jz restore_all
 382         call preempt_schedule_irq
 383         jmp need_resched
 384 END(resume_kernel)
 385 #endif
 386         CFI_ENDPROC
 387
 388 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 389    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 390
 391         # sysenter call handler stub
 392 ENTRY(ia32_sysenter_target)
 393         CFI_STARTPROC simple
 394         CFI_SIGNAL_FRAME
 395         CFI_DEF_CFA esp, 0
 396         CFI_REGISTER esp, ebp
 397         movl TSS_sysenter_sp0(%esp),%esp
 398 sysenter_past_esp:
 399         /*
 400          * Interrupts are disabled here, but we can't trace it until
 401          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 402          * we immediately enable interrupts at that point anyway.
 403          */
 404         pushl_cfi $__USER_DS
 405         /*CFI_REL_OFFSET ss, 0*/
 406         pushl_cfi %ebp
 407         CFI_REL_OFFSET esp, 0
 408         pushfl_cfi
 409         orl $X86_EFLAGS_IF, (%esp)
 410         pushl_cfi $__USER_CS
 411         /*CFI_REL_OFFSET cs, 0*/
 412         /*
 413          * Push current_thread_info()->sysenter_return to the stack.
 414          * A tiny bit of offset fixup is necessary: TI_sysenter_return
 415          * is relative to thread_info, which is at the bottom of the
 416          * kernel stack page.  4*4 means the 4 words pushed above;
 417          * TOP_OF_KERNEL_STACK_PADDING takes us to the top of the stack;
 418          * and THREAD_SIZE takes us to the bottom.
 419          */
 420         pushl_cfi ((TI_sysenter_return) - THREAD_SIZE + TOP_OF_KERNEL_STACK_PADDING + 4*4)(%esp)
 421         CFI_REL_OFFSET eip, 0
 422
 423         pushl_cfi %eax
 424         SAVE_ALL
 425         ENABLE_INTERRUPTS(CLBR_NONE)
 426
 427 /*
 428  * Load the potential sixth argument from user stack.
 429  * Careful about security.
 430  */
 431         cmpl $__PAGE_OFFSET-3,%ebp
 432         jae syscall_fault
 433         ASM_STAC
 434 1:      movl (%ebp),%ebp
 435         ASM_CLAC
 436         movl %ebp,PT_EBP(%esp)
 437         _ASM_EXTABLE(1b,syscall_fault)
 438
 439         GET_THREAD_INFO(%ebp)
 440
 441         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 442         jnz sysenter_audit
 443 sysenter_do_call:
 444         cmpl $(NR_syscalls), %eax
 445         jae sysenter_badsys
 446         call *sys_call_table(,%eax,4)
 447 sysenter_after_call:
 448         movl %eax,PT_EAX(%esp)
 449         LOCKDEP_SYS_EXIT
 450         DISABLE_INTERRUPTS(CLBR_ANY)
 451         TRACE_IRQS_OFF
 452         movl TI_flags(%ebp), %ecx
 453         testl $_TIF_ALLWORK_MASK, %ecx
 454         jnz sysexit_audit
 455 sysenter_exit:
 456 /* if something modifies registers it must also disable sysexit */
 457         movl PT_EIP(%esp), %edx
 458         movl PT_OLDESP(%esp), %ecx
 459         xorl %ebp,%ebp
 460         TRACE_IRQS_ON
 461 1:      mov  PT_FS(%esp), %fs
 462         PTGS_TO_GS
 463         ENABLE_INTERRUPTS_SYSEXIT
 464
 465 #ifdef CONFIG_AUDITSYSCALL
 466 sysenter_audit:
 467         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 468         jnz syscall_trace_entry
 469         /* movl PT_EAX(%esp), %eax      already set, syscall number: 1st arg to audit */
 470         movl PT_EBX(%esp), %edx         /* ebx/a0: 2nd arg to audit */
 471         /* movl PT_ECX(%esp), %ecx      already set, a1: 3nd arg to audit */
 472         pushl_cfi PT_ESI(%esp)          /* a3: 5th arg */
 473         pushl_cfi PT_EDX+4(%esp)        /* a2: 4th arg */
 474         call __audit_syscall_entry
 475         popl_cfi %ecx /* get that remapped edx off the stack */
 476         popl_cfi %ecx /* get that remapped esi off the stack */
 477         movl PT_EAX(%esp),%eax          /* reload syscall number */
 478         jmp sysenter_do_call
 479
 480 sysexit_audit:
 481         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 482         jnz syscall_exit_work
 483         TRACE_IRQS_ON
 484         ENABLE_INTERRUPTS(CLBR_ANY)
 485         movl %eax,%edx          /* second arg, syscall return value */
 486         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 487         setbe %al               /* 1 if so, 0 if not */
 488         movzbl %al,%eax         /* zero-extend that */
 489         call __audit_syscall_exit
 490         DISABLE_INTERRUPTS(CLBR_ANY)
 491         TRACE_IRQS_OFF
 492         movl TI_flags(%ebp), %ecx
 493         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 494         jnz syscall_exit_work
 495         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 496         jmp sysenter_exit
 497 #endif
 498
 499         CFI_ENDPROC
 500 .pushsection .fixup,"ax"
 501 2:      movl $0,PT_FS(%esp)
 502         jmp 1b
 503 .popsection
 504         _ASM_EXTABLE(1b,2b)
 505         PTGS_TO_GS_EX
 506 ENDPROC(ia32_sysenter_target)
 507
 508         # system call handler stub
 509 ENTRY(system_call)
 510         RING0_INT_FRAME                 # can't unwind into user space anyway
 511         ASM_CLAC
 512         pushl_cfi %eax                  # save orig_eax
 513         SAVE_ALL
 514         GET_THREAD_INFO(%ebp)
 515                                         # system call tracing in operation / emulation
 516         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 517         jnz syscall_trace_entry
 518         cmpl $(NR_syscalls), %eax
 519         jae syscall_badsys
 520 syscall_call:
 521         call *sys_call_table(,%eax,4)
 522 syscall_after_call:
 523         movl %eax,PT_EAX(%esp)          # store the return value
 524 syscall_exit:
 525         LOCKDEP_SYS_EXIT
 526         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 527                                         # setting need_resched or sigpending
 528                                         # between sampling and the iret
 529         TRACE_IRQS_OFF
 530         movl TI_flags(%ebp), %ecx
 531         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 532         jnz syscall_exit_work
 533
 534 restore_all:
 535         TRACE_IRQS_IRET
 536 restore_all_notrace:
 537 #ifdef CONFIG_X86_ESPFIX32
 538         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 539         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 540         # are returning to the kernel.
 541         # See comments in process.c:copy_thread() for details.
 542         movb PT_OLDSS(%esp), %ah
 543         movb PT_CS(%esp), %al
 544         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 545         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 546         CFI_REMEMBER_STATE
 547         je ldt_ss                       # returning to user-space with LDT SS
 548 #endif
 549 restore_nocheck:
 550         RESTORE_REGS 4                  # skip orig_eax/error_code
 551 irq_return:
 552         INTERRUPT_RETURN
 553 .section .fixup,"ax"
 554 ENTRY(iret_exc)
 555         pushl $0                        # no error code
 556         pushl $do_iret_error
 557         jmp error_code
 558 .previous
 559         _ASM_EXTABLE(irq_return,iret_exc)
 560
 561 #ifdef CONFIG_X86_ESPFIX32
 562         CFI_RESTORE_STATE
 563 ldt_ss:
 564 #ifdef CONFIG_PARAVIRT
 565         /*
 566          * The kernel can't run on a non-flat stack if paravirt mode
 567          * is active.  Rather than try to fixup the high bits of
 568          * ESP, bypass this code entirely.  This may break DOSemu
 569          * and/or Wine support in a paravirt VM, although the option
 570          * is still available to implement the setting of the high
 571          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 572          */
 573         cmpl $0, pv_info+PARAVIRT_enabled
 574         jne restore_nocheck
 575 #endif
 576
 577 /*
 578  * Setup and switch to ESPFIX stack
 579  *
 580  * We're returning to userspace with a 16 bit stack. The CPU will not
 581  * restore the high word of ESP for us on executing iret... This is an
 582  * "official" bug of all the x86-compatible CPUs, which we can work
 583  * around to make dosemu and wine happy. We do this by preloading the
 584  * high word of ESP with the high word of the userspace ESP while
 585  * compensating for the offset by changing to the ESPFIX segment with
 586  * a base address that matches for the difference.
 587  */
 588 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 589         mov %esp, %edx                  /* load kernel esp */
 590         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 591         mov %dx, %ax                    /* eax: new kernel esp */
 592         sub %eax, %edx                  /* offset (low word is 0) */
 593         shr $16, %edx
 594         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 595         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 596         pushl_cfi $__ESPFIX_SS
 597         pushl_cfi %eax                  /* new kernel esp */
 598         /* Disable interrupts, but do not irqtrace this section: we
 599          * will soon execute iret and the tracer was already set to
 600          * the irqstate after the iret */
 601         DISABLE_INTERRUPTS(CLBR_EAX)
 602         lss (%esp), %esp                /* switch to espfix segment */
 603         CFI_ADJUST_CFA_OFFSET -8
 604         jmp restore_nocheck
 605 #endif
 606         CFI_ENDPROC
 607 ENDPROC(system_call)
 608
 609         # perform work that needs to be done immediately before resumption
 610         ALIGN
 611         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 612 work_pending:
 613         testl $_TIF_NEED_RESCHED_MASK, %ecx
 614         jz work_notifysig
 615 work_resched:
 616         call schedule
 617         LOCKDEP_SYS_EXIT
 618         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 619                                         # setting need_resched or sigpending
 620                                         # between sampling and the iret
 621         TRACE_IRQS_OFF
 622         movl TI_flags(%ebp), %ecx
 623         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 624                                         # than syscall tracing?
 625         jz restore_all
 626         testl $_TIF_NEED_RESCHED_MASK, %ecx
 627         jnz work_resched
 628
 629 work_notifysig:                         # deal with pending signals and
 630                                         # notify-resume requests
 631 #ifdef CONFIG_VM86
 632         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 633         movl %esp, %eax
 634         jnz work_notifysig_v86          # returning to kernel-space or
 635                                         # vm86-space
 636 1:
 637 #else
 638         movl %esp, %eax
 639 #endif
 640         TRACE_IRQS_ON
 641         ENABLE_INTERRUPTS(CLBR_NONE)
 642         movb PT_CS(%esp), %bl
 643         andb $SEGMENT_RPL_MASK, %bl
 644         cmpb $USER_RPL, %bl
 645         jb resume_kernel
 646         xorl %edx, %edx
 647         call do_notify_resume
 648         jmp resume_userspace
 649
 650 #ifdef CONFIG_VM86
 651         ALIGN
 652 work_notifysig_v86:
 653         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 654         call save_v86_state             # %eax contains pt_regs pointer
 655         popl_cfi %ecx
 656         movl %eax, %esp
 657         jmp 1b
 658 #endif
 659 END(work_pending)
 660
 661         # perform syscall exit tracing
 662         ALIGN
 663 syscall_trace_entry:
 664         movl $-ENOSYS,PT_EAX(%esp)
 665         movl %esp, %eax
 666         call syscall_trace_enter
 667         /* What it returned is what we'll actually use.  */
 668         cmpl $(NR_syscalls), %eax
 669         jnae syscall_call
 670         jmp syscall_exit
 671 END(syscall_trace_entry)
 672
 673         # perform syscall exit tracing
 674         ALIGN
 675 syscall_exit_work:
 676         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 677         jz work_pending
 678         TRACE_IRQS_ON
 679         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 680                                         # schedule() instead
 681         movl %esp, %eax
 682         call syscall_trace_leave
 683         jmp resume_userspace
 684 END(syscall_exit_work)
 685         CFI_ENDPROC
 686
 687         RING0_INT_FRAME                 # can't unwind into user space anyway
 688 syscall_fault:
 689         ASM_CLAC
 690         GET_THREAD_INFO(%ebp)
 691         movl $-EFAULT,PT_EAX(%esp)
 692         jmp resume_userspace
 693 END(syscall_fault)
 694
 695 syscall_badsys:
 696         movl $-ENOSYS,%eax
 697         jmp syscall_after_call
 698 END(syscall_badsys)
 699
 700 sysenter_badsys:
 701         movl $-ENOSYS,%eax
 702         jmp sysenter_after_call
 703 END(sysenter_badsys)
 704         CFI_ENDPROC
 705
 706 .macro FIXUP_ESPFIX_STACK
 707 /*
 708  * Switch back for ESPFIX stack to the normal zerobased stack
 709  *
 710  * We can't call C functions using the ESPFIX stack. This code reads
 711  * the high word of the segment base from the GDT and swiches to the
 712  * normal stack and adjusts ESP with the matching offset.
 713  */
 714 #ifdef CONFIG_X86_ESPFIX32
 715         /* fixup the stack */
 716         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 717         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 718         shl $16, %eax
 719         addl %esp, %eax                 /* the adjusted stack pointer */
 720         pushl_cfi $__KERNEL_DS
 721         pushl_cfi %eax
 722         lss (%esp), %esp                /* switch to the normal stack segment */
 723         CFI_ADJUST_CFA_OFFSET -8
 724 #endif
 725 .endm
 726 .macro UNWIND_ESPFIX_STACK
 727 #ifdef CONFIG_X86_ESPFIX32
 728         movl %ss, %eax
 729         /* see if on espfix stack */
 730         cmpw $__ESPFIX_SS, %ax
 731         jne 27f
 732         movl $__KERNEL_DS, %eax
 733         movl %eax, %ds
 734         movl %eax, %es
 735         /* switch to normal stack */
 736         FIXUP_ESPFIX_STACK
 737 27:
 738 #endif
 739 .endm
 740
 741 /*
 742  * Build the entry stubs with some assembler magic.
 743  * We pack 1 stub into every 8-byte block.
 744  */
 745         .align 8
 746 ENTRY(irq_entries_start)
 747         RING0_INT_FRAME
 748     vector=FIRST_EXTERNAL_VECTOR
 749     .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
 750         pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 751     vector=vector+1
 752         jmp     common_interrupt
 753         CFI_ADJUST_CFA_OFFSET -4
 754         .align  8
 755     .endr
 756 END(irq_entries_start)
 757
 758 /*
 759  * the CPU automatically disables interrupts when executing an IRQ vector,
 760  * so IRQ-flags tracing has to follow that:
 761  */
 762         .p2align CONFIG_X86_L1_CACHE_SHIFT
 763 common_interrupt:
 764         ASM_CLAC
 765         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 766         SAVE_ALL
 767         TRACE_IRQS_OFF
 768         movl %esp,%eax
 769         call do_IRQ
 770         jmp ret_from_intr
 771 ENDPROC(common_interrupt)
 772         CFI_ENDPROC
 773
 774 #define BUILD_INTERRUPT3(name, nr, fn)  \
 775 ENTRY(name)                             \
 776         RING0_INT_FRAME;                \
 777         ASM_CLAC;                       \
 778         pushl_cfi $~(nr);               \
 779         SAVE_ALL;                       \
 780         TRACE_IRQS_OFF                  \
 781         movl %esp,%eax;                 \
 782         call fn;                        \
 783         jmp ret_from_intr;              \
 784         CFI_ENDPROC;                    \
 785 ENDPROC(name)
 786
 787
 788 #ifdef CONFIG_TRACING
 789 #define TRACE_BUILD_INTERRUPT(name, nr)         \
 790         BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
 791 #else
 792 #define TRACE_BUILD_INTERRUPT(name, nr)
 793 #endif
 794
 795 #define BUILD_INTERRUPT(name, nr) \
 796         BUILD_INTERRUPT3(name, nr, smp_##name); \
 797         TRACE_BUILD_INTERRUPT(name, nr)
 798
 799 /* The include is where all of the SMP etc. interrupts come from */
 800 #include <asm/entry_arch.h>
 801
 802 ENTRY(coprocessor_error)
 803         RING0_INT_FRAME
 804         ASM_CLAC
 805         pushl_cfi $0
 806         pushl_cfi $do_coprocessor_error
 807         jmp error_code
 808         CFI_ENDPROC
 809 END(coprocessor_error)
 810
 811 ENTRY(simd_coprocessor_error)
 812         RING0_INT_FRAME
 813         ASM_CLAC
 814         pushl_cfi $0
 815 #ifdef CONFIG_X86_INVD_BUG
 816         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 817         ALTERNATIVE "pushl_cfi $do_general_protection", \
 818                     "pushl $do_simd_coprocessor_error", \
 819                     X86_FEATURE_XMM
 820 #else
 821         pushl_cfi $do_simd_coprocessor_error
 822 #endif
 823         jmp error_code
 824         CFI_ENDPROC
 825 END(simd_coprocessor_error)
 826
 827 ENTRY(device_not_available)
 828         RING0_INT_FRAME
 829         ASM_CLAC
 830         pushl_cfi $-1                   # mark this as an int
 831         pushl_cfi $do_device_not_available
 832         jmp error_code
 833         CFI_ENDPROC
 834 END(device_not_available)
 835
 836 #ifdef CONFIG_PARAVIRT
 837 ENTRY(native_iret)
 838         iret
 839         _ASM_EXTABLE(native_iret, iret_exc)
 840 END(native_iret)
 841
 842 ENTRY(native_irq_enable_sysexit)
 843         sti
 844         sysexit
 845 END(native_irq_enable_sysexit)
 846 #endif
 847
 848 ENTRY(overflow)
 849         RING0_INT_FRAME
 850         ASM_CLAC
 851         pushl_cfi $0
 852         pushl_cfi $do_overflow
 853         jmp error_code
 854         CFI_ENDPROC
 855 END(overflow)
 856
 857 ENTRY(bounds)
 858         RING0_INT_FRAME
 859         ASM_CLAC
 860         pushl_cfi $0
 861         pushl_cfi $do_bounds
 862         jmp error_code
 863         CFI_ENDPROC
 864 END(bounds)
 865
 866 ENTRY(invalid_op)
 867         RING0_INT_FRAME
 868         ASM_CLAC
 869         pushl_cfi $0
 870         pushl_cfi $do_invalid_op
 871         jmp error_code
 872         CFI_ENDPROC
 873 END(invalid_op)
 874
 875 ENTRY(coprocessor_segment_overrun)
 876         RING0_INT_FRAME
 877         ASM_CLAC
 878         pushl_cfi $0
 879         pushl_cfi $do_coprocessor_segment_overrun
 880         jmp error_code
 881         CFI_ENDPROC
 882 END(coprocessor_segment_overrun)
 883
 884 ENTRY(invalid_TSS)
 885         RING0_EC_FRAME
 886         ASM_CLAC
 887         pushl_cfi $do_invalid_TSS
 888         jmp error_code
 889         CFI_ENDPROC
 890 END(invalid_TSS)
 891
 892 ENTRY(segment_not_present)
 893         RING0_EC_FRAME
 894         ASM_CLAC
 895         pushl_cfi $do_segment_not_present
 896         jmp error_code
 897         CFI_ENDPROC
 898 END(segment_not_present)
 899
 900 ENTRY(stack_segment)
 901         RING0_EC_FRAME
 902         ASM_CLAC
 903         pushl_cfi $do_stack_segment
 904         jmp error_code
 905         CFI_ENDPROC
 906 END(stack_segment)
 907
 908 ENTRY(alignment_check)
 909         RING0_EC_FRAME
 910         ASM_CLAC
 911         pushl_cfi $do_alignment_check
 912         jmp error_code
 913         CFI_ENDPROC
 914 END(alignment_check)
 915
 916 ENTRY(divide_error)
 917         RING0_INT_FRAME
 918         ASM_CLAC
 919         pushl_cfi $0                    # no error code
 920         pushl_cfi $do_divide_error
 921         jmp error_code
 922         CFI_ENDPROC
 923 END(divide_error)
 924
 925 #ifdef CONFIG_X86_MCE
 926 ENTRY(machine_check)
 927         RING0_INT_FRAME
 928         ASM_CLAC
 929         pushl_cfi $0
 930         pushl_cfi machine_check_vector
 931         jmp error_code
 932         CFI_ENDPROC
 933 END(machine_check)
 934 #endif
 935
 936 ENTRY(spurious_interrupt_bug)
 937         RING0_INT_FRAME
 938         ASM_CLAC
 939         pushl_cfi $0
 940         pushl_cfi $do_spurious_interrupt_bug
 941         jmp error_code
 942         CFI_ENDPROC
 943 END(spurious_interrupt_bug)
 944
 945 #ifdef CONFIG_XEN
 946 /* Xen doesn't set %esp to be precisely what the normal sysenter
 947    entrypoint expects, so fix it up before using the normal path. */
 948 ENTRY(xen_sysenter_target)
 949         RING0_INT_FRAME
 950         addl $5*4, %esp         /* remove xen-provided frame */
 951         CFI_ADJUST_CFA_OFFSET -5*4
 952         jmp sysenter_past_esp
 953         CFI_ENDPROC
 954
 955 ENTRY(xen_hypervisor_callback)
 956         CFI_STARTPROC
 957         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
 958         SAVE_ALL
 959         TRACE_IRQS_OFF
 960
 961         /* Check to see if we got the event in the critical
 962            region in xen_iret_direct, after we've reenabled
 963            events and checked for pending events.  This simulates
 964            iret instruction's behaviour where it delivers a
 965            pending interrupt when enabling interrupts. */
 966         movl PT_EIP(%esp),%eax
 967         cmpl $xen_iret_start_crit,%eax
 968         jb   1f
 969         cmpl $xen_iret_end_crit,%eax
 970         jae  1f
 971
 972         jmp  xen_iret_crit_fixup
 973
 974 ENTRY(xen_do_upcall)
 975 1:      mov %esp, %eax
 976         call xen_evtchn_do_upcall
 977 #ifndef CONFIG_PREEMPT
 978         call xen_maybe_preempt_hcall
 979 #endif
 980         jmp  ret_from_intr
 981         CFI_ENDPROC
 982 ENDPROC(xen_hypervisor_callback)
 983
 984 # Hypervisor uses this for application faults while it executes.
 985 # We get here for two reasons:
 986 #  1. Fault while reloading DS, ES, FS or GS
 987 #  2. Fault while executing IRET
 988 # Category 1 we fix up by reattempting the load, and zeroing the segment
 989 # register if the load fails.
 990 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
 991 # normal Linux return path in this case because if we use the IRET hypercall
 992 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
 993 # We distinguish between categories by maintaining a status value in EAX.
 994 ENTRY(xen_failsafe_callback)
 995         CFI_STARTPROC
 996         pushl_cfi %eax
 997         movl $1,%eax
 998 1:      mov 4(%esp),%ds
 999 2:      mov 8(%esp),%es
1000 3:      mov 12(%esp),%fs
1001 4:      mov 16(%esp),%gs
1002         /* EAX == 0 => Category 1 (Bad segment)
1003            EAX != 0 => Category 2 (Bad IRET) */
1004         testl %eax,%eax
1005         popl_cfi %eax
1006         lea 16(%esp),%esp
1007         CFI_ADJUST_CFA_OFFSET -16
1008         jz 5f
1009         jmp iret_exc
1010 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1011         SAVE_ALL
1012         jmp ret_from_exception
1013         CFI_ENDPROC
1014
1015 .section .fixup,"ax"
1016 6:      xorl %eax,%eax
1017         movl %eax,4(%esp)
1018         jmp 1b
1019 7:      xorl %eax,%eax
1020         movl %eax,8(%esp)
1021         jmp 2b
1022 8:      xorl %eax,%eax
1023         movl %eax,12(%esp)
1024         jmp 3b
1025 9:      xorl %eax,%eax
1026         movl %eax,16(%esp)
1027         jmp 4b
1028 .previous
1029         _ASM_EXTABLE(1b,6b)
1030         _ASM_EXTABLE(2b,7b)
1031         _ASM_EXTABLE(3b,8b)
1032         _ASM_EXTABLE(4b,9b)
1033 ENDPROC(xen_failsafe_callback)
1034
1035 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1036                 xen_evtchn_do_upcall)
1037
1038 #endif  /* CONFIG_XEN */
1039
1040 #if IS_ENABLED(CONFIG_HYPERV)
1041
1042 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1043         hyperv_vector_handler)
1044
1045 #endif /* CONFIG_HYPERV */
1046
1047 #ifdef CONFIG_FUNCTION_TRACER
1048 #ifdef CONFIG_DYNAMIC_FTRACE
1049
1050 ENTRY(mcount)
1051         ret
1052 END(mcount)
1053
1054 ENTRY(ftrace_caller)
1055         pushl %eax
1056         pushl %ecx
1057         pushl %edx
1058         pushl $0        /* Pass NULL as regs pointer */
1059         movl 4*4(%esp), %eax
1060         movl 0x4(%ebp), %edx
1061         movl function_trace_op, %ecx
1062         subl $MCOUNT_INSN_SIZE, %eax
1063
1064 .globl ftrace_call
1065 ftrace_call:
1066         call ftrace_stub
1067
1068         addl $4,%esp    /* skip NULL pointer */
1069         popl %edx
1070         popl %ecx
1071         popl %eax
1072 ftrace_ret:
1073 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1074 .globl ftrace_graph_call
1075 ftrace_graph_call:
1076         jmp ftrace_stub
1077 #endif
1078
1079 .globl ftrace_stub
1080 ftrace_stub:
1081         ret
1082 END(ftrace_caller)
1083
1084 ENTRY(ftrace_regs_caller)
1085         pushf   /* push flags before compare (in cs location) */
1086
1087         /*
1088          * i386 does not save SS and ESP when coming from kernel.
1089          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1090          * Unfortunately, that means eflags must be at the same location
1091          * as the current return ip is. We move the return ip into the
1092          * ip location, and move flags into the return ip location.
1093          */
1094         pushl 4(%esp)   /* save return ip into ip slot */
1095
1096         pushl $0        /* Load 0 into orig_ax */
1097         pushl %gs
1098         pushl %fs
1099         pushl %es
1100         pushl %ds
1101         pushl %eax
1102         pushl %ebp
1103         pushl %edi
1104         pushl %esi
1105         pushl %edx
1106         pushl %ecx
1107         pushl %ebx
1108
1109         movl 13*4(%esp), %eax   /* Get the saved flags */
1110         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1111                                 /* clobbering return ip */
1112         movl $__KERNEL_CS,13*4(%esp)
1113
1114         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1115         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1116         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1117         movl function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1118         pushl %esp              /* Save pt_regs as 4th parameter */
1119
1120 GLOBAL(ftrace_regs_call)
1121         call ftrace_stub
1122
1123         addl $4, %esp           /* Skip pt_regs */
1124         movl 14*4(%esp), %eax   /* Move flags back into cs */
1125         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1126         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1127         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1128
1129         popl %ebx
1130         popl %ecx
1131         popl %edx
1132         popl %esi
1133         popl %edi
1134         popl %ebp
1135         popl %eax
1136         popl %ds
1137         popl %es
1138         popl %fs
1139         popl %gs
1140         addl $8, %esp           /* Skip orig_ax and ip */
1141         popf                    /* Pop flags at end (no addl to corrupt flags) */
1142         jmp ftrace_ret
1143
1144         popf
1145         jmp  ftrace_stub
1146 #else /* ! CONFIG_DYNAMIC_FTRACE */
1147
1148 ENTRY(mcount)
1149         cmpl $__PAGE_OFFSET, %esp
1150         jb ftrace_stub          /* Paging not enabled yet? */
1151
1152         cmpl $ftrace_stub, ftrace_trace_function
1153         jnz trace
1154 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1155         cmpl $ftrace_stub, ftrace_graph_return
1156         jnz ftrace_graph_caller
1157
1158         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1159         jnz ftrace_graph_caller
1160 #endif
1161 .globl ftrace_stub
1162 ftrace_stub:
1163         ret
1164
1165         /* taken from glibc */
1166 trace:
1167         pushl %eax
1168         pushl %ecx
1169         pushl %edx
1170         movl 0xc(%esp), %eax
1171         movl 0x4(%ebp), %edx
1172         subl $MCOUNT_INSN_SIZE, %eax
1173
1174         call *ftrace_trace_function
1175
1176         popl %edx
1177         popl %ecx
1178         popl %eax
1179         jmp ftrace_stub
1180 END(mcount)
1181 #endif /* CONFIG_DYNAMIC_FTRACE */
1182 #endif /* CONFIG_FUNCTION_TRACER */
1183
1184 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1185 ENTRY(ftrace_graph_caller)
1186         pushl %eax
1187         pushl %ecx
1188         pushl %edx
1189         movl 0xc(%esp), %eax
1190         lea 0x4(%ebp), %edx
1191         movl (%ebp), %ecx
1192         subl $MCOUNT_INSN_SIZE, %eax
1193         call prepare_ftrace_return
1194         popl %edx
1195         popl %ecx
1196         popl %eax
1197         ret
1198 END(ftrace_graph_caller)
1199
1200 .globl return_to_handler
1201 return_to_handler:
1202         pushl %eax
1203         pushl %edx
1204         movl %ebp, %eax
1205         call ftrace_return_to_handler
1206         movl %eax, %ecx
1207         popl %edx
1208         popl %eax
1209         jmp *%ecx
1210 #endif
1211
1212 #ifdef CONFIG_TRACING
1213 ENTRY(trace_page_fault)
1214         RING0_EC_FRAME
1215         ASM_CLAC
1216         pushl_cfi $trace_do_page_fault
1217         jmp error_code
1218         CFI_ENDPROC
1219 END(trace_page_fault)
1220 #endif
1221
1222 ENTRY(page_fault)
1223         RING0_EC_FRAME
1224         ASM_CLAC
1225         pushl_cfi $do_page_fault
1226         ALIGN
1227 error_code:
1228         /* the function address is in %gs's slot on the stack */
1229         pushl_cfi %fs
1230         /*CFI_REL_OFFSET fs, 0*/
1231         pushl_cfi %es
1232         /*CFI_REL_OFFSET es, 0*/
1233         pushl_cfi %ds
1234         /*CFI_REL_OFFSET ds, 0*/
1235         pushl_cfi_reg eax
1236         pushl_cfi_reg ebp
1237         pushl_cfi_reg edi
1238         pushl_cfi_reg esi
1239         pushl_cfi_reg edx
1240         pushl_cfi_reg ecx
1241         pushl_cfi_reg ebx
1242         cld
1243         movl $(__KERNEL_PERCPU), %ecx
1244         movl %ecx, %fs
1245         UNWIND_ESPFIX_STACK
1246         GS_TO_REG %ecx
1247         movl PT_GS(%esp), %edi          # get the function address
1248         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1249         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1250         REG_TO_PTGS %ecx
1251         SET_KERNEL_GS %ecx
1252         movl $(__USER_DS), %ecx
1253         movl %ecx, %ds
1254         movl %ecx, %es
1255         TRACE_IRQS_OFF
1256         movl %esp,%eax                  # pt_regs pointer
1257         call *%edi
1258         jmp ret_from_exception
1259         CFI_ENDPROC
1260 END(page_fault)
1261
1262 /*
1263  * Debug traps and NMI can happen at the one SYSENTER instruction
1264  * that sets up the real kernel stack. Check here, since we can't
1265  * allow the wrong stack to be used.
1266  *
1267  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1268  * already pushed 3 words if it hits on the sysenter instruction:
1269  * eflags, cs and eip.
1270  *
1271  * We just load the right stack, and push the three (known) values
1272  * by hand onto the new stack - while updating the return eip past
1273  * the instruction that would have done it for sysenter.
1274  */
1275 .macro FIX_STACK offset ok label
1276         cmpw $__KERNEL_CS, 4(%esp)
1277         jne \ok
1278 \label:
1279         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1280         CFI_DEF_CFA esp, 0
1281         CFI_UNDEFINED eip
1282         pushfl_cfi
1283         pushl_cfi $__KERNEL_CS
1284         pushl_cfi $sysenter_past_esp
1285         CFI_REL_OFFSET eip, 0
1286 .endm
1287
1288 ENTRY(debug)
1289         RING0_INT_FRAME
1290         ASM_CLAC
1291         cmpl $ia32_sysenter_target,(%esp)
1292         jne debug_stack_correct
1293         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1294 debug_stack_correct:
1295         pushl_cfi $-1                   # mark this as an int
1296         SAVE_ALL
1297         TRACE_IRQS_OFF
1298         xorl %edx,%edx                  # error code 0
1299         movl %esp,%eax                  # pt_regs pointer
1300         call do_debug
1301         jmp ret_from_exception
1302         CFI_ENDPROC
1303 END(debug)
1304
1305 /*
1306  * NMI is doubly nasty. It can happen _while_ we're handling
1307  * a debug fault, and the debug fault hasn't yet been able to
1308  * clear up the stack. So we first check whether we got  an
1309  * NMI on the sysenter entry path, but after that we need to
1310  * check whether we got an NMI on the debug path where the debug
1311  * fault happened on the sysenter path.
1312  */
1313 ENTRY(nmi)
1314         RING0_INT_FRAME
1315         ASM_CLAC
1316 #ifdef CONFIG_X86_ESPFIX32
1317         pushl_cfi %eax
1318         movl %ss, %eax
1319         cmpw $__ESPFIX_SS, %ax
1320         popl_cfi %eax
1321         je nmi_espfix_stack
1322 #endif
1323         cmpl $ia32_sysenter_target,(%esp)
1324         je nmi_stack_fixup
1325         pushl_cfi %eax
1326         movl %esp,%eax
1327         /* Do not access memory above the end of our stack page,
1328          * it might not exist.
1329          */
1330         andl $(THREAD_SIZE-1),%eax
1331         cmpl $(THREAD_SIZE-20),%eax
1332         popl_cfi %eax
1333         jae nmi_stack_correct
1334         cmpl $ia32_sysenter_target,12(%esp)
1335         je nmi_debug_stack_check
1336 nmi_stack_correct:
1337         /* We have a RING0_INT_FRAME here */
1338         pushl_cfi %eax
1339         SAVE_ALL
1340         xorl %edx,%edx          # zero error code
1341         movl %esp,%eax          # pt_regs pointer
1342         call do_nmi
1343         jmp restore_all_notrace
1344         CFI_ENDPROC
1345
1346 nmi_stack_fixup:
1347         RING0_INT_FRAME
1348         FIX_STACK 12, nmi_stack_correct, 1
1349         jmp nmi_stack_correct
1350
1351 nmi_debug_stack_check:
1352         /* We have a RING0_INT_FRAME here */
1353         cmpw $__KERNEL_CS,16(%esp)
1354         jne nmi_stack_correct
1355         cmpl $debug,(%esp)
1356         jb nmi_stack_correct
1357         cmpl $debug_esp_fix_insn,(%esp)
1358         ja nmi_stack_correct
1359         FIX_STACK 24, nmi_stack_correct, 1
1360         jmp nmi_stack_correct
1361
1362 #ifdef CONFIG_X86_ESPFIX32
1363 nmi_espfix_stack:
1364         /* We have a RING0_INT_FRAME here.
1365          *
1366          * create the pointer to lss back
1367          */
1368         pushl_cfi %ss
1369         pushl_cfi %esp
1370         addl $4, (%esp)
1371         /* copy the iret frame of 12 bytes */
1372         .rept 3
1373         pushl_cfi 16(%esp)
1374         .endr
1375         pushl_cfi %eax
1376         SAVE_ALL
1377         FIXUP_ESPFIX_STACK              # %eax == %esp
1378         xorl %edx,%edx                  # zero error code
1379         call do_nmi
1380         RESTORE_REGS
1381         lss 12+4(%esp), %esp            # back to espfix stack
1382         CFI_ADJUST_CFA_OFFSET -24
1383         jmp irq_return
1384 #endif
1385         CFI_ENDPROC
1386 END(nmi)
1387
1388 ENTRY(int3)
1389         RING0_INT_FRAME
1390         ASM_CLAC
1391         pushl_cfi $-1                   # mark this as an int
1392         SAVE_ALL
1393         TRACE_IRQS_OFF
1394         xorl %edx,%edx          # zero error code
1395         movl %esp,%eax          # pt_regs pointer
1396         call do_int3
1397         jmp ret_from_exception
1398         CFI_ENDPROC
1399 END(int3)
1400
1401 ENTRY(general_protection)
1402         RING0_EC_FRAME
1403         pushl_cfi $do_general_protection
1404         jmp error_code
1405         CFI_ENDPROC
1406 END(general_protection)
1407
1408 #ifdef CONFIG_KVM_GUEST
1409 ENTRY(async_page_fault)
1410         RING0_EC_FRAME
1411         ASM_CLAC
1412         pushl_cfi $do_async_page_fault
1413         jmp error_code
1414         CFI_ENDPROC
1415 END(async_page_fault)
1416 #endif
1417