kernel/arch/arm64/kernel/vdso/vdso.lds.S

   1 /*
   2  * GNU linker script for the VDSO library.
   3 *
   4  * Copyright (C) 2012 ARM Limited
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  * This program is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17  *
  18  * Author: Will Deacon <will.deacon@arm.com>
  19  * Heavily based on the vDSO linker scripts for other archs.
  20  */
  21
  22 #include <linux/const.h>
  23 #include <asm/page.h>
  24 #include <asm/vdso.h>
  25
  26 OUTPUT_FORMAT("elf64-littleaarch64", "elf64-bigaarch64", "elf64-littleaarch64")
  27 OUTPUT_ARCH(aarch64)
  28
  29 SECTIONS
  30 {
  31         PROVIDE(_vdso_data = . - PAGE_SIZE);
  32         . = VDSO_LBASE + SIZEOF_HEADERS;
  33
  34         .hash           : { *(.hash) }                  :text
  35         .gnu.hash       : { *(.gnu.hash) }
  36         .dynsym         : { *(.dynsym) }
  37         .dynstr         : { *(.dynstr) }
  38         .gnu.version    : { *(.gnu.version) }
  39         .gnu.version_d  : { *(.gnu.version_d) }
  40         .gnu.version_r  : { *(.gnu.version_r) }
  41
  42         .note           : { *(.note.*) }                :text   :note
  43
  44         . = ALIGN(16);
  45
  46         .text           : { *(.text*) }                 :text   =0xd503201f
  47         PROVIDE (__etext = .);
  48         PROVIDE (_etext = .);
  49         PROVIDE (etext = .);
  50
  51         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  52         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  53
  54         .dynamic        : { *(.dynamic) }               :text   :dynamic
  55
  56         .rodata         : { *(.rodata*) }               :text
  57
  58         _end = .;
  59         PROVIDE(end = .);
  60
  61         /DISCARD/       : {
  62                 *(.note.GNU-stack)
  63                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
  64                 *(.bss .sbss .dynbss .dynsbss)
  65         }
  66 }
  67
  68 /*
  69  * We must supply the ELF program headers explicitly to get just one
  70  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  71  */
  72 PHDRS
  73 {
  74         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
  75         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
  76         note            PT_NOTE         FLAGS(4);               /* PF_R */
  77         eh_frame_hdr    PT_GNU_EH_FRAME;
  78 }
  79
  80 /*
  81  * This controls what symbols we export from the DSO.
  82  */
  83 VERSION
  84 {
  85         LINUX_2.6.39 {
  86         global:
  87                 __kernel_rt_sigreturn;
  88                 __kernel_gettimeofday;
  89                 __kernel_clock_gettime;
  90                 __kernel_clock_getres;
  91         local: *;
  92         };
  93 }
  94
  95 /*
  96  * Make the sigreturn code visible to the kernel.
  97  */
  98 VDSO_sigtramp           = __kernel_rt_sigreturn;