kernel/arch/x86/include/asm/calling.h

   1 /*
   2
   3  x86 function call convention, 64-bit:
   4  -------------------------------------
   5   arguments           |  callee-saved      | extra caller-saved | return
   6  [callee-clobbered]   |                    | [callee-clobbered] |
   7  ---------------------------------------------------------------------------
   8  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
   9
  10  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  11    functions when it sees tail-call optimization possibilities) rflags is
  12    clobbered. Leftover arguments are passed over the stack frame.)
  13
  14  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  15
  16  [**] for struct return values wider than 64 bits the return convention is a
  17       bit more complex: up to 128 bits width we return small structures
  18       straight in rax, rdx. For structures larger than that (3 words or
  19       larger) the caller puts a pointer to an on-stack return struct
  20       [allocated in the caller's stack frame] into the first argument - i.e.
  21       into rdi. All other arguments shift up by one in this case.
  22       Fortunately this case is rare in the kernel.
  23
  24 For 32-bit we have the following conventions - kernel is built with
  25 -mregparm=3 and -freg-struct-return:
  26
  27  x86 function calling convention, 32-bit:
  28  ----------------------------------------
  29   arguments         | callee-saved        | extra caller-saved | return
  30  [callee-clobbered] |                     | [callee-clobbered] |
  31  -------------------------------------------------------------------------
  32  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  33
  34  ( here too esp is obviously invariant across normal function calls. eflags
  35    is clobbered. Leftover arguments are passed over the stack frame. )
  36
  37  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  38
  39  [**] We build with -freg-struct-return, which on 32-bit means similar
  40       semantics as on 64-bit: edx can be used for a second return value
  41       (i.e. covering integer and structure sizes up to 64 bits) - after that
  42       it gets more complex and more expensive: 3-word or larger struct returns
  43       get done in the caller's frame and the pointer to the return struct goes
  44       into regparm0, i.e. eax - the other arguments shift up and the
  45       function's register parameters degenerate to regparm=2 in essence.
  46
  47 */
  48
  49 #include <asm/dwarf2.h>
  50
  51 #ifdef CONFIG_X86_64
  52
  53 /*
  54  * 64-bit system call stack frame layout defines and helpers,
  55  * for assembly code:
  56  */
  57
  58 /* The layout forms the "struct pt_regs" on the stack: */
  59 /*
  60  * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
  61  * unless syscall needs a complete, fully filled "struct pt_regs".
  62  */
  63 #define R15             0*8
  64 #define R14             1*8
  65 #define R13             2*8
  66 #define R12             3*8
  67 #define RBP             4*8
  68 #define RBX             5*8
  69 /* These regs are callee-clobbered. Always saved on kernel entry. */
  70 #define R11             6*8
  71 #define R10             7*8
  72 #define R9              8*8
  73 #define R8              9*8
  74 #define RAX             10*8
  75 #define RCX             11*8
  76 #define RDX             12*8
  77 #define RSI             13*8
  78 #define RDI             14*8
  79 /*
  80  * On syscall entry, this is syscall#. On CPU exception, this is error code.
  81  * On hw interrupt, it's IRQ number:
  82  */
  83 #define ORIG_RAX        15*8
  84 /* Return frame for iretq */
  85 #define RIP             16*8
  86 #define CS              17*8
  87 #define EFLAGS          18*8
  88 #define RSP             19*8
  89 #define SS              20*8
  90
  91 #define SIZEOF_PTREGS   21*8
  92
  93         .macro ALLOC_PT_GPREGS_ON_STACK addskip=0
  94         subq    $15*8+\addskip, %rsp
  95         CFI_ADJUST_CFA_OFFSET 15*8+\addskip
  96         .endm
  97
  98         .macro SAVE_C_REGS_HELPER offset=0 rax=1 rcx=1 r8910=1 r11=1
  99         .if \r11
 100         movq_cfi r11, 6*8+\offset
 101         .endif
 102         .if \r8910
 103         movq_cfi r10, 7*8+\offset
 104         movq_cfi r9,  8*8+\offset
 105         movq_cfi r8,  9*8+\offset
 106         .endif
 107         .if \rax
 108         movq_cfi rax, 10*8+\offset
 109         .endif
 110         .if \rcx
 111         movq_cfi rcx, 11*8+\offset
 112         .endif
 113         movq_cfi rdx, 12*8+\offset
 114         movq_cfi rsi, 13*8+\offset
 115         movq_cfi rdi, 14*8+\offset
 116         .endm
 117         .macro SAVE_C_REGS offset=0
 118         SAVE_C_REGS_HELPER \offset, 1, 1, 1, 1
 119         .endm
 120         .macro SAVE_C_REGS_EXCEPT_RAX_RCX offset=0
 121         SAVE_C_REGS_HELPER \offset, 0, 0, 1, 1
 122         .endm
 123         .macro SAVE_C_REGS_EXCEPT_R891011
 124         SAVE_C_REGS_HELPER 0, 1, 1, 0, 0
 125         .endm
 126         .macro SAVE_C_REGS_EXCEPT_RCX_R891011
 127         SAVE_C_REGS_HELPER 0, 1, 0, 0, 0
 128         .endm
 129         .macro SAVE_C_REGS_EXCEPT_RAX_RCX_R11
 130         SAVE_C_REGS_HELPER 0, 0, 0, 1, 0
 131         .endm
 132
 133         .macro SAVE_EXTRA_REGS offset=0
 134         movq_cfi r15, 0*8+\offset
 135         movq_cfi r14, 1*8+\offset
 136         movq_cfi r13, 2*8+\offset
 137         movq_cfi r12, 3*8+\offset
 138         movq_cfi rbp, 4*8+\offset
 139         movq_cfi rbx, 5*8+\offset
 140         .endm
 141         .macro SAVE_EXTRA_REGS_RBP offset=0
 142         movq_cfi rbp, 4*8+\offset
 143         .endm
 144
 145         .macro RESTORE_EXTRA_REGS offset=0
 146         movq_cfi_restore 0*8+\offset, r15
 147         movq_cfi_restore 1*8+\offset, r14
 148         movq_cfi_restore 2*8+\offset, r13
 149         movq_cfi_restore 3*8+\offset, r12
 150         movq_cfi_restore 4*8+\offset, rbp
 151         movq_cfi_restore 5*8+\offset, rbx
 152         .endm
 153
 154         .macro ZERO_EXTRA_REGS
 155         xorl    %r15d, %r15d
 156         xorl    %r14d, %r14d
 157         xorl    %r13d, %r13d
 158         xorl    %r12d, %r12d
 159         xorl    %ebp, %ebp
 160         xorl    %ebx, %ebx
 161         .endm
 162
 163         .macro RESTORE_C_REGS_HELPER rstor_rax=1, rstor_rcx=1, rstor_r11=1, rstor_r8910=1, rstor_rdx=1
 164         .if \rstor_r11
 165         movq_cfi_restore 6*8, r11
 166         .endif
 167         .if \rstor_r8910
 168         movq_cfi_restore 7*8, r10
 169         movq_cfi_restore 8*8, r9
 170         movq_cfi_restore 9*8, r8
 171         .endif
 172         .if \rstor_rax
 173         movq_cfi_restore 10*8, rax
 174         .endif
 175         .if \rstor_rcx
 176         movq_cfi_restore 11*8, rcx
 177         .endif
 178         .if \rstor_rdx
 179         movq_cfi_restore 12*8, rdx
 180         .endif
 181         movq_cfi_restore 13*8, rsi
 182         movq_cfi_restore 14*8, rdi
 183         .endm
 184         .macro RESTORE_C_REGS
 185         RESTORE_C_REGS_HELPER 1,1,1,1,1
 186         .endm
 187         .macro RESTORE_C_REGS_EXCEPT_RAX
 188         RESTORE_C_REGS_HELPER 0,1,1,1,1
 189         .endm
 190         .macro RESTORE_C_REGS_EXCEPT_RCX
 191         RESTORE_C_REGS_HELPER 1,0,1,1,1
 192         .endm
 193         .macro RESTORE_C_REGS_EXCEPT_R11
 194         RESTORE_C_REGS_HELPER 1,1,0,1,1
 195         .endm
 196         .macro RESTORE_C_REGS_EXCEPT_RCX_R11
 197         RESTORE_C_REGS_HELPER 1,0,0,1,1
 198         .endm
 199         .macro RESTORE_RSI_RDI
 200         RESTORE_C_REGS_HELPER 0,0,0,0,0
 201         .endm
 202         .macro RESTORE_RSI_RDI_RDX
 203         RESTORE_C_REGS_HELPER 0,0,0,0,1
 204         .endm
 205
 206         .macro REMOVE_PT_GPREGS_FROM_STACK addskip=0
 207         addq $15*8+\addskip, %rsp
 208         CFI_ADJUST_CFA_OFFSET -(15*8+\addskip)
 209         .endm
 210
 211         .macro icebp
 212         .byte 0xf1
 213         .endm
 214
 215 #else /* CONFIG_X86_64 */
 216
 217 /*
 218  * For 32bit only simplified versions of SAVE_ALL/RESTORE_ALL. These
 219  * are different from the entry_32.S versions in not changing the segment
 220  * registers. So only suitable for in kernel use, not when transitioning
 221  * from or to user space. The resulting stack frame is not a standard
 222  * pt_regs frame. The main use case is calling C code from assembler
 223  * when all the registers need to be preserved.
 224  */
 225
 226         .macro SAVE_ALL
 227         pushl_cfi_reg eax
 228         pushl_cfi_reg ebp
 229         pushl_cfi_reg edi
 230         pushl_cfi_reg esi
 231         pushl_cfi_reg edx
 232         pushl_cfi_reg ecx
 233         pushl_cfi_reg ebx
 234         .endm
 235
 236         .macro RESTORE_ALL
 237         popl_cfi_reg ebx
 238         popl_cfi_reg ecx
 239         popl_cfi_reg edx
 240         popl_cfi_reg esi
 241         popl_cfi_reg edi
 242         popl_cfi_reg ebp
 243         popl_cfi_reg eax
 244         .endm
 245
 246 #endif /* CONFIG_X86_64 */
 247