rubbos/app/httpd-2.0.64/modules/filters/config.m4

   1 dnl modules enabled in this directory by default
   2
   3 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
   4
   5 APACHE_MODPATH_INIT(filters)
   6
   7 APACHE_MODULE(ext_filter, external filter module, , , most)
   8 APACHE_MODULE(include, Server Side Includes, , , yes)
   9
  10 APR_ADDTO(LT_LDFLAGS,-export-dynamic)
  11
  12 APACHE_MODULE(deflate, Deflate transfer encoding support, , , no, [
  13   AC_ARG_WITH(z, APACHE_HELP_STRING(--with-z=DIR,use a specific zlib library),
  14   [
  15     if test "x$withval" != "xyes" && test "x$withval" != "x"; then
  16       ap_zlib_base="$withval"
  17     fi
  18   ])
  19   if test "x$ap_zlib_base" = "x"; then
  20     AC_MSG_CHECKING([for zlib location])
  21     AC_CACHE_VAL(ap_cv_zlib,[
  22       for dir in /usr/local /usr ; do
  23         if test -d $dir && test -f $dir/include/zlib.h; then
  24           ap_cv_zlib=$dir
  25           break
  26         fi
  27       done
  28     ])
  29     ap_zlib_base=$ap_cv_zlib
  30     if test "x$ap_zlib_base" = "x"; then
  31       enable_deflate=no
  32       AC_MSG_RESULT([not found])
  33     else
  34       AC_MSG_RESULT([$ap_zlib_base])
  35     fi
  36   fi
  37   if test "$enable_deflate" != "no"; then
  38     ap_save_includes=$INCLUDE
  39     ap_save_ldflags=$LDFLAGS
  40     ap_save_libs=$LIBS
  41     ap_save_cppflags=$CPPFLAGS
  42     if test "$ap_zlib_base" != "/usr"; then
  43       APR_ADDTO(INCLUDES, [-I${ap_zlib_base}/include])
  44       dnl put in CPPFLAGS temporarily so that AC_TRY_LINK below will work
  45       CPPFLAGS="$CPPFLAGS $INCLUDES"
  46       APR_ADDTO(LDFLAGS, [-L${ap_zlib_base}/lib])
  47       if test "x$ap_platform_runtime_link_flag" != "x"; then
  48          APR_ADDTO(LDFLAGS, [$ap_platform_runtime_link_flag${ap_zlib_base}/lib])
  49       fi
  50     fi
  51     APR_ADDTO(LIBS, [-lz])
  52     AC_MSG_CHECKING([for zlib library])
  53     AC_TRY_LINK([#include <zlib.h>], [int i = Z_OK;],
  54     [AC_MSG_RESULT(found)
  55      AC_CHECK_HEADERS(zutil.h)],
  56     [AC_MSG_RESULT(not found)
  57      enable_deflate=no
  58      INCLUDES=$ap_save_includes
  59      LDFLAGS=$ap_save_ldflags
  60      LIBS=$ap_save_libs])
  61     CPPFLAGS=$ap_save_cppflags
  62   fi
  63 ])
  64
  65 APACHE_MODPATH_FINISH