Adds auto-detection for VIP interfaces

Previously the ctrl plane VIP would default to 'br-ex' which in non-vlan
deployments ends up being the wrong interface.  The public VIP interface
was also defaulted to 'br-ex' which would be incorrect for vlan based
deployments.  Since a user has already given the nic template (and in
most cases the subnet that corresponds to the nic) the installer should
be able to figure out which interface the public/control vip should be
on.

These changes enable that type of auto-detection, unless a user
explicitly overrides the heat parameters for ControlVirtualInterface and
PublicVirtualInterface.  Also removes calling keepalived from haproxy
now that the services are composed separately on the Controller role.

Partial-Bug: 1606632

Change-Id: I05105fce85be8ace986db351cdca2916f405ed04
Signed-off-by: Tim Rozet <trozet@redhat.com>

diff --git a/manifests/haproxy.pp b/manifests/haproxy.pp
index 6f68562..64bcf1c 100644 (file)
--- a/manifests/haproxy.pp
+++ b/manifests/haproxy.pp
@@ -19,10 +19,6 @@
 #
 # === Parameters:
 #
-# [*keepalived*]
-#  Whether to configure keepalived to manage the VIPs or not.
-#  Defaults to hiera('keepalived_enabled')
-#
 # [*haproxy_service_manage*]
 #  Will be passed as value for service_manage to HAProxy module.
 #  Defaults to true
@@ -449,7 +445,6 @@
 class tripleo::haproxy (
   $controller_virtual_ip,
   $public_virtual_ip,
-  $keepalived                  = hiera('keepalived_enabled', false),
   $haproxy_service_manage      = true,
   $haproxy_global_maxconn      = 20480,
   $haproxy_default_maxconn     = 4096,
@@ -605,13 +600,6 @@ class tripleo::haproxy (
     $controller_hosts_names_real = downcase(any2array(split($controller_hosts_names, ',')))
   }
 
-  # This code will be removed once we switch undercloud and overcloud to use both haproxy & keepalived roles.
-  if str2bool($keepalived) {
-    include ::tripleo::keepalived
-    # Make sure keepalive starts before haproxy.
-    Class['::keepalived::service'] -> Class['::haproxy']
-  }
-
   # TODO(bnemec): When we have support for SSL on private and admin endpoints,
   # have the haproxy stats endpoint use that certificate by default.
   if $haproxy_stats_certificate {

diff --git a/manifests/profile/base/keepalived.pp b/manifests/profile/base/keepalived.pp
index f2063d6..8dd03dc 100644 (file)
--- a/manifests/profile/base/keepalived.pp
+++ b/manifests/profile/base/keepalived.pp
@@ -27,13 +27,54 @@
 #   for more details.
 #   Defaults to hiera('step')
 #
+# [*control_virtual_interface*]
+#   (Optional) Interface specified for control plane network
+#   Defaults to hiera('tripleo::keepalived::control_virtual_interface', false)
+#
+# [*control_virtual_ip*]
+#   Virtual IP address used for control plane network
+#   Defaults to hiera('tripleo::keepalived::controller_virtual_ip')
+#
+# [*public_virtual_interface*]
+#   (Optional) Interface specified for public/external network
+#   Defaults to hiera('tripleo::keepalived::public_virtual_interface', false)
+#
+# [*public_virtual_ip*]
+#   Virtual IP address used for public/ network
+#   Defaults to hiera('tripleo::keepalived::public_virtual_ip')
+#
 class tripleo::profile::base::keepalived (
-  $enable_load_balancer = hiera('enable_load_balancer', true),
-  $step                 = hiera('step'),
+  $enable_load_balancer      = hiera('enable_load_balancer', true),
+  $control_virtual_interface = hiera('tripleo::keepalived::control_virtual_interface', false),
+  $control_virtual_ip        = hiera('tripleo::keepalived::controller_virtual_ip'),
+  $public_virtual_interface  = hiera('tripleo::keepalived::public_virtual_interface', false),
+  $public_virtual_ip         = hiera('tripleo::keepalived::public_virtual_ip'),
+  $step                      = hiera('step'),
 ) {
   if $step >= 1 {
     if $enable_load_balancer and hiera('enable_keepalived', true){
-      include ::tripleo::keepalived
+      if ! $control_virtual_interface {
+        $control_detected_interface = interface_for_ip($control_virtual_ip)
+        if ! $control_detected_interface {
+          fail('Unable to find interface for control plane network')
+        }
+      } else {
+        $control_detected_interface = $control_virtual_interface
+      }
+
+      if ! $public_virtual_interface {
+        $public_detected_interface = interface_for_ip($public_virtual_ip)
+        if ! $public_detected_interface {
+          fail('Unable to find interface for public network')
+        }
+      } else {
+        $public_detected_interface = $public_virtual_interface
+      }
+
+      class { '::tripleo::keepalived':
+        control_virtual_interface => $control_detected_interface,
+        public_virtual_interface  => $public_detected_interface,
+      }
     }
   }
 }