rubbos/app/httpd-2.0.64/configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APACHE_ENABLE_LAYOUT
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1)
  65
  66 if test "$apr_found" = "no"; then
  67   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  68 fi
  69
  70 if test "$apr_found" = "reconfig"; then
  71   APR_SUBDIR_CONFIG(srclib/apr,
  72                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  73                     [--enable-layout=*|\'--enable-layout=*])
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_SETIFNULL(CC, `$apr_config --cc`)
  80 APR_SETIFNULL(CPP, `$apr_config --cpp`)
  81 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  82 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  83 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  84 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  85 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  86 APR_BINDIR=`$apr_config --bindir`
  87 APR_INCLUDEDIR=`$apr_config --includedir`
  88
  89 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  90
  91 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1)
  92
  93 if test "$apu_found" = "no"; then
  94   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  95 fi
  96
  97 # Catch some misconfigurations:
  98 case ${apr_found}.${apu_found} in
  99 reconfig.yes)
 100   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 101   ;;
 102 yes.reconfig)
 103   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 104   ;;
 105 esac
 106
 107 if test "$apu_found" = "reconfig"; then
 108   APR_SUBDIR_CONFIG(srclib/apr-util,
 109                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 110                     [--enable-layout=*|\'--enable-layout=*])
 111   dnl We must be the last to build and the first to be cleaned
 112   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 113   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 114 fi
 115
 116 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 117 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 118 APU_BINDIR=`$apu_config --bindir`
 119 APU_INCLUDEDIR=`$apu_config --includedir`
 120
 121 dnl In case we picked up CC and CPP from APR, get that info into the
 122 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 123 dnl PCRE and for our config tests will be whatever PCRE determines.
 124 AC_PROG_CC
 125 AC_PROG_CPP
 126
 127 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 128
 129 APR_SUBDIR_CONFIG(srclib/pcre,
 130                   [--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir])
 131
 132 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 133
 134 dnl Absolute source/build directory
 135 abs_srcdir=`(cd $srcdir && pwd)`
 136 abs_builddir=`pwd`
 137
 138 dnl If the source dir is not equal to the build dir,
 139 dnl then we are running in VPATH mode.
 140
 141 APR_ADDTO(INCLUDES, [-I.])
 142
 143 if test "$abs_builddir" != "$abs_srcdir"; then
 144   USE_VPATH=1
 145   APR_ADDTO(INCLUDES, [-I\$(srcdir) -I\$(top_builddir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_builddir)/include])
 146 fi
 147
 148 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators])
 149
 150 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 151
 152 case $host in
 153   *os2*)
 154       # Use a custom made libtool replacement
 155       echo "using aplibtool"
 156       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 157       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 158       SH_LIBS="\$(ALL_LIBS)"
 159       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 160       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 161       MK_IMPLIB="emximp"
 162       other_targets="$other_targets os2core"
 163       INSTALL_PROG_FLAGS="-e .exe"
 164       SHLTCFLAGS=""
 165       LTCFLAGS=""
 166       ;;
 167   *)
 168       if test "x$LTFLAGS" = "x"; then
 169           LTFLAGS='--silent'
 170       fi
 171       my_libtool=`$apr_config --apr-libtool`
 172       LIBTOOL="$my_libtool \$(LTFLAGS)"
 173       libtoolversion=`$my_libtool --version`
 174       case $libtoolversion in
 175           *1.[[45]]*)
 176               SH_LIBTOOL='$(LIBTOOL)'
 177               SHLTCFLAGS="-prefer-pic"
 178               LTCFLAGS="-prefer-non-pic -static"
 179               ;;
 180           *)
 181               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 182               SHLTCFLAGS=""
 183               LTCFLAGS=""
 184               ;;
 185       esac
 186       ;;
 187 esac
 188 APACHE_SUBST(SHLTCFLAGS)
 189 APACHE_SUBST(LTCFLAGS)
 190
 191 AP_SIG_GRACEFUL=USR1
 192
 193 case $host in
 194   *-apple-aux3*)
 195       APR_SETVAR(APACHE_MPM, [prefork])
 196       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 197       ;;
 198   *-beos*)
 199       APR_SETVAR(APACHE_MPM, [beos])
 200       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 201       ;;
 202   *os2_emx*)
 203       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 204       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 205       ;;
 206   *-linux-*)
 207       case `uname -r` in
 208         2.0* )
 209             AP_SIG_GRACEFUL=WINCH
 210             ;;
 211         2.[[2-9]]* )
 212             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 213             ;;
 214         * )
 215             ;;
 216       esac
 217       ;;
 218   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 219       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 220       ;;
 221   *-solaris2*)
 222       dnl This is a hack -- we should be using AC_TRY_RUN instead
 223       ap_platform_runtime_link_flag="-R"
 224       dnl solaris 8 and above don't have a thundering herd
 225       dnl not sure about rev's before this one.
 226       case `uname -r` in
 227         5.[567]*)
 228             ;;
 229         * )
 230             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 231             ;;
 232       esac
 233       ;;
 234   *cygwin*)
 235       APR_SETVAR(APACHE_MPM, [prefork])
 236       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 237       ;;
 238   *aix*)
 239       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 240       if test $aixver -ge 4320; then
 241         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 242       fi
 243       ;;
 244   *os390*)
 245       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 246       ;;
 247 esac
 248
 249 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 250
 251 dnl
 252 dnl Process command line arguments. This is done early in the process so the
 253 dnl user can get feedback quickly in case of an error.
 254 dnl
 255 dnl ### need to move some of the arguments "up here"
 256
 257 dnl ## Check for programs
 258
 259 AC_PATH_PROG(RM, rm)
 260 AC_PROG_AWK
 261 AC_PROG_INSTALL
 262 AC_PROG_LN_S
 263 AC_CHECK_TOOL(RANLIB, ranlib, true)
 264 dnl AC_PATH_PROG(PERL_PATH, perl)
 265
 266 dnl Various OS checks that apparently set required flags
 267 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 268 AC_USE_SYSTEM_EXTENSIONS
 269 ], [
 270 AC_AIX
 271 AC_MINIX
 272 ])
 273
 274 AC_ISC_POSIX
 275
 276 dnl ## Check for libraries
 277
 278 dnl ## Check for header files
 279
 280 dnl I think these are just used all over the place, so just check for
 281 dnl them at the base of the tree. If some are specific to a single
 282 dnl directory, they should be moved (Comment #Spoon)
 283
 284 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 285 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 286 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 287
 288 AC_HEADER_STDC
 289 AC_CHECK_HEADERS( \
 290 string.h \
 291 limits.h \
 292 unistd.h \
 293 sys/socket.h \
 294 pwd.h \
 295 grp.h \
 296 strings.h \
 297 sys/prctl.h \
 298 sys/processor.h \
 299 sys/sem.h
 300 )
 301 AC_HEADER_SYS_WAIT
 302
 303 dnl ## Check for typedefs, structures, and compiler characteristics.
 304
 305 AC_C_CONST
 306 if test "$ac_cv_prog_gcc" = "yes"; then
 307   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 308 fi
 309
 310 dnl ## Check for library functions
 311
 312 dnl See Comment #Spoon
 313
 314 AC_CHECK_FUNCS( \
 315 getpwnam \
 316 getgrnam \
 317 initgroups \
 318 bindprocessor \
 319 prctl \
 320 timegm \
 321 )
 322
 323 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 324 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 325 [AC_TRY_COMPILE([#include <sys/types.h>
 326 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 327   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 328 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 329     AC_DEFINE(HAVE_GMTOFF)
 330 fi
 331
 332 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 333
 334 case $host in
 335     *aix*)
 336         # for 32-bit builds, increase MAXDATA to allow lots of threads
 337         if test x$OBJECT_MODE != x64; then
 338             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 339         fi
 340         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 341         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 342         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 343         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 344         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 345         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 346         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 347         ;;
 348     *os390*)
 349         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 350         ;;
 351     *)
 352         OS_SPECIFIC_VARS=""
 353 esac
 354
 355 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 356         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 357         [PORT=80])
 358
 359 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 360
 361 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 362 [
 363   v4mapped=$enableval
 364 ],
 365 [
 366     case $host in
 367     *freebsd5*|*netbsd*|*openbsd*)
 368         v4mapped=no
 369         ;;
 370     *)
 371         v4mapped=yes
 372         ;;
 373 esac
 374 ])
 375
 376 if test $v4mapped = "yes" -o $ac_cv_define_APR_HAVE_IPV6 = "no"; then
 377     nonssl_listen_stmt_1=""
 378     nonssl_listen_stmt_2="Listen @@Port@@"
 379     if test $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 380         AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 381                   [Allow IPv4 connections on IPv6 listening sockets])
 382     fi
 383 else
 384     nonssl_listen_stmt_1="Listen 0.0.0.0:@@Port@@"
 385     nonssl_listen_stmt_2="Listen [[::]]:@@Port@@"
 386 fi
 387
 388 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 389 [
 390     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 391               [Allow modules to run hook after a fatal exception])
 392 ])dnl
 393
 394 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 395 [
 396   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 397 ])dnl
 398
 399 prefix="$orig_prefix"
 400 APACHE_ENABLE_MODULES
 401
 402 dnl reading config stubs
 403 esyscmd(./build/config-stubs .)
 404
 405 APACHE_SUBST(progname)
 406 APACHE_SUBST(MPM_LIB)
 407 APACHE_SUBST(OS)
 408 APACHE_SUBST(OS_DIR)
 409 APACHE_SUBST(BUILTIN_LIBS)
 410 APACHE_SUBST(SHLIBPATH_VAR)
 411 APACHE_SUBST(OS_SPECIFIC_VARS)
 412
 413 PRE_SHARED_CMDS='echo ""'
 414 POST_SHARED_CMDS='echo ""'
 415
 416 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 417
 418 if test "$apache_need_shared" = "yes"; then
 419   if test -f $ac_aux_dir/ltconfig; then
 420     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 421   fi
 422   shared_build="shared-build"
 423 fi
 424
 425 dnl enable_so tells us if *any* modules can be built as DSOs
 426
 427 if test "$enable_so" = "yes"; then
 428   case $host in
 429     *-ibm-aix*)
 430       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 431       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 432       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 433       ;;
 434     *beos)
 435       SH_LDFLAGS='$(top_builddir)/_APP_'
 436       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 437       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 438       ;;
 439     *os390)
 440       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 441       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 442   esac
 443 fi
 444
 445 APACHE_SUBST(PRE_SHARED_CMDS)
 446 APACHE_SUBST(POST_SHARED_CMDS)
 447 APACHE_SUBST(shared_build)
 448
 449 AC_ARG_WITH(program-name,
 450 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 451   progname="$withval" ], [
 452   progname="httpd"] )
 453
 454 # SuExec parameters
 455 AC_ARG_WITH(suexec-bin,
 456 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 457   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 458 ] )
 459
 460 AC_ARG_WITH(suexec-caller,
 461 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 462   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 463
 464 AC_ARG_WITH(suexec-userdir,
 465 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 466   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 467
 468 AC_ARG_WITH(suexec-docroot,
 469 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 470   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 471
 472 AC_ARG_WITH(suexec-uidmin,
 473 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 474   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 475
 476 AC_ARG_WITH(suexec-gidmin,
 477 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 478   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 479
 480 AC_ARG_WITH(suexec-logfile,
 481 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 482   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 483
 484 AC_ARG_WITH(suexec-safepath,
 485 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 486   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 487
 488 AC_ARG_WITH(suexec-umask,
 489 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 490   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 491
 492 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 493 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 494
 495 dnl APR should go after the other libs, so the right symbols can be picked up
 496 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 497 APACHE_SUBST(AP_LIBS)
 498 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 499 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 500
 501 AC_DEFINE(AP_USING_AUTOCONF, 1,
 502                 [Using autoconf to configure Apache])
 503
 504 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 505     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 506               [This platform doesn't suffer from the thundering herd problem])
 507 fi
 508
 509 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 510     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 511               [Listening sockets are non-blocking when there are more than 1])
 512 fi
 513
 514 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 515 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 516 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 517 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 518 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 519 AC_SUBST(AP_SIG_GRACEFUL)
 520 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 521 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 522
 523 dnl check for endianness
 524 if test "$cross_compiling" = "no"; then
 525   AC_C_BIGENDIAN
 526 else
 527   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 528                 [byte order is unknown due to cross-compilation])
 529 fi
 530
 531 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 532 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 533 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 534 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 535
 536 if test -d ./test; then
 537     APACHE_FAST_OUTPUT(test/Makefile)
 538 fi
 539
 540 dnl ## Finalize the variables
 541 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 542
 543 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 544 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 545 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 546 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 547 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 548 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 549
 550 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 551
 552 APACHE_GEN_CONFIG_VARS
 553
 554 dnl ## Build modules.c
 555 rm -f modules.c
 556 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 557
 558 APR_EXPAND_VAR(ap_prefix, $prefix)
 559 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 560         [Root directory of the Apache install area])
 561 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 562         [Location of the config file, relative to the Apache root directory])
 563 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 564         [Location of the MIME types config file, relative to the Apache root directory])
 565 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 566         [Location of the source for the current MPM])
 567
 568 perlbin=`$ac_aux_dir/PrintPath perl`
 569 if test "x$perlbin" = "x"; then
 570     perlbin="/replace/with/path/to/perl/interpreter"
 571 fi
 572 AC_SUBST(perlbin)
 573
 574 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 575
 576 BSD_MAKEFILE=no
 577 ap_make_include=include
 578 ap_make_delimiter=' '
 579 case $host in
 580 *bsdi*)
 581     # Check whether they've installed GNU make
 582     if make --version > /dev/null 2>&1; then
 583         true
 584     else
 585         BSD_MAKEFILE=yes
 586         ap_make_include=.include
 587         ap_make_delimiter='"'
 588     fi
 589     ;;
 590 esac
 591 AC_SUBST(ap_make_include)
 592 AC_SUBST(ap_make_delimiter)
 593
 594 dnl Ensure that docs/conf is created.
 595 test -d docs/conf||$mkdir_p docs/conf
 596
 597 dnl Ensure that the httpd version is included
 598 HTTPD_VERSION=`$srcdir/build/get-version.sh all $srcdir/include/ap_release.h AP_SERVER`
 599 AC_SUBST(HTTPD_VERSION)
 600
 601 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf docs/conf/ssl-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo,[true],[
 602   APACHE_GEN_MAKEFILES
 603 ])
 604