puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 if !str2bool(hiera('enable_package_install', 'false')) {
  22   case $::osfamily {
  23     'RedHat': {
  24       Package { provider => 'norpm' } # provided by tripleo-puppet
  25     }
  26     default: {
  27       warning('enable_package_install option not supported.')
  28     }
  29   }
  30 }
  31
  32 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  33   $pacemaker_master = true
  34   $sync_db = true
  35 } else {
  36   $pacemaker_master = false
  37   $sync_db = false
  38 }
  39
  40 # When to start and enable services which haven't been Pacemakerized
  41 # FIXME: remove when we start all OpenStack services using Pacemaker
  42 # (occurences of this variable will be gradually replaced with false)
  43 $non_pcmk_start = hiera('step') >= 4
  44
  45 if hiera('step') >= 1 {
  46
  47   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  48
  49   if count(hiera('ntp::servers')) > 0 {
  50     include ::ntp
  51   }
  52
  53   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  54   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  55   class { '::tripleo::loadbalancer' :
  56     controller_hosts       => $controller_node_ips,
  57     controller_hosts_names => $controller_node_names,
  58     manage_vip             => false,
  59     haproxy_service_manage => false,
  60   }
  61
  62   $pacemaker_cluster_members = downcase(regsubst(hiera('controller_node_names'), ',', ' ', 'G'))
  63   user { 'hacluster':
  64    ensure => present,
  65   } ->
  66   class { '::pacemaker':
  67     hacluster_pwd => hiera('hacluster_pwd'),
  68   } ->
  69   class { '::pacemaker::corosync':
  70     cluster_members => $pacemaker_cluster_members,
  71     setup_cluster   => $pacemaker_master,
  72   }
  73   class { '::pacemaker::stonith':
  74     disable => true,
  75   }
  76
  77   # Only configure RabbitMQ in this step, don't start it yet to
  78   # avoid races where non-master nodes attempt to start without
  79   # config (eg. binding on 0.0.0.0)
  80   # The module ignores erlang_cookie if cluster_config is false
  81   class { '::rabbitmq':
  82     service_manage          => false,
  83     tcp_keepalive           => false,
  84     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
  85     config_variables        => hiera('rabbitmq_config_variables'),
  86     environment_variables   => hiera('rabbitmq_environment'),
  87   } ->
  88   file { '/var/lib/rabbitmq/.erlang.cookie':
  89     ensure  => 'present',
  90     owner   => 'rabbitmq',
  91     group   => 'rabbitmq',
  92     mode    => '0400',
  93     content => hiera('rabbitmq::erlang_cookie'),
  94     replace => true,
  95   }
  96
  97   # MongoDB
  98   include ::mongodb::globals
  99
 100   # FIXME: replace with service_manage => false on ::mongodb::server
 101   # when this is merged: https://github.com/puppetlabs/pupp etlabs-mongodb/pull/198
 102   class { '::mongodb::server' :
 103     service_ensure => undef,
 104     service_enable => false,
 105   }
 106
 107   # Galera
 108   if str2bool(hiera('enable_galera', 'true')) {
 109     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 110   } else {
 111     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 112   }
 113   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 114   $galera_nodes_count = count(split($galera_nodes, ','))
 115
 116   $mysqld_options = {
 117     'mysqld' => {
 118       'skip-name-resolve'             => '1',
 119       'binlog_format'                 => 'ROW',
 120       'default-storage-engine'        => 'innodb',
 121       'innodb_autoinc_lock_mode'      => '2',
 122       'innodb_locks_unsafe_for_binlog'=> '1',
 123       'query_cache_size'              => '0',
 124       'query_cache_type'              => '0',
 125       'bind-address'                  => hiera('controller_host'),
 126       'max_connections'               => '1024',
 127       'open_files_limit'              => '-1',
 128       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 129       'wsrep_cluster_name'            => 'galera_cluster',
 130       'wsrep_slave_threads'           => '1',
 131       'wsrep_certify_nonPK'           => '1',
 132       'wsrep_max_ws_rows'             => '131072',
 133       'wsrep_max_ws_size'             => '1073741824',
 134       'wsrep_debug'                   => '0',
 135       'wsrep_convert_LOCK_to_trx'     => '0',
 136       'wsrep_retry_autocommit'        => '1',
 137       'wsrep_auto_increment_control'  => '1',
 138       'wsrep_drupal_282555_workaround'=> '0',
 139       'wsrep_causal_reads'            => '0',
 140       'wsrep_notify_cmd'              => '',
 141       'wsrep_sst_method'              => 'rsync',
 142     }
 143   }
 144
 145   class { '::mysql::server':
 146     create_root_user   => false,
 147     create_root_my_cnf => false,
 148     config_file        => $mysql_config_file,
 149     override_options   => $mysqld_options,
 150     service_manage     => false,
 151   }
 152
 153 }
 154
 155 if hiera('step') >= 2 {
 156
 157   if $pacemaker_master {
 158     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
 159     pacemaker::resource::ip { 'control_vip':
 160       ip_address => $control_vip,
 161     }
 162     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
 163     pacemaker::resource::ip { 'public_vip':
 164       ip_address => $public_vip,
 165     }
 166     pacemaker::resource::service { 'haproxy':
 167       clone_params => true,
 168     }
 169
 170     pacemaker::resource::ocf { 'rabbitmq':
 171       ocf_agent_name  => 'heartbeat:rabbitmq-cluster',
 172       resource_params => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 173       clone_params    => 'ordered=true interleave=true',
 174       require         => Class['::rabbitmq'],
 175     }
 176
 177     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 178       pacemaker::resource::service { $::mongodb::params::service_name :
 179         op_params    => 'start timeout=120s',
 180         clone_params => true,
 181         require      => Class['::mongodb::server'],
 182         before       => Exec['mongodb-ready'],
 183       }
 184       # NOTE (spredzy) : The replset can only be run
 185       # once all the nodes have joined the cluster.
 186       $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
 187       $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
 188       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 189       $mongodb_replset = hiera('mongodb::server::replset')
 190       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 191       exec { 'mongodb-ready' :
 192         command   => $mongodb_cluster_ready_command,
 193         timeout   => 30,
 194         tries     => 180,
 195         try_sleep => 10,
 196       }
 197       mongodb_replset { $mongodb_replset :
 198         members => $mongo_node_ips_with_port,
 199         require => Exec['mongodb-ready'],
 200       }
 201     }
 202
 203     pacemaker::resource::ocf { 'galera' :
 204       ocf_agent_name  => 'heartbeat:galera',
 205       op_params       => 'promote timeout=300s on-fail=block --master',
 206       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 207       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 208       require         => Class['::mysql::server'],
 209       before          => Exec['galera-ready'],
 210     }
 211     mysql_user { 'clustercheckuser@localhost' :
 212       password_hash => mysql_password($clustercheck_password),
 213       require       => Exec['galera-ready'],
 214     }
 215   }
 216
 217   # Redis
 218   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 219   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 220
 221   if $redis_master_hostname == $::hostname {
 222     $slaveof = undef
 223   } else {
 224     $slaveof = "${redis_master_hostname} 6379"
 225   }
 226   class {'::redis' :
 227     slaveof => $slaveof,
 228   }
 229
 230   if count($redis_node_ips) > 1 {
 231     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 232     include ::redis::sentinel
 233     class {'::tripleo::redis_notification' :
 234       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 235     }
 236   }
 237
 238   exec { 'galera-ready' :
 239     command     => '/usr/bin/clustercheck >/dev/null',
 240     timeout     => 30,
 241     tries       => 180,
 242     try_sleep   => 10,
 243     environment => ["AVAILABLE_WHEN_READONLY=0"],
 244     require     => File['/etc/sysconfig/clustercheck'],
 245   }
 246
 247   file { '/etc/sysconfig/clustercheck' :
 248     ensure  => file,
 249     content => "MYSQL_USERNAME=root\n
 250 MYSQL_PASSWORD=''\n
 251 MYSQL_HOST=localhost\n",
 252   }
 253
 254   xinetd::service { 'galera-monitor' :
 255     port           => '9200',
 256     server         => '/usr/bin/clustercheck',
 257     per_source     => 'UNLIMITED',
 258     log_on_success => '',
 259     log_on_failure => 'HOST',
 260     flags          => 'REUSE',
 261     service_type   => 'UNLISTED',
 262     user           => 'root',
 263     group          => 'root',
 264     require        => File['/etc/sysconfig/clustercheck'],
 265   }
 266
 267   # Create all the database schemas
 268   # Example DSN format: mysql://user:password@host/dbname
 269   if $sync_db {
 270     $allowed_hosts = ['%',hiera('controller_host')]
 271     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 272     class { 'keystone::db::mysql':
 273       user          => $keystone_dsn[3],
 274       password      => $keystone_dsn[4],
 275       host          => $keystone_dsn[5],
 276       dbname        => $keystone_dsn[6],
 277       allowed_hosts => $allowed_hosts,
 278       require       => Exec['galera-ready'],
 279     }
 280     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 281     class { 'glance::db::mysql':
 282       user          => $glance_dsn[3],
 283       password      => $glance_dsn[4],
 284       host          => $glance_dsn[5],
 285       dbname        => $glance_dsn[6],
 286       allowed_hosts => $allowed_hosts,
 287       require       => Exec['galera-ready'],
 288     }
 289     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 290     class { 'nova::db::mysql':
 291       user          => $nova_dsn[3],
 292       password      => $nova_dsn[4],
 293       host          => $nova_dsn[5],
 294       dbname        => $nova_dsn[6],
 295       allowed_hosts => $allowed_hosts,
 296       require       => Exec['galera-ready'],
 297     }
 298     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 299     class { 'neutron::db::mysql':
 300       user          => $neutron_dsn[3],
 301       password      => $neutron_dsn[4],
 302       host          => $neutron_dsn[5],
 303       dbname        => $neutron_dsn[6],
 304       allowed_hosts => $allowed_hosts,
 305       require       => Exec['galera-ready'],
 306     }
 307     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 308     class { 'cinder::db::mysql':
 309       user          => $cinder_dsn[3],
 310       password      => $cinder_dsn[4],
 311       host          => $cinder_dsn[5],
 312       dbname        => $cinder_dsn[6],
 313       allowed_hosts => $allowed_hosts,
 314       require       => Exec['galera-ready'],
 315     }
 316     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 317     class { 'heat::db::mysql':
 318       user          => $heat_dsn[3],
 319       password      => $heat_dsn[4],
 320       host          => $heat_dsn[5],
 321       dbname        => $heat_dsn[6],
 322       allowed_hosts => $allowed_hosts,
 323       require       => Exec['galera-ready'],
 324     }
 325     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 326       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 327       class { 'ceilometer::db::mysql':
 328         user          => $ceilometer_dsn[3],
 329         password      => $ceilometer_dsn[4],
 330         host          => $ceilometer_dsn[5],
 331         dbname        => $ceilometer_dsn[6],
 332         allowed_hosts => $allowed_hosts,
 333         require       => Exec['galera-ready'],
 334       }
 335     }
 336   }
 337
 338   # pre-install swift here so we can build rings
 339   include ::swift
 340
 341   # Ceph
 342   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 343   $enable_ceph = $cinder_enable_rbd_backend
 344
 345   if $enable_ceph {
 346     class { 'ceph::profile::params':
 347       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 348     }
 349     include ::ceph::profile::mon
 350   }
 351
 352   if str2bool(hiera('enable_ceph_storage', 'false')) {
 353     include ::ceph::profile::client
 354     include ::ceph::profile::osd
 355   }
 356
 357   # Memcached
 358   include ::memcached
 359
 360 } #END STEP 2
 361
 362 if hiera('step') >= 3 {
 363
 364   class { '::keystone':
 365     sync_db => $sync_db,
 366     manage_service => $non_pcmk_start,
 367     enabled => $non_pcmk_start,
 368   }
 369
 370   #TODO: need a cleanup-keystone-tokens.sh solution here
 371   keystone_config {
 372     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 373   }
 374   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 375     ensure  => 'directory',
 376     owner   => 'keystone',
 377     group   => 'keystone',
 378     require => Package['keystone'],
 379   }
 380   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 381     content => hiera('keystone_signing_certificate'),
 382     owner   => 'keystone',
 383     group   => 'keystone',
 384     notify  => Service['keystone'],
 385     require => File['/etc/keystone/ssl/certs'],
 386   }
 387   file { '/etc/keystone/ssl/private/signing_key.pem':
 388     content => hiera('keystone_signing_key'),
 389     owner   => 'keystone',
 390     group   => 'keystone',
 391     notify  => Service['keystone'],
 392     require => File['/etc/keystone/ssl/private'],
 393   }
 394   file { '/etc/keystone/ssl/certs/ca.pem':
 395     content => hiera('keystone_ca_certificate'),
 396     owner   => 'keystone',
 397     group   => 'keystone',
 398     notify  => Service['keystone'],
 399     require => File['/etc/keystone/ssl/certs'],
 400   }
 401
 402   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 403   case $glance_backend {
 404       swift: { $glance_store = 'glance.store.swift.Store' }
 405       file: { $glance_store = 'glance.store.filesystem.Store' }
 406       rbd: { $glance_store = 'glance.store.rbd.Store' }
 407       default: { fail('Unrecognized glance_backend parameter.') }
 408   }
 409
 410   # TODO: notifications, scrubber, etc.
 411   include ::glance
 412   class { 'glance::api':
 413     known_stores => [$glance_store],
 414     manage_service => $non_pcmk_start,
 415     enabled => $non_pcmk_start,
 416   }
 417   class { '::glance::registry' :
 418     sync_db => $sync_db,
 419     manage_service => $non_pcmk_start,
 420     enabled => $non_pcmk_start,
 421   }
 422   include join(['::glance::backend::', $glance_backend])
 423
 424   class { 'nova':
 425     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 426   }
 427
 428   class { '::nova::api' :
 429     sync_db => $sync_db,
 430     manage_service => $non_pcmk_start,
 431     enabled => $non_pcmk_start,
 432   }
 433   class { '::nova::cert' :
 434     manage_service => $non_pcmk_start,
 435     enabled => $non_pcmk_start,
 436   }
 437   class { '::nova::conductor' :
 438     manage_service => $non_pcmk_start,
 439     enabled => $non_pcmk_start,
 440   }
 441   class { '::nova::consoleauth' :
 442     manage_service => $non_pcmk_start,
 443     enabled => $non_pcmk_start,
 444   }
 445   class { '::nova::vncproxy' :
 446     manage_service => $non_pcmk_start,
 447     enabled => $non_pcmk_start,
 448   }
 449   class { '::nova::scheduler' :
 450     manage_service => $non_pcmk_start,
 451     enabled => $non_pcmk_start,
 452   }
 453   include ::nova::network::neutron
 454
 455   include ::neutron
 456   class { '::neutron::server' :
 457     sync_db => $sync_db,
 458     manage_service => $non_pcmk_start,
 459     enabled => $non_pcmk_start,
 460   }
 461   class { '::neutron::agents::dhcp' :
 462     manage_service => $non_pcmk_start,
 463     enabled => $non_pcmk_start,
 464   }
 465   class { '::neutron::agents::l3' :
 466     manage_service => $non_pcmk_start,
 467     enabled => $non_pcmk_start,
 468   }
 469
 470   file { '/etc/neutron/dnsmasq-neutron.conf':
 471     content => hiera('neutron_dnsmasq_options'),
 472     owner   => 'neutron',
 473     group   => 'neutron',
 474     notify  => Service['neutron-dhcp-service'],
 475     require => Package['neutron'],
 476   }
 477
 478   class { 'neutron::plugins::ml2':
 479     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 480     tenant_network_types => [hiera('neutron_tenant_network_type')],
 481     type_drivers         => [hiera('neutron_tenant_network_type')],
 482   }
 483
 484   class { 'neutron::agents::ml2::ovs':
 485     # manage_service   => $non_pcmk_start,  -- not implemented
 486     enabled          => $non_pcmk_start,
 487     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 488     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 489   }
 490
 491   class { 'neutron::agents::metadata':
 492     manage_service   => $non_pcmk_start,
 493     enabled          => $non_pcmk_start,
 494     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 495   }
 496
 497   Service['neutron-server'] -> Service['neutron-dhcp-service']
 498   Service['neutron-server'] -> Service['neutron-l3']
 499   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 500   Service['neutron-server'] -> Service['neutron-metadata']
 501
 502   include ::cinder
 503   class { '::cinder::api':
 504     sync_db => $sync_db,
 505     manage_service => $non_pcmk_start,
 506     enabled => $non_pcmk_start,
 507   }
 508   class { '::cinder::scheduler' :
 509     manage_service => $non_pcmk_start,
 510     enabled => $non_pcmk_start,
 511   }
 512   class { '::cinder::volume' :
 513     manage_service => $non_pcmk_start,
 514     enabled => $non_pcmk_start,
 515   }
 516   include ::cinder::glance
 517   class {'cinder::setup_test_volume':
 518     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 519   }
 520
 521   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 522   if $cinder_enable_iscsi {
 523     $cinder_iscsi_backend = 'tripleo_iscsi'
 524
 525     cinder::backend::iscsi { $cinder_iscsi_backend :
 526       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 527       iscsi_helper     => hiera('cinder_iscsi_helper'),
 528     }
 529   }
 530
 531   if $enable_ceph {
 532
 533     Ceph_pool {
 534       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 535       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 536       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 537     }
 538
 539     $ceph_pools = hiera('ceph_pools')
 540     ceph::pool { $ceph_pools : }
 541   }
 542
 543   if $cinder_enable_rbd_backend {
 544     $cinder_rbd_backend = 'tripleo_ceph'
 545
 546     cinder_config {
 547       "${cinder_rbd_backend}/host": value => 'hostgroup';
 548     }
 549
 550     cinder::backend::rbd { $cinder_rbd_backend :
 551       rbd_pool        => 'volumes',
 552       rbd_user        => 'openstack',
 553       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 554       require         => Ceph::Pool['volumes'],
 555     }
 556   }
 557
 558   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 559   class { '::cinder::backends' :
 560     enabled_backends => $cinder_enabled_backends,
 561   }
 562
 563   # swift proxy
 564   class { '::swift::proxy' :
 565     manage_service => $non_pcmk_start,
 566     enabled => $non_pcmk_start,
 567   }
 568   include ::swift::proxy::proxy_logging
 569   include ::swift::proxy::healthcheck
 570   include ::swift::proxy::cache
 571   include ::swift::proxy::keystone
 572   include ::swift::proxy::authtoken
 573   include ::swift::proxy::staticweb
 574   include ::swift::proxy::ceilometer
 575   include ::swift::proxy::ratelimit
 576   include ::swift::proxy::catch_errors
 577   include ::swift::proxy::tempurl
 578   include ::swift::proxy::formpost
 579
 580   # swift storage
 581   if str2bool(hiera('enable_swift_storage', 'true')) {
 582     class {'::swift::storage::all':
 583       mount_check => str2bool(hiera('swift_mount_check'))
 584     }
 585     class {'::swift::storage::account':
 586       manage_service => $non_pcmk_start,
 587       enabled => $non_pcmk_start,
 588     }
 589     class {'::swift::storage::container':
 590       manage_service => $non_pcmk_start,
 591       enabled => $non_pcmk_start,
 592     }
 593     class {'::swift::storage::object':
 594       manage_service => $non_pcmk_start,
 595       enabled => $non_pcmk_start,
 596     }
 597     if(!defined(File['/srv/node'])) {
 598       file { '/srv/node':
 599         ensure  => directory,
 600         owner   => 'swift',
 601         group   => 'swift',
 602         require => Package['openstack-swift'],
 603       }
 604     }
 605     $swift_components = ['account', 'container', 'object']
 606     swift::storage::filter::recon { $swift_components : }
 607     swift::storage::filter::healthcheck { $swift_components : }
 608   }
 609
 610   # Ceilometer
 611   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 612   case $ceilometer_backend {
 613     /mysql/ : {
 614       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 615     }
 616     default : {
 617       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 618     }
 619   }
 620   include ::ceilometer
 621   class { '::ceilometer::api' :
 622     manage_service => $non_pcmk_start,
 623     enabled => $non_pcmk_start,
 624   }
 625   class { '::ceilometer::agent::notification' :
 626     manage_service => $non_pcmk_start,
 627     enabled => $non_pcmk_start,
 628   }
 629   class { '::ceilometer::agent::central' :
 630     manage_service => $non_pcmk_start,
 631     enabled => $non_pcmk_start,
 632   }
 633   class { '::ceilometer::alarm::notifier' :
 634     manage_service => $non_pcmk_start,
 635     enabled => $non_pcmk_start,
 636   }
 637   class { '::ceilometer::alarm::evaluator' :
 638     manage_service => $non_pcmk_start,
 639     enabled => $non_pcmk_start,
 640   }
 641   class { '::ceilometer::collector' :
 642     manage_service => $non_pcmk_start,
 643     enabled => $non_pcmk_start,
 644   }
 645   include ::ceilometer::expirer
 646   class { '::ceilometer::db' :
 647     database_connection => $ceilometer_database_connection,
 648     sync_db             => $sync_db,
 649   }
 650   class { 'ceilometer::agent::auth':
 651     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 652   }
 653
 654   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 655
 656   # Heat
 657   class { '::heat' :
 658     sync_db => $sync_db,
 659   }
 660   class { '::heat::api' :
 661     manage_service => $non_pcmk_start,
 662     enabled => $non_pcmk_start,
 663   }
 664   class { '::heat::api_cfn' :
 665     manage_service => $non_pcmk_start,
 666     enabled => $non_pcmk_start,
 667   }
 668   class { '::heat::api_cloudwatch' :
 669     manage_service => $non_pcmk_start,
 670     enabled => $non_pcmk_start,
 671   }
 672   class { '::heat::engine' :
 673     manage_service => $non_pcmk_start,
 674     enabled => $non_pcmk_start,
 675   }
 676
 677   # Horizon
 678   $vhost_params = { add_listen => false }
 679   class { 'horizon':
 680     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 681     vhost_extra_params => $vhost_params,
 682   }
 683
 684   $snmpd_user = hiera('snmpd_readonly_user_name')
 685   snmp::snmpv3_user { $snmpd_user:
 686     authtype => 'MD5',
 687     authpass => hiera('snmpd_readonly_user_password'),
 688   }
 689   class { 'snmp':
 690     agentaddress => ['udp:161','udp6:[::1]:161'],
 691     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 692   }
 693
 694 } #END STEP 3
 695
 696 if hiera('step') >= 4 {
 697   # TODO: pacemaker::resource::service for OpenStack services go here
 698 } #END STEP 4