Add loadbalancer profile for ha & non-ha

The profile contains Puppet classes to deploy loadbalancer services
(HAproxy & Keepalived) for ha & non-ha scenarios.

A future iteration will split HAproxy & keepalived, but for now, we just
want to move out the code from THT to puppet-tripleo.

Change-Id: I9b106dcc1a4d446ab5dea8430ed295e6ec209cbd
Implements: blueprint refactor-puppet-manifests

diff --git a/manifests/profile/base/loadbalancer.pp b/manifests/profile/base/loadbalancer.pp
new file mode 100644 (file)
index 0000000..2a961c4
--- /dev/null
+++ b/manifests/profile/base/loadbalancer.pp
@@ -0,0 +1,55 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::loadbalancer
+#
+# Loadbalancer profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*enable_load_balancer*]
+#   (Optional) Whether or not loadbalancer is enabled.
+#   Defaults to hiera('enable_load_balancer', true).
+#
+# [*controller_node_ips*]
+#   (Optional) List of IPs for controller nodes.
+#   Defaults to split(hiera('controller_node_ips'), ',')).
+#
+# [*controller_node_names*]
+#   (Optional) List of hostnames for controller nodes.
+#   Defaults to split(downcase(hiera('controller_node_names')), ',').
+#
+class tripleo::profile::base::loadbalancer (
+  $enable_load_balancer   = hiera('enable_load_balancer', true),
+  $controller_node_ips    = split(hiera('controller_node_ips'), ','),
+  $controller_node_names  = split(downcase(hiera('controller_node_names')), ','),
+  $step                   = hiera('step'),
+) {
+
+  if $step >= 1 {
+    if $enable_load_balancer {
+      class { '::tripleo::loadbalancer':
+        controller_hosts       => $controller_node_ips,
+        controller_hosts_names => $controller_node_names,
+      }
+    }
+  }
+
+}
+

diff --git a/manifests/profile/pacemaker/loadbalancer.pp b/manifests/profile/pacemaker/loadbalancer.pp
new file mode 100644 (file)
index 0000000..926b482
--- /dev/null
+++ b/manifests/profile/pacemaker/loadbalancer.pp
@@ -0,0 +1,99 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::loadbalancer
+#
+# Loadbalancer Pacemaker HA profile for tripleo
+#
+# === Parameters
+#
+# [*bootstrap_node*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*enable_load_balancer*]
+#   (Optional) Whether load balancing is enabled for this cluster
+#   Defaults to hiera('enable_load_balancer', true)
+#
+class tripleo::profile::pacemaker::loadbalancer (
+  $bootstrap_node       = hiera('bootstrap_nodeid'),
+  $step                 = hiera('step'),
+  $enable_load_balancer = hiera('enable_load_balancer', true)
+) {
+
+  include ::tripleo::profile::base::loadbalancer
+
+  if $::hostname == downcase($bootstrap_node) {
+    $pacemaker_master = true
+  } else {
+    $pacemaker_master = false
+  }
+
+  if $step >= 2 and $pacemaker_master and $enable_load_balancer {
+      # FIXME: we should not have to access tripleo::loadbalancer class
+      # parameters here to configure pacemaker VIPs. The configuration
+      # of pacemaker VIPs could move into puppet-tripleo or we should
+      # make use of less specific hiera parameters here for the settings.
+      pacemaker::resource::service { 'haproxy':
+        clone_params => true,
+      }
+
+      $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
+      tripleo::pacemaker::haproxy_with_vip { 'haproxy_and_control_vip':
+        vip_name   => 'control',
+        ip_address => $control_vip,
+      }
+
+      $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
+      tripleo::pacemaker::haproxy_with_vip { 'haproxy_and_public_vip':
+        ensure     => $public_vip and $public_vip != $control_vip,
+        vip_name   => 'public',
+        ip_address => $public_vip,
+      }
+
+      $redis_vip = hiera('redis_vip')
+      tripleo::pacemaker::haproxy_with_vip { 'haproxy_and_redis_vip':
+        ensure     => $redis_vip and $redis_vip != $control_vip,
+        vip_name   => 'redis',
+        ip_address => $redis_vip,
+      }
+
+      $internal_api_vip = hiera('tripleo::loadbalancer::internal_api_virtual_ip')
+      tripleo::pacemaker::haproxy_with_vip { 'haproxy_and_internal_api_vip':
+        ensure     => $internal_api_vip and $internal_api_vip != $control_vip,
+        vip_name   => 'internal_api',
+        ip_address => $internal_api_vip,
+      }
+
+      $storage_vip = hiera('tripleo::loadbalancer::storage_virtual_ip')
+      tripleo::pacemaker::haproxy_with_vip { 'haproxy_and_storage_vip':
+        ensure     => $storage_vip and $storage_vip != $control_vip,
+        vip_name   => 'storage',
+        ip_address => $storage_vip,
+      }
+
+      $storage_mgmt_vip = hiera('tripleo::loadbalancer::storage_mgmt_virtual_ip')
+      tripleo::pacemaker::haproxy_with_vip { 'haproxy_and_storage_mgmt_vip':
+        ensure     => $storage_mgmt_vip and $storage_mgmt_vip != $control_vip,
+        vip_name   => 'storage_mgmt',
+        ip_address => $storage_mgmt_vip,
+      }
+  }
+
+}