kernel/arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative-asm.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/thread_info.h>
  31 #include <asm/unistd.h>
  32
  33 /*
  34  * Context tracking subsystem.  Used to instrument transitions
  35  * between user and kernel mode.
  36  */
  37         .macro ct_user_exit, syscall = 0
  38 #ifdef CONFIG_CONTEXT_TRACKING
  39         bl      context_tracking_user_exit
  40         .if \syscall == 1
  41         /*
  42          * Save/restore needed during syscalls.  Restore syscall arguments from
  43          * the values already saved on stack during kernel_entry.
  44          */
  45         ldp     x0, x1, [sp]
  46         ldp     x2, x3, [sp, #S_X2]
  47         ldp     x4, x5, [sp, #S_X4]
  48         ldp     x6, x7, [sp, #S_X6]
  49         .endif
  50 #endif
  51         .endm
  52
  53         .macro ct_user_enter
  54 #ifdef CONFIG_CONTEXT_TRACKING
  55         bl      context_tracking_user_enter
  56 #endif
  57         .endm
  58
  59 /*
  60  * Bad Abort numbers
  61  *-----------------
  62  */
  63 #define BAD_SYNC        0
  64 #define BAD_IRQ         1
  65 #define BAD_FIQ         2
  66 #define BAD_ERROR       3
  67
  68         .macro  kernel_entry, el, regsize = 64
  69         sub     sp, sp, #S_FRAME_SIZE
  70         .if     \regsize == 32
  71         mov     w0, w0                          // zero upper 32 bits of x0
  72         .endif
  73         stp     x0, x1, [sp, #16 * 0]
  74         stp     x2, x3, [sp, #16 * 1]
  75         stp     x4, x5, [sp, #16 * 2]
  76         stp     x6, x7, [sp, #16 * 3]
  77         stp     x8, x9, [sp, #16 * 4]
  78         stp     x10, x11, [sp, #16 * 5]
  79         stp     x12, x13, [sp, #16 * 6]
  80         stp     x14, x15, [sp, #16 * 7]
  81         stp     x16, x17, [sp, #16 * 8]
  82         stp     x18, x19, [sp, #16 * 9]
  83         stp     x20, x21, [sp, #16 * 10]
  84         stp     x22, x23, [sp, #16 * 11]
  85         stp     x24, x25, [sp, #16 * 12]
  86         stp     x26, x27, [sp, #16 * 13]
  87         stp     x28, x29, [sp, #16 * 14]
  88
  89         .if     \el == 0
  90         mrs     x21, sp_el0
  91         get_thread_info tsk                     // Ensure MDSCR_EL1.SS is clear,
  92         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  93         disable_step_tsk x19, x20               // exceptions when scheduling.
  94         .else
  95         add     x21, sp, #S_FRAME_SIZE
  96         .endif
  97         mrs     x22, elr_el1
  98         mrs     x23, spsr_el1
  99         stp     lr, x21, [sp, #S_LR]
 100         stp     x22, x23, [sp, #S_PC]
 101
 102         /*
 103          * Set syscallno to -1 by default (overridden later if real syscall).
 104          */
 105         .if     \el == 0
 106         mvn     x21, xzr
 107         str     x21, [sp, #S_SYSCALLNO]
 108         .endif
 109
 110         /*
 111          * Registers that may be useful after this macro is invoked:
 112          *
 113          * x21 - aborted SP
 114          * x22 - aborted PC
 115          * x23 - aborted PSTATE
 116         */
 117         .endm
 118
 119         .macro  kernel_exit, el, ret = 0
 120         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 121         .if     \el == 0
 122         ct_user_enter
 123         ldr     x23, [sp, #S_SP]                // load return stack pointer
 124         msr     sp_el0, x23
 125
 126 #ifdef CONFIG_ARM64_ERRATUM_845719
 127         alternative_insn                                                \
 128         "nop",                                                          \
 129         "tbz x22, #4, 1f",                                              \
 130         ARM64_WORKAROUND_845719
 131 #ifdef CONFIG_PID_IN_CONTEXTIDR
 132         alternative_insn                                                \
 133         "nop; nop",                                                     \
 134         "mrs x29, contextidr_el1; msr contextidr_el1, x29; 1:",         \
 135         ARM64_WORKAROUND_845719
 136 #else
 137         alternative_insn                                                \
 138         "nop",                                                          \
 139         "msr contextidr_el1, xzr; 1:",                                  \
 140         ARM64_WORKAROUND_845719
 141 #endif
 142 #endif
 143         .endif
 144         msr     elr_el1, x21                    // set up the return data
 145         msr     spsr_el1, x22
 146         .if     \ret
 147         ldr     x1, [sp, #S_X1]                 // preserve x0 (syscall return)
 148         .else
 149         ldp     x0, x1, [sp, #16 * 0]
 150         .endif
 151         ldp     x2, x3, [sp, #16 * 1]
 152         ldp     x4, x5, [sp, #16 * 2]
 153         ldp     x6, x7, [sp, #16 * 3]
 154         ldp     x8, x9, [sp, #16 * 4]
 155         ldp     x10, x11, [sp, #16 * 5]
 156         ldp     x12, x13, [sp, #16 * 6]
 157         ldp     x14, x15, [sp, #16 * 7]
 158         ldp     x16, x17, [sp, #16 * 8]
 159         ldp     x18, x19, [sp, #16 * 9]
 160         ldp     x20, x21, [sp, #16 * 10]
 161         ldp     x22, x23, [sp, #16 * 11]
 162         ldp     x24, x25, [sp, #16 * 12]
 163         ldp     x26, x27, [sp, #16 * 13]
 164         ldp     x28, x29, [sp, #16 * 14]
 165         ldr     lr, [sp, #S_LR]
 166         add     sp, sp, #S_FRAME_SIZE           // restore sp
 167         eret                                    // return to kernel
 168         .endm
 169
 170         .macro  get_thread_info, rd
 171         mov     \rd, sp
 172         and     \rd, \rd, #~(THREAD_SIZE - 1)   // top of stack
 173         .endm
 174
 175 /*
 176  * These are the registers used in the syscall handler, and allow us to
 177  * have in theory up to 7 arguments to a function - x0 to x6.
 178  *
 179  * x7 is reserved for the system call number in 32-bit mode.
 180  */
 181 sc_nr   .req    x25             // number of system calls
 182 scno    .req    x26             // syscall number
 183 stbl    .req    x27             // syscall table pointer
 184 tsk     .req    x28             // current thread_info
 185
 186 /*
 187  * Interrupt handling.
 188  */
 189         .macro  irq_handler
 190         adrp    x1, handle_arch_irq
 191         ldr     x1, [x1, #:lo12:handle_arch_irq]
 192         mov     x0, sp
 193         blr     x1
 194         .endm
 195
 196         .text
 197
 198 /*
 199  * Exception vectors.
 200  */
 201
 202         .align  11
 203 ENTRY(vectors)
 204         ventry  el1_sync_invalid                // Synchronous EL1t
 205         ventry  el1_irq_invalid                 // IRQ EL1t
 206         ventry  el1_fiq_invalid                 // FIQ EL1t
 207         ventry  el1_error_invalid               // Error EL1t
 208
 209         ventry  el1_sync                        // Synchronous EL1h
 210         ventry  el1_irq                         // IRQ EL1h
 211         ventry  el1_fiq_invalid                 // FIQ EL1h
 212         ventry  el1_error_invalid               // Error EL1h
 213
 214         ventry  el0_sync                        // Synchronous 64-bit EL0
 215         ventry  el0_irq                         // IRQ 64-bit EL0
 216         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 217         ventry  el0_error_invalid               // Error 64-bit EL0
 218
 219 #ifdef CONFIG_COMPAT
 220         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 221         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 222         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 223         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 224 #else
 225         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 226         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 227         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 228         ventry  el0_error_invalid               // Error 32-bit EL0
 229 #endif
 230 END(vectors)
 231
 232 /*
 233  * Invalid mode handlers
 234  */
 235         .macro  inv_entry, el, reason, regsize = 64
 236         kernel_entry el, \regsize
 237         mov     x0, sp
 238         mov     x1, #\reason
 239         mrs     x2, esr_el1
 240         b       bad_mode
 241         .endm
 242
 243 el0_sync_invalid:
 244         inv_entry 0, BAD_SYNC
 245 ENDPROC(el0_sync_invalid)
 246
 247 el0_irq_invalid:
 248         inv_entry 0, BAD_IRQ
 249 ENDPROC(el0_irq_invalid)
 250
 251 el0_fiq_invalid:
 252         inv_entry 0, BAD_FIQ
 253 ENDPROC(el0_fiq_invalid)
 254
 255 el0_error_invalid:
 256         inv_entry 0, BAD_ERROR
 257 ENDPROC(el0_error_invalid)
 258
 259 #ifdef CONFIG_COMPAT
 260 el0_fiq_invalid_compat:
 261         inv_entry 0, BAD_FIQ, 32
 262 ENDPROC(el0_fiq_invalid_compat)
 263
 264 el0_error_invalid_compat:
 265         inv_entry 0, BAD_ERROR, 32
 266 ENDPROC(el0_error_invalid_compat)
 267 #endif
 268
 269 el1_sync_invalid:
 270         inv_entry 1, BAD_SYNC
 271 ENDPROC(el1_sync_invalid)
 272
 273 el1_irq_invalid:
 274         inv_entry 1, BAD_IRQ
 275 ENDPROC(el1_irq_invalid)
 276
 277 el1_fiq_invalid:
 278         inv_entry 1, BAD_FIQ
 279 ENDPROC(el1_fiq_invalid)
 280
 281 el1_error_invalid:
 282         inv_entry 1, BAD_ERROR
 283 ENDPROC(el1_error_invalid)
 284
 285 /*
 286  * EL1 mode handlers.
 287  */
 288         .align  6
 289 el1_sync:
 290         kernel_entry 1
 291         mrs     x1, esr_el1                     // read the syndrome register
 292         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 293         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 294         b.eq    el1_da
 295         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 296         b.eq    el1_undef
 297         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 298         b.eq    el1_sp_pc
 299         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 300         b.eq    el1_sp_pc
 301         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 302         b.eq    el1_undef
 303         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 304         b.ge    el1_dbg
 305         b       el1_inv
 306 el1_da:
 307         /*
 308          * Data abort handling
 309          */
 310         mrs     x0, far_el1
 311         enable_dbg
 312         // re-enable interrupts if they were enabled in the aborted context
 313         tbnz    x23, #7, 1f                     // PSR_I_BIT
 314         enable_irq
 315 1:
 316         mov     x2, sp                          // struct pt_regs
 317         bl      do_mem_abort
 318
 319         // disable interrupts before pulling preserved data off the stack
 320         disable_irq
 321         kernel_exit 1
 322 el1_sp_pc:
 323         /*
 324          * Stack or PC alignment exception handling
 325          */
 326         mrs     x0, far_el1
 327         enable_dbg
 328         mov     x2, sp
 329         b       do_sp_pc_abort
 330 el1_undef:
 331         /*
 332          * Undefined instruction
 333          */
 334         enable_dbg
 335         mov     x0, sp
 336         b       do_undefinstr
 337 el1_dbg:
 338         /*
 339          * Debug exception handling
 340          */
 341         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 342         cinc    x24, x24, eq                    // set bit '0'
 343         tbz     x24, #0, el1_inv                // EL1 only
 344         mrs     x0, far_el1
 345         mov     x2, sp                          // struct pt_regs
 346         bl      do_debug_exception
 347         kernel_exit 1
 348 el1_inv:
 349         // TODO: add support for undefined instructions in kernel mode
 350         enable_dbg
 351         mov     x0, sp
 352         mov     x1, #BAD_SYNC
 353         mrs     x2, esr_el1
 354         b       bad_mode
 355 ENDPROC(el1_sync)
 356
 357         .align  6
 358 el1_irq:
 359         kernel_entry 1
 360         enable_dbg
 361 #ifdef CONFIG_TRACE_IRQFLAGS
 362         bl      trace_hardirqs_off
 363 #endif
 364
 365         irq_handler
 366
 367 #ifdef CONFIG_PREEMPT
 368         get_thread_info tsk
 369         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 370         cbnz    w24, 2f                         // preempt count != 0
 371         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 372         tbnz    x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 373
 374         ldr     w24, [tsk, #TI_PREEMPT_LAZY]    // get preempt lazy count
 375         cbnz    w24, 2f                         // preempt lazy count != 0
 376         tbz     x0, #TIF_NEED_RESCHED_LAZY, 2f  // needs rescheduling?
 377 1:
 378         bl      el1_preempt
 379 2:
 380 #endif
 381 #ifdef CONFIG_TRACE_IRQFLAGS
 382         bl      trace_hardirqs_on
 383 #endif
 384         kernel_exit 1
 385 ENDPROC(el1_irq)
 386
 387 #ifdef CONFIG_PREEMPT
 388 el1_preempt:
 389         mov     x24, lr
 390 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 391         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 392         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 393         tbnz    x0, #TIF_NEED_RESCHED_LAZY, 1b  // needs rescheduling?
 394         ret     x24
 395 #endif
 396
 397 /*
 398  * EL0 mode handlers.
 399  */
 400         .align  6
 401 el0_sync:
 402         kernel_entry 0
 403         mrs     x25, esr_el1                    // read the syndrome register
 404         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 405         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 406         b.eq    el0_svc
 407         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 408         b.eq    el0_da
 409         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 410         b.eq    el0_ia
 411         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 412         b.eq    el0_fpsimd_acc
 413         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 414         b.eq    el0_fpsimd_exc
 415         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 416         b.eq    el0_undef
 417         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 418         b.eq    el0_sp_pc
 419         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 420         b.eq    el0_sp_pc
 421         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 422         b.eq    el0_undef
 423         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 424         b.ge    el0_dbg
 425         b       el0_inv
 426
 427 #ifdef CONFIG_COMPAT
 428         .align  6
 429 el0_sync_compat:
 430         kernel_entry 0, 32
 431         mrs     x25, esr_el1                    // read the syndrome register
 432         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 433         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 434         b.eq    el0_svc_compat
 435         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 436         b.eq    el0_da
 437         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 438         b.eq    el0_ia
 439         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 440         b.eq    el0_fpsimd_acc
 441         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 442         b.eq    el0_fpsimd_exc
 443         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 444         b.eq    el0_undef
 445         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 446         b.eq    el0_undef
 447         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 448         b.eq    el0_undef
 449         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 450         b.eq    el0_undef
 451         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 452         b.eq    el0_undef
 453         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 454         b.eq    el0_undef
 455         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 456         b.ge    el0_dbg
 457         b       el0_inv
 458 el0_svc_compat:
 459         /*
 460          * AArch32 syscall handling
 461          */
 462         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 463         uxtw    scno, w7                        // syscall number in w7 (r7)
 464         mov     sc_nr, #__NR_compat_syscalls
 465         b       el0_svc_naked
 466
 467         .align  6
 468 el0_irq_compat:
 469         kernel_entry 0, 32
 470         b       el0_irq_naked
 471 #endif
 472
 473 el0_da:
 474         /*
 475          * Data abort handling
 476          */
 477         mrs     x26, far_el1
 478         // enable interrupts before calling the main handler
 479         enable_dbg_and_irq
 480         ct_user_exit
 481         bic     x0, x26, #(0xff << 56)
 482         mov     x1, x25
 483         mov     x2, sp
 484         bl      do_mem_abort
 485         b       ret_to_user
 486 el0_ia:
 487         /*
 488          * Instruction abort handling
 489          */
 490         mrs     x26, far_el1
 491         // enable interrupts before calling the main handler
 492         enable_dbg_and_irq
 493         ct_user_exit
 494         mov     x0, x26
 495         orr     x1, x25, #1 << 24               // use reserved ISS bit for instruction aborts
 496         mov     x2, sp
 497         bl      do_mem_abort
 498         b       ret_to_user
 499 el0_fpsimd_acc:
 500         /*
 501          * Floating Point or Advanced SIMD access
 502          */
 503         enable_dbg
 504         ct_user_exit
 505         mov     x0, x25
 506         mov     x1, sp
 507         bl      do_fpsimd_acc
 508         b       ret_to_user
 509 el0_fpsimd_exc:
 510         /*
 511          * Floating Point or Advanced SIMD exception
 512          */
 513         enable_dbg
 514         ct_user_exit
 515         mov     x0, x25
 516         mov     x1, sp
 517         bl      do_fpsimd_exc
 518         b       ret_to_user
 519 el0_sp_pc:
 520         /*
 521          * Stack or PC alignment exception handling
 522          */
 523         mrs     x26, far_el1
 524         // enable interrupts before calling the main handler
 525         enable_dbg_and_irq
 526         ct_user_exit
 527         mov     x0, x26
 528         mov     x1, x25
 529         mov     x2, sp
 530         bl      do_sp_pc_abort
 531         b       ret_to_user
 532 el0_undef:
 533         /*
 534          * Undefined instruction
 535          */
 536         // enable interrupts before calling the main handler
 537         enable_dbg_and_irq
 538         ct_user_exit
 539         mov     x0, sp
 540         bl      do_undefinstr
 541         b       ret_to_user
 542 el0_dbg:
 543         /*
 544          * Debug exception handling
 545          */
 546         tbnz    x24, #0, el0_inv                // EL0 only
 547         mrs     x0, far_el1
 548         mov     x1, x25
 549         mov     x2, sp
 550         bl      do_debug_exception
 551         enable_dbg
 552         ct_user_exit
 553         b       ret_to_user
 554 el0_inv:
 555         enable_dbg
 556         ct_user_exit
 557         mov     x0, sp
 558         mov     x1, #BAD_SYNC
 559         mrs     x2, esr_el1
 560         bl      bad_mode
 561         b       ret_to_user
 562 ENDPROC(el0_sync)
 563
 564         .align  6
 565 el0_irq:
 566         kernel_entry 0
 567 el0_irq_naked:
 568         enable_dbg
 569 #ifdef CONFIG_TRACE_IRQFLAGS
 570         bl      trace_hardirqs_off
 571 #endif
 572
 573         ct_user_exit
 574         irq_handler
 575
 576 #ifdef CONFIG_TRACE_IRQFLAGS
 577         bl      trace_hardirqs_on
 578 #endif
 579         b       ret_to_user
 580 ENDPROC(el0_irq)
 581
 582 /*
 583  * Register switch for AArch64. The callee-saved registers need to be saved
 584  * and restored. On entry:
 585  *   x0 = previous task_struct (must be preserved across the switch)
 586  *   x1 = next task_struct
 587  * Previous and next are guaranteed not to be the same.
 588  *
 589  */
 590 ENTRY(cpu_switch_to)
 591         add     x8, x0, #THREAD_CPU_CONTEXT
 592         mov     x9, sp
 593         stp     x19, x20, [x8], #16             // store callee-saved registers
 594         stp     x21, x22, [x8], #16
 595         stp     x23, x24, [x8], #16
 596         stp     x25, x26, [x8], #16
 597         stp     x27, x28, [x8], #16
 598         stp     x29, x9, [x8], #16
 599         str     lr, [x8]
 600         add     x8, x1, #THREAD_CPU_CONTEXT
 601         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 602         ldp     x21, x22, [x8], #16
 603         ldp     x23, x24, [x8], #16
 604         ldp     x25, x26, [x8], #16
 605         ldp     x27, x28, [x8], #16
 606         ldp     x29, x9, [x8], #16
 607         ldr     lr, [x8]
 608         mov     sp, x9
 609         ret
 610 ENDPROC(cpu_switch_to)
 611
 612 /*
 613  * This is the fast syscall return path.  We do as little as possible here,
 614  * and this includes saving x0 back into the kernel stack.
 615  */
 616 ret_fast_syscall:
 617         disable_irq                             // disable interrupts
 618         ldr     x1, [tsk, #TI_FLAGS]
 619         and     x2, x1, #_TIF_WORK_MASK
 620         cbnz    x2, fast_work_pending
 621         enable_step_tsk x1, x2
 622         kernel_exit 0, ret = 1
 623
 624 /*
 625  * Ok, we need to do extra processing, enter the slow path.
 626  */
 627 fast_work_pending:
 628         str     x0, [sp, #S_X0]                 // returned x0
 629 work_pending:
 630         tbnz    x1, #TIF_NEED_RESCHED, work_resched
 631         tbnz    x1, #TIF_NEED_RESCHED_LAZY, work_resched
 632         /* TIF_SIGPENDING, TIF_NOTIFY_RESUME or TIF_FOREIGN_FPSTATE case */
 633         ldr     x2, [sp, #S_PSTATE]
 634         mov     x0, sp                          // 'regs'
 635         tst     x2, #PSR_MODE_MASK              // user mode regs?
 636         b.ne    no_work_pending                 // returning to kernel
 637         enable_irq                              // enable interrupts for do_notify_resume()
 638         bl      do_notify_resume
 639         b       ret_to_user
 640 work_resched:
 641         bl      schedule
 642
 643 /*
 644  * "slow" syscall return path.
 645  */
 646 ret_to_user:
 647         disable_irq                             // disable interrupts
 648         ldr     x1, [tsk, #TI_FLAGS]
 649         and     x2, x1, #_TIF_WORK_MASK
 650         cbnz    x2, work_pending
 651         enable_step_tsk x1, x2
 652 no_work_pending:
 653         kernel_exit 0, ret = 0
 654 ENDPROC(ret_to_user)
 655
 656 /*
 657  * This is how we return from a fork.
 658  */
 659 ENTRY(ret_from_fork)
 660         bl      schedule_tail
 661         cbz     x19, 1f                         // not a kernel thread
 662         mov     x0, x20
 663         blr     x19
 664 1:      get_thread_info tsk
 665         b       ret_to_user
 666 ENDPROC(ret_from_fork)
 667
 668 /*
 669  * SVC handler.
 670  */
 671         .align  6
 672 el0_svc:
 673         adrp    stbl, sys_call_table            // load syscall table pointer
 674         uxtw    scno, w8                        // syscall number in w8
 675         mov     sc_nr, #__NR_syscalls
 676 el0_svc_naked:                                  // compat entry point
 677         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 678         enable_dbg_and_irq
 679         ct_user_exit 1
 680
 681         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 682         tst     x16, #_TIF_SYSCALL_WORK
 683         b.ne    __sys_trace
 684         cmp     scno, sc_nr                     // check upper syscall limit
 685         b.hs    ni_sys
 686         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 687         blr     x16                             // call sys_* routine
 688         b       ret_fast_syscall
 689 ni_sys:
 690         mov     x0, sp
 691         bl      do_ni_syscall
 692         b       ret_fast_syscall
 693 ENDPROC(el0_svc)
 694
 695         /*
 696          * This is the really slow path.  We're going to be doing context
 697          * switches, and waiting for our parent to respond.
 698          */
 699 __sys_trace:
 700         mov     w0, #-1                         // set default errno for
 701         cmp     scno, x0                        // user-issued syscall(-1)
 702         b.ne    1f
 703         mov     x0, #-ENOSYS
 704         str     x0, [sp, #S_X0]
 705 1:      mov     x0, sp
 706         bl      syscall_trace_enter
 707         cmp     w0, #-1                         // skip the syscall?
 708         b.eq    __sys_trace_return_skipped
 709         uxtw    scno, w0                        // syscall number (possibly new)
 710         mov     x1, sp                          // pointer to regs
 711         cmp     scno, sc_nr                     // check upper syscall limit
 712         b.hs    __ni_sys_trace
 713         ldp     x0, x1, [sp]                    // restore the syscall args
 714         ldp     x2, x3, [sp, #S_X2]
 715         ldp     x4, x5, [sp, #S_X4]
 716         ldp     x6, x7, [sp, #S_X6]
 717         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 718         blr     x16                             // call sys_* routine
 719
 720 __sys_trace_return:
 721         str     x0, [sp, #S_X0]                 // save returned x0
 722 __sys_trace_return_skipped:
 723         mov     x0, sp
 724         bl      syscall_trace_exit
 725         b       ret_to_user
 726
 727 __ni_sys_trace:
 728         mov     x0, sp
 729         bl      do_ni_syscall
 730         b       __sys_trace_return
 731
 732 /*
 733  * Special system call wrappers.
 734  */
 735 ENTRY(sys_rt_sigreturn_wrapper)
 736         mov     x0, sp
 737         b       sys_rt_sigreturn
 738 ENDPROC(sys_rt_sigreturn_wrapper)