kernel/arch/c6x/lib/remu.S

   1 ;;  Copyright 2010  Free Software Foundation, Inc.
   2 ;;  Contributed by Bernd Schmidt <bernds@codesourcery.com>.
   3 ;;
   4 ;; This program is free software; you can redistribute it and/or modify
   5 ;; it under the terms of the GNU General Public License as published by
   6 ;; the Free Software Foundation; either version 2 of the License, or
   7 ;; (at your option) any later version.
   8 ;;
   9 ;; This program is distributed in the hope that it will be useful,
  10 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 ;; GNU General Public License for more details.
  13 ;;
  14 ;; You should have received a copy of the GNU General Public License
  15 ;; along with this program; if not, write to the Free Software
  16 ;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17
  18 #include <linux/linkage.h>
  19
  20         ;; ABI considerations for the divide functions
  21         ;; The following registers are call-used:
  22         ;; __c6xabi_divi A0,A1,A2,A4,A6,B0,B1,B2,B4,B5
  23         ;; __c6xabi_divu A0,A1,A2,A4,A6,B0,B1,B2,B4
  24         ;; __c6xabi_remi A1,A2,A4,A5,A6,B0,B1,B2,B4
  25         ;; __c6xabi_remu A1,A4,A5,A7,B0,B1,B2,B4
  26         ;;
  27         ;; In our implementation, divu and remu are leaf functions,
  28         ;; while both divi and remi call into divu.
  29         ;; A0 is not clobbered by any of the functions.
  30         ;; divu does not clobber B2 either, which is taken advantage of
  31         ;; in remi.
  32         ;; divi uses B5 to hold the original return address during
  33         ;; the call to divu.
  34         ;; remi uses B2 and A5 to hold the input values during the
  35         ;; call to divu.  It stores B3 in on the stack.
  36
  37
  38         .text
  39
  40 ENTRY(__c6xabi_remu)
  41         ;; The ABI seems designed to prevent these functions calling each other,
  42         ;; so we duplicate most of the divsi3 code here.
  43          mv     .s2x    A4, B1
  44          lmbd   .l2     1, B4, B1
  45 || [!B1] b      .s2     B3      ; RETURN A
  46 || [!B1] mvk    .d2     1, B4
  47
  48          mv     .l1x    B1, A7
  49 ||       shl    .s2     B4, B1, B4
  50
  51          cmpltu .l1x    A4, B4, A1
  52    [!A1] sub    .l1x    A4, B4, A4
  53          shru   .s2     B4, 1, B4
  54
  55 _remu_loop:
  56          cmpgt  .l2     B1, 7, B0
  57 || [B1]  subc   .l1x    A4,B4,A4
  58 || [B1]  add    .s2     -1, B1, B1
  59         ;; RETURN A may happen here (note: must happen before the next branch)
  60    [B1]  subc   .l1x    A4,B4,A4
  61 || [B1]  add    .s2     -1, B1, B1
  62 || [B0]  b      .s1     _remu_loop
  63    [B1]  subc   .l1x    A4,B4,A4
  64 || [B1]  add    .s2     -1, B1, B1
  65    [B1]  subc   .l1x    A4,B4,A4
  66 || [B1]  add    .s2     -1, B1, B1
  67    [B1]  subc   .l1x    A4,B4,A4
  68 || [B1]  add    .s2     -1, B1, B1
  69    [B1]  subc   .l1x    A4,B4,A4
  70 || [B1]  add    .s2     -1, B1, B1
  71    [B1]  subc   .l1x    A4,B4,A4
  72 || [B1]  add    .s2     -1, B1, B1
  73         ;; loop backwards branch happens here
  74
  75          ret    .s2     B3
  76    [B1]  subc   .l1x    A4,B4,A4
  77 || [B1]  add    .s2     -1, B1, B1
  78    [B1]  subc   .l1x    A4,B4,A4
  79
  80          extu   .s1     A4, A7, A4
  81          nop    2
  82 ENDPROC(__c6xabi_remu)