kernel/arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code / Linux gateway page
   5  * Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   6  * Licensed under the GNU GPL.
   7  * thanks to Philipp Rumpf, Mike Shaver and various others
   8  * sorry about the wall, puffin..
   9  */
  10
  11 /*
  12 How does the Linux gateway page on PA-RISC work?
  13 ------------------------------------------------
  14 The Linux gateway page on PA-RISC is "special".
  15 It actually has PAGE_GATEWAY bits set (this is linux terminology; in parisc
  16 terminology it's Execute, promote to PL0) in the page map.  So anything
  17 executing on this page executes with kernel level privilege (there's more to it
  18 than that: to have this happen, you also have to use a branch with a ,gate
  19 completer to activate the privilege promotion).  The upshot is that everything
  20 that runs on the gateway page runs at kernel privilege but with the current
  21 user process address space (although you have access to kernel space via %sr2).
  22 For the 0x100 syscall entry, we redo the space registers to point to the kernel
  23 address space (preserving the user address space in %sr3), move to wide mode if
  24 required, save the user registers and branch into the kernel syscall entry
  25 point.  For all the other functions, we execute at kernel privilege but don't
  26 flip address spaces. The basic upshot of this is that these code snippets are
  27 executed atomically (because the kernel can't be pre-empted) and they may
  28 perform architecturally forbidden (to PL3) operations (like setting control
  29 registers).
  30 */
  31
  32
  33 #include <asm/asm-offsets.h>
  34 #include <asm/unistd.h>
  35 #include <asm/errno.h>
  36 #include <asm/page.h>
  37 #include <asm/psw.h>
  38 #include <asm/thread_info.h>
  39 #include <asm/assembly.h>
  40 #include <asm/processor.h>
  41 #include <asm/cache.h>
  42
  43 #include <linux/linkage.h>
  44
  45         /* We fill the empty parts of the gateway page with
  46          * something that will kill the kernel or a
  47          * userspace application.
  48          */
  49 #define KILL_INSN       break   0,0
  50
  51         .level          LEVEL
  52
  53         .text
  54
  55         .import syscall_exit,code
  56         .import syscall_exit_rfi,code
  57
  58         /* Linux gateway page is aliased to virtual page 0 in the kernel
  59          * address space. Since it is a gateway page it cannot be
  60          * dereferenced, so null pointers will still fault. We start
  61          * the actual entry point at 0x100. We put break instructions
  62          * at the beginning of the page to trap null indirect function
  63          * pointers.
  64          */
  65
  66         .align PAGE_SIZE
  67 ENTRY(linux_gateway_page)
  68
  69         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  70         .rept 44
  71         KILL_INSN
  72         .endr
  73
  74         /* ADDRESS 0xb0 to 0xb8, lws uses two insns for entry */
  75         /* Light-weight-syscall entry must always be located at 0xb0 */
  76         /* WARNING: Keep this number updated with table size changes */
  77 #define __NR_lws_entries (3)
  78
  79 lws_entry:
  80         gate    lws_start, %r0          /* increase privilege */
  81         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  82
  83         /* Fill from 0xb8 to 0xe0 */
  84         .rept 10
  85         KILL_INSN
  86         .endr
  87
  88         /* This function MUST be located at 0xe0 for glibc's threading
  89         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  90 set_thread_pointer:
  91         gate    .+8, %r0                /* increase privilege */
  92         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  93         be      0(%sr7,%r31)            /* return to user space */
  94         mtctl   %r26, %cr27             /* move arg0 to the control register */
  95
  96         /* Increase the chance of trapping if random jumps occur to this
  97         address, fill from 0xf0 to 0x100 */
  98         .rept 4
  99         KILL_INSN
 100         .endr
 101
 102 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
 103         .align 256
 104 linux_gateway_entry:
 105         gate    .+8, %r0                        /* become privileged */
 106         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
 107         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
 108         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
 109
 110 #ifdef CONFIG_64BIT
 111         /* for now we can *always* set the W bit on entry to the syscall
 112          * since we don't support wide userland processes.  We could
 113          * also save the current SM other than in r0 and restore it on
 114          * exit from the syscall, and also use that value to know
 115          * whether to do narrow or wide syscalls. -PB
 116          */
 117         ssm     PSW_SM_W, %r1
 118         extrd,u %r1,PSW_W_BIT,1,%r1
 119         /* sp must be aligned on 4, so deposit the W bit setting into
 120          * the bottom of sp temporarily */
 121         or,ev   %r1,%r30,%r30
 122         b,n     1f
 123         /* The top halves of argument registers must be cleared on syscall
 124          * entry from narrow executable.
 125          */
 126         depdi   0, 31, 32, %r26
 127         depdi   0, 31, 32, %r25
 128         depdi   0, 31, 32, %r24
 129         depdi   0, 31, 32, %r23
 130         depdi   0, 31, 32, %r22
 131         depdi   0, 31, 32, %r21
 132 1:
 133 #endif
 134
 135         /* We use a rsm/ssm pair to prevent sr3 from being clobbered
 136          * by external interrupts.
 137          */
 138         mfsp    %sr7,%r1                        /* save user sr7 */
 139         rsm     PSW_SM_I, %r0                   /* disable interrupts */
 140         mtsp    %r1,%sr3                        /* and store it in sr3 */
 141
 142         mfctl   %cr30,%r1
 143         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 144         xor     %r1,%r30,%r1
 145         xor     %r1,%r30,%r30
 146
 147         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 148
 149         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 150          *       contains a valid kernel stack pointer. It is also
 151          *       critical that we don't start using the kernel stack
 152          *       until after sr7 has been set to 0.
 153          */
 154
 155         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 156         ssm     PSW_SM_I, %r0                   /* enable interrupts */
 157         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 158         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 159         LDREG   TI_TASK(%r1),%r1
 160
 161         /* Save some registers for sigcontext and potential task
 162            switch (see entry.S for the details of which ones are
 163            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 164            a process is on a syscall or not.  For an interrupt the real
 165            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 166         STREG   %r0,  TASK_PT_PSW(%r1)
 167         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 168         STREG   %r19, TASK_PT_GR19(%r1)
 169
 170         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 171 #ifdef CONFIG_64BIT
 172         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 173 #if 0
 174         xor     %r19,%r2,%r2                    /* clear bottom bit */
 175         depd,z  %r19,1,1,%r19
 176         std     %r19,TASK_PT_PSW(%r1)
 177 #endif
 178 #endif
 179         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 180
 181         STREG   %r20, TASK_PT_GR20(%r1)         /* Syscall number */
 182         STREG   %r21, TASK_PT_GR21(%r1)
 183         STREG   %r22, TASK_PT_GR22(%r1)
 184         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 185         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 186         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 187         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 188         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 189         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 190         STREG   %r0, TASK_PT_ORIG_R28(%r1)      /* don't prohibit restarts */
 191         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 192         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 193
 194         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 195         save_fp %r27                            /* or potential task switch  */
 196
 197         mfctl   %cr11, %r27                     /* i.e. SAR */
 198         STREG   %r27, TASK_PT_SAR(%r1)
 199
 200         loadgp
 201
 202 #ifdef CONFIG_64BIT
 203         ldo     -16(%r30),%r29                  /* Reference param save area */
 204         copy    %r19,%r2                        /* W bit back to r2 */
 205 #else
 206         /* no need to save these on stack in wide mode because the first 8
 207          * args are passed in registers */
 208         stw     %r22, -52(%r30)                 /* 5th argument */
 209         stw     %r21, -56(%r30)                 /* 6th argument */
 210 #endif
 211
 212         /* Are we being ptraced? */
 213         mfctl   %cr30, %r1
 214         LDREG   TI_FLAGS(%r1),%r1
 215         ldi     _TIF_SYSCALL_TRACE_MASK, %r19
 216         and,COND(=) %r1, %r19, %r0
 217         b,n     .Ltracesys
 218
 219         /* Note!  We cannot use the syscall table that is mapped
 220         nearby since the gateway page is mapped execute-only. */
 221
 222 #ifdef CONFIG_64BIT
 223         ldil    L%sys_call_table, %r1
 224         or,=    %r2,%r2,%r2
 225         addil   L%(sys_call_table64-sys_call_table), %r1
 226         ldo     R%sys_call_table(%r1), %r19
 227         or,=    %r2,%r2,%r2
 228         ldo     R%sys_call_table64(%r1), %r19
 229 #else
 230         ldil    L%sys_call_table, %r1
 231         ldo     R%sys_call_table(%r1), %r19
 232 #endif
 233         comiclr,>>      __NR_Linux_syscalls, %r20, %r0
 234         b,n     .Lsyscall_nosys
 235
 236         LDREGX  %r20(%r19), %r19
 237
 238         /* If this is a sys_rt_sigreturn call, and the signal was received
 239          * when not in_syscall, then we want to return via syscall_exit_rfi,
 240          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 241          * trampoline code in signal.c).
 242          */
 243         ldi     __NR_rt_sigreturn,%r2
 244         comb,=  %r2,%r20,.Lrt_sigreturn
 245 .Lin_syscall:
 246         ldil    L%syscall_exit,%r2
 247         be      0(%sr7,%r19)
 248         ldo     R%syscall_exit(%r2),%r2
 249 .Lrt_sigreturn:
 250         comib,<> 0,%r25,.Lin_syscall
 251         ldil    L%syscall_exit_rfi,%r2
 252         be      0(%sr7,%r19)
 253         ldo     R%syscall_exit_rfi(%r2),%r2
 254
 255         /* Note!  Because we are not running where we were linked, any
 256         calls to functions external to this file must be indirect.  To
 257         be safe, we apply the opposite rule to functions within this
 258         file, with local labels given to them to ensure correctness. */
 259
 260 .Lsyscall_nosys:
 261 syscall_nosys:
 262         ldil    L%syscall_exit,%r1
 263         be      R%syscall_exit(%sr7,%r1)
 264         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 265
 266
 267 /* Warning! This trace code is a virtual duplicate of the code above so be
 268  * sure to maintain both! */
 269 .Ltracesys:
 270 tracesys:
 271         /* Need to save more registers so the debugger can see where we
 272          * are.  This saves only the lower 8 bits of PSW, so that the C
 273          * bit is still clear on syscalls, and the D bit is set if this
 274          * full register save path has been executed.  We check the D
 275          * bit on syscall_return_rfi to determine which registers to
 276          * restore.  An interrupt results in a full PSW saved with the
 277          * C bit set, a non-straced syscall entry results in C and D clear
 278          * in the saved PSW.
 279          */
 280         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 281         LDREG   TI_TASK(%r1), %r1
 282         ssm     0,%r2
 283         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 284         mfsp    %sr0,%r2
 285         STREG   %r2,TASK_PT_SR0(%r1)
 286         mfsp    %sr1,%r2
 287         STREG   %r2,TASK_PT_SR1(%r1)
 288         mfsp    %sr2,%r2
 289         STREG   %r2,TASK_PT_SR2(%r1)
 290         mfsp    %sr3,%r2
 291         STREG   %r2,TASK_PT_SR3(%r1)
 292         STREG   %r2,TASK_PT_SR4(%r1)
 293         STREG   %r2,TASK_PT_SR5(%r1)
 294         STREG   %r2,TASK_PT_SR6(%r1)
 295         STREG   %r2,TASK_PT_SR7(%r1)
 296         STREG   %r2,TASK_PT_IASQ0(%r1)
 297         STREG   %r2,TASK_PT_IASQ1(%r1)
 298         LDREG   TASK_PT_GR31(%r1),%r2
 299         STREG   %r2,TASK_PT_IAOQ0(%r1)
 300         ldo     4(%r2),%r2
 301         STREG   %r2,TASK_PT_IAOQ1(%r1)
 302         ldo     TASK_REGS(%r1),%r2
 303         /* reg_save %r2 */
 304         STREG   %r3,PT_GR3(%r2)
 305         STREG   %r4,PT_GR4(%r2)
 306         STREG   %r5,PT_GR5(%r2)
 307         STREG   %r6,PT_GR6(%r2)
 308         STREG   %r7,PT_GR7(%r2)
 309         STREG   %r8,PT_GR8(%r2)
 310         STREG   %r9,PT_GR9(%r2)
 311         STREG   %r10,PT_GR10(%r2)
 312         STREG   %r11,PT_GR11(%r2)
 313         STREG   %r12,PT_GR12(%r2)
 314         STREG   %r13,PT_GR13(%r2)
 315         STREG   %r14,PT_GR14(%r2)
 316         STREG   %r15,PT_GR15(%r2)
 317         STREG   %r16,PT_GR16(%r2)
 318         STREG   %r17,PT_GR17(%r2)
 319         STREG   %r18,PT_GR18(%r2)
 320         /* Finished saving things for the debugger */
 321
 322         copy    %r2,%r26
 323         ldil    L%do_syscall_trace_enter,%r1
 324         ldil    L%tracesys_next,%r2
 325         be      R%do_syscall_trace_enter(%sr7,%r1)
 326         ldo     R%tracesys_next(%r2),%r2
 327
 328 tracesys_next:
 329         /* do_syscall_trace_enter either returned the syscallno, or -1L,
 330          *  so we skip restoring the PT_GR20 below, since we pulled it from
 331          *  task->thread.regs.gr[20] above.
 332          */
 333         copy    %ret0,%r20
 334         ldil    L%sys_call_table,%r1
 335         ldo     R%sys_call_table(%r1), %r19
 336
 337         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 338         LDREG   TI_TASK(%r1), %r1
 339         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 340         LDREG   TASK_PT_GR25(%r1), %r25
 341         LDREG   TASK_PT_GR24(%r1), %r24
 342         LDREG   TASK_PT_GR23(%r1), %r23
 343         LDREG   TASK_PT_GR22(%r1), %r22
 344         LDREG   TASK_PT_GR21(%r1), %r21
 345 #ifdef CONFIG_64BIT
 346         ldo     -16(%r30),%r29                  /* Reference param save area */
 347 #else
 348         stw     %r22, -52(%r30)                 /* 5th argument */
 349         stw     %r21, -56(%r30)                 /* 6th argument */
 350 #endif
 351
 352         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 353         b,n     .Ltracesys_nosys
 354
 355         LDREGX  %r20(%r19), %r19
 356
 357         /* If this is a sys_rt_sigreturn call, and the signal was received
 358          * when not in_syscall, then we want to return via syscall_exit_rfi,
 359          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 360          * trampoline code in signal.c).
 361          */
 362         ldi     __NR_rt_sigreturn,%r2
 363         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 364 .Ltrace_in_syscall:
 365         ldil    L%tracesys_exit,%r2
 366         be      0(%sr7,%r19)
 367         ldo     R%tracesys_exit(%r2),%r2
 368
 369 .Ltracesys_nosys:
 370         ldo     -ENOSYS(%r0),%r28               /* set errno */
 371
 372         /* Do *not* call this function on the gateway page, because it
 373         makes a direct call to syscall_trace. */
 374
 375 tracesys_exit:
 376         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 377         LDREG   TI_TASK(%r1), %r1
 378 #ifdef CONFIG_64BIT
 379         ldo     -16(%r30),%r29                  /* Reference param save area */
 380 #endif
 381         ldo     TASK_REGS(%r1),%r26
 382         BL      do_syscall_trace_exit,%r2
 383         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 384         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 385         LDREG   TI_TASK(%r1), %r1
 386         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 387
 388         ldil    L%syscall_exit,%r1
 389         be,n    R%syscall_exit(%sr7,%r1)
 390
 391 .Ltrace_rt_sigreturn:
 392         comib,<> 0,%r25,.Ltrace_in_syscall
 393         ldil    L%tracesys_sigexit,%r2
 394         be      0(%sr7,%r19)
 395         ldo     R%tracesys_sigexit(%r2),%r2
 396
 397 tracesys_sigexit:
 398         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 399         LDREG   TI_TASK(%r1), %r1
 400 #ifdef CONFIG_64BIT
 401         ldo     -16(%r30),%r29                  /* Reference param save area */
 402 #endif
 403         BL      do_syscall_trace_exit,%r2
 404         ldo     TASK_REGS(%r1),%r26
 405
 406         ldil    L%syscall_exit_rfi,%r1
 407         be,n    R%syscall_exit_rfi(%sr7,%r1)
 408
 409
 410         /*********************************************************
 411                 32/64-bit Light-Weight-Syscall ABI
 412
 413                 * - Indicates a hint for userspace inline asm
 414                 implementations.
 415
 416                 Syscall number (caller-saves)
 417                 - %r20
 418                 * In asm clobber.
 419
 420                 Argument registers (caller-saves)
 421                 - %r26, %r25, %r24, %r23, %r22
 422                 * In asm input.
 423
 424                 Return registers (caller-saves)
 425                 - %r28 (return), %r21 (errno)
 426                 * In asm output.
 427
 428                 Caller-saves registers
 429                 - %r1, %r27, %r29
 430                 - %r2 (return pointer)
 431                 - %r31 (ble link register)
 432                 * In asm clobber.
 433
 434                 Callee-saves registers
 435                 - %r3-%r18
 436                 - %r30 (stack pointer)
 437                 * Not in asm clobber.
 438
 439                 If userspace is 32-bit:
 440                 Callee-saves registers
 441                 - %r19 (32-bit PIC register)
 442
 443                 Differences from 32-bit calling convention:
 444                 - Syscall number in %r20
 445                 - Additional argument register %r22 (arg4)
 446                 - Callee-saves %r19.
 447
 448                 If userspace is 64-bit:
 449                 Callee-saves registers
 450                 - %r27 (64-bit PIC register)
 451
 452                 Differences from 64-bit calling convention:
 453                 - Syscall number in %r20
 454                 - Additional argument register %r22 (arg4)
 455                 - Callee-saves %r27.
 456
 457                 Error codes returned by entry path:
 458
 459                 ENOSYS - r20 was an invalid LWS number.
 460
 461         *********************************************************/
 462 lws_start:
 463
 464 #ifdef CONFIG_64BIT
 465         /* FIXME: If we are a 64-bit kernel just
 466          *        turn this on unconditionally.
 467          */
 468         ssm     PSW_SM_W, %r1
 469         extrd,u %r1,PSW_W_BIT,1,%r1
 470         /* sp must be aligned on 4, so deposit the W bit setting into
 471          * the bottom of sp temporarily */
 472         or,ev   %r1,%r30,%r30
 473
 474         /* Clip LWS number to a 32-bit value always */
 475         depdi   0, 31, 32, %r20
 476 #endif
 477
 478         /* Is the lws entry number valid? */
 479         comiclr,>>      __NR_lws_entries, %r20, %r0
 480         b,n     lws_exit_nosys
 481
 482         /* WARNING: Trashing sr2 and sr3 */
 483         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 484         mtsp    %r1,%sr3
 485         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 486
 487         /* Load table start */
 488         ldil    L%lws_table, %r1
 489         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 490         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 491
 492         /* Jump to lws, lws table pointers already relocated */
 493         be,n    0(%sr2,%r21)
 494
 495 lws_exit_nosys:
 496         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 497         /* Fall through: Return to userspace */
 498
 499 lws_exit:
 500 #ifdef CONFIG_64BIT
 501         /* decide whether to reset the wide mode bit
 502          *
 503          * For a syscall, the W bit is stored in the lowest bit
 504          * of sp.  Extract it and reset W if it is zero */
 505         extrd,u,*<>     %r30,63,1,%r1
 506         rsm     PSW_SM_W, %r0
 507         /* now reset the lowest bit of sp if it was set */
 508         xor     %r30,%r1,%r30
 509 #endif
 510         be,n    0(%sr7, %r31)
 511
 512
 513
 514         /***************************************************
 515                 Implementing 32bit CAS as an atomic operation:
 516
 517                 %r26 - Address to examine
 518                 %r25 - Old value to check (old)
 519                 %r24 - New value to set (new)
 520                 %r28 - Return prev through this register.
 521                 %r21 - Kernel error code
 522
 523                 If debugging is DISabled:
 524
 525                 %r21 has the following meanings:
 526
 527                 EAGAIN - CAS is busy, ldcw failed, try again.
 528                 EFAULT - Read or write failed.
 529
 530                 If debugging is enabled:
 531
 532                 EDEADLOCK - CAS called recursively.
 533                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 534                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 535                 EFAULT - Read or write failed.
 536
 537                 Scratch: r20, r28, r1
 538
 539         ****************************************************/
 540
 541         /* Do not enable LWS debugging */
 542 #define ENABLE_LWS_DEBUG 0
 543
 544         /* ELF64 Process entry path */
 545 lws_compare_and_swap64:
 546 #ifdef CONFIG_64BIT
 547         b,n     lws_compare_and_swap
 548 #else
 549         /* If we are not a 64-bit kernel, then we don't
 550          * have 64-bit input registers, and calling
 551          * the 64-bit LWS CAS returns ENOSYS.
 552          */
 553         b,n     lws_exit_nosys
 554 #endif
 555
 556         /* ELF32 Process entry path */
 557 lws_compare_and_swap32:
 558 #ifdef CONFIG_64BIT
 559         /* Clip all the input registers */
 560         depdi   0, 31, 32, %r26
 561         depdi   0, 31, 32, %r25
 562         depdi   0, 31, 32, %r24
 563 #endif
 564
 565 lws_compare_and_swap:
 566         /* Load start of lock table */
 567         ldil    L%lws_lock_start, %r20
 568         ldo     R%lws_lock_start(%r20), %r28
 569
 570         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 571         extru  %r26, 27, 4, %r20
 572
 573         /* Find lock to use, the hash is either one of 0 to
 574            15, multiplied by 16 (keep it 16-byte aligned)
 575            and add to the lock table offset. */
 576         shlw    %r20, 4, %r20
 577         add     %r20, %r28, %r20
 578
 579 # if ENABLE_LWS_DEBUG
 580         /*
 581                 DEBUG, check for deadlock!
 582                 If the thread register values are the same
 583                 then we were the one that locked it last and
 584                 this is a recurisve call that will deadlock.
 585                 We *must* giveup this call and fail.
 586         */
 587         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 588         /* WARNING: If cr27 cycles to the same value we have problems */
 589         mfctl   %cr27, %r21                             /* Get current thread register */
 590         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 591         b       lws_exit                                /* Return error! */
 592         ldo     -EDEADLOCK(%r0), %r21
 593 cas_lock:
 594         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 595         ldo     1(%r0), %r28                            /* 1st case */
 596         b       lws_exit                                /* Contended... */
 597         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 598 cas_nocontend:
 599 # endif
 600 /* ENABLE_LWS_DEBUG */
 601
 602         rsm     PSW_SM_I, %r0                           /* Disable interrupts */
 603         /* COW breaks can cause contention on UP systems */
 604         LDCW    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 605         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 606 cas_wouldblock:
 607         ldo     2(%r0), %r28                            /* 2nd case */
 608         ssm     PSW_SM_I, %r0
 609         b       lws_exit                                /* Contended... */
 610         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 611
 612         /*
 613                 prev = *addr;
 614                 if ( prev == old )
 615                   *addr = new;
 616                 return prev;
 617         */
 618
 619         /* NOTES:
 620                 This all works becuse intr_do_signal
 621                 and schedule both check the return iasq
 622                 and see that we are on the kernel page
 623                 so this process is never scheduled off
 624                 or is ever sent any signal of any sort,
 625                 thus it is wholly atomic from usrspaces
 626                 perspective
 627         */
 628 cas_action:
 629 #if defined CONFIG_SMP && ENABLE_LWS_DEBUG
 630         /* DEBUG */
 631         mfctl   %cr27, %r1
 632         stw     %r1, 4(%sr2,%r20)
 633 #endif
 634         /* The load and store could fail */
 635 1:      ldw,ma  0(%sr3,%r26), %r28
 636         sub,<>  %r28, %r25, %r0
 637 2:      stw,ma  %r24, 0(%sr3,%r26)
 638         /* Free lock */
 639         stw,ma  %r20, 0(%sr2,%r20)
 640 #if ENABLE_LWS_DEBUG
 641         /* Clear thread register indicator */
 642         stw     %r0, 4(%sr2,%r20)
 643 #endif
 644         /* Enable interrupts */
 645         ssm     PSW_SM_I, %r0
 646         /* Return to userspace, set no error */
 647         b       lws_exit
 648         copy    %r0, %r21
 649
 650 3:
 651         /* Error occurred on load or store */
 652         /* Free lock */
 653         stw     %r20, 0(%sr2,%r20)
 654 #if ENABLE_LWS_DEBUG
 655         stw     %r0, 4(%sr2,%r20)
 656 #endif
 657         ssm     PSW_SM_I, %r0
 658         b       lws_exit
 659         ldo     -EFAULT(%r0),%r21       /* set errno */
 660         nop
 661         nop
 662         nop
 663         nop
 664
 665         /* Two exception table entries, one for the load,
 666            the other for the store. Either return -EFAULT.
 667            Each of the entries must be relocated. */
 668         ASM_EXCEPTIONTABLE_ENTRY(1b-linux_gateway_page, 3b-linux_gateway_page)
 669         ASM_EXCEPTIONTABLE_ENTRY(2b-linux_gateway_page, 3b-linux_gateway_page)
 670
 671
 672         /***************************************************
 673                 New CAS implementation which uses pointers and variable size
 674                 information. The value pointed by old and new MUST NOT change
 675                 while performing CAS. The lock only protect the value at %r26.
 676
 677                 %r26 - Address to examine
 678                 %r25 - Pointer to the value to check (old)
 679                 %r24 - Pointer to the value to set (new)
 680                 %r23 - Size of the variable (0/1/2/3 for 8/16/32/64 bit)
 681                 %r28 - Return non-zero on failure
 682                 %r21 - Kernel error code
 683
 684                 %r21 has the following meanings:
 685
 686                 EAGAIN - CAS is busy, ldcw failed, try again.
 687                 EFAULT - Read or write failed.
 688
 689                 Scratch: r20, r22, r28, r29, r1, fr4 (32bit for 64bit CAS only)
 690
 691         ****************************************************/
 692
 693         /* ELF32 Process entry path */
 694 lws_compare_and_swap_2:
 695 #ifdef CONFIG_64BIT
 696         /* Clip the input registers */
 697         depdi   0, 31, 32, %r26
 698         depdi   0, 31, 32, %r25
 699         depdi   0, 31, 32, %r24
 700         depdi   0, 31, 32, %r23
 701 #endif
 702
 703         /* Check the validity of the size pointer */
 704         subi,>>= 4, %r23, %r0
 705         b,n     lws_exit_nosys
 706
 707         /* Jump to the functions which will load the old and new values into
 708            registers depending on the their size */
 709         shlw    %r23, 2, %r29
 710         blr     %r29, %r0
 711         nop
 712
 713         /* 8bit load */
 714 4:      ldb     0(%sr3,%r25), %r25
 715         b       cas2_lock_start
 716 5:      ldb     0(%sr3,%r24), %r24
 717         nop
 718         nop
 719         nop
 720         nop
 721         nop
 722
 723         /* 16bit load */
 724 6:      ldh     0(%sr3,%r25), %r25
 725         b       cas2_lock_start
 726 7:      ldh     0(%sr3,%r24), %r24
 727         nop
 728         nop
 729         nop
 730         nop
 731         nop
 732
 733         /* 32bit load */
 734 8:      ldw     0(%sr3,%r25), %r25
 735         b       cas2_lock_start
 736 9:      ldw     0(%sr3,%r24), %r24
 737         nop
 738         nop
 739         nop
 740         nop
 741         nop
 742
 743         /* 64bit load */
 744 #ifdef CONFIG_64BIT
 745 10:     ldd     0(%sr3,%r25), %r25
 746 11:     ldd     0(%sr3,%r24), %r24
 747 #else
 748         /* Load new value into r22/r23 - high/low */
 749 10:     ldw     0(%sr3,%r25), %r22
 750 11:     ldw     4(%sr3,%r25), %r23
 751         /* Load new value into fr4 for atomic store later */
 752 12:     flddx   0(%sr3,%r24), %fr4
 753 #endif
 754
 755 cas2_lock_start:
 756         /* Load start of lock table */
 757         ldil    L%lws_lock_start, %r20
 758         ldo     R%lws_lock_start(%r20), %r28
 759
 760         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 761         extru  %r26, 27, 4, %r20
 762
 763         /* Find lock to use, the hash is either one of 0 to
 764            15, multiplied by 16 (keep it 16-byte aligned)
 765            and add to the lock table offset. */
 766         shlw    %r20, 4, %r20
 767         add     %r20, %r28, %r20
 768
 769         rsm     PSW_SM_I, %r0                   /* Disable interrupts */
 770         /* COW breaks can cause contention on UP systems */
 771         LDCW    0(%sr2,%r20), %r28              /* Try to acquire the lock */
 772         cmpb,<>,n       %r0, %r28, cas2_action  /* Did we get it? */
 773 cas2_wouldblock:
 774         ldo     2(%r0), %r28                    /* 2nd case */
 775         ssm     PSW_SM_I, %r0
 776         b       lws_exit                        /* Contended... */
 777         ldo     -EAGAIN(%r0), %r21              /* Spin in userspace */
 778
 779         /*
 780                 prev = *addr;
 781                 if ( prev == old )
 782                   *addr = new;
 783                 return prev;
 784         */
 785
 786         /* NOTES:
 787                 This all works becuse intr_do_signal
 788                 and schedule both check the return iasq
 789                 and see that we are on the kernel page
 790                 so this process is never scheduled off
 791                 or is ever sent any signal of any sort,
 792                 thus it is wholly atomic from usrspaces
 793                 perspective
 794         */
 795 cas2_action:
 796         /* Jump to the correct function */
 797         blr     %r29, %r0
 798         /* Set %r28 as non-zero for now */
 799         ldo     1(%r0),%r28
 800
 801         /* 8bit CAS */
 802 13:     ldb,ma  0(%sr3,%r26), %r29
 803         sub,=   %r29, %r25, %r0
 804         b,n     cas2_end
 805 14:     stb,ma  %r24, 0(%sr3,%r26)
 806         b       cas2_end
 807         copy    %r0, %r28
 808         nop
 809         nop
 810
 811         /* 16bit CAS */
 812 15:     ldh,ma  0(%sr3,%r26), %r29
 813         sub,=   %r29, %r25, %r0
 814         b,n     cas2_end
 815 16:     sth,ma  %r24, 0(%sr3,%r26)
 816         b       cas2_end
 817         copy    %r0, %r28
 818         nop
 819         nop
 820
 821         /* 32bit CAS */
 822 17:     ldw,ma  0(%sr3,%r26), %r29
 823         sub,=   %r29, %r25, %r0
 824         b,n     cas2_end
 825 18:     stw,ma  %r24, 0(%sr3,%r26)
 826         b       cas2_end
 827         copy    %r0, %r28
 828         nop
 829         nop
 830
 831         /* 64bit CAS */
 832 #ifdef CONFIG_64BIT
 833 19:     ldd,ma  0(%sr3,%r26), %r29
 834         sub,*=  %r29, %r25, %r0
 835         b,n     cas2_end
 836 20:     std,ma  %r24, 0(%sr3,%r26)
 837         copy    %r0, %r28
 838 #else
 839         /* Compare first word */
 840 19:     ldw,ma  0(%sr3,%r26), %r29
 841         sub,=   %r29, %r22, %r0
 842         b,n     cas2_end
 843         /* Compare second word */
 844 20:     ldw,ma  4(%sr3,%r26), %r29
 845         sub,=   %r29, %r23, %r0
 846         b,n     cas2_end
 847         /* Perform the store */
 848 21:     fstdx   %fr4, 0(%sr3,%r26)
 849         copy    %r0, %r28
 850 #endif
 851
 852 cas2_end:
 853         /* Free lock */
 854         stw,ma  %r20, 0(%sr2,%r20)
 855         /* Enable interrupts */
 856         ssm     PSW_SM_I, %r0
 857         /* Return to userspace, set no error */
 858         b       lws_exit
 859         copy    %r0, %r21
 860
 861 22:
 862         /* Error occurred on load or store */
 863         /* Free lock */
 864         stw     %r20, 0(%sr2,%r20)
 865         ssm     PSW_SM_I, %r0
 866         ldo     1(%r0),%r28
 867         b       lws_exit
 868         ldo     -EFAULT(%r0),%r21       /* set errno */
 869         nop
 870         nop
 871         nop
 872
 873         /* Exception table entries, for the load and store, return EFAULT.
 874            Each of the entries must be relocated. */
 875         ASM_EXCEPTIONTABLE_ENTRY(4b-linux_gateway_page, 22b-linux_gateway_page)
 876         ASM_EXCEPTIONTABLE_ENTRY(5b-linux_gateway_page, 22b-linux_gateway_page)
 877         ASM_EXCEPTIONTABLE_ENTRY(6b-linux_gateway_page, 22b-linux_gateway_page)
 878         ASM_EXCEPTIONTABLE_ENTRY(7b-linux_gateway_page, 22b-linux_gateway_page)
 879         ASM_EXCEPTIONTABLE_ENTRY(8b-linux_gateway_page, 22b-linux_gateway_page)
 880         ASM_EXCEPTIONTABLE_ENTRY(9b-linux_gateway_page, 22b-linux_gateway_page)
 881         ASM_EXCEPTIONTABLE_ENTRY(10b-linux_gateway_page, 22b-linux_gateway_page)
 882         ASM_EXCEPTIONTABLE_ENTRY(11b-linux_gateway_page, 22b-linux_gateway_page)
 883         ASM_EXCEPTIONTABLE_ENTRY(13b-linux_gateway_page, 22b-linux_gateway_page)
 884         ASM_EXCEPTIONTABLE_ENTRY(14b-linux_gateway_page, 22b-linux_gateway_page)
 885         ASM_EXCEPTIONTABLE_ENTRY(15b-linux_gateway_page, 22b-linux_gateway_page)
 886         ASM_EXCEPTIONTABLE_ENTRY(16b-linux_gateway_page, 22b-linux_gateway_page)
 887         ASM_EXCEPTIONTABLE_ENTRY(17b-linux_gateway_page, 22b-linux_gateway_page)
 888         ASM_EXCEPTIONTABLE_ENTRY(18b-linux_gateway_page, 22b-linux_gateway_page)
 889         ASM_EXCEPTIONTABLE_ENTRY(19b-linux_gateway_page, 22b-linux_gateway_page)
 890         ASM_EXCEPTIONTABLE_ENTRY(20b-linux_gateway_page, 22b-linux_gateway_page)
 891 #ifndef CONFIG_64BIT
 892         ASM_EXCEPTIONTABLE_ENTRY(12b-linux_gateway_page, 22b-linux_gateway_page)
 893         ASM_EXCEPTIONTABLE_ENTRY(21b-linux_gateway_page, 22b-linux_gateway_page)
 894 #endif
 895
 896         /* Make sure nothing else is placed on this page */
 897         .align PAGE_SIZE
 898 END(linux_gateway_page)
 899 ENTRY(end_linux_gateway_page)
 900
 901         /* Relocate symbols assuming linux_gateway_page is mapped
 902            to virtual address 0x0 */
 903
 904 #define LWS_ENTRY(_name_) ASM_ULONG_INSN (lws_##_name_ - linux_gateway_page)
 905
 906         .section .rodata,"a"
 907
 908         .align 8
 909         /* Light-weight-syscall table */
 910         /* Start of lws table. */
 911 ENTRY(lws_table)
 912         LWS_ENTRY(compare_and_swap32)           /* 0 - ELF32 Atomic 32bit CAS */
 913         LWS_ENTRY(compare_and_swap64)           /* 1 - ELF64 Atomic 32bit CAS */
 914         LWS_ENTRY(compare_and_swap_2)           /* 2 - ELF32 Atomic 64bit CAS */
 915 END(lws_table)
 916         /* End of lws table */
 917
 918         .align 8
 919 ENTRY(sys_call_table)
 920 #include "syscall_table.S"
 921 END(sys_call_table)
 922
 923 #ifdef CONFIG_64BIT
 924         .align 8
 925 ENTRY(sys_call_table64)
 926 #define SYSCALL_TABLE_64BIT
 927 #include "syscall_table.S"
 928 END(sys_call_table64)
 929 #endif
 930
 931         /*
 932                 All light-weight-syscall atomic operations
 933                 will use this set of locks
 934
 935                 NOTE: The lws_lock_start symbol must be
 936                 at least 16-byte aligned for safe use
 937                 with ldcw.
 938         */
 939         .section .data
 940         .align  L1_CACHE_BYTES
 941 ENTRY(lws_lock_start)
 942         /* lws locks */
 943         .rept 16
 944         /* Keep locks aligned at 16-bytes */
 945         .word 1
 946         .word 0
 947         .word 0
 948         .word 0
 949         .endr
 950 END(lws_lock_start)
 951         .previous
 952
 953 .end
 954
 955