Add Heat profiles

Add Heat profiles for non-ha & ha scenarios.

Implements: blueprint refactor-puppet-manifests

Change-Id: I194cbb6aa307c2331597147545cf10299cab132f

diff --git a/manifests/profile/base/heat.pp b/manifests/profile/base/heat.pp
new file mode 100644 (file)
index 0000000..0fc30d8
--- /dev/null
+++ b/manifests/profile/base/heat.pp
@@ -0,0 +1,72 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::heat
+#
+# Heat profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*notification_driver*]
+#   (Optional) Heat notification driver to use.
+#   Defaults to 'messaging'
+#
+# [*bootstrap_master*]
+#   (Optional) The hostname of the node responsible for bootstrapping
+#   Defaults to downcase(hiera('bootstrap_nodeid'))
+#
+# [*manage_db_purge*]
+#   (Optional) Whether keystone token flushing should be enabled
+#   Defaults to hiera('keystone_enable_db_purge', true)
+#
+class tripleo::profile::base::heat (
+  $step = hiera('step'),
+  $notification_driver = 'messaging',
+  $bootstrap_master = downcase(hiera('bootstrap_nodeid')),
+  $manage_db_purge = hiera('heat_enable_db_purge', true),
+) {
+
+  if $step >= 4 {
+    class { '::heat' :
+      notification_driver => $notification_driver,
+    }
+    include ::heat::config
+  }
+
+  if $step >= 5 {
+    if $manage_db_purge {
+      include ::heat::cron::purge_deleted
+    }
+    if $bootstrap_master == $::hostname {
+      # Class ::heat::keystone::domain has to run on bootstrap node
+      # because it creates DB entities via API calls.
+      include ::heat::keystone::domain
+
+      Class['::keystone::roles::admin'] -> Class['::heat::keystone::domain']
+    } else {
+      # On non-bootstrap node we don't need to create Keystone resources again
+      class { '::heat::keystone::domain':
+        manage_domain => false,
+        manage_user   => false,
+        manage_role   => false,
+      }
+    }
+  }
+}
+

diff --git a/manifests/profile/base/heat/api.pp b/manifests/profile/base/heat/api.pp
new file mode 100644 (file)
index 0000000..67a0bfc
--- /dev/null
+++ b/manifests/profile/base/heat/api.pp
@@ -0,0 +1,35 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::heat::api
+#
+# Heat API profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::heat::api (
+  $step           = hiera('step'),
+) {
+
+  if $step >= 4 {
+    include ::tripleo::profile::base::heat
+    include ::heat::api
+  }
+}
+

diff --git a/manifests/profile/base/heat/api_cfn.pp b/manifests/profile/base/heat/api_cfn.pp
new file mode 100644 (file)
index 0000000..2813826
--- /dev/null
+++ b/manifests/profile/base/heat/api_cfn.pp
@@ -0,0 +1,35 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::heat::api_cfn
+#
+# Heat CloudFormation API profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::heat::api_cfn (
+  $step           = hiera('step'),
+) {
+
+  if $step >= 4 {
+    include ::tripleo::profile::base::heat
+    include ::heat::api_cfn
+  }
+}
+

diff --git a/manifests/profile/base/heat/api_cloudwatch.pp b/manifests/profile/base/heat/api_cloudwatch.pp
new file mode 100644 (file)
index 0000000..b2adf92
--- /dev/null
+++ b/manifests/profile/base/heat/api_cloudwatch.pp
@@ -0,0 +1,35 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::heat::api_cloudwatch
+#
+# Heat CloudWatch API profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::heat::api_cloudwatch (
+  $step           = hiera('step'),
+) {
+
+  if $step >= 4 {
+    include ::tripleo::profile::base::heat
+    include ::heat::api_cloudwatch
+  }
+}
+

diff --git a/manifests/profile/base/heat/engine.pp b/manifests/profile/base/heat/engine.pp
new file mode 100644 (file)
index 0000000..b48837c
--- /dev/null
+++ b/manifests/profile/base/heat/engine.pp
@@ -0,0 +1,44 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::heat::engine
+#
+# Heat Engine profile for tripleo
+#
+# === Parameters
+#
+# [*sync_db*]
+#   (Optional) Whether to run db sync
+#   Defaults to undef
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::heat::engine (
+  $sync_db        = true,
+  $step           = hiera('step'),
+) {
+
+  if $step >= 3 and $sync_db {
+    include ::heat::db::mysql
+  }
+
+  if $step >= 4 or ( $step >= 3 and $sync_db ) {
+    include ::tripleo::profile::base::heat
+    include ::heat::engine
+  }
+
+}

