kernel/arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15
  16 #ifdef CONFIG_NEED_RET_TO_USER
  17 #include <mach/entry-macro.S>
  18 #else
  19         .macro  arch_ret_to_user, tmp1, tmp2
  20         .endm
  21 #endif
  22
  23 #include "entry-header.S"
  24
  25
  26         .align  5
  27 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING))
  28 /*
  29  * This is the fast syscall return path.  We do as little as possible here,
  30  * such as avoiding writing r0 to the stack.  We only use this path if we
  31  * have tracing and context tracking disabled - the overheads from those
  32  * features make this path too inefficient.
  33  */
  34 ret_fast_syscall:
  35  UNWIND(.fnstart        )
  36  UNWIND(.cantunwind     )
  37         disable_irq_notrace                     @ disable interrupts
  38         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  39         tst     r1, #((_TIF_SYSCALL_WORK | _TIF_WORK_MASK) & ~_TIF_SECCOMP)
  40         bne     fast_work_pending
  41         tst     r1, #_TIF_SECCOMP
  42         bne     fast_work_pending
  43
  44         /* perform architecture specific actions before user return */
  45         arch_ret_to_user r1, lr
  46
  47         restore_user_regs fast = 1, offset = S_OFF
  48  UNWIND(.fnend          )
  49 ENDPROC(ret_fast_syscall)
  50
  51         /* Ok, we need to do extra processing, enter the slow path. */
  52 fast_work_pending:
  53         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  54         /* fall through to work_pending */
  55 #else
  56 /*
  57  * The "replacement" ret_fast_syscall for when tracing or context tracking
  58  * is enabled.  As we will need to call out to some C functions, we save
  59  * r0 first to avoid needing to save registers around each C function call.
  60  */
  61 ret_fast_syscall:
  62  UNWIND(.fnstart        )
  63  UNWIND(.cantunwind     )
  64         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  65         disable_irq_notrace                     @ disable interrupts
  66         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  67         tst     r1, #((_TIF_SYSCALL_WORK | _TIF_WORK_MASK) & ~_TIF_SECCOMP)
  68         bne     do_slower_path
  69         tst     r1, #_TIF_SECCOMP
  70         beq     no_work_pending
  71 do_slower_path:
  72  UNWIND(.fnend          )
  73 ENDPROC(ret_fast_syscall)
  74
  75         /* Slower path - fall through to work_pending */
  76 #endif
  77
  78         tst     r1, #_TIF_SYSCALL_WORK
  79         bne     __sys_trace_return_nosave
  80 slow_work_pending:
  81         mov     r0, sp                          @ 'regs'
  82         mov     r2, why                         @ 'syscall'
  83         bl      do_work_pending
  84         cmp     r0, #0
  85         beq     no_work_pending
  86         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  87         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  88         b       local_restart                   @ ... and off we go
  89 ENDPROC(ret_fast_syscall)
  90
  91 /*
  92  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  93  * IRQs may be enabled here, so always disable them.  Note that we use the
  94  * "notrace" version to avoid calling into the tracing code unnecessarily.
  95  * do_work_pending() will update this state if necessary.
  96  */
  97 ENTRY(ret_to_user)
  98 ret_slow_syscall:
  99         disable_irq_notrace                     @ disable interrupts
 100 ENTRY(ret_to_user_from_irq)
 101         ldr     r1, [tsk, #TI_FLAGS]
 102         tst     r1, #_TIF_WORK_MASK
 103         bne     slow_work_pending
 104 no_work_pending:
 105         asm_trace_hardirqs_on save = 0
 106
 107         /* perform architecture specific actions before user return */
 108         arch_ret_to_user r1, lr
 109         ct_user_enter save = 0
 110
 111         restore_user_regs fast = 0, offset = 0
 112 ENDPROC(ret_to_user_from_irq)
 113 ENDPROC(ret_to_user)
 114
 115 /*
 116  * This is how we return from a fork.
 117  */
 118 ENTRY(ret_from_fork)
 119         bl      schedule_tail
 120         cmp     r5, #0
 121         movne   r0, r4
 122         badrne  lr, 1f
 123         retne   r5
 124 1:      get_thread_info tsk
 125         b       ret_slow_syscall
 126 ENDPROC(ret_from_fork)
 127
 128         .equ NR_syscalls,0
 129 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
 130 #include "calls.S"
 131
 132 /*
 133  * Ensure that the system call table is equal to __NR_syscalls,
 134  * which is the value the rest of the system sees
 135  */
 136 .ifne NR_syscalls - __NR_syscalls
 137 .error "__NR_syscalls is not equal to the size of the syscall table"
 138 .endif
 139
 140 #undef CALL
 141 #define CALL(x) .long x
 142
 143 /*=============================================================================
 144  * SWI handler
 145  *-----------------------------------------------------------------------------
 146  */
 147
 148         .align  5
 149 ENTRY(vector_swi)
 150 #ifdef CONFIG_CPU_V7M
 151         v7m_exception_entry
 152 #else
 153         sub     sp, sp, #S_FRAME_SIZE
 154         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 155  ARM(   add     r8, sp, #S_PC           )
 156  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 157  THUMB( mov     r8, sp                  )
 158  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 159         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 160         str     lr, [sp, #S_PC]                 @ Save calling PC
 161         str     r8, [sp, #S_PSR]                @ Save CPSR
 162         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 163 #endif
 164         zero_fp
 165         alignment_trap r10, ip, __cr_alignment
 166         enable_irq
 167         ct_user_exit
 168         get_thread_info tsk
 169
 170         /*
 171          * Get the system call number.
 172          */
 173
 174 #if defined(CONFIG_OABI_COMPAT)
 175
 176         /*
 177          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 178          * value to determine if it is an EABI or an old ABI call.
 179          */
 180 #ifdef CONFIG_ARM_THUMB
 181         tst     r8, #PSR_T_BIT
 182         movne   r10, #0                         @ no thumb OABI emulation
 183  USER(  ldreq   r10, [lr, #-4]          )       @ get SWI instruction
 184 #else
 185  USER(  ldr     r10, [lr, #-4]          )       @ get SWI instruction
 186 #endif
 187  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 188
 189 #elif defined(CONFIG_AEABI)
 190
 191         /*
 192          * Pure EABI user space always put syscall number into scno (r7).
 193          */
 194 #elif defined(CONFIG_ARM_THUMB)
 195         /* Legacy ABI only, possibly thumb mode. */
 196         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 197         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 198  USER(  ldreq   scno, [lr, #-4]         )
 199
 200 #else
 201         /* Legacy ABI only. */
 202  USER(  ldr     scno, [lr, #-4]         )       @ get SWI instruction
 203 #endif
 204
 205         uaccess_disable tbl
 206
 207         adr     tbl, sys_call_table             @ load syscall table pointer
 208
 209 #if defined(CONFIG_OABI_COMPAT)
 210         /*
 211          * If the swi argument is zero, this is an EABI call and we do nothing.
 212          *
 213          * If this is an old ABI call, get the syscall number into scno and
 214          * get the old ABI syscall table address.
 215          */
 216         bics    r10, r10, #0xff000000
 217         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 218         ldrne   tbl, =sys_oabi_call_table
 219 #elif !defined(CONFIG_AEABI)
 220         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 221         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 222 #endif
 223
 224 local_restart:
 225         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 226         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 227
 228         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 229         bne     __sys_trace
 230
 231         cmp     scno, #NR_syscalls              @ check upper syscall limit
 232         badr    lr, ret_fast_syscall            @ return address
 233         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 234
 235         add     r1, sp, #S_OFF
 236 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 237         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 238         bcs     arm_syscall
 239         mov     why, #0                         @ no longer a real syscall
 240         b       sys_ni_syscall                  @ not private func
 241
 242 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 243         /*
 244          * We failed to handle a fault trying to access the page
 245          * containing the swi instruction, but we're not really in a
 246          * position to return -EFAULT. Instead, return back to the
 247          * instruction and re-enter the user fault handling path trying
 248          * to page it in. This will likely result in sending SEGV to the
 249          * current task.
 250          */
 251 9001:
 252         sub     lr, lr, #4
 253         str     lr, [sp, #S_PC]
 254         b       ret_fast_syscall
 255 #endif
 256 ENDPROC(vector_swi)
 257
 258         /*
 259          * This is the really slow path.  We're going to be doing
 260          * context switches, and waiting for our parent to respond.
 261          */
 262 __sys_trace:
 263         mov     r1, scno
 264         add     r0, sp, #S_OFF
 265         bl      syscall_trace_enter
 266
 267         badr    lr, __sys_trace_return          @ return address
 268         mov     scno, r0                        @ syscall number (possibly new)
 269         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 270         cmp     scno, #NR_syscalls              @ check upper syscall limit
 271         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 272         stmccia sp, {r4, r5}                    @ and update the stack args
 273         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 274         cmp     scno, #-1                       @ skip the syscall?
 275         bne     2b
 276         add     sp, sp, #S_OFF                  @ restore stack
 277         b       ret_slow_syscall
 278
 279 __sys_trace_return:
 280         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 281         mov     r0, sp
 282         bl      syscall_trace_exit
 283         b       ret_slow_syscall
 284
 285 __sys_trace_return_nosave:
 286         enable_irq_notrace
 287         mov     r0, sp
 288         bl      syscall_trace_exit
 289         b       ret_slow_syscall
 290
 291         .align  5
 292 #ifdef CONFIG_ALIGNMENT_TRAP
 293         .type   __cr_alignment, #object
 294 __cr_alignment:
 295         .word   cr_alignment
 296 #endif
 297         .ltorg
 298
 299 /*
 300  * This is the syscall table declaration for native ABI syscalls.
 301  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 302  */
 303 #define ABI(native, compat) native
 304 #ifdef CONFIG_AEABI
 305 #define OBSOLETE(syscall) sys_ni_syscall
 306 #else
 307 #define OBSOLETE(syscall) syscall
 308 #endif
 309
 310         .type   sys_call_table, #object
 311 ENTRY(sys_call_table)
 312 #include "calls.S"
 313 #undef ABI
 314 #undef OBSOLETE
 315
 316 /*============================================================================
 317  * Special system call wrappers
 318  */
 319 @ r0 = syscall number
 320 @ r8 = syscall table
 321 sys_syscall:
 322                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 323                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 324                 cmpne   scno, #NR_syscalls      @ check range
 325                 stmloia sp, {r5, r6}            @ shuffle args
 326                 movlo   r0, r1
 327                 movlo   r1, r2
 328                 movlo   r2, r3
 329                 movlo   r3, r4
 330                 ldrlo   pc, [tbl, scno, lsl #2]
 331                 b       sys_ni_syscall
 332 ENDPROC(sys_syscall)
 333
 334 sys_sigreturn_wrapper:
 335                 add     r0, sp, #S_OFF
 336                 mov     why, #0         @ prevent syscall restart handling
 337                 b       sys_sigreturn
 338 ENDPROC(sys_sigreturn_wrapper)
 339
 340 sys_rt_sigreturn_wrapper:
 341                 add     r0, sp, #S_OFF
 342                 mov     why, #0         @ prevent syscall restart handling
 343                 b       sys_rt_sigreturn
 344 ENDPROC(sys_rt_sigreturn_wrapper)
 345
 346 sys_statfs64_wrapper:
 347                 teq     r1, #88
 348                 moveq   r1, #84
 349                 b       sys_statfs64
 350 ENDPROC(sys_statfs64_wrapper)
 351
 352 sys_fstatfs64_wrapper:
 353                 teq     r1, #88
 354                 moveq   r1, #84
 355                 b       sys_fstatfs64
 356 ENDPROC(sys_fstatfs64_wrapper)
 357
 358 /*
 359  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 360  * offset, we return EINVAL.
 361  */
 362 sys_mmap2:
 363 #if PAGE_SHIFT > 12
 364                 tst     r5, #PGOFF_MASK
 365                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 366                 streq   r5, [sp, #4]
 367                 beq     sys_mmap_pgoff
 368                 mov     r0, #-EINVAL
 369                 ret     lr
 370 #else
 371                 str     r5, [sp, #4]
 372                 b       sys_mmap_pgoff
 373 #endif
 374 ENDPROC(sys_mmap2)
 375
 376 #ifdef CONFIG_OABI_COMPAT
 377
 378 /*
 379  * These are syscalls with argument register differences
 380  */
 381
 382 sys_oabi_pread64:
 383                 stmia   sp, {r3, r4}
 384                 b       sys_pread64
 385 ENDPROC(sys_oabi_pread64)
 386
 387 sys_oabi_pwrite64:
 388                 stmia   sp, {r3, r4}
 389                 b       sys_pwrite64
 390 ENDPROC(sys_oabi_pwrite64)
 391
 392 sys_oabi_truncate64:
 393                 mov     r3, r2
 394                 mov     r2, r1
 395                 b       sys_truncate64
 396 ENDPROC(sys_oabi_truncate64)
 397
 398 sys_oabi_ftruncate64:
 399                 mov     r3, r2
 400                 mov     r2, r1
 401                 b       sys_ftruncate64
 402 ENDPROC(sys_oabi_ftruncate64)
 403
 404 sys_oabi_readahead:
 405                 str     r3, [sp]
 406                 mov     r3, r2
 407                 mov     r2, r1
 408                 b       sys_readahead
 409 ENDPROC(sys_oabi_readahead)
 410
 411 /*
 412  * Let's declare a second syscall table for old ABI binaries
 413  * using the compatibility syscall entries.
 414  */
 415 #define ABI(native, compat) compat
 416 #define OBSOLETE(syscall) syscall
 417
 418         .type   sys_oabi_call_table, #object
 419 ENTRY(sys_oabi_call_table)
 420 #include "calls.S"
 421 #undef ABI
 422 #undef OBSOLETE
 423
 424 #endif
 425