kernel/arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/memory.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/unistd.h>
  33
  34 /*
  35  * Context tracking subsystem.  Used to instrument transitions
  36  * between user and kernel mode.
  37  */
  38         .macro ct_user_exit, syscall = 0
  39 #ifdef CONFIG_CONTEXT_TRACKING
  40         bl      context_tracking_user_exit
  41         .if \syscall == 1
  42         /*
  43          * Save/restore needed during syscalls.  Restore syscall arguments from
  44          * the values already saved on stack during kernel_entry.
  45          */
  46         ldp     x0, x1, [sp]
  47         ldp     x2, x3, [sp, #S_X2]
  48         ldp     x4, x5, [sp, #S_X4]
  49         ldp     x6, x7, [sp, #S_X6]
  50         .endif
  51 #endif
  52         .endm
  53
  54         .macro ct_user_enter
  55 #ifdef CONFIG_CONTEXT_TRACKING
  56         bl      context_tracking_user_enter
  57 #endif
  58         .endm
  59
  60 /*
  61  * Bad Abort numbers
  62  *-----------------
  63  */
  64 #define BAD_SYNC        0
  65 #define BAD_IRQ         1
  66 #define BAD_FIQ         2
  67 #define BAD_ERROR       3
  68
  69         .macro  kernel_entry, el, regsize = 64
  70         sub     sp, sp, #S_FRAME_SIZE
  71         .if     \regsize == 32
  72         mov     w0, w0                          // zero upper 32 bits of x0
  73         .endif
  74         stp     x0, x1, [sp, #16 * 0]
  75         stp     x2, x3, [sp, #16 * 1]
  76         stp     x4, x5, [sp, #16 * 2]
  77         stp     x6, x7, [sp, #16 * 3]
  78         stp     x8, x9, [sp, #16 * 4]
  79         stp     x10, x11, [sp, #16 * 5]
  80         stp     x12, x13, [sp, #16 * 6]
  81         stp     x14, x15, [sp, #16 * 7]
  82         stp     x16, x17, [sp, #16 * 8]
  83         stp     x18, x19, [sp, #16 * 9]
  84         stp     x20, x21, [sp, #16 * 10]
  85         stp     x22, x23, [sp, #16 * 11]
  86         stp     x24, x25, [sp, #16 * 12]
  87         stp     x26, x27, [sp, #16 * 13]
  88         stp     x28, x29, [sp, #16 * 14]
  89
  90         .if     \el == 0
  91         mrs     x21, sp_el0
  92         get_thread_info tsk                     // Ensure MDSCR_EL1.SS is clear,
  93         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  94         disable_step_tsk x19, x20               // exceptions when scheduling.
  95         .else
  96         add     x21, sp, #S_FRAME_SIZE
  97         get_thread_info tsk
  98         /* Save the task's original addr_limit and set USER_DS (TASK_SIZE_64) */
  99         ldr     x20, [tsk, #TI_ADDR_LIMIT]
 100         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 101         mov     x20, #TASK_SIZE_64
 102         str     x20, [tsk, #TI_ADDR_LIMIT]
 103         .endif /* \el == 0 */
 104         mrs     x22, elr_el1
 105         mrs     x23, spsr_el1
 106         stp     lr, x21, [sp, #S_LR]
 107         stp     x22, x23, [sp, #S_PC]
 108
 109         /*
 110          * Set syscallno to -1 by default (overridden later if real syscall).
 111          */
 112         .if     \el == 0
 113         mvn     x21, xzr
 114         str     x21, [sp, #S_SYSCALLNO]
 115         .endif
 116
 117         /*
 118          * Registers that may be useful after this macro is invoked:
 119          *
 120          * x21 - aborted SP
 121          * x22 - aborted PC
 122          * x23 - aborted PSTATE
 123         */
 124         .endm
 125
 126         .macro  kernel_exit, el
 127         .if     \el != 0
 128         /* Restore the task's original addr_limit. */
 129         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 130         str     x20, [tsk, #TI_ADDR_LIMIT]
 131         .endif
 132
 133         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 134         .if     \el == 0
 135         ct_user_enter
 136         ldr     x23, [sp, #S_SP]                // load return stack pointer
 137         msr     sp_el0, x23
 138 #ifdef CONFIG_ARM64_ERRATUM_845719
 139 alternative_if_not ARM64_WORKAROUND_845719
 140         nop
 141         nop
 142 #ifdef CONFIG_PID_IN_CONTEXTIDR
 143         nop
 144 #endif
 145 alternative_else
 146         tbz     x22, #4, 1f
 147 #ifdef CONFIG_PID_IN_CONTEXTIDR
 148         mrs     x29, contextidr_el1
 149         msr     contextidr_el1, x29
 150 #else
 151         msr contextidr_el1, xzr
 152 #endif
 153 1:
 154 alternative_endif
 155 #endif
 156         .endif
 157         msr     elr_el1, x21                    // set up the return data
 158         msr     spsr_el1, x22
 159         ldp     x0, x1, [sp, #16 * 0]
 160         ldp     x2, x3, [sp, #16 * 1]
 161         ldp     x4, x5, [sp, #16 * 2]
 162         ldp     x6, x7, [sp, #16 * 3]
 163         ldp     x8, x9, [sp, #16 * 4]
 164         ldp     x10, x11, [sp, #16 * 5]
 165         ldp     x12, x13, [sp, #16 * 6]
 166         ldp     x14, x15, [sp, #16 * 7]
 167         ldp     x16, x17, [sp, #16 * 8]
 168         ldp     x18, x19, [sp, #16 * 9]
 169         ldp     x20, x21, [sp, #16 * 10]
 170         ldp     x22, x23, [sp, #16 * 11]
 171         ldp     x24, x25, [sp, #16 * 12]
 172         ldp     x26, x27, [sp, #16 * 13]
 173         ldp     x28, x29, [sp, #16 * 14]
 174         ldr     lr, [sp, #S_LR]
 175         add     sp, sp, #S_FRAME_SIZE           // restore sp
 176         eret                                    // return to kernel
 177         .endm
 178
 179         .macro  get_thread_info, rd
 180         mov     \rd, sp
 181         and     \rd, \rd, #~(THREAD_SIZE - 1)   // top of stack
 182         .endm
 183
 184 /*
 185  * These are the registers used in the syscall handler, and allow us to
 186  * have in theory up to 7 arguments to a function - x0 to x6.
 187  *
 188  * x7 is reserved for the system call number in 32-bit mode.
 189  */
 190 sc_nr   .req    x25             // number of system calls
 191 scno    .req    x26             // syscall number
 192 stbl    .req    x27             // syscall table pointer
 193 tsk     .req    x28             // current thread_info
 194
 195 /*
 196  * Interrupt handling.
 197  */
 198         .macro  irq_handler
 199         adrp    x1, handle_arch_irq
 200         ldr     x1, [x1, #:lo12:handle_arch_irq]
 201         mov     x0, sp
 202         blr     x1
 203         .endm
 204
 205         .text
 206
 207 /*
 208  * Exception vectors.
 209  */
 210
 211         .align  11
 212 ENTRY(vectors)
 213         ventry  el1_sync_invalid                // Synchronous EL1t
 214         ventry  el1_irq_invalid                 // IRQ EL1t
 215         ventry  el1_fiq_invalid                 // FIQ EL1t
 216         ventry  el1_error_invalid               // Error EL1t
 217
 218         ventry  el1_sync                        // Synchronous EL1h
 219         ventry  el1_irq                         // IRQ EL1h
 220         ventry  el1_fiq_invalid                 // FIQ EL1h
 221         ventry  el1_error_invalid               // Error EL1h
 222
 223         ventry  el0_sync                        // Synchronous 64-bit EL0
 224         ventry  el0_irq                         // IRQ 64-bit EL0
 225         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 226         ventry  el0_error_invalid               // Error 64-bit EL0
 227
 228 #ifdef CONFIG_COMPAT
 229         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 230         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 231         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 232         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 233 #else
 234         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 235         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 236         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 237         ventry  el0_error_invalid               // Error 32-bit EL0
 238 #endif
 239 END(vectors)
 240
 241 /*
 242  * Invalid mode handlers
 243  */
 244         .macro  inv_entry, el, reason, regsize = 64
 245         kernel_entry el, \regsize
 246         mov     x0, sp
 247         mov     x1, #\reason
 248         mrs     x2, esr_el1
 249         b       bad_mode
 250         .endm
 251
 252 el0_sync_invalid:
 253         inv_entry 0, BAD_SYNC
 254 ENDPROC(el0_sync_invalid)
 255
 256 el0_irq_invalid:
 257         inv_entry 0, BAD_IRQ
 258 ENDPROC(el0_irq_invalid)
 259
 260 el0_fiq_invalid:
 261         inv_entry 0, BAD_FIQ
 262 ENDPROC(el0_fiq_invalid)
 263
 264 el0_error_invalid:
 265         inv_entry 0, BAD_ERROR
 266 ENDPROC(el0_error_invalid)
 267
 268 #ifdef CONFIG_COMPAT
 269 el0_fiq_invalid_compat:
 270         inv_entry 0, BAD_FIQ, 32
 271 ENDPROC(el0_fiq_invalid_compat)
 272
 273 el0_error_invalid_compat:
 274         inv_entry 0, BAD_ERROR, 32
 275 ENDPROC(el0_error_invalid_compat)
 276 #endif
 277
 278 el1_sync_invalid:
 279         inv_entry 1, BAD_SYNC
 280 ENDPROC(el1_sync_invalid)
 281
 282 el1_irq_invalid:
 283         inv_entry 1, BAD_IRQ
 284 ENDPROC(el1_irq_invalid)
 285
 286 el1_fiq_invalid:
 287         inv_entry 1, BAD_FIQ
 288 ENDPROC(el1_fiq_invalid)
 289
 290 el1_error_invalid:
 291         inv_entry 1, BAD_ERROR
 292 ENDPROC(el1_error_invalid)
 293
 294 /*
 295  * EL1 mode handlers.
 296  */
 297         .align  6
 298 el1_sync:
 299         kernel_entry 1
 300         mrs     x1, esr_el1                     // read the syndrome register
 301         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 302         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 303         b.eq    el1_da
 304         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 305         b.eq    el1_undef
 306         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 307         b.eq    el1_sp_pc
 308         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 309         b.eq    el1_sp_pc
 310         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 311         b.eq    el1_undef
 312         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 313         b.ge    el1_dbg
 314         b       el1_inv
 315 el1_da:
 316         /*
 317          * Data abort handling
 318          */
 319         mrs     x0, far_el1
 320         enable_dbg
 321         // re-enable interrupts if they were enabled in the aborted context
 322         tbnz    x23, #7, 1f                     // PSR_I_BIT
 323         enable_irq
 324 1:
 325         mov     x2, sp                          // struct pt_regs
 326         bl      do_mem_abort
 327
 328         // disable interrupts before pulling preserved data off the stack
 329         disable_irq
 330         kernel_exit 1
 331 el1_sp_pc:
 332         /*
 333          * Stack or PC alignment exception handling
 334          */
 335         mrs     x0, far_el1
 336         enable_dbg
 337         mov     x2, sp
 338         b       do_sp_pc_abort
 339 el1_undef:
 340         /*
 341          * Undefined instruction
 342          */
 343         enable_dbg
 344         mov     x0, sp
 345         b       do_undefinstr
 346 el1_dbg:
 347         /*
 348          * Debug exception handling
 349          */
 350         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 351         cinc    x24, x24, eq                    // set bit '0'
 352         tbz     x24, #0, el1_inv                // EL1 only
 353         mrs     x0, far_el1
 354         mov     x2, sp                          // struct pt_regs
 355         bl      do_debug_exception
 356         kernel_exit 1
 357 el1_inv:
 358         // TODO: add support for undefined instructions in kernel mode
 359         enable_dbg
 360         mov     x0, sp
 361         mov     x2, x1
 362         mov     x1, #BAD_SYNC
 363         b       bad_mode
 364 ENDPROC(el1_sync)
 365
 366         .align  6
 367 el1_irq:
 368         kernel_entry 1
 369         enable_dbg
 370 #ifdef CONFIG_TRACE_IRQFLAGS
 371         bl      trace_hardirqs_off
 372 #endif
 373
 374         irq_handler
 375
 376 #ifdef CONFIG_PREEMPT
 377         get_thread_info tsk
 378         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 379         cbnz    w24, 2f                         // preempt count != 0
 380         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 381         tbnz    x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 382
 383         ldr     w24, [tsk, #TI_PREEMPT_LAZY]    // get preempt lazy count
 384         cbnz    w24, 2f                         // preempt lazy count != 0
 385         tbz     x0, #TIF_NEED_RESCHED_LAZY, 2f  // needs rescheduling?
 386 1:
 387         bl      el1_preempt
 388 2:
 389 #endif
 390 #ifdef CONFIG_TRACE_IRQFLAGS
 391         bl      trace_hardirqs_on
 392 #endif
 393         kernel_exit 1
 394 ENDPROC(el1_irq)
 395
 396 #ifdef CONFIG_PREEMPT
 397 el1_preempt:
 398         mov     x24, lr
 399 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 400         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 401         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 402         tbnz    x0, #TIF_NEED_RESCHED_LAZY, 1b  // needs rescheduling?
 403         ret     x24
 404 #endif
 405
 406 /*
 407  * EL0 mode handlers.
 408  */
 409         .align  6
 410 el0_sync:
 411         kernel_entry 0
 412         mrs     x25, esr_el1                    // read the syndrome register
 413         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 414         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 415         b.eq    el0_svc
 416         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 417         b.eq    el0_da
 418         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 419         b.eq    el0_ia
 420         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 421         b.eq    el0_fpsimd_acc
 422         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 423         b.eq    el0_fpsimd_exc
 424         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 425         b.eq    el0_undef
 426         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 427         b.eq    el0_sp_pc
 428         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 429         b.eq    el0_sp_pc
 430         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 431         b.eq    el0_undef
 432         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 433         b.ge    el0_dbg
 434         b       el0_inv
 435
 436 #ifdef CONFIG_COMPAT
 437         .align  6
 438 el0_sync_compat:
 439         kernel_entry 0, 32
 440         mrs     x25, esr_el1                    // read the syndrome register
 441         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 442         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 443         b.eq    el0_svc_compat
 444         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 445         b.eq    el0_da
 446         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 447         b.eq    el0_ia
 448         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 449         b.eq    el0_fpsimd_acc
 450         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 451         b.eq    el0_fpsimd_exc
 452         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 453         b.eq    el0_sp_pc
 454         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 455         b.eq    el0_undef
 456         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 457         b.eq    el0_undef
 458         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 459         b.eq    el0_undef
 460         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 461         b.eq    el0_undef
 462         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 463         b.eq    el0_undef
 464         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 465         b.eq    el0_undef
 466         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 467         b.ge    el0_dbg
 468         b       el0_inv
 469 el0_svc_compat:
 470         /*
 471          * AArch32 syscall handling
 472          */
 473         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 474         uxtw    scno, w7                        // syscall number in w7 (r7)
 475         mov     sc_nr, #__NR_compat_syscalls
 476         b       el0_svc_naked
 477
 478         .align  6
 479 el0_irq_compat:
 480         kernel_entry 0, 32
 481         b       el0_irq_naked
 482 #endif
 483
 484 el0_da:
 485         /*
 486          * Data abort handling
 487          */
 488         mrs     x26, far_el1
 489         // enable interrupts before calling the main handler
 490         enable_dbg_and_irq
 491         ct_user_exit
 492         bic     x0, x26, #(0xff << 56)
 493         mov     x1, x25
 494         mov     x2, sp
 495         bl      do_mem_abort
 496         b       ret_to_user
 497 el0_ia:
 498         /*
 499          * Instruction abort handling
 500          */
 501         mrs     x26, far_el1
 502         // enable interrupts before calling the main handler
 503         enable_dbg_and_irq
 504         ct_user_exit
 505         mov     x0, x26
 506         orr     x1, x25, #1 << 24               // use reserved ISS bit for instruction aborts
 507         mov     x2, sp
 508         bl      do_mem_abort
 509         b       ret_to_user
 510 el0_fpsimd_acc:
 511         /*
 512          * Floating Point or Advanced SIMD access
 513          */
 514         enable_dbg
 515         ct_user_exit
 516         mov     x0, x25
 517         mov     x1, sp
 518         bl      do_fpsimd_acc
 519         b       ret_to_user
 520 el0_fpsimd_exc:
 521         /*
 522          * Floating Point or Advanced SIMD exception
 523          */
 524         enable_dbg
 525         ct_user_exit
 526         mov     x0, x25
 527         mov     x1, sp
 528         bl      do_fpsimd_exc
 529         b       ret_to_user
 530 el0_sp_pc:
 531         /*
 532          * Stack or PC alignment exception handling
 533          */
 534         mrs     x26, far_el1
 535         // enable interrupts before calling the main handler
 536         enable_dbg_and_irq
 537         ct_user_exit
 538         mov     x0, x26
 539         mov     x1, x25
 540         mov     x2, sp
 541         bl      do_sp_pc_abort
 542         b       ret_to_user
 543 el0_undef:
 544         /*
 545          * Undefined instruction
 546          */
 547         // enable interrupts before calling the main handler
 548         enable_dbg_and_irq
 549         ct_user_exit
 550         mov     x0, sp
 551         bl      do_undefinstr
 552         b       ret_to_user
 553 el0_dbg:
 554         /*
 555          * Debug exception handling
 556          */
 557         tbnz    x24, #0, el0_inv                // EL0 only
 558         mrs     x0, far_el1
 559         mov     x1, x25
 560         mov     x2, sp
 561         bl      do_debug_exception
 562         enable_dbg
 563         ct_user_exit
 564         b       ret_to_user
 565 el0_inv:
 566         enable_dbg
 567         ct_user_exit
 568         mov     x0, sp
 569         mov     x1, #BAD_SYNC
 570         mov     x2, x25
 571         bl      bad_el0_sync
 572         b       ret_to_user
 573 ENDPROC(el0_sync)
 574
 575         .align  6
 576 el0_irq:
 577         kernel_entry 0
 578 el0_irq_naked:
 579         enable_dbg
 580 #ifdef CONFIG_TRACE_IRQFLAGS
 581         bl      trace_hardirqs_off
 582 #endif
 583
 584         ct_user_exit
 585         irq_handler
 586
 587 #ifdef CONFIG_TRACE_IRQFLAGS
 588         bl      trace_hardirqs_on
 589 #endif
 590         b       ret_to_user
 591 ENDPROC(el0_irq)
 592
 593 /*
 594  * Register switch for AArch64. The callee-saved registers need to be saved
 595  * and restored. On entry:
 596  *   x0 = previous task_struct (must be preserved across the switch)
 597  *   x1 = next task_struct
 598  * Previous and next are guaranteed not to be the same.
 599  *
 600  */
 601 ENTRY(cpu_switch_to)
 602         mov     x10, #THREAD_CPU_CONTEXT
 603         add     x8, x0, x10
 604         mov     x9, sp
 605         stp     x19, x20, [x8], #16             // store callee-saved registers
 606         stp     x21, x22, [x8], #16
 607         stp     x23, x24, [x8], #16
 608         stp     x25, x26, [x8], #16
 609         stp     x27, x28, [x8], #16
 610         stp     x29, x9, [x8], #16
 611         str     lr, [x8]
 612         add     x8, x1, x10
 613         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 614         ldp     x21, x22, [x8], #16
 615         ldp     x23, x24, [x8], #16
 616         ldp     x25, x26, [x8], #16
 617         ldp     x27, x28, [x8], #16
 618         ldp     x29, x9, [x8], #16
 619         ldr     lr, [x8]
 620         mov     sp, x9
 621         ret
 622 ENDPROC(cpu_switch_to)
 623
 624 /*
 625  * This is the fast syscall return path.  We do as little as possible here,
 626  * and this includes saving x0 back into the kernel stack.
 627  */
 628 ret_fast_syscall:
 629         disable_irq                             // disable interrupts
 630         str     x0, [sp, #S_X0]                 // returned x0
 631         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 632         and     x2, x1, #_TIF_SYSCALL_WORK
 633         cbnz    x2, ret_fast_syscall_trace
 634         and     x2, x1, #_TIF_WORK_MASK
 635         cbnz    x2, work_pending
 636         enable_step_tsk x1, x2
 637         kernel_exit 0
 638 ret_fast_syscall_trace:
 639         enable_irq                              // enable interrupts
 640         b       __sys_trace_return_skipped      // we already saved x0
 641
 642 /*
 643  * Ok, we need to do extra processing, enter the slow path.
 644  */
 645 work_pending:
 646         tbnz    x1, #TIF_NEED_RESCHED, work_resched
 647         tbnz    x1, #TIF_NEED_RESCHED_LAZY, work_resched
 648         /* TIF_SIGPENDING, TIF_NOTIFY_RESUME or TIF_FOREIGN_FPSTATE case */
 649         ldr     x2, [sp, #S_PSTATE]
 650         mov     x0, sp                          // 'regs'
 651         tst     x2, #PSR_MODE_MASK              // user mode regs?
 652         b.ne    no_work_pending                 // returning to kernel
 653         enable_irq                              // enable interrupts for do_notify_resume()
 654         bl      do_notify_resume
 655         b       ret_to_user
 656 work_resched:
 657         bl      schedule
 658
 659 /*
 660  * "slow" syscall return path.
 661  */
 662 ret_to_user:
 663         disable_irq                             // disable interrupts
 664         ldr     x1, [tsk, #TI_FLAGS]
 665         and     x2, x1, #_TIF_WORK_MASK
 666         cbnz    x2, work_pending
 667         enable_step_tsk x1, x2
 668 no_work_pending:
 669         kernel_exit 0
 670 ENDPROC(ret_to_user)
 671
 672 /*
 673  * This is how we return from a fork.
 674  */
 675 ENTRY(ret_from_fork)
 676         bl      schedule_tail
 677         cbz     x19, 1f                         // not a kernel thread
 678         mov     x0, x20
 679         blr     x19
 680 1:      get_thread_info tsk
 681         b       ret_to_user
 682 ENDPROC(ret_from_fork)
 683
 684 /*
 685  * SVC handler.
 686  */
 687         .align  6
 688 el0_svc:
 689         adrp    stbl, sys_call_table            // load syscall table pointer
 690         uxtw    scno, w8                        // syscall number in w8
 691         mov     sc_nr, #__NR_syscalls
 692 el0_svc_naked:                                  // compat entry point
 693         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 694         enable_dbg_and_irq
 695         ct_user_exit 1
 696
 697         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 698         tst     x16, #_TIF_SYSCALL_WORK
 699         b.ne    __sys_trace
 700         cmp     scno, sc_nr                     // check upper syscall limit
 701         b.hs    ni_sys
 702         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 703         blr     x16                             // call sys_* routine
 704         b       ret_fast_syscall
 705 ni_sys:
 706         mov     x0, sp
 707         bl      do_ni_syscall
 708         b       ret_fast_syscall
 709 ENDPROC(el0_svc)
 710
 711         /*
 712          * This is the really slow path.  We're going to be doing context
 713          * switches, and waiting for our parent to respond.
 714          */
 715 __sys_trace:
 716         mov     w0, #-1                         // set default errno for
 717         cmp     scno, x0                        // user-issued syscall(-1)
 718         b.ne    1f
 719         mov     x0, #-ENOSYS
 720         str     x0, [sp, #S_X0]
 721 1:      mov     x0, sp
 722         bl      syscall_trace_enter
 723         cmp     w0, #-1                         // skip the syscall?
 724         b.eq    __sys_trace_return_skipped
 725         uxtw    scno, w0                        // syscall number (possibly new)
 726         mov     x1, sp                          // pointer to regs
 727         cmp     scno, sc_nr                     // check upper syscall limit
 728         b.hs    __ni_sys_trace
 729         ldp     x0, x1, [sp]                    // restore the syscall args
 730         ldp     x2, x3, [sp, #S_X2]
 731         ldp     x4, x5, [sp, #S_X4]
 732         ldp     x6, x7, [sp, #S_X6]
 733         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 734         blr     x16                             // call sys_* routine
 735
 736 __sys_trace_return:
 737         str     x0, [sp, #S_X0]                 // save returned x0
 738 __sys_trace_return_skipped:
 739         mov     x0, sp
 740         bl      syscall_trace_exit
 741         b       ret_to_user
 742
 743 __ni_sys_trace:
 744         mov     x0, sp
 745         bl      do_ni_syscall
 746         b       __sys_trace_return
 747
 748 /*
 749  * Special system call wrappers.
 750  */
 751 ENTRY(sys_rt_sigreturn_wrapper)
 752         mov     x0, sp
 753         b       sys_rt_sigreturn
 754 ENDPROC(sys_rt_sigreturn_wrapper)