diff --git a/manifests/profile/pacemaker/heat.pp b/manifests/profile/pacemaker/heat.pp
new file mode 100644 (file)
index 0000000..001b36f
--- /dev/null
+++ b/manifests/profile/pacemaker/heat.pp
@@ -0,0 +1,132 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::heat
+#
+# Heat Pacemaker HA profile for tripleo
+#
+# === Parameters
+#
+# [*bootstrap_node*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::pacemaker::heat (
+  $bootstrap_node             = hiera('bootstrap_nodeid'),
+  $step                       = hiera('step'),
+) {
+
+  Service <| tag == 'heat-service' |> {
+    hasrestart => true,
+    restart    => '/bin/true',
+    start      => '/bin/true',
+    stop       => '/bin/true',
+  }
+
+  if $::hostname == downcase($bootstrap_node) {
+    $pacemaker_master = true
+  } else {
+    $pacemaker_master = false
+  }
+
+  class { '::tripleo::profile::base::heat':
+    bootstrap_master         => $bootstrap_node,
+  }
+  include ::tripleo::profile::base::heat::api
+  include ::tripleo::profile::base::heat::api_cfn
+  include ::tripleo::profile::base::heat::api_cloudwatch
+  class { '::tripleo::profile::base::heat::engine':
+    sync_db        => $pacemaker_master,
+  }
+
+  if $step >= 5 and $pacemaker_master {
+    # Heat
+    pacemaker::resource::service { $::heat::params::api_service_name :
+      clone_params => 'interleave=true',
+    }
+    pacemaker::resource::service { $::heat::params::api_cloudwatch_service_name :
+      clone_params => 'interleave=true',
+    }
+    pacemaker::resource::service { $::heat::params::api_cfn_service_name :
+      clone_params => 'interleave=true',
+    }
+    pacemaker::resource::service { $::heat::params::engine_service_name :
+      clone_params => 'interleave=true',
+    }
+    pacemaker::constraint::base { 'heat-api-then-heat-api-cfn-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::heat::params::api_service_name}-clone",
+      second_resource => "${::heat::params::api_cfn_service_name}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::heat::params::api_service_name],
+                          Pacemaker::Resource::Service[$::heat::params::api_cfn_service_name]],
+    }
+    pacemaker::constraint::colocation { 'heat-api-cfn-with-heat-api-colocation':
+      source  => "${::heat::params::api_cfn_service_name}-clone",
+      target  => "${::heat::params::api_service_name}-clone",
+      score   => 'INFINITY',
+      require => [Pacemaker::Resource::Service[$::heat::params::api_cfn_service_name],
+                  Pacemaker::Resource::Service[$::heat::params::api_service_name]],
+    }
+    pacemaker::constraint::base { 'heat-api-cfn-then-heat-api-cloudwatch-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::heat::params::api_cfn_service_name}-clone",
+      second_resource => "${::heat::params::api_cloudwatch_service_name}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::heat::params::api_cloudwatch_service_name],
+                          Pacemaker::Resource::Service[$::heat::params::api_cfn_service_name]],
+    }
+    pacemaker::constraint::colocation { 'heat-api-cloudwatch-with-heat-api-cfn-colocation':
+      source  => "${::heat::params::api_cloudwatch_service_name}-clone",
+      target  => "${::heat::params::api_cfn_service_name}-clone",
+      score   => 'INFINITY',
+      require => [Pacemaker::Resource::Service[$::heat::params::api_cfn_service_name],
+                  Pacemaker::Resource::Service[$::heat::params::api_cloudwatch_service_name]],
+    }
+    pacemaker::constraint::base { 'heat-api-cloudwatch-then-heat-engine-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::heat::params::api_cloudwatch_service_name}-clone",
+      second_resource => "${::heat::params::engine_service_name}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::heat::params::api_cloudwatch_service_name],
+                          Pacemaker::Resource::Service[$::heat::params::engine_service_name]],
+    }
+    pacemaker::constraint::colocation { 'heat-engine-with-heat-api-cloudwatch-colocation':
+      source  => "${::heat::params::engine_service_name}-clone",
+      target  => "${::heat::params::api_cloudwatch_service_name}-clone",
+      score   => 'INFINITY',
+      require => [Pacemaker::Resource::Service[$::heat::params::api_cloudwatch_service_name],
+                  Pacemaker::Resource::Service[$::heat::params::engine_service_name]],
+    }
+    pacemaker::constraint::base { 'ceilometer-notification-then-heat-api-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::ceilometer::params::agent_notification_service_name}-clone",
+      second_resource => "${::heat::params::api_service_name}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::heat::params::api_service_name],
+                          Pacemaker::Resource::Service[$::ceilometer::params::agent_notification_service_name]],
+    }
+
+  }
+
+}