rubbos/app/httpd-2.0.64/modules/mappers/config9.m4

   1 dnl modules enabled in this directory by default
   2
   3 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
   4
   5 APACHE_MODPATH_INIT(mappers)
   6
   7 APACHE_MODULE(vhost_alias, mass virtual hosting module, , , most)
   8 APACHE_MODULE(negotiation, content negotiation, , , yes)
   9 APACHE_MODULE(dir, directory request handling, , , yes)
  10 APACHE_MODULE(imap, server-side imagemaps, , , yes)
  11 APACHE_MODULE(actions, Action triggering on requests, , , yes)
  12 APACHE_MODULE(speling, correct common URL misspellings, , , most)
  13 APACHE_MODULE(userdir, mapping of requests to user-specific directories, , , yes)
  14 APACHE_MODULE(alias, mapping of requests to different filesystem parts, , , yes)
  15
  16 APACHE_MODULE(rewrite, rule based URL manipulation, , , most)
  17
  18
  19 APR_CHECK_APR_DEFINE(APR_HAS_DSO)
  20
  21 case "x$enable_so" in
  22     "xyes")
  23         if test $ac_cv_define_APR_HAS_DSO = "no"; then
  24             AC_MSG_ERROR([mod_so has been requested but cannot be built on your system])
  25         fi
  26         ;;
  27     "xshared")
  28         AC_MSG_ERROR([mod_so can not be built as a shared DSO])
  29         ;;
  30     "xno")
  31         ;;
  32     "x")
  33         enable_so=$ac_cv_define_APR_HAS_DSO
  34         ;;
  35 esac
  36
  37 dnl mod_so can only be built statically. If the user wants modules to
  38 dnl be built as DSOs by default (eg. ./configure --enable-mods-shared=most)
  39 dnl then we must override the default here.
  40 if test "x$enable_so" = "xyes"; then
  41     enable_so="static"
  42 fi
  43
  44 if test "$sharedobjs" = "yes"; then
  45     if test $ac_cv_define_APR_HAS_DSO = "no"; then
  46         AC_MSG_ERROR([shared objects have been requested but cannot be built since mod_so cannot be built])
  47     elif test $enable_so = "no"; then
  48         AC_MSG_ERROR([shared objects have been requested but cannot be built since mod_so was disabled])
  49     fi
  50 fi
  51
  52 APACHE_MODULE(so, DSO capability, , , $enable_so)
  53
  54 dnl ### why save the cache?
  55 AC_CACHE_SAVE
  56
  57 APACHE_MODPATH_FINISH