kernel/arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36 #include <asm/context_tracking.h>
  37
  38 /*
  39  * System calls.
  40  */
  41         .section        ".toc","aw"
  42 SYS_CALL_TABLE:
  43         .tc sys_call_table[TC],sys_call_table
  44
  45 /* This value is used to mark exception frames on the stack. */
  46 exception_marker:
  47         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  48
  49         .section        ".text"
  50         .align 7
  51
  52         .globl system_call_common
  53 system_call_common:
  54         andi.   r10,r12,MSR_PR
  55         mr      r10,r1
  56         addi    r1,r1,-INT_FRAME_SIZE
  57         beq-    1f
  58         ld      r1,PACAKSAVE(r13)
  59 1:      std     r10,0(r1)
  60         std     r11,_NIP(r1)
  61         std     r12,_MSR(r1)
  62         std     r0,GPR0(r1)
  63         std     r10,GPR1(r1)
  64         beq     2f                      /* if from kernel mode */
  65         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  66 2:      std     r2,GPR2(r1)
  67         std     r3,GPR3(r1)
  68         mfcr    r2
  69         std     r4,GPR4(r1)
  70         std     r5,GPR5(r1)
  71         std     r6,GPR6(r1)
  72         std     r7,GPR7(r1)
  73         std     r8,GPR8(r1)
  74         li      r11,0
  75         std     r11,GPR9(r1)
  76         std     r11,GPR10(r1)
  77         std     r11,GPR11(r1)
  78         std     r11,GPR12(r1)
  79         std     r11,_XER(r1)
  80         std     r11,_CTR(r1)
  81         std     r9,GPR13(r1)
  82         mflr    r10
  83         /*
  84          * This clears CR0.SO (bit 28), which is the error indication on
  85          * return from this system call.
  86          */
  87         rldimi  r2,r11,28,(63-28)
  88         li      r11,0xc01
  89         std     r10,_LINK(r1)
  90         std     r11,_TRAP(r1)
  91         std     r3,ORIG_GPR3(r1)
  92         std     r2,_CCR(r1)
  93         ld      r2,PACATOC(r13)
  94         addi    r9,r1,STACK_FRAME_OVERHEAD
  95         ld      r11,exception_marker@toc(r2)
  96         std     r11,-16(r9)             /* "regshere" marker */
  97 #if defined(CONFIG_VIRT_CPU_ACCOUNTING_NATIVE) && defined(CONFIG_PPC_SPLPAR)
  98 BEGIN_FW_FTR_SECTION
  99         beq     33f
 100         /* if from user, see if there are any DTL entries to process */
 101         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 102         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 103         addi    r10,r10,LPPACA_DTLIDX
 104         LDX_BE  r10,0,r10               /* get log write index */
 105         cmpd    cr1,r11,r10
 106         beq+    cr1,33f
 107         bl      accumulate_stolen_time
 108         REST_GPR(0,r1)
 109         REST_4GPRS(3,r1)
 110         REST_2GPRS(7,r1)
 111         addi    r9,r1,STACK_FRAME_OVERHEAD
 112 33:
 113 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 114 #endif /* CONFIG_VIRT_CPU_ACCOUNTING_NATIVE && CONFIG_PPC_SPLPAR */
 115
 116         /*
 117          * A syscall should always be called with interrupts enabled
 118          * so we just unconditionally hard-enable here. When some kind
 119          * of irq tracing is used, we additionally check that condition
 120          * is correct
 121          */
 122 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 123         lbz     r10,PACASOFTIRQEN(r13)
 124         xori    r10,r10,1
 125 1:      tdnei   r10,0
 126         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 127 #endif
 128
 129 #ifdef CONFIG_PPC_BOOK3E
 130         wrteei  1
 131 #else
 132         ld      r11,PACAKMSR(r13)
 133         ori     r11,r11,MSR_EE
 134         mtmsrd  r11,1
 135 #endif /* CONFIG_PPC_BOOK3E */
 136
 137         /* We do need to set SOFTE in the stack frame or the return
 138          * from interrupt will be painful
 139          */
 140         li      r10,1
 141         std     r10,SOFTE(r1)
 142
 143         CURRENT_THREAD_INFO(r11, r1)
 144         ld      r10,TI_FLAGS(r11)
 145         andi.   r11,r10,_TIF_SYSCALL_DOTRACE
 146         bne     syscall_dotrace
 147 .Lsyscall_dotrace_cont:
 148         cmpldi  0,r0,NR_syscalls
 149         bge-    syscall_enosys
 150
 151 system_call:                    /* label this so stack traces look sane */
 152 /*
 153  * Need to vector to 32 Bit or default sys_call_table here,
 154  * based on caller's run-mode / personality.
 155  */
 156         ld      r11,SYS_CALL_TABLE@toc(2)
 157         andi.   r10,r10,_TIF_32BIT
 158         beq     15f
 159         addi    r11,r11,8       /* use 32-bit syscall entries */
 160         clrldi  r3,r3,32
 161         clrldi  r4,r4,32
 162         clrldi  r5,r5,32
 163         clrldi  r6,r6,32
 164         clrldi  r7,r7,32
 165         clrldi  r8,r8,32
 166 15:
 167         slwi    r0,r0,4
 168         ldx     r12,r11,r0      /* Fetch system call handler [ptr] */
 169         mtctr   r12
 170         bctrl                   /* Call handler */
 171
 172 .Lsyscall_exit:
 173         std     r3,RESULT(r1)
 174         CURRENT_THREAD_INFO(r12, r1)
 175
 176         ld      r8,_MSR(r1)
 177 #ifdef CONFIG_PPC_BOOK3S
 178         /* No MSR:RI on BookE */
 179         andi.   r10,r8,MSR_RI
 180         beq-    unrecov_restore
 181 #endif
 182         /*
 183          * Disable interrupts so current_thread_info()->flags can't change,
 184          * and so that we don't get interrupted after loading SRR0/1.
 185          */
 186 #ifdef CONFIG_PPC_BOOK3E
 187         wrteei  0
 188 #else
 189         ld      r10,PACAKMSR(r13)
 190         /*
 191          * For performance reasons we clear RI the same time that we
 192          * clear EE. We only need to clear RI just before we restore r13
 193          * below, but batching it with EE saves us one expensive mtmsrd call.
 194          * We have to be careful to restore RI if we branch anywhere from
 195          * here (eg syscall_exit_work).
 196          */
 197         li      r9,MSR_RI
 198         andc    r11,r10,r9
 199         mtmsrd  r11,1
 200 #endif /* CONFIG_PPC_BOOK3E */
 201
 202         ld      r9,TI_FLAGS(r12)
 203         li      r11,-_LAST_ERRNO
 204         andi.   r0,r9,(_TIF_SYSCALL_DOTRACE|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 205         bne-    syscall_exit_work
 206         cmpld   r3,r11
 207         ld      r5,_CCR(r1)
 208         bge-    syscall_error
 209 .Lsyscall_error_cont:
 210         ld      r7,_NIP(r1)
 211 BEGIN_FTR_SECTION
 212         stdcx.  r0,0,r1                 /* to clear the reservation */
 213 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 214         andi.   r6,r8,MSR_PR
 215         ld      r4,_LINK(r1)
 216
 217         beq-    1f
 218         ACCOUNT_CPU_USER_EXIT(r11, r12)
 219         HMT_MEDIUM_LOW_HAS_PPR
 220         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 221 1:      ld      r2,GPR2(r1)
 222         ld      r1,GPR1(r1)
 223         mtlr    r4
 224         mtcr    r5
 225         mtspr   SPRN_SRR0,r7
 226         mtspr   SPRN_SRR1,r8
 227         RFI
 228         b       .       /* prevent speculative execution */
 229
 230 syscall_error:
 231         oris    r5,r5,0x1000    /* Set SO bit in CR */
 232         neg     r3,r3
 233         std     r5,_CCR(r1)
 234         b       .Lsyscall_error_cont
 235
 236 /* Traced system call support */
 237 syscall_dotrace:
 238         bl      save_nvgprs
 239         addi    r3,r1,STACK_FRAME_OVERHEAD
 240         bl      do_syscall_trace_enter
 241         /*
 242          * Restore argument registers possibly just changed.
 243          * We use the return value of do_syscall_trace_enter
 244          * for the call number to look up in the table (r0).
 245          */
 246         mr      r0,r3
 247         ld      r3,GPR3(r1)
 248         ld      r4,GPR4(r1)
 249         ld      r5,GPR5(r1)
 250         ld      r6,GPR6(r1)
 251         ld      r7,GPR7(r1)
 252         ld      r8,GPR8(r1)
 253         addi    r9,r1,STACK_FRAME_OVERHEAD
 254         CURRENT_THREAD_INFO(r10, r1)
 255         ld      r10,TI_FLAGS(r10)
 256         b       .Lsyscall_dotrace_cont
 257
 258 syscall_enosys:
 259         li      r3,-ENOSYS
 260         b       .Lsyscall_exit
 261
 262 syscall_exit_work:
 263 #ifdef CONFIG_PPC_BOOK3S
 264         mtmsrd  r10,1           /* Restore RI */
 265 #endif
 266         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 267          If TIF_NOERROR is set, just save r3 as it is. */
 268
 269         andi.   r0,r9,_TIF_RESTOREALL
 270         beq+    0f
 271         REST_NVGPRS(r1)
 272         b       2f
 273 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 274         blt+    1f
 275         andi.   r0,r9,_TIF_NOERROR
 276         bne-    1f
 277         ld      r5,_CCR(r1)
 278         neg     r3,r3
 279         oris    r5,r5,0x1000    /* Set SO bit in CR */
 280         std     r5,_CCR(r1)
 281 1:      std     r3,GPR3(r1)
 282 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 283         beq     4f
 284
 285         /* Clear per-syscall TIF flags if any are set.  */
 286
 287         li      r11,_TIF_PERSYSCALL_MASK
 288         addi    r12,r12,TI_FLAGS
 289 3:      ldarx   r10,0,r12
 290         andc    r10,r10,r11
 291         stdcx.  r10,0,r12
 292         bne-    3b
 293         subi    r12,r12,TI_FLAGS
 294
 295 4:      /* Anything else left to do? */
 296         SET_DEFAULT_THREAD_PPR(r3, r10)         /* Set thread.ppr = 3 */
 297         andi.   r0,r9,(_TIF_SYSCALL_DOTRACE|_TIF_SINGLESTEP)
 298         beq     ret_from_except_lite
 299
 300         /* Re-enable interrupts */
 301 #ifdef CONFIG_PPC_BOOK3E
 302         wrteei  1
 303 #else
 304         ld      r10,PACAKMSR(r13)
 305         ori     r10,r10,MSR_EE
 306         mtmsrd  r10,1
 307 #endif /* CONFIG_PPC_BOOK3E */
 308
 309         bl      save_nvgprs
 310         addi    r3,r1,STACK_FRAME_OVERHEAD
 311         bl      do_syscall_trace_leave
 312         b       ret_from_except
 313
 314 /* Save non-volatile GPRs, if not already saved. */
 315 _GLOBAL(save_nvgprs)
 316         ld      r11,_TRAP(r1)
 317         andi.   r0,r11,1
 318         beqlr-
 319         SAVE_NVGPRS(r1)
 320         clrrdi  r0,r11,1
 321         std     r0,_TRAP(r1)
 322         blr
 323
 324
 325 /*
 326  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 327  * and thus put the process into the stopped state where we might
 328  * want to examine its user state with ptrace.  Therefore we need
 329  * to save all the nonvolatile registers (r14 - r31) before calling
 330  * the C code.  Similarly, fork, vfork and clone need the full
 331  * register state on the stack so that it can be copied to the child.
 332  */
 333
 334 _GLOBAL(ppc_fork)
 335         bl      save_nvgprs
 336         bl      sys_fork
 337         b       .Lsyscall_exit
 338
 339 _GLOBAL(ppc_vfork)
 340         bl      save_nvgprs
 341         bl      sys_vfork
 342         b       .Lsyscall_exit
 343
 344 _GLOBAL(ppc_clone)
 345         bl      save_nvgprs
 346         bl      sys_clone
 347         b       .Lsyscall_exit
 348
 349 _GLOBAL(ppc32_swapcontext)
 350         bl      save_nvgprs
 351         bl      compat_sys_swapcontext
 352         b       .Lsyscall_exit
 353
 354 _GLOBAL(ppc64_swapcontext)
 355         bl      save_nvgprs
 356         bl      sys_swapcontext
 357         b       .Lsyscall_exit
 358
 359 _GLOBAL(ppc_switch_endian)
 360         bl      save_nvgprs
 361         bl      sys_switch_endian
 362         b       .Lsyscall_exit
 363
 364 _GLOBAL(ret_from_fork)
 365         bl      schedule_tail
 366         REST_NVGPRS(r1)
 367         li      r3,0
 368         b       .Lsyscall_exit
 369
 370 _GLOBAL(ret_from_kernel_thread)
 371         bl      schedule_tail
 372         REST_NVGPRS(r1)
 373         mtlr    r14
 374         mr      r3,r15
 375 #if defined(_CALL_ELF) && _CALL_ELF == 2
 376         mr      r12,r14
 377 #endif
 378         blrl
 379         li      r3,0
 380         b       .Lsyscall_exit
 381
 382 /*
 383  * This routine switches between two different tasks.  The process
 384  * state of one is saved on its kernel stack.  Then the state
 385  * of the other is restored from its kernel stack.  The memory
 386  * management hardware is updated to the second process's state.
 387  * Finally, we can return to the second process, via ret_from_except.
 388  * On entry, r3 points to the THREAD for the current task, r4
 389  * points to the THREAD for the new task.
 390  *
 391  * Note: there are two ways to get to the "going out" portion
 392  * of this code; either by coming in via the entry (_switch)
 393  * or via "fork" which must set up an environment equivalent
 394  * to the "_switch" path.  If you change this you'll have to change
 395  * the fork code also.
 396  *
 397  * The code which creates the new task context is in 'copy_thread'
 398  * in arch/powerpc/kernel/process.c
 399  */
 400         .align  7
 401 _GLOBAL(_switch)
 402         mflr    r0
 403         std     r0,16(r1)
 404         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 405         /* r3-r13 are caller saved -- Cort */
 406         SAVE_8GPRS(14, r1)
 407         SAVE_10GPRS(22, r1)
 408         mflr    r20             /* Return to switch caller */
 409         mfmsr   r22
 410         li      r0, MSR_FP
 411 #ifdef CONFIG_VSX
 412 BEGIN_FTR_SECTION
 413         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 414 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 415 #endif /* CONFIG_VSX */
 416 #ifdef CONFIG_ALTIVEC
 417 BEGIN_FTR_SECTION
 418         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 419         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 420         std     r24,THREAD_VRSAVE(r3)
 421 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 422 #endif /* CONFIG_ALTIVEC */
 423         and.    r0,r0,r22
 424         beq+    1f
 425         andc    r22,r22,r0
 426         MTMSRD(r22)
 427         isync
 428 1:      std     r20,_NIP(r1)
 429         mfcr    r23
 430         std     r23,_CCR(r1)
 431         std     r1,KSP(r3)      /* Set old stack pointer */
 432
 433 #ifdef CONFIG_PPC_BOOK3S_64
 434 BEGIN_FTR_SECTION
 435         /* Event based branch registers */
 436         mfspr   r0, SPRN_BESCR
 437         std     r0, THREAD_BESCR(r3)
 438         mfspr   r0, SPRN_EBBHR
 439         std     r0, THREAD_EBBHR(r3)
 440         mfspr   r0, SPRN_EBBRR
 441         std     r0, THREAD_EBBRR(r3)
 442 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 443 #endif
 444
 445 #ifdef CONFIG_SMP
 446         /* We need a sync somewhere here to make sure that if the
 447          * previous task gets rescheduled on another CPU, it sees all
 448          * stores it has performed on this one.
 449          */
 450         sync
 451 #endif /* CONFIG_SMP */
 452
 453         /*
 454          * If we optimise away the clear of the reservation in system
 455          * calls because we know the CPU tracks the address of the
 456          * reservation, then we need to clear it here to cover the
 457          * case that the kernel context switch path has no larx
 458          * instructions.
 459          */
 460 BEGIN_FTR_SECTION
 461         ldarx   r6,0,r1
 462 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 463
 464 #ifdef CONFIG_PPC_BOOK3S
 465 /* Cancel all explict user streams as they will have no use after context
 466  * switch and will stop the HW from creating streams itself
 467  */
 468         DCBT_STOP_ALL_STREAM_IDS(r6)
 469 #endif
 470
 471         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 472         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 473
 474         ld      r8,KSP(r4)      /* new stack pointer */
 475 #ifdef CONFIG_PPC_BOOK3S
 476 BEGIN_FTR_SECTION
 477         clrrdi  r6,r8,28        /* get its ESID */
 478         clrrdi  r9,r1,28        /* get current sp ESID */
 479 FTR_SECTION_ELSE
 480         clrrdi  r6,r8,40        /* get its 1T ESID */
 481         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 482 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_1T_SEGMENT)
 483         clrldi. r0,r6,2         /* is new ESID c00000000? */
 484         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 485         cror    eq,4*cr1+eq,eq
 486         beq     2f              /* if yes, don't slbie it */
 487
 488         /* Bolt in the new stack SLB entry */
 489         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 490         oris    r0,r6,(SLB_ESID_V)@h
 491         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 492 BEGIN_FTR_SECTION
 493         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 494         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 495         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 496 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 497
 498         /* Update the last bolted SLB.  No write barriers are needed
 499          * here, provided we only update the current CPU's SLB shadow
 500          * buffer.
 501          */
 502         ld      r9,PACA_SLBSHADOWPTR(r13)
 503         li      r12,0
 504         std     r12,SLBSHADOW_STACKESID(r9)     /* Clear ESID */
 505         li      r12,SLBSHADOW_STACKVSID
 506         STDX_BE r7,r12,r9                       /* Save VSID */
 507         li      r12,SLBSHADOW_STACKESID
 508         STDX_BE r0,r12,r9                       /* Save ESID */
 509
 510         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 511          * we have 1TB segments, the only CPUs known to have the errata
 512          * only support less than 1TB of system memory and we'll never
 513          * actually hit this code path.
 514          */
 515
 516         slbie   r6
 517         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 518         slbmte  r7,r0
 519         isync
 520 2:
 521 #endif /* !CONFIG_PPC_BOOK3S */
 522
 523         CURRENT_THREAD_INFO(r7, r8)  /* base of new stack */
 524         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 525            because we don't need to leave the 288-byte ABI gap at the
 526            top of the kernel stack. */
 527         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 528
 529         mr      r1,r8           /* start using new stack pointer */
 530         std     r7,PACAKSAVE(r13)
 531
 532 #ifdef CONFIG_PPC_BOOK3S_64
 533 BEGIN_FTR_SECTION
 534         /* Event based branch registers */
 535         ld      r0, THREAD_BESCR(r4)
 536         mtspr   SPRN_BESCR, r0
 537         ld      r0, THREAD_EBBHR(r4)
 538         mtspr   SPRN_EBBHR, r0
 539         ld      r0, THREAD_EBBRR(r4)
 540         mtspr   SPRN_EBBRR, r0
 541
 542         ld      r0,THREAD_TAR(r4)
 543         mtspr   SPRN_TAR,r0
 544 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 545 #endif
 546
 547 #ifdef CONFIG_ALTIVEC
 548 BEGIN_FTR_SECTION
 549         ld      r0,THREAD_VRSAVE(r4)
 550         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 551 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 552 #endif /* CONFIG_ALTIVEC */
 553 #ifdef CONFIG_PPC64
 554 BEGIN_FTR_SECTION
 555         lwz     r6,THREAD_DSCR_INHERIT(r4)
 556         ld      r0,THREAD_DSCR(r4)
 557         cmpwi   r6,0
 558         bne     1f
 559         ld      r0,PACA_DSCR(r13)
 560 1:
 561 BEGIN_FTR_SECTION_NESTED(70)
 562         mfspr   r8, SPRN_FSCR
 563         rldimi  r8, r6, FSCR_DSCR_LG, (63 - FSCR_DSCR_LG)
 564         mtspr   SPRN_FSCR, r8
 565 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_207S, CPU_FTR_ARCH_207S, 70)
 566         cmpd    r0,r25
 567         beq     2f
 568         mtspr   SPRN_DSCR,r0
 569 2:
 570 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 571 #endif
 572
 573         ld      r6,_CCR(r1)
 574         mtcrf   0xFF,r6
 575
 576         /* r3-r13 are destroyed -- Cort */
 577         REST_8GPRS(14, r1)
 578         REST_10GPRS(22, r1)
 579
 580         /* convert old thread to its task_struct for return value */
 581         addi    r3,r3,-THREAD
 582         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 583         mtlr    r7
 584         addi    r1,r1,SWITCH_FRAME_SIZE
 585         blr
 586
 587         .align  7
 588 _GLOBAL(ret_from_except)
 589         ld      r11,_TRAP(r1)
 590         andi.   r0,r11,1
 591         bne     ret_from_except_lite
 592         REST_NVGPRS(r1)
 593
 594 _GLOBAL(ret_from_except_lite)
 595         /*
 596          * Disable interrupts so that current_thread_info()->flags
 597          * can't change between when we test it and when we return
 598          * from the interrupt.
 599          */
 600 #ifdef CONFIG_PPC_BOOK3E
 601         wrteei  0
 602 #else
 603         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 604         mtmsrd  r10,1             /* Update machine state */
 605 #endif /* CONFIG_PPC_BOOK3E */
 606
 607         CURRENT_THREAD_INFO(r9, r1)
 608         ld      r3,_MSR(r1)
 609 #ifdef CONFIG_PPC_BOOK3E
 610         ld      r10,PACACURRENT(r13)
 611 #endif /* CONFIG_PPC_BOOK3E */
 612         ld      r4,TI_FLAGS(r9)
 613         andi.   r3,r3,MSR_PR
 614         beq     resume_kernel
 615 #ifdef CONFIG_PPC_BOOK3E
 616         lwz     r3,(THREAD+THREAD_DBCR0)(r10)
 617 #endif /* CONFIG_PPC_BOOK3E */
 618
 619         /* Check current_thread_info()->flags */
 620         andi.   r0,r4,_TIF_USER_WORK_MASK
 621 #ifdef CONFIG_PPC_BOOK3E
 622         bne     1f
 623         /*
 624          * Check to see if the dbcr0 register is set up to debug.
 625          * Use the internal debug mode bit to do this.
 626          */
 627         andis.  r0,r3,DBCR0_IDM@h
 628         beq     restore
 629         mfmsr   r0
 630         rlwinm  r0,r0,0,~MSR_DE /* Clear MSR.DE */
 631         mtmsr   r0
 632         mtspr   SPRN_DBCR0,r3
 633         li      r10, -1
 634         mtspr   SPRN_DBSR,r10
 635         b       restore
 636 #else
 637         beq     restore
 638 #endif
 639 1:      andi.   r0,r4,_TIF_NEED_RESCHED_MASK
 640         beq     2f
 641         bl      restore_interrupts
 642         SCHEDULE_USER
 643         b       ret_from_except_lite
 644 2:
 645 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 646         andi.   r0,r4,_TIF_USER_WORK_MASK & ~_TIF_RESTORE_TM
 647         bne     3f              /* only restore TM if nothing else to do */
 648         addi    r3,r1,STACK_FRAME_OVERHEAD
 649         bl      restore_tm_state
 650         b       restore
 651 3:
 652 #endif
 653         bl      save_nvgprs
 654         /*
 655          * Use a non volatile GPR to save and restore our thread_info flags
 656          * across the call to restore_interrupts.
 657          */
 658         mr      r30,r4
 659         bl      restore_interrupts
 660         mr      r4,r30
 661         addi    r3,r1,STACK_FRAME_OVERHEAD
 662         bl      do_notify_resume
 663         b       ret_from_except
 664
 665 resume_kernel:
 666         /* check current_thread_info, _TIF_EMULATE_STACK_STORE */
 667         andis.  r8,r4,_TIF_EMULATE_STACK_STORE@h
 668         beq+    1f
 669
 670         addi    r8,r1,INT_FRAME_SIZE    /* Get the kprobed function entry */
 671
 672         lwz     r3,GPR1(r1)
 673         subi    r3,r3,INT_FRAME_SIZE    /* dst: Allocate a trampoline exception frame */
 674         mr      r4,r1                   /* src:  current exception frame */
 675         mr      r1,r3                   /* Reroute the trampoline frame to r1 */
 676
 677         /* Copy from the original to the trampoline. */
 678         li      r5,INT_FRAME_SIZE/8     /* size: INT_FRAME_SIZE */
 679         li      r6,0                    /* start offset: 0 */
 680         mtctr   r5
 681 2:      ldx     r0,r6,r4
 682         stdx    r0,r6,r3
 683         addi    r6,r6,8
 684         bdnz    2b
 685
 686         /* Do real store operation to complete stwu */
 687         lwz     r5,GPR1(r1)
 688         std     r8,0(r5)
 689
 690         /* Clear _TIF_EMULATE_STACK_STORE flag */
 691         lis     r11,_TIF_EMULATE_STACK_STORE@h
 692         addi    r5,r9,TI_FLAGS
 693 0:      ldarx   r4,0,r5
 694         andc    r4,r4,r11
 695         stdcx.  r4,0,r5
 696         bne-    0b
 697 1:
 698
 699 #ifdef CONFIG_PREEMPT
 700         /* Check if we need to preempt */
 701         lwz     r8,TI_PREEMPT(r9)
 702         cmpwi   0,r8,0          /* if non-zero, just restore regs and return */
 703         bne     restore
 704         andi.   r0,r4,_TIF_NEED_RESCHED
 705         bne+    check_count
 706
 707         andi.   r0,r4,_TIF_NEED_RESCHED_LAZY
 708         beq+    restore
 709         lwz     r8,TI_PREEMPT_LAZY(r9)
 710
 711         /* Check that preempt_count() == 0 and interrupts are enabled */
 712 check_count:
 713         cmpwi   cr1,r8,0
 714         ld      r0,SOFTE(r1)
 715         cmpdi   r0,0
 716         crandc  eq,cr1*4+eq,eq
 717         bne     restore
 718
 719         /*
 720          * Here we are preempting the current task. We want to make
 721          * sure we are soft-disabled first and reconcile irq state.
 722          */
 723         RECONCILE_IRQ_STATE(r3,r4)
 724 1:      bl      preempt_schedule_irq
 725
 726         /* Re-test flags and eventually loop */
 727         CURRENT_THREAD_INFO(r9, r1)
 728         ld      r4,TI_FLAGS(r9)
 729         andi.   r0,r4,_TIF_NEED_RESCHED_MASK
 730         bne     1b
 731
 732         /*
 733          * arch_local_irq_restore() from preempt_schedule_irq above may
 734          * enable hard interrupt but we really should disable interrupts
 735          * when we return from the interrupt, and so that we don't get
 736          * interrupted after loading SRR0/1.
 737          */
 738 #ifdef CONFIG_PPC_BOOK3E
 739         wrteei  0
 740 #else
 741         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 742         mtmsrd  r10,1             /* Update machine state */
 743 #endif /* CONFIG_PPC_BOOK3E */
 744 #endif /* CONFIG_PREEMPT */
 745
 746         .globl  fast_exc_return_irq
 747 fast_exc_return_irq:
 748 restore:
 749         /*
 750          * This is the main kernel exit path. First we check if we
 751          * are about to re-enable interrupts
 752          */
 753         ld      r5,SOFTE(r1)
 754         lbz     r6,PACASOFTIRQEN(r13)
 755         cmpwi   cr0,r5,0
 756         beq     restore_irq_off
 757
 758         /* We are enabling, were we already enabled ? Yes, just return */
 759         cmpwi   cr0,r6,1
 760         beq     cr0,do_restore
 761
 762         /*
 763          * We are about to soft-enable interrupts (we are hard disabled
 764          * at this point). We check if there's anything that needs to
 765          * be replayed first.
 766          */
 767         lbz     r0,PACAIRQHAPPENED(r13)
 768         cmpwi   cr0,r0,0
 769         bne-    restore_check_irq_replay
 770
 771         /*
 772          * Get here when nothing happened while soft-disabled, just
 773          * soft-enable and move-on. We will hard-enable as a side
 774          * effect of rfi
 775          */
 776 restore_no_replay:
 777         TRACE_ENABLE_INTS
 778         li      r0,1
 779         stb     r0,PACASOFTIRQEN(r13);
 780
 781         /*
 782          * Final return path. BookE is handled in a different file
 783          */
 784 do_restore:
 785 #ifdef CONFIG_PPC_BOOK3E
 786         b       exception_return_book3e
 787 #else
 788         /*
 789          * Clear the reservation. If we know the CPU tracks the address of
 790          * the reservation then we can potentially save some cycles and use
 791          * a larx. On POWER6 and POWER7 this is significantly faster.
 792          */
 793 BEGIN_FTR_SECTION
 794         stdcx.  r0,0,r1         /* to clear the reservation */
 795 FTR_SECTION_ELSE
 796         ldarx   r4,0,r1
 797 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 798
 799         /*
 800          * Some code path such as load_up_fpu or altivec return directly
 801          * here. They run entirely hard disabled and do not alter the
 802          * interrupt state. They also don't use lwarx/stwcx. and thus
 803          * are known not to leave dangling reservations.
 804          */
 805         .globl  fast_exception_return
 806 fast_exception_return:
 807         ld      r3,_MSR(r1)
 808         ld      r4,_CTR(r1)
 809         ld      r0,_LINK(r1)
 810         mtctr   r4
 811         mtlr    r0
 812         ld      r4,_XER(r1)
 813         mtspr   SPRN_XER,r4
 814
 815         REST_8GPRS(5, r1)
 816
 817         andi.   r0,r3,MSR_RI
 818         beq-    unrecov_restore
 819
 820         /* Load PPR from thread struct before we clear MSR:RI */
 821 BEGIN_FTR_SECTION
 822         ld      r2,PACACURRENT(r13)
 823         ld      r2,TASKTHREADPPR(r2)
 824 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 825
 826         /*
 827          * Clear RI before restoring r13.  If we are returning to
 828          * userspace and we take an exception after restoring r13,
 829          * we end up corrupting the userspace r13 value.
 830          */
 831         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 832         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 833         mtmsrd  r4,1
 834
 835 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 836         /* TM debug */
 837         std     r3, PACATMSCRATCH(r13) /* Stash returned-to MSR */
 838 #endif
 839         /*
 840          * r13 is our per cpu area, only restore it if we are returning to
 841          * userspace the value stored in the stack frame may belong to
 842          * another CPU.
 843          */
 844         andi.   r0,r3,MSR_PR
 845         beq     1f
 846 BEGIN_FTR_SECTION
 847         mtspr   SPRN_PPR,r2     /* Restore PPR */
 848 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 849         ACCOUNT_CPU_USER_EXIT(r2, r4)
 850         REST_GPR(13, r1)
 851 1:
 852         mtspr   SPRN_SRR1,r3
 853
 854         ld      r2,_CCR(r1)
 855         mtcrf   0xFF,r2
 856         ld      r2,_NIP(r1)
 857         mtspr   SPRN_SRR0,r2
 858
 859         ld      r0,GPR0(r1)
 860         ld      r2,GPR2(r1)
 861         ld      r3,GPR3(r1)
 862         ld      r4,GPR4(r1)
 863         ld      r1,GPR1(r1)
 864
 865         rfid
 866         b       .       /* prevent speculative execution */
 867
 868 #endif /* CONFIG_PPC_BOOK3E */
 869
 870         /*
 871          * We are returning to a context with interrupts soft disabled.
 872          *
 873          * However, we may also about to hard enable, so we need to
 874          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 875          * or that bit can get out of sync and bad things will happen
 876          */
 877 restore_irq_off:
 878         ld      r3,_MSR(r1)
 879         lbz     r7,PACAIRQHAPPENED(r13)
 880         andi.   r0,r3,MSR_EE
 881         beq     1f
 882         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 883         stb     r7,PACAIRQHAPPENED(r13)
 884 1:      li      r0,0
 885         stb     r0,PACASOFTIRQEN(r13);
 886         TRACE_DISABLE_INTS
 887         b       do_restore
 888
 889         /*
 890          * Something did happen, check if a re-emit is needed
 891          * (this also clears paca->irq_happened)
 892          */
 893 restore_check_irq_replay:
 894         /* XXX: We could implement a fast path here where we check
 895          * for irq_happened being just 0x01, in which case we can
 896          * clear it and return. That means that we would potentially
 897          * miss a decrementer having wrapped all the way around.
 898          *
 899          * Still, this might be useful for things like hash_page
 900          */
 901         bl      __check_irq_replay
 902         cmpwi   cr0,r3,0
 903         beq     restore_no_replay
 904
 905         /*
 906          * We need to re-emit an interrupt. We do so by re-using our
 907          * existing exception frame. We first change the trap value,
 908          * but we need to ensure we preserve the low nibble of it
 909          */
 910         ld      r4,_TRAP(r1)
 911         clrldi  r4,r4,60
 912         or      r4,r4,r3
 913         std     r4,_TRAP(r1)
 914
 915         /*
 916          * Then find the right handler and call it. Interrupts are
 917          * still soft-disabled and we keep them that way.
 918         */
 919         cmpwi   cr0,r3,0x500
 920         bne     1f
 921         addi    r3,r1,STACK_FRAME_OVERHEAD;
 922         bl      do_IRQ
 923         b       ret_from_except
 924 1:      cmpwi   cr0,r3,0xe60
 925         bne     1f
 926         addi    r3,r1,STACK_FRAME_OVERHEAD;
 927         bl      handle_hmi_exception
 928         b       ret_from_except
 929 1:      cmpwi   cr0,r3,0x900
 930         bne     1f
 931         addi    r3,r1,STACK_FRAME_OVERHEAD;
 932         bl      timer_interrupt
 933         b       ret_from_except
 934 #ifdef CONFIG_PPC_DOORBELL
 935 1:
 936 #ifdef CONFIG_PPC_BOOK3E
 937         cmpwi   cr0,r3,0x280
 938 #else
 939         BEGIN_FTR_SECTION
 940                 cmpwi   cr0,r3,0xe80
 941         FTR_SECTION_ELSE
 942                 cmpwi   cr0,r3,0xa00
 943         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 944 #endif /* CONFIG_PPC_BOOK3E */
 945         bne     1f
 946         addi    r3,r1,STACK_FRAME_OVERHEAD;
 947         bl      doorbell_exception
 948         b       ret_from_except
 949 #endif /* CONFIG_PPC_DOORBELL */
 950 1:      b       ret_from_except /* What else to do here ? */
 951
 952 unrecov_restore:
 953         addi    r3,r1,STACK_FRAME_OVERHEAD
 954         bl      unrecoverable_exception
 955         b       unrecov_restore
 956
 957 #ifdef CONFIG_PPC_RTAS
 958 /*
 959  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 960  * called with the MMU off.
 961  *
 962  * In addition, we need to be in 32b mode, at least for now.
 963  *
 964  * Note: r3 is an input parameter to rtas, so don't trash it...
 965  */
 966 _GLOBAL(enter_rtas)
 967         mflr    r0
 968         std     r0,16(r1)
 969         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 970
 971         /* Because RTAS is running in 32b mode, it clobbers the high order half
 972          * of all registers that it saves.  We therefore save those registers
 973          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 974          */
 975         SAVE_GPR(2, r1)                 /* Save the TOC */
 976         SAVE_GPR(13, r1)                /* Save paca */
 977         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 978         SAVE_10GPRS(22, r1)             /* ditto */
 979
 980         mfcr    r4
 981         std     r4,_CCR(r1)
 982         mfctr   r5
 983         std     r5,_CTR(r1)
 984         mfspr   r6,SPRN_XER
 985         std     r6,_XER(r1)
 986         mfdar   r7
 987         std     r7,_DAR(r1)
 988         mfdsisr r8
 989         std     r8,_DSISR(r1)
 990
 991         /* Temporary workaround to clear CR until RTAS can be modified to
 992          * ignore all bits.
 993          */
 994         li      r0,0
 995         mtcr    r0
 996
 997 #ifdef CONFIG_BUG
 998         /* There is no way it is acceptable to get here with interrupts enabled,
 999          * check it with the asm equivalent of WARN_ON
1000          */
1001         lbz     r0,PACASOFTIRQEN(r13)
1002 1:      tdnei   r0,0
1003         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
1004 #endif
1005
1006         /* Hard-disable interrupts */
1007         mfmsr   r6
1008         rldicl  r7,r6,48,1
1009         rotldi  r7,r7,16
1010         mtmsrd  r7,1
1011
1012         /* Unfortunately, the stack pointer and the MSR are also clobbered,
1013          * so they are saved in the PACA which allows us to restore
1014          * our original state after RTAS returns.
1015          */
1016         std     r1,PACAR1(r13)
1017         std     r6,PACASAVEDMSR(r13)
1018
1019         /* Setup our real return addr */
1020         LOAD_REG_ADDR(r4,rtas_return_loc)
1021         clrldi  r4,r4,2                 /* convert to realmode address */
1022         mtlr    r4
1023
1024         li      r0,0
1025         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
1026         andc    r0,r6,r0
1027
1028         li      r9,1
1029         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
1030         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI|MSR_LE
1031         andc    r6,r0,r9
1032         sync                            /* disable interrupts so SRR0/1 */
1033         mtmsrd  r0                      /* don't get trashed */
1034
1035         LOAD_REG_ADDR(r4, rtas)
1036         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
1037         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
1038
1039         mtspr   SPRN_SRR0,r5
1040         mtspr   SPRN_SRR1,r6
1041         rfid
1042         b       .       /* prevent speculative execution */
1043
1044 rtas_return_loc:
1045         FIXUP_ENDIAN
1046
1047         /* relocation is off at this point */
1048         GET_PACA(r4)
1049         clrldi  r4,r4,2                 /* convert to realmode address */
1050
1051         bcl     20,31,$+4
1052 0:      mflr    r3
1053         ld      r3,(1f-0b)(r3)          /* get &rtas_restore_regs */
1054
1055         mfmsr   r6
1056         li      r0,MSR_RI
1057         andc    r6,r6,r0
1058         sync
1059         mtmsrd  r6
1060
1061         ld      r1,PACAR1(r4)           /* Restore our SP */
1062         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
1063
1064         mtspr   SPRN_SRR0,r3
1065         mtspr   SPRN_SRR1,r4
1066         rfid
1067         b       .       /* prevent speculative execution */
1068
1069         .align  3
1070 1:      .llong  rtas_restore_regs
1071
1072 rtas_restore_regs:
1073         /* relocation is on at this point */
1074         REST_GPR(2, r1)                 /* Restore the TOC */
1075         REST_GPR(13, r1)                /* Restore paca */
1076         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
1077         REST_10GPRS(22, r1)             /* ditto */
1078
1079         GET_PACA(r13)
1080
1081         ld      r4,_CCR(r1)
1082         mtcr    r4
1083         ld      r5,_CTR(r1)
1084         mtctr   r5
1085         ld      r6,_XER(r1)
1086         mtspr   SPRN_XER,r6
1087         ld      r7,_DAR(r1)
1088         mtdar   r7
1089         ld      r8,_DSISR(r1)
1090         mtdsisr r8
1091
1092         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
1093         ld      r0,16(r1)               /* get return address */
1094
1095         mtlr    r0
1096         blr                             /* return to caller */
1097
1098 #endif /* CONFIG_PPC_RTAS */
1099
1100 _GLOBAL(enter_prom)
1101         mflr    r0
1102         std     r0,16(r1)
1103         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
1104
1105         /* Because PROM is running in 32b mode, it clobbers the high order half
1106          * of all registers that it saves.  We therefore save those registers
1107          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
1108          */
1109         SAVE_GPR(2, r1)
1110         SAVE_GPR(13, r1)
1111         SAVE_8GPRS(14, r1)
1112         SAVE_10GPRS(22, r1)
1113         mfcr    r10
1114         mfmsr   r11
1115         std     r10,_CCR(r1)
1116         std     r11,_MSR(r1)
1117
1118         /* Put PROM address in SRR0 */
1119         mtsrr0  r4
1120
1121         /* Setup our trampoline return addr in LR */
1122         bcl     20,31,$+4
1123 0:      mflr    r4
1124         addi    r4,r4,(1f - 0b)
1125         mtlr    r4
1126
1127         /* Prepare a 32-bit mode big endian MSR
1128          */
1129 #ifdef CONFIG_PPC_BOOK3E
1130         rlwinm  r11,r11,0,1,31
1131         mtsrr1  r11
1132         rfi
1133 #else /* CONFIG_PPC_BOOK3E */
1134         LOAD_REG_IMMEDIATE(r12, MSR_SF | MSR_ISF | MSR_LE)
1135         andc    r11,r11,r12
1136         mtsrr1  r11
1137         rfid
1138 #endif /* CONFIG_PPC_BOOK3E */
1139
1140 1:      /* Return from OF */
1141         FIXUP_ENDIAN
1142
1143         /* Just make sure that r1 top 32 bits didn't get
1144          * corrupt by OF
1145          */
1146         rldicl  r1,r1,0,32
1147
1148         /* Restore the MSR (back to 64 bits) */
1149         ld      r0,_MSR(r1)
1150         MTMSRD(r0)
1151         isync
1152
1153         /* Restore other registers */
1154         REST_GPR(2, r1)
1155         REST_GPR(13, r1)
1156         REST_8GPRS(14, r1)
1157         REST_10GPRS(22, r1)
1158         ld      r4,_CCR(r1)
1159         mtcr    r4
1160
1161         addi    r1,r1,PROM_FRAME_SIZE
1162         ld      r0,16(r1)
1163         mtlr    r0
1164         blr
1165
1166 #ifdef CONFIG_FUNCTION_TRACER
1167 #ifdef CONFIG_DYNAMIC_FTRACE
1168 _GLOBAL(mcount)
1169 _GLOBAL(_mcount)
1170         blr
1171
1172 _GLOBAL_TOC(ftrace_caller)
1173         /* Taken from output of objdump from lib64/glibc */
1174         mflr    r3
1175         ld      r11, 0(r1)
1176         stdu    r1, -112(r1)
1177         std     r3, 128(r1)
1178         ld      r4, 16(r11)
1179         subi    r3, r3, MCOUNT_INSN_SIZE
1180 .globl ftrace_call
1181 ftrace_call:
1182         bl      ftrace_stub
1183         nop
1184 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1185 .globl ftrace_graph_call
1186 ftrace_graph_call:
1187         b       ftrace_graph_stub
1188 _GLOBAL(ftrace_graph_stub)
1189 #endif
1190         ld      r0, 128(r1)
1191         mtlr    r0
1192         addi    r1, r1, 112
1193 _GLOBAL(ftrace_stub)
1194         blr
1195 #else
1196 _GLOBAL_TOC(_mcount)
1197         /* Taken from output of objdump from lib64/glibc */
1198         mflr    r3
1199         ld      r11, 0(r1)
1200         stdu    r1, -112(r1)
1201         std     r3, 128(r1)
1202         ld      r4, 16(r11)
1203
1204         subi    r3, r3, MCOUNT_INSN_SIZE
1205         LOAD_REG_ADDR(r5,ftrace_trace_function)
1206         ld      r5,0(r5)
1207         ld      r5,0(r5)
1208         mtctr   r5
1209         bctrl
1210         nop
1211
1212
1213 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1214         b       ftrace_graph_caller
1215 #endif
1216         ld      r0, 128(r1)
1217         mtlr    r0
1218         addi    r1, r1, 112
1219 _GLOBAL(ftrace_stub)
1220         blr
1221
1222 #endif /* CONFIG_DYNAMIC_FTRACE */
1223
1224 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1225 _GLOBAL(ftrace_graph_caller)
1226         /* load r4 with local address */
1227         ld      r4, 128(r1)
1228         subi    r4, r4, MCOUNT_INSN_SIZE
1229
1230         /* Grab the LR out of the caller stack frame */
1231         ld      r11, 112(r1)
1232         ld      r3, 16(r11)
1233
1234         bl      prepare_ftrace_return
1235         nop
1236
1237         /*
1238          * prepare_ftrace_return gives us the address we divert to.
1239          * Change the LR in the callers stack frame to this.
1240          */
1241         ld      r11, 112(r1)
1242         std     r3, 16(r11)
1243
1244         ld      r0, 128(r1)
1245         mtlr    r0
1246         addi    r1, r1, 112
1247         blr
1248
1249 _GLOBAL(return_to_handler)
1250         /* need to save return values */
1251         std     r4,  -32(r1)
1252         std     r3,  -24(r1)
1253         /* save TOC */
1254         std     r2,  -16(r1)
1255         std     r31, -8(r1)
1256         mr      r31, r1
1257         stdu    r1, -112(r1)
1258
1259         /*
1260          * We might be called from a module.
1261          * Switch to our TOC to run inside the core kernel.
1262          */
1263         ld      r2, PACATOC(r13)
1264
1265         bl      ftrace_return_to_handler
1266         nop
1267
1268         /* return value has real return address */
1269         mtlr    r3
1270
1271         ld      r1, 0(r1)
1272         ld      r4,  -32(r1)
1273         ld      r3,  -24(r1)
1274         ld      r2,  -16(r1)
1275         ld      r31, -8(r1)
1276
1277         /* Jump back to real return address */
1278         blr
1279 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1280 #endif /* CONFIG_FUNCTION_TRACER */