puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 if !str2bool(hiera('enable_package_install', 'false')) {
  22   case $::osfamily {
  23     'RedHat': {
  24       Package { provider => 'norpm' } # provided by tripleo-puppet
  25     }
  26     default: {
  27       warning('enable_package_install option not supported.')
  28     }
  29   }
  30 }
  31
  32 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  33   $pacemaker_master = true
  34   $sync_db = true
  35 } else {
  36   $pacemaker_master = false
  37   $sync_db = false
  38 }
  39
  40 # When to start and enable services which haven't been Pacemakerized
  41 # FIXME: remove when we start all OpenStack services using Pacemaker
  42 # (occurences of this variable will be gradually replaced with false)
  43 $non_pcmk_start = hiera('step') >= 4
  44
  45 if hiera('step') >= 1 {
  46
  47   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  48
  49   if count(hiera('ntp::servers')) > 0 {
  50     include ::ntp
  51   }
  52
  53   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  54   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  55   class { '::tripleo::loadbalancer' :
  56     controller_hosts       => $controller_node_ips,
  57     controller_hosts_names => $controller_node_names,
  58     manage_vip             => false,
  59     haproxy_service_manage => false,
  60   }
  61
  62   $pacemaker_cluster_members = downcase(regsubst(hiera('controller_node_names'), ',', ' ', 'G'))
  63   user { 'hacluster':
  64    ensure => present,
  65   } ->
  66   class { '::pacemaker':
  67     hacluster_pwd => hiera('hacluster_pwd'),
  68   } ->
  69   class { '::pacemaker::corosync':
  70     cluster_members => $pacemaker_cluster_members,
  71     setup_cluster   => $pacemaker_master,
  72   }
  73   class { '::pacemaker::stonith':
  74     disable => true,
  75   }
  76
  77   # Only configure RabbitMQ in this step, don't start it yet to
  78   # avoid races where non-master nodes attempt to start without
  79   # config (eg. binding on 0.0.0.0)
  80   # The module ignores erlang_cookie if cluster_config is false
  81   class { '::rabbitmq':
  82     service_manage          => false,
  83     tcp_keepalive           => false,
  84     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
  85     config_variables        => hiera('rabbitmq_config_variables'),
  86     environment_variables   => hiera('rabbitmq_environment'),
  87   } ->
  88   file { '/var/lib/rabbitmq/.erlang.cookie':
  89     ensure  => 'present',
  90     owner   => 'rabbitmq',
  91     group   => 'rabbitmq',
  92     mode    => '0400',
  93     content => hiera('rabbitmq::erlang_cookie'),
  94     replace => true,
  95   }
  96
  97   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  98     include ::mongodb::globals
  99     # FIXME: replace with service_manage => false on ::mongodb::server
 100     # when this is merged: https://github.com/puppetlabs/pupp etlabs-mongodb/pull/198
 101     class { '::mongodb::server' :
 102       service_ensure => undef,
 103       service_enable => false,
 104     }
 105   }
 106
 107   # Galera
 108   if str2bool(hiera('enable_galera', 'true')) {
 109     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 110   } else {
 111     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 112   }
 113   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 114   $galera_nodes_count = count(split($galera_nodes, ','))
 115
 116   $mysqld_options = {
 117     'mysqld' => {
 118       'skip-name-resolve'             => '1',
 119       'binlog_format'                 => 'ROW',
 120       'default-storage-engine'        => 'innodb',
 121       'innodb_autoinc_lock_mode'      => '2',
 122       'innodb_locks_unsafe_for_binlog'=> '1',
 123       'query_cache_size'              => '0',
 124       'query_cache_type'              => '0',
 125       'bind-address'                  => hiera('controller_host'),
 126       'max_connections'               => '1024',
 127       'open_files_limit'              => '-1',
 128       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 129       'wsrep_cluster_name'            => 'galera_cluster',
 130       'wsrep_slave_threads'           => '1',
 131       'wsrep_certify_nonPK'           => '1',
 132       'wsrep_max_ws_rows'             => '131072',
 133       'wsrep_max_ws_size'             => '1073741824',
 134       'wsrep_debug'                   => '0',
 135       'wsrep_convert_LOCK_to_trx'     => '0',
 136       'wsrep_retry_autocommit'        => '1',
 137       'wsrep_auto_increment_control'  => '1',
 138       'wsrep_drupal_282555_workaround'=> '0',
 139       'wsrep_causal_reads'            => '0',
 140       'wsrep_notify_cmd'              => '',
 141       'wsrep_sst_method'              => 'rsync',
 142     }
 143   }
 144
 145   class { '::mysql::server':
 146     create_root_user   => false,
 147     create_root_my_cnf => false,
 148     config_file        => $mysql_config_file,
 149     override_options   => $mysqld_options,
 150     service_manage     => false,
 151   }
 152
 153 }
 154
 155 if hiera('step') >= 2 {
 156
 157   if $pacemaker_master {
 158     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
 159     pacemaker::resource::ip { 'control_vip':
 160       ip_address => $control_vip,
 161     }
 162     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
 163     pacemaker::resource::ip { 'public_vip':
 164       ip_address => $public_vip,
 165     }
 166     pacemaker::resource::service { 'haproxy':
 167       clone_params => true,
 168     }
 169
 170     pacemaker::resource::ocf { 'rabbitmq':
 171       ocf_agent_name  => 'heartbeat:rabbitmq-cluster',
 172       resource_params => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 173       clone_params    => 'ordered=true interleave=true',
 174       require         => Class['::rabbitmq'],
 175     }
 176
 177     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 178       pacemaker::resource::service { $::mongodb::params::service_name :
 179         op_params    => 'start timeout=120s',
 180         clone_params => true,
 181         require      => Class['::mongodb::server'],
 182         before       => Exec['mongodb-ready'],
 183       }
 184       # NOTE (spredzy) : The replset can only be run
 185       # once all the nodes have joined the cluster.
 186       $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
 187       $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
 188       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 189       $mongodb_replset = hiera('mongodb::server::replset')
 190       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 191       exec { 'mongodb-ready' :
 192         command   => $mongodb_cluster_ready_command,
 193         timeout   => 30,
 194         tries     => 180,
 195         try_sleep => 10,
 196       }
 197       mongodb_replset { $mongodb_replset :
 198         members => $mongo_node_ips_with_port,
 199         require => Exec['mongodb-ready'],
 200       }
 201     }
 202
 203     pacemaker::resource::ocf { 'galera' :
 204       ocf_agent_name  => 'heartbeat:galera',
 205       op_params       => 'promote timeout=300s on-fail=block',
 206       master_params   => '',
 207       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 208       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 209       require         => Class['::mysql::server'],
 210       before          => Exec['galera-ready'],
 211     }
 212   }
 213
 214   # Redis
 215   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 216   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 217
 218   if $redis_master_hostname == $::hostname {
 219     $slaveof = undef
 220   } else {
 221     $slaveof = "${redis_master_hostname} 6379"
 222   }
 223   class {'::redis' :
 224     slaveof => $slaveof,
 225   }
 226
 227   if count($redis_node_ips) > 1 {
 228     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 229     include ::redis::sentinel
 230     class {'::tripleo::redis_notification' :
 231       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 232     }
 233   }
 234
 235   exec { 'galera-ready' :
 236     command     => '/usr/bin/clustercheck >/dev/null',
 237     timeout     => 30,
 238     tries       => 180,
 239     try_sleep   => 10,
 240     environment => ["AVAILABLE_WHEN_READONLY=0"],
 241     require     => File['/etc/sysconfig/clustercheck'],
 242   }
 243
 244   file { '/etc/sysconfig/clustercheck' :
 245     ensure  => file,
 246     content => "MYSQL_USERNAME=root\n
 247 MYSQL_PASSWORD=''\n
 248 MYSQL_HOST=localhost\n",
 249   }
 250
 251   xinetd::service { 'galera-monitor' :
 252     port           => '9200',
 253     server         => '/usr/bin/clustercheck',
 254     per_source     => 'UNLIMITED',
 255     log_on_success => '',
 256     log_on_failure => 'HOST',
 257     flags          => 'REUSE',
 258     service_type   => 'UNLISTED',
 259     user           => 'root',
 260     group          => 'root',
 261     require        => File['/etc/sysconfig/clustercheck'],
 262   }
 263
 264   # Create all the database schemas
 265   # Example DSN format: mysql://user:password@host/dbname
 266   if $sync_db {
 267     $allowed_hosts = ['%',hiera('controller_host')]
 268     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 269     class { 'keystone::db::mysql':
 270       user          => $keystone_dsn[3],
 271       password      => $keystone_dsn[4],
 272       host          => $keystone_dsn[5],
 273       dbname        => $keystone_dsn[6],
 274       allowed_hosts => $allowed_hosts,
 275       require       => Exec['galera-ready'],
 276     }
 277     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 278     class { 'glance::db::mysql':
 279       user          => $glance_dsn[3],
 280       password      => $glance_dsn[4],
 281       host          => $glance_dsn[5],
 282       dbname        => $glance_dsn[6],
 283       allowed_hosts => $allowed_hosts,
 284       require       => Exec['galera-ready'],
 285     }
 286     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 287     class { 'nova::db::mysql':
 288       user          => $nova_dsn[3],
 289       password      => $nova_dsn[4],
 290       host          => $nova_dsn[5],
 291       dbname        => $nova_dsn[6],
 292       allowed_hosts => $allowed_hosts,
 293       require       => Exec['galera-ready'],
 294     }
 295     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 296     class { 'neutron::db::mysql':
 297       user          => $neutron_dsn[3],
 298       password      => $neutron_dsn[4],
 299       host          => $neutron_dsn[5],
 300       dbname        => $neutron_dsn[6],
 301       allowed_hosts => $allowed_hosts,
 302       require       => Exec['galera-ready'],
 303     }
 304     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 305     class { 'cinder::db::mysql':
 306       user          => $cinder_dsn[3],
 307       password      => $cinder_dsn[4],
 308       host          => $cinder_dsn[5],
 309       dbname        => $cinder_dsn[6],
 310       allowed_hosts => $allowed_hosts,
 311       require       => Exec['galera-ready'],
 312     }
 313     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 314     class { 'heat::db::mysql':
 315       user          => $heat_dsn[3],
 316       password      => $heat_dsn[4],
 317       host          => $heat_dsn[5],
 318       dbname        => $heat_dsn[6],
 319       allowed_hosts => $allowed_hosts,
 320       require       => Exec['galera-ready'],
 321     }
 322     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 323       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 324       class { 'ceilometer::db::mysql':
 325         user          => $ceilometer_dsn[3],
 326         password      => $ceilometer_dsn[4],
 327         host          => $ceilometer_dsn[5],
 328         dbname        => $ceilometer_dsn[6],
 329         allowed_hosts => $allowed_hosts,
 330         require       => Exec['galera-ready'],
 331       }
 332     }
 333   }
 334
 335   # pre-install swift here so we can build rings
 336   include ::swift
 337
 338   # Ceph
 339   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 340   $enable_ceph = $cinder_enable_rbd_backend
 341
 342   if $enable_ceph {
 343     class { 'ceph::profile::params':
 344       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 345     }
 346     include ::ceph::profile::mon
 347   }
 348
 349   if str2bool(hiera('enable_ceph_storage', 'false')) {
 350     include ::ceph::profile::client
 351     include ::ceph::profile::osd
 352   }
 353
 354   # Memcached
 355   include ::memcached
 356
 357 } #END STEP 2
 358
 359 if hiera('step') >= 3 {
 360
 361   class { '::keystone':
 362     sync_db => $sync_db,
 363     manage_service => false,
 364     enabled => false,
 365   }
 366
 367   #TODO: need a cleanup-keystone-tokens.sh solution here
 368   keystone_config {
 369     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 370   }
 371   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 372     ensure  => 'directory',
 373     owner   => 'keystone',
 374     group   => 'keystone',
 375     require => Package['keystone'],
 376   }
 377   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 378     content => hiera('keystone_signing_certificate'),
 379     owner   => 'keystone',
 380     group   => 'keystone',
 381     notify  => Service['keystone'],
 382     require => File['/etc/keystone/ssl/certs'],
 383   }
 384   file { '/etc/keystone/ssl/private/signing_key.pem':
 385     content => hiera('keystone_signing_key'),
 386     owner   => 'keystone',
 387     group   => 'keystone',
 388     notify  => Service['keystone'],
 389     require => File['/etc/keystone/ssl/private'],
 390   }
 391   file { '/etc/keystone/ssl/certs/ca.pem':
 392     content => hiera('keystone_ca_certificate'),
 393     owner   => 'keystone',
 394     group   => 'keystone',
 395     notify  => Service['keystone'],
 396     require => File['/etc/keystone/ssl/certs'],
 397   }
 398
 399   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 400   case $glance_backend {
 401       swift: { $glance_store = 'glance.store.swift.Store' }
 402       file: { $glance_store = 'glance.store.filesystem.Store' }
 403       rbd: { $glance_store = 'glance.store.rbd.Store' }
 404       default: { fail('Unrecognized glance_backend parameter.') }
 405   }
 406
 407   # TODO: notifications, scrubber, etc.
 408   include ::glance
 409   class { 'glance::api':
 410     known_stores => [$glance_store],
 411     manage_service => false,
 412     enabled => false,
 413   }
 414   class { '::glance::registry' :
 415     sync_db => $sync_db,
 416     manage_service => false,
 417     enabled => false,
 418   }
 419   include join(['::glance::backend::', $glance_backend])
 420
 421   class { 'nova':
 422     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 423   }
 424
 425   class { '::nova::api' :
 426     sync_db => $sync_db,
 427     manage_service => $non_pcmk_start,
 428     enabled => $non_pcmk_start,
 429   }
 430   class { '::nova::cert' :
 431     manage_service => $non_pcmk_start,
 432     enabled => $non_pcmk_start,
 433   }
 434   class { '::nova::conductor' :
 435     manage_service => $non_pcmk_start,
 436     enabled => $non_pcmk_start,
 437   }
 438   class { '::nova::consoleauth' :
 439     manage_service => $non_pcmk_start,
 440     enabled => $non_pcmk_start,
 441   }
 442   class { '::nova::vncproxy' :
 443     manage_service => $non_pcmk_start,
 444     enabled => $non_pcmk_start,
 445   }
 446   class { '::nova::scheduler' :
 447     manage_service => $non_pcmk_start,
 448     enabled => $non_pcmk_start,
 449   }
 450   include ::nova::network::neutron
 451
 452   include ::neutron
 453   class { '::neutron::server' :
 454     sync_db => $sync_db,
 455     manage_service => $non_pcmk_start,
 456     enabled => $non_pcmk_start,
 457   }
 458   class { '::neutron::agents::dhcp' :
 459     manage_service => $non_pcmk_start,
 460     enabled => $non_pcmk_start,
 461   }
 462   class { '::neutron::agents::l3' :
 463     manage_service => $non_pcmk_start,
 464     enabled => $non_pcmk_start,
 465   }
 466
 467   file { '/etc/neutron/dnsmasq-neutron.conf':
 468     content => hiera('neutron_dnsmasq_options'),
 469     owner   => 'neutron',
 470     group   => 'neutron',
 471     notify  => Service['neutron-dhcp-service'],
 472     require => Package['neutron'],
 473   }
 474
 475   class { 'neutron::plugins::ml2':
 476     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 477     tenant_network_types => [hiera('neutron_tenant_network_type')],
 478     type_drivers         => [hiera('neutron_tenant_network_type')],
 479   }
 480
 481   class { 'neutron::agents::ml2::ovs':
 482     # manage_service   => $non_pcmk_start,  -- not implemented
 483     enabled          => $non_pcmk_start,
 484     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 485     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 486   }
 487
 488   class { 'neutron::agents::metadata':
 489     manage_service   => $non_pcmk_start,
 490     enabled          => $non_pcmk_start,
 491     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 492   }
 493
 494   Service['neutron-server'] -> Service['neutron-dhcp-service']
 495   Service['neutron-server'] -> Service['neutron-l3']
 496   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 497   Service['neutron-server'] -> Service['neutron-metadata']
 498
 499   include ::cinder
 500   class { '::cinder::api':
 501     sync_db => $sync_db,
 502     manage_service => false,
 503     enabled => false,
 504   }
 505   class { '::cinder::scheduler' :
 506     manage_service => false,
 507     enabled => false,
 508   }
 509   class { '::cinder::volume' :
 510     manage_service => false,
 511     enabled => false,
 512   }
 513   include ::cinder::glance
 514   class {'cinder::setup_test_volume':
 515     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 516   }
 517
 518   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 519   if $cinder_enable_iscsi {
 520     $cinder_iscsi_backend = 'tripleo_iscsi'
 521
 522     cinder::backend::iscsi { $cinder_iscsi_backend :
 523       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 524       iscsi_helper     => hiera('cinder_iscsi_helper'),
 525     }
 526   }
 527
 528   if $enable_ceph {
 529
 530     Ceph_pool {
 531       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 532       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 533       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 534     }
 535
 536     $ceph_pools = hiera('ceph_pools')
 537     ceph::pool { $ceph_pools : }
 538   }
 539
 540   if $cinder_enable_rbd_backend {
 541     $cinder_rbd_backend = 'tripleo_ceph'
 542
 543     cinder_config {
 544       "${cinder_rbd_backend}/host": value => 'hostgroup';
 545     }
 546
 547     cinder::backend::rbd { $cinder_rbd_backend :
 548       rbd_pool        => 'volumes',
 549       rbd_user        => 'openstack',
 550       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 551       require         => Ceph::Pool['volumes'],
 552     }
 553   }
 554
 555   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 556   class { '::cinder::backends' :
 557     enabled_backends => $cinder_enabled_backends,
 558   }
 559
 560   # swift proxy
 561   class { '::swift::proxy' :
 562     manage_service => $non_pcmk_start,
 563     enabled => $non_pcmk_start,
 564   }
 565   include ::swift::proxy::proxy_logging
 566   include ::swift::proxy::healthcheck
 567   include ::swift::proxy::cache
 568   include ::swift::proxy::keystone
 569   include ::swift::proxy::authtoken
 570   include ::swift::proxy::staticweb
 571   include ::swift::proxy::ceilometer
 572   include ::swift::proxy::ratelimit
 573   include ::swift::proxy::catch_errors
 574   include ::swift::proxy::tempurl
 575   include ::swift::proxy::formpost
 576
 577   # swift storage
 578   if str2bool(hiera('enable_swift_storage', 'true')) {
 579     class {'::swift::storage::all':
 580       mount_check => str2bool(hiera('swift_mount_check'))
 581     }
 582     class {'::swift::storage::account':
 583       manage_service => $non_pcmk_start,
 584       enabled => $non_pcmk_start,
 585     }
 586     class {'::swift::storage::container':
 587       manage_service => $non_pcmk_start,
 588       enabled => $non_pcmk_start,
 589     }
 590     class {'::swift::storage::object':
 591       manage_service => $non_pcmk_start,
 592       enabled => $non_pcmk_start,
 593     }
 594     if(!defined(File['/srv/node'])) {
 595       file { '/srv/node':
 596         ensure  => directory,
 597         owner   => 'swift',
 598         group   => 'swift',
 599         require => Package['openstack-swift'],
 600       }
 601     }
 602     $swift_components = ['account', 'container', 'object']
 603     swift::storage::filter::recon { $swift_components : }
 604     swift::storage::filter::healthcheck { $swift_components : }
 605   }
 606
 607   # Ceilometer
 608   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 609   case $ceilometer_backend {
 610     /mysql/ : {
 611       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 612     }
 613     default : {
 614       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 615     }
 616   }
 617   include ::ceilometer
 618   class { '::ceilometer::api' :
 619     manage_service => $non_pcmk_start,
 620     enabled => $non_pcmk_start,
 621   }
 622   class { '::ceilometer::agent::notification' :
 623     manage_service => $non_pcmk_start,
 624     enabled => $non_pcmk_start,
 625   }
 626   class { '::ceilometer::agent::central' :
 627     manage_service => $non_pcmk_start,
 628     enabled => $non_pcmk_start,
 629   }
 630   class { '::ceilometer::alarm::notifier' :
 631     manage_service => $non_pcmk_start,
 632     enabled => $non_pcmk_start,
 633   }
 634   class { '::ceilometer::alarm::evaluator' :
 635     manage_service => $non_pcmk_start,
 636     enabled => $non_pcmk_start,
 637   }
 638   class { '::ceilometer::collector' :
 639     manage_service => $non_pcmk_start,
 640     enabled => $non_pcmk_start,
 641   }
 642   include ::ceilometer::expirer
 643   class { '::ceilometer::db' :
 644     database_connection => $ceilometer_database_connection,
 645     sync_db             => $sync_db,
 646   }
 647   class { 'ceilometer::agent::auth':
 648     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 649   }
 650
 651   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 652
 653   # Heat
 654   class { '::heat' :
 655     sync_db => $sync_db,
 656   }
 657   class { '::heat::api' :
 658     manage_service => $non_pcmk_start,
 659     enabled => $non_pcmk_start,
 660   }
 661   class { '::heat::api_cfn' :
 662     manage_service => $non_pcmk_start,
 663     enabled => $non_pcmk_start,
 664   }
 665   class { '::heat::api_cloudwatch' :
 666     manage_service => $non_pcmk_start,
 667     enabled => $non_pcmk_start,
 668   }
 669   class { '::heat::engine' :
 670     manage_service => $non_pcmk_start,
 671     enabled => $non_pcmk_start,
 672   }
 673
 674   # Horizon
 675   $vhost_params = { add_listen => false }
 676   class { 'horizon':
 677     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 678     vhost_extra_params => $vhost_params,
 679   }
 680
 681   $snmpd_user = hiera('snmpd_readonly_user_name')
 682   snmp::snmpv3_user { $snmpd_user:
 683     authtype => 'MD5',
 684     authpass => hiera('snmpd_readonly_user_password'),
 685   }
 686   class { 'snmp':
 687     agentaddress => ['udp:161','udp6:[::1]:161'],
 688     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 689   }
 690
 691 } #END STEP 3
 692
 693 if hiera('step') >= 4 {
 694   if $pacemaker_master {
 695
 696     # Keystone
 697     pacemaker::resource::service { $::keystone::params::service_name :
 698       clone_params => "interleave=true",
 699     }
 700
 701     # Cinder
 702     pacemaker::resource::service { $::cinder::params::api_service :
 703       clone_params => "interleave=true",
 704       require      => Pacemaker::Resource::Service[$::keystone::params::service_name],
 705     }
 706     pacemaker::resource::service { $::cinder::params::scheduler_service :
 707       clone_params => "interleave=true",
 708     }
 709     pacemaker::resource::service { $::cinder::params::volume_service : }
 710
 711     pacemaker::constraint::base { 'keystone-then-cinder-api-constraint':
 712       constraint_type => 'order',
 713       first_resource  => "${::keystone::params::service_name}-clone",
 714       second_resource => "${::cinder::params::api_service}-clone",
 715       first_action    => 'start',
 716       second_action   => 'start',
 717       require         => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 718                           Pacemaker::Resource::Service[$::keystone::params::service_name]],
 719     }
 720     pacemaker::constraint::base { 'cinder-api-then-cinder-scheduler-constraint':
 721       constraint_type => "order",
 722       first_resource => "${::cinder::params::api_service}-clone",
 723       second_resource => "${::cinder::params::scheduler_service}-clone",
 724       first_action => "start",
 725       second_action => "start",
 726       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 727                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 728     }
 729     pacemaker::constraint::colocation { 'cinder-scheduler-with-cinder-api-colocation':
 730       source => "${::cinder::params::scheduler_service}-clone",
 731       target => "${::cinder::params::api_service}-clone",
 732       score => "INFINITY",
 733       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 734                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 735     }
 736     pacemaker::constraint::base { 'cinder-scheduler-then-cinder-volume-constraint':
 737       constraint_type => "order",
 738       first_resource => "${::cinder::params::scheduler_service}-clone",
 739       second_resource => "${::cinder::params::volume_service}",
 740       first_action => "start",
 741       second_action => "start",
 742       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 743                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 744     }
 745     pacemaker::constraint::colocation { 'cinder-volume-with-cinder-scheduler-colocation':
 746       source => "${::cinder::params::volume_service}",
 747       target => "${::cinder::params::scheduler_service}-clone",
 748       score => "INFINITY",
 749       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 750                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 751     }
 752
 753     # Glance
 754     pacemaker::resource::service { $::glance::params::registry_service_name :
 755       clone_params => "interleave=true",
 756       require      => Pacemaker::Resource::Service[$::keystone::params::service_name],
 757     }
 758     pacemaker::resource::service { $::glance::params::api_service_name :
 759       clone_params => "interleave=true",
 760     }
 761
 762     pacemaker::constraint::base { 'keystone-then-glance-registry-constraint':
 763       constraint_type => 'order',
 764       first_resource  => "${::keystone::params::service_name}-clone",
 765       second_resource => "${::glance::params::registry_service_name}-clone",
 766       first_action    => 'start',
 767       second_action   => 'start',
 768       require         => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 769                           Pacemaker::Resource::Service[$::keystone::params::service_name]],
 770     }
 771     pacemaker::constraint::base { 'glance-registry-then-glance-api-constraint':
 772       constraint_type => "order",
 773       first_resource  => "${::glance::params::registry_service_name}-clone",
 774       second_resource => "${::glance::params::api_service_name}-clone",
 775       first_action    => "start",
 776       second_action   => "start",
 777       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 778                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 779     }
 780     pacemaker::constraint::colocation { 'glance-registry-with-glance-api-colocation':
 781       source  => "${::glance::params::registry_service_name}-clone",
 782       target  => "${::glance::params::api_service_name}-clone",
 783       score   => "INFINITY",
 784       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 785                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 786     }
 787   }
 788
 789 } #END STEP 4