kernel/arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/thread_info.h>
  31 #include <asm/unistd.h>
  32
  33 /*
  34  * Context tracking subsystem.  Used to instrument transitions
  35  * between user and kernel mode.
  36  */
  37         .macro ct_user_exit, syscall = 0
  38 #ifdef CONFIG_CONTEXT_TRACKING
  39         bl      context_tracking_user_exit
  40         .if \syscall == 1
  41         /*
  42          * Save/restore needed during syscalls.  Restore syscall arguments from
  43          * the values already saved on stack during kernel_entry.
  44          */
  45         ldp     x0, x1, [sp]
  46         ldp     x2, x3, [sp, #S_X2]
  47         ldp     x4, x5, [sp, #S_X4]
  48         ldp     x6, x7, [sp, #S_X6]
  49         .endif
  50 #endif
  51         .endm
  52
  53         .macro ct_user_enter
  54 #ifdef CONFIG_CONTEXT_TRACKING
  55         bl      context_tracking_user_enter
  56 #endif
  57         .endm
  58
  59 /*
  60  * Bad Abort numbers
  61  *-----------------
  62  */
  63 #define BAD_SYNC        0
  64 #define BAD_IRQ         1
  65 #define BAD_FIQ         2
  66 #define BAD_ERROR       3
  67
  68         .macro  kernel_entry, el, regsize = 64
  69         sub     sp, sp, #S_FRAME_SIZE
  70         .if     \regsize == 32
  71         mov     w0, w0                          // zero upper 32 bits of x0
  72         .endif
  73         stp     x0, x1, [sp, #16 * 0]
  74         stp     x2, x3, [sp, #16 * 1]
  75         stp     x4, x5, [sp, #16 * 2]
  76         stp     x6, x7, [sp, #16 * 3]
  77         stp     x8, x9, [sp, #16 * 4]
  78         stp     x10, x11, [sp, #16 * 5]
  79         stp     x12, x13, [sp, #16 * 6]
  80         stp     x14, x15, [sp, #16 * 7]
  81         stp     x16, x17, [sp, #16 * 8]
  82         stp     x18, x19, [sp, #16 * 9]
  83         stp     x20, x21, [sp, #16 * 10]
  84         stp     x22, x23, [sp, #16 * 11]
  85         stp     x24, x25, [sp, #16 * 12]
  86         stp     x26, x27, [sp, #16 * 13]
  87         stp     x28, x29, [sp, #16 * 14]
  88
  89         .if     \el == 0
  90         mrs     x21, sp_el0
  91         get_thread_info tsk                     // Ensure MDSCR_EL1.SS is clear,
  92         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  93         disable_step_tsk x19, x20               // exceptions when scheduling.
  94         .else
  95         add     x21, sp, #S_FRAME_SIZE
  96         .endif
  97         mrs     x22, elr_el1
  98         mrs     x23, spsr_el1
  99         stp     lr, x21, [sp, #S_LR]
 100         stp     x22, x23, [sp, #S_PC]
 101
 102         /*
 103          * Set syscallno to -1 by default (overridden later if real syscall).
 104          */
 105         .if     \el == 0
 106         mvn     x21, xzr
 107         str     x21, [sp, #S_SYSCALLNO]
 108         .endif
 109
 110         /*
 111          * Registers that may be useful after this macro is invoked:
 112          *
 113          * x21 - aborted SP
 114          * x22 - aborted PC
 115          * x23 - aborted PSTATE
 116         */
 117         .endm
 118
 119         .macro  kernel_exit, el
 120         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 121         .if     \el == 0
 122         ct_user_enter
 123         ldr     x23, [sp, #S_SP]                // load return stack pointer
 124         msr     sp_el0, x23
 125 #ifdef CONFIG_ARM64_ERRATUM_845719
 126 alternative_if_not ARM64_WORKAROUND_845719
 127         nop
 128         nop
 129 #ifdef CONFIG_PID_IN_CONTEXTIDR
 130         nop
 131 #endif
 132 alternative_else
 133         tbz     x22, #4, 1f
 134 #ifdef CONFIG_PID_IN_CONTEXTIDR
 135         mrs     x29, contextidr_el1
 136         msr     contextidr_el1, x29
 137 #else
 138         msr contextidr_el1, xzr
 139 #endif
 140 1:
 141 alternative_endif
 142 #endif
 143         .endif
 144         msr     elr_el1, x21                    // set up the return data
 145         msr     spsr_el1, x22
 146         ldp     x0, x1, [sp, #16 * 0]
 147         ldp     x2, x3, [sp, #16 * 1]
 148         ldp     x4, x5, [sp, #16 * 2]
 149         ldp     x6, x7, [sp, #16 * 3]
 150         ldp     x8, x9, [sp, #16 * 4]
 151         ldp     x10, x11, [sp, #16 * 5]
 152         ldp     x12, x13, [sp, #16 * 6]
 153         ldp     x14, x15, [sp, #16 * 7]
 154         ldp     x16, x17, [sp, #16 * 8]
 155         ldp     x18, x19, [sp, #16 * 9]
 156         ldp     x20, x21, [sp, #16 * 10]
 157         ldp     x22, x23, [sp, #16 * 11]
 158         ldp     x24, x25, [sp, #16 * 12]
 159         ldp     x26, x27, [sp, #16 * 13]
 160         ldp     x28, x29, [sp, #16 * 14]
 161         ldr     lr, [sp, #S_LR]
 162         add     sp, sp, #S_FRAME_SIZE           // restore sp
 163         eret                                    // return to kernel
 164         .endm
 165
 166         .macro  get_thread_info, rd
 167         mov     \rd, sp
 168         and     \rd, \rd, #~(THREAD_SIZE - 1)   // top of stack
 169         .endm
 170
 171 /*
 172  * These are the registers used in the syscall handler, and allow us to
 173  * have in theory up to 7 arguments to a function - x0 to x6.
 174  *
 175  * x7 is reserved for the system call number in 32-bit mode.
 176  */
 177 sc_nr   .req    x25             // number of system calls
 178 scno    .req    x26             // syscall number
 179 stbl    .req    x27             // syscall table pointer
 180 tsk     .req    x28             // current thread_info
 181
 182 /*
 183  * Interrupt handling.
 184  */
 185         .macro  irq_handler
 186         adrp    x1, handle_arch_irq
 187         ldr     x1, [x1, #:lo12:handle_arch_irq]
 188         mov     x0, sp
 189         blr     x1
 190         .endm
 191
 192         .text
 193
 194 /*
 195  * Exception vectors.
 196  */
 197
 198         .align  11
 199 ENTRY(vectors)
 200         ventry  el1_sync_invalid                // Synchronous EL1t
 201         ventry  el1_irq_invalid                 // IRQ EL1t
 202         ventry  el1_fiq_invalid                 // FIQ EL1t
 203         ventry  el1_error_invalid               // Error EL1t
 204
 205         ventry  el1_sync                        // Synchronous EL1h
 206         ventry  el1_irq                         // IRQ EL1h
 207         ventry  el1_fiq_invalid                 // FIQ EL1h
 208         ventry  el1_error_invalid               // Error EL1h
 209
 210         ventry  el0_sync                        // Synchronous 64-bit EL0
 211         ventry  el0_irq                         // IRQ 64-bit EL0
 212         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 213         ventry  el0_error_invalid               // Error 64-bit EL0
 214
 215 #ifdef CONFIG_COMPAT
 216         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 217         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 218         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 219         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 220 #else
 221         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 222         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 223         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 224         ventry  el0_error_invalid               // Error 32-bit EL0
 225 #endif
 226 END(vectors)
 227
 228 /*
 229  * Invalid mode handlers
 230  */
 231         .macro  inv_entry, el, reason, regsize = 64
 232         kernel_entry el, \regsize
 233         mov     x0, sp
 234         mov     x1, #\reason
 235         mrs     x2, esr_el1
 236         b       bad_mode
 237         .endm
 238
 239 el0_sync_invalid:
 240         inv_entry 0, BAD_SYNC
 241 ENDPROC(el0_sync_invalid)
 242
 243 el0_irq_invalid:
 244         inv_entry 0, BAD_IRQ
 245 ENDPROC(el0_irq_invalid)
 246
 247 el0_fiq_invalid:
 248         inv_entry 0, BAD_FIQ
 249 ENDPROC(el0_fiq_invalid)
 250
 251 el0_error_invalid:
 252         inv_entry 0, BAD_ERROR
 253 ENDPROC(el0_error_invalid)
 254
 255 #ifdef CONFIG_COMPAT
 256 el0_fiq_invalid_compat:
 257         inv_entry 0, BAD_FIQ, 32
 258 ENDPROC(el0_fiq_invalid_compat)
 259
 260 el0_error_invalid_compat:
 261         inv_entry 0, BAD_ERROR, 32
 262 ENDPROC(el0_error_invalid_compat)
 263 #endif
 264
 265 el1_sync_invalid:
 266         inv_entry 1, BAD_SYNC
 267 ENDPROC(el1_sync_invalid)
 268
 269 el1_irq_invalid:
 270         inv_entry 1, BAD_IRQ
 271 ENDPROC(el1_irq_invalid)
 272
 273 el1_fiq_invalid:
 274         inv_entry 1, BAD_FIQ
 275 ENDPROC(el1_fiq_invalid)
 276
 277 el1_error_invalid:
 278         inv_entry 1, BAD_ERROR
 279 ENDPROC(el1_error_invalid)
 280
 281 /*
 282  * EL1 mode handlers.
 283  */
 284         .align  6
 285 el1_sync:
 286         kernel_entry 1
 287         mrs     x1, esr_el1                     // read the syndrome register
 288         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 289         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 290         b.eq    el1_da
 291         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 292         b.eq    el1_undef
 293         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 294         b.eq    el1_sp_pc
 295         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 296         b.eq    el1_sp_pc
 297         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 298         b.eq    el1_undef
 299         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 300         b.ge    el1_dbg
 301         b       el1_inv
 302 el1_da:
 303         /*
 304          * Data abort handling
 305          */
 306         mrs     x0, far_el1
 307         enable_dbg
 308         // re-enable interrupts if they were enabled in the aborted context
 309         tbnz    x23, #7, 1f                     // PSR_I_BIT
 310         enable_irq
 311 1:
 312         mov     x2, sp                          // struct pt_regs
 313         bl      do_mem_abort
 314
 315         // disable interrupts before pulling preserved data off the stack
 316         disable_irq
 317         kernel_exit 1
 318 el1_sp_pc:
 319         /*
 320          * Stack or PC alignment exception handling
 321          */
 322         mrs     x0, far_el1
 323         enable_dbg
 324         mov     x2, sp
 325         b       do_sp_pc_abort
 326 el1_undef:
 327         /*
 328          * Undefined instruction
 329          */
 330         enable_dbg
 331         mov     x0, sp
 332         b       do_undefinstr
 333 el1_dbg:
 334         /*
 335          * Debug exception handling
 336          */
 337         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 338         cinc    x24, x24, eq                    // set bit '0'
 339         tbz     x24, #0, el1_inv                // EL1 only
 340         mrs     x0, far_el1
 341         mov     x2, sp                          // struct pt_regs
 342         bl      do_debug_exception
 343         kernel_exit 1
 344 el1_inv:
 345         // TODO: add support for undefined instructions in kernel mode
 346         enable_dbg
 347         mov     x0, sp
 348         mov     x2, x1
 349         mov     x1, #BAD_SYNC
 350         b       bad_mode
 351 ENDPROC(el1_sync)
 352
 353         .align  6
 354 el1_irq:
 355         kernel_entry 1
 356         enable_dbg
 357 #ifdef CONFIG_TRACE_IRQFLAGS
 358         bl      trace_hardirqs_off
 359 #endif
 360
 361         irq_handler
 362
 363 #ifdef CONFIG_PREEMPT
 364         get_thread_info tsk
 365         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 366         cbnz    w24, 2f                         // preempt count != 0
 367         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 368         tbnz    x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 369
 370         ldr     w24, [tsk, #TI_PREEMPT_LAZY]    // get preempt lazy count
 371         cbnz    w24, 2f                         // preempt lazy count != 0
 372         tbz     x0, #TIF_NEED_RESCHED_LAZY, 2f  // needs rescheduling?
 373 1:
 374         bl      el1_preempt
 375 2:
 376 #endif
 377 #ifdef CONFIG_TRACE_IRQFLAGS
 378         bl      trace_hardirqs_on
 379 #endif
 380         kernel_exit 1
 381 ENDPROC(el1_irq)
 382
 383 #ifdef CONFIG_PREEMPT
 384 el1_preempt:
 385         mov     x24, lr
 386 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 387         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 388         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 389         tbnz    x0, #TIF_NEED_RESCHED_LAZY, 1b  // needs rescheduling?
 390         ret     x24
 391 #endif
 392
 393 /*
 394  * EL0 mode handlers.
 395  */
 396         .align  6
 397 el0_sync:
 398         kernel_entry 0
 399         mrs     x25, esr_el1                    // read the syndrome register
 400         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 401         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 402         b.eq    el0_svc
 403         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 404         b.eq    el0_da
 405         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 406         b.eq    el0_ia
 407         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 408         b.eq    el0_fpsimd_acc
 409         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 410         b.eq    el0_fpsimd_exc
 411         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 412         b.eq    el0_undef
 413         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 414         b.eq    el0_sp_pc
 415         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 416         b.eq    el0_sp_pc
 417         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 418         b.eq    el0_undef
 419         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 420         b.ge    el0_dbg
 421         b       el0_inv
 422
 423 #ifdef CONFIG_COMPAT
 424         .align  6
 425 el0_sync_compat:
 426         kernel_entry 0, 32
 427         mrs     x25, esr_el1                    // read the syndrome register
 428         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 429         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 430         b.eq    el0_svc_compat
 431         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 432         b.eq    el0_da
 433         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 434         b.eq    el0_ia
 435         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 436         b.eq    el0_fpsimd_acc
 437         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 438         b.eq    el0_fpsimd_exc
 439         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 440         b.eq    el0_sp_pc
 441         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 442         b.eq    el0_undef
 443         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 444         b.eq    el0_undef
 445         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 446         b.eq    el0_undef
 447         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 448         b.eq    el0_undef
 449         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 450         b.eq    el0_undef
 451         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 452         b.eq    el0_undef
 453         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 454         b.ge    el0_dbg
 455         b       el0_inv
 456 el0_svc_compat:
 457         /*
 458          * AArch32 syscall handling
 459          */
 460         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 461         uxtw    scno, w7                        // syscall number in w7 (r7)
 462         mov     sc_nr, #__NR_compat_syscalls
 463         b       el0_svc_naked
 464
 465         .align  6
 466 el0_irq_compat:
 467         kernel_entry 0, 32
 468         b       el0_irq_naked
 469 #endif
 470
 471 el0_da:
 472         /*
 473          * Data abort handling
 474          */
 475         mrs     x26, far_el1
 476         // enable interrupts before calling the main handler
 477         enable_dbg_and_irq
 478         ct_user_exit
 479         bic     x0, x26, #(0xff << 56)
 480         mov     x1, x25
 481         mov     x2, sp
 482         bl      do_mem_abort
 483         b       ret_to_user
 484 el0_ia:
 485         /*
 486          * Instruction abort handling
 487          */
 488         mrs     x26, far_el1
 489         // enable interrupts before calling the main handler
 490         enable_dbg_and_irq
 491         ct_user_exit
 492         mov     x0, x26
 493         orr     x1, x25, #1 << 24               // use reserved ISS bit for instruction aborts
 494         mov     x2, sp
 495         bl      do_mem_abort
 496         b       ret_to_user
 497 el0_fpsimd_acc:
 498         /*
 499          * Floating Point or Advanced SIMD access
 500          */
 501         enable_dbg
 502         ct_user_exit
 503         mov     x0, x25
 504         mov     x1, sp
 505         bl      do_fpsimd_acc
 506         b       ret_to_user
 507 el0_fpsimd_exc:
 508         /*
 509          * Floating Point or Advanced SIMD exception
 510          */
 511         enable_dbg
 512         ct_user_exit
 513         mov     x0, x25
 514         mov     x1, sp
 515         bl      do_fpsimd_exc
 516         b       ret_to_user
 517 el0_sp_pc:
 518         /*
 519          * Stack or PC alignment exception handling
 520          */
 521         mrs     x26, far_el1
 522         // enable interrupts before calling the main handler
 523         enable_dbg_and_irq
 524         ct_user_exit
 525         mov     x0, x26
 526         mov     x1, x25
 527         mov     x2, sp
 528         bl      do_sp_pc_abort
 529         b       ret_to_user
 530 el0_undef:
 531         /*
 532          * Undefined instruction
 533          */
 534         // enable interrupts before calling the main handler
 535         enable_dbg_and_irq
 536         ct_user_exit
 537         mov     x0, sp
 538         bl      do_undefinstr
 539         b       ret_to_user
 540 el0_dbg:
 541         /*
 542          * Debug exception handling
 543          */
 544         tbnz    x24, #0, el0_inv                // EL0 only
 545         mrs     x0, far_el1
 546         mov     x1, x25
 547         mov     x2, sp
 548         bl      do_debug_exception
 549         enable_dbg
 550         ct_user_exit
 551         b       ret_to_user
 552 el0_inv:
 553         enable_dbg
 554         ct_user_exit
 555         mov     x0, sp
 556         mov     x1, #BAD_SYNC
 557         mov     x2, x25
 558         bl      bad_mode
 559         b       ret_to_user
 560 ENDPROC(el0_sync)
 561
 562         .align  6
 563 el0_irq:
 564         kernel_entry 0
 565 el0_irq_naked:
 566         enable_dbg
 567 #ifdef CONFIG_TRACE_IRQFLAGS
 568         bl      trace_hardirqs_off
 569 #endif
 570
 571         ct_user_exit
 572         irq_handler
 573
 574 #ifdef CONFIG_TRACE_IRQFLAGS
 575         bl      trace_hardirqs_on
 576 #endif
 577         b       ret_to_user
 578 ENDPROC(el0_irq)
 579
 580 /*
 581  * Register switch for AArch64. The callee-saved registers need to be saved
 582  * and restored. On entry:
 583  *   x0 = previous task_struct (must be preserved across the switch)
 584  *   x1 = next task_struct
 585  * Previous and next are guaranteed not to be the same.
 586  *
 587  */
 588 ENTRY(cpu_switch_to)
 589         mov     x10, #THREAD_CPU_CONTEXT
 590         add     x8, x0, x10
 591         mov     x9, sp
 592         stp     x19, x20, [x8], #16             // store callee-saved registers
 593         stp     x21, x22, [x8], #16
 594         stp     x23, x24, [x8], #16
 595         stp     x25, x26, [x8], #16
 596         stp     x27, x28, [x8], #16
 597         stp     x29, x9, [x8], #16
 598         str     lr, [x8]
 599         add     x8, x1, x10
 600         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 601         ldp     x21, x22, [x8], #16
 602         ldp     x23, x24, [x8], #16
 603         ldp     x25, x26, [x8], #16
 604         ldp     x27, x28, [x8], #16
 605         ldp     x29, x9, [x8], #16
 606         ldr     lr, [x8]
 607         mov     sp, x9
 608         ret
 609 ENDPROC(cpu_switch_to)
 610
 611 /*
 612  * This is the fast syscall return path.  We do as little as possible here,
 613  * and this includes saving x0 back into the kernel stack.
 614  */
 615 ret_fast_syscall:
 616         disable_irq                             // disable interrupts
 617         str     x0, [sp, #S_X0]                 // returned x0
 618         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 619         and     x2, x1, #_TIF_SYSCALL_WORK
 620         cbnz    x2, ret_fast_syscall_trace
 621         and     x2, x1, #_TIF_WORK_MASK
 622         cbnz    x2, work_pending
 623         enable_step_tsk x1, x2
 624         kernel_exit 0
 625 ret_fast_syscall_trace:
 626         enable_irq                              // enable interrupts
 627         b       __sys_trace_return_skipped      // we already saved x0
 628
 629 /*
 630  * Ok, we need to do extra processing, enter the slow path.
 631  */
 632 work_pending:
 633         tbnz    x1, #TIF_NEED_RESCHED, work_resched
 634         tbnz    x1, #TIF_NEED_RESCHED_LAZY, work_resched
 635         /* TIF_SIGPENDING, TIF_NOTIFY_RESUME or TIF_FOREIGN_FPSTATE case */
 636         ldr     x2, [sp, #S_PSTATE]
 637         mov     x0, sp                          // 'regs'
 638         tst     x2, #PSR_MODE_MASK              // user mode regs?
 639         b.ne    no_work_pending                 // returning to kernel
 640         enable_irq                              // enable interrupts for do_notify_resume()
 641         bl      do_notify_resume
 642         b       ret_to_user
 643 work_resched:
 644         bl      schedule
 645
 646 /*
 647  * "slow" syscall return path.
 648  */
 649 ret_to_user:
 650         disable_irq                             // disable interrupts
 651         ldr     x1, [tsk, #TI_FLAGS]
 652         and     x2, x1, #_TIF_WORK_MASK
 653         cbnz    x2, work_pending
 654         enable_step_tsk x1, x2
 655 no_work_pending:
 656         kernel_exit 0
 657 ENDPROC(ret_to_user)
 658
 659 /*
 660  * This is how we return from a fork.
 661  */
 662 ENTRY(ret_from_fork)
 663         bl      schedule_tail
 664         cbz     x19, 1f                         // not a kernel thread
 665         mov     x0, x20
 666         blr     x19
 667 1:      get_thread_info tsk
 668         b       ret_to_user
 669 ENDPROC(ret_from_fork)
 670
 671 /*
 672  * SVC handler.
 673  */
 674         .align  6
 675 el0_svc:
 676         adrp    stbl, sys_call_table            // load syscall table pointer
 677         uxtw    scno, w8                        // syscall number in w8
 678         mov     sc_nr, #__NR_syscalls
 679 el0_svc_naked:                                  // compat entry point
 680         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 681         enable_dbg_and_irq
 682         ct_user_exit 1
 683
 684         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 685         tst     x16, #_TIF_SYSCALL_WORK
 686         b.ne    __sys_trace
 687         cmp     scno, sc_nr                     // check upper syscall limit
 688         b.hs    ni_sys
 689         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 690         blr     x16                             // call sys_* routine
 691         b       ret_fast_syscall
 692 ni_sys:
 693         mov     x0, sp
 694         bl      do_ni_syscall
 695         b       ret_fast_syscall
 696 ENDPROC(el0_svc)
 697
 698         /*
 699          * This is the really slow path.  We're going to be doing context
 700          * switches, and waiting for our parent to respond.
 701          */
 702 __sys_trace:
 703         mov     w0, #-1                         // set default errno for
 704         cmp     scno, x0                        // user-issued syscall(-1)
 705         b.ne    1f
 706         mov     x0, #-ENOSYS
 707         str     x0, [sp, #S_X0]
 708 1:      mov     x0, sp
 709         bl      syscall_trace_enter
 710         cmp     w0, #-1                         // skip the syscall?
 711         b.eq    __sys_trace_return_skipped
 712         uxtw    scno, w0                        // syscall number (possibly new)
 713         mov     x1, sp                          // pointer to regs
 714         cmp     scno, sc_nr                     // check upper syscall limit
 715         b.hs    __ni_sys_trace
 716         ldp     x0, x1, [sp]                    // restore the syscall args
 717         ldp     x2, x3, [sp, #S_X2]
 718         ldp     x4, x5, [sp, #S_X4]
 719         ldp     x6, x7, [sp, #S_X6]
 720         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 721         blr     x16                             // call sys_* routine
 722
 723 __sys_trace_return:
 724         str     x0, [sp, #S_X0]                 // save returned x0
 725 __sys_trace_return_skipped:
 726         mov     x0, sp
 727         bl      syscall_trace_exit
 728         b       ret_to_user
 729
 730 __ni_sys_trace:
 731         mov     x0, sp
 732         bl      do_ni_syscall
 733         b       __sys_trace_return
 734
 735 /*
 736  * Special system call wrappers.
 737  */
 738 ENTRY(sys_rt_sigreturn_wrapper)
 739         mov     x0, sp
 740         b       sys_rt_sigreturn
 741 ENDPROC(sys_rt_sigreturn_wrapper)