puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 if !str2bool(hiera('enable_package_install', 'false')) {
  22   case $::osfamily {
  23     'RedHat': {
  24       Package { provider => 'norpm' } # provided by tripleo-puppet
  25     }
  26     default: {
  27       warning('enable_package_install option not supported.')
  28     }
  29   }
  30 }
  31
  32 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  33   $pacemaker_master = true
  34   $sync_db = true
  35 } else {
  36   $pacemaker_master = false
  37   $sync_db = false
  38 }
  39
  40 # When to start and enable services which haven't been Pacemakerized
  41 # FIXME: remove when we start all OpenStack services using Pacemaker
  42 # (occurences of this variable will be gradually replaced with false)
  43 $non_pcmk_start = hiera('step') >= 4
  44
  45 if hiera('step') >= 1 {
  46
  47   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  48
  49   if count(hiera('ntp::servers')) > 0 {
  50     include ::ntp
  51   }
  52
  53   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  54   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  55   class { '::tripleo::loadbalancer' :
  56     controller_hosts       => $controller_node_ips,
  57     controller_hosts_names => $controller_node_names,
  58     manage_vip             => false,
  59     haproxy_service_manage => false,
  60   }
  61
  62   $pacemaker_cluster_members = downcase(regsubst(hiera('controller_node_names'), ',', ' ', 'G'))
  63   user { 'hacluster':
  64    ensure => present,
  65   } ->
  66   class { '::pacemaker':
  67     hacluster_pwd => hiera('hacluster_pwd'),
  68   } ->
  69   class { '::pacemaker::corosync':
  70     cluster_members => $pacemaker_cluster_members,
  71     setup_cluster   => $pacemaker_master,
  72   }
  73   class { '::pacemaker::stonith':
  74     disable => true,
  75   }
  76
  77   # Only configure RabbitMQ in this step, don't start it yet to
  78   # avoid races where non-master nodes attempt to start without
  79   # config (eg. binding on 0.0.0.0)
  80   # The module ignores erlang_cookie if cluster_config is false
  81   class { '::rabbitmq':
  82     service_manage          => false,
  83     tcp_keepalive           => false,
  84     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
  85     config_variables        => hiera('rabbitmq_config_variables'),
  86     environment_variables   => hiera('rabbitmq_environment'),
  87   } ->
  88   file { '/var/lib/rabbitmq/.erlang.cookie':
  89     ensure  => 'present',
  90     owner   => 'rabbitmq',
  91     group   => 'rabbitmq',
  92     mode    => '0400',
  93     content => hiera('rabbitmq::erlang_cookie'),
  94     replace => true,
  95   }
  96
  97   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  98     include ::mongodb::globals
  99     # FIXME: replace with service_manage => false on ::mongodb::server
 100     # when this is merged: https://github.com/puppetlabs/pupp etlabs-mongodb/pull/198
 101     class { '::mongodb::server' :
 102       service_ensure => undef,
 103       service_enable => false,
 104     }
 105   }
 106
 107   # Memcached
 108   class {'::memcached' :
 109     service_manage => false,
 110   }
 111
 112   # Galera
 113   if str2bool(hiera('enable_galera', 'true')) {
 114     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 115   } else {
 116     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 117   }
 118   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 119   $galera_nodes_count = count(split($galera_nodes, ','))
 120
 121   $mysqld_options = {
 122     'mysqld' => {
 123       'skip-name-resolve'             => '1',
 124       'binlog_format'                 => 'ROW',
 125       'default-storage-engine'        => 'innodb',
 126       'innodb_autoinc_lock_mode'      => '2',
 127       'innodb_locks_unsafe_for_binlog'=> '1',
 128       'query_cache_size'              => '0',
 129       'query_cache_type'              => '0',
 130       'bind-address'                  => hiera('controller_host'),
 131       'max_connections'               => '1024',
 132       'open_files_limit'              => '-1',
 133       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 134       'wsrep_cluster_name'            => 'galera_cluster',
 135       'wsrep_slave_threads'           => '1',
 136       'wsrep_certify_nonPK'           => '1',
 137       'wsrep_max_ws_rows'             => '131072',
 138       'wsrep_max_ws_size'             => '1073741824',
 139       'wsrep_debug'                   => '0',
 140       'wsrep_convert_LOCK_to_trx'     => '0',
 141       'wsrep_retry_autocommit'        => '1',
 142       'wsrep_auto_increment_control'  => '1',
 143       'wsrep_drupal_282555_workaround'=> '0',
 144       'wsrep_causal_reads'            => '0',
 145       'wsrep_notify_cmd'              => '',
 146       'wsrep_sst_method'              => 'rsync',
 147     }
 148   }
 149
 150   class { '::mysql::server':
 151     create_root_user   => false,
 152     create_root_my_cnf => false,
 153     config_file        => $mysql_config_file,
 154     override_options   => $mysqld_options,
 155     service_manage     => false,
 156   }
 157
 158 }
 159
 160 if hiera('step') >= 2 {
 161
 162   if $pacemaker_master {
 163     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
 164     pacemaker::resource::ip { 'control_vip':
 165       ip_address => $control_vip,
 166     }
 167     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
 168     pacemaker::resource::ip { 'public_vip':
 169       ip_address => $public_vip,
 170     }
 171     pacemaker::resource::service { 'haproxy':
 172       clone_params => true,
 173     }
 174     pacemaker::resource::service { $::memcached::params::service_name :
 175       clone_params => true,
 176       require      => Class['::memcached'],
 177     }
 178
 179     pacemaker::resource::ocf { 'rabbitmq':
 180       ocf_agent_name  => 'heartbeat:rabbitmq-cluster',
 181       resource_params => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 182       clone_params    => 'ordered=true interleave=true',
 183       require         => Class['::rabbitmq'],
 184     }
 185
 186     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 187       pacemaker::resource::service { $::mongodb::params::service_name :
 188         op_params    => 'start timeout=120s',
 189         clone_params => true,
 190         require      => Class['::mongodb::server'],
 191         before       => Exec['mongodb-ready'],
 192       }
 193       # NOTE (spredzy) : The replset can only be run
 194       # once all the nodes have joined the cluster.
 195       $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
 196       $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
 197       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 198       $mongodb_replset = hiera('mongodb::server::replset')
 199       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 200       exec { 'mongodb-ready' :
 201         command   => $mongodb_cluster_ready_command,
 202         timeout   => 30,
 203         tries     => 180,
 204         try_sleep => 10,
 205       }
 206       mongodb_replset { $mongodb_replset :
 207         members => $mongo_node_ips_with_port,
 208         require => Exec['mongodb-ready'],
 209       }
 210     }
 211
 212     pacemaker::resource::ocf { 'galera' :
 213       ocf_agent_name  => 'heartbeat:galera',
 214       op_params       => 'promote timeout=300s on-fail=block',
 215       master_params   => '',
 216       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 217       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 218       require         => Class['::mysql::server'],
 219       before          => Exec['galera-ready'],
 220     }
 221   }
 222
 223   # Redis
 224   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 225   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 226
 227   if $redis_master_hostname == $::hostname {
 228     $slaveof = undef
 229   } else {
 230     $slaveof = "${redis_master_hostname} 6379"
 231   }
 232   class {'::redis' :
 233     slaveof => $slaveof,
 234   }
 235
 236   if count($redis_node_ips) > 1 {
 237     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 238     include ::redis::sentinel
 239     class {'::tripleo::redis_notification' :
 240       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 241     }
 242   }
 243
 244   exec { 'galera-ready' :
 245     command     => '/usr/bin/clustercheck >/dev/null',
 246     timeout     => 30,
 247     tries       => 180,
 248     try_sleep   => 10,
 249     environment => ["AVAILABLE_WHEN_READONLY=0"],
 250     require     => File['/etc/sysconfig/clustercheck'],
 251   }
 252
 253   file { '/etc/sysconfig/clustercheck' :
 254     ensure  => file,
 255     content => "MYSQL_USERNAME=root\n
 256 MYSQL_PASSWORD=''\n
 257 MYSQL_HOST=localhost\n",
 258   }
 259
 260   xinetd::service { 'galera-monitor' :
 261     port           => '9200',
 262     server         => '/usr/bin/clustercheck',
 263     per_source     => 'UNLIMITED',
 264     log_on_success => '',
 265     log_on_failure => 'HOST',
 266     flags          => 'REUSE',
 267     service_type   => 'UNLISTED',
 268     user           => 'root',
 269     group          => 'root',
 270     require        => File['/etc/sysconfig/clustercheck'],
 271   }
 272
 273   # Create all the database schemas
 274   # Example DSN format: mysql://user:password@host/dbname
 275   if $sync_db {
 276     $allowed_hosts = ['%',hiera('controller_host')]
 277     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 278     class { 'keystone::db::mysql':
 279       user          => $keystone_dsn[3],
 280       password      => $keystone_dsn[4],
 281       host          => $keystone_dsn[5],
 282       dbname        => $keystone_dsn[6],
 283       allowed_hosts => $allowed_hosts,
 284       require       => Exec['galera-ready'],
 285     }
 286     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 287     class { 'glance::db::mysql':
 288       user          => $glance_dsn[3],
 289       password      => $glance_dsn[4],
 290       host          => $glance_dsn[5],
 291       dbname        => $glance_dsn[6],
 292       allowed_hosts => $allowed_hosts,
 293       require       => Exec['galera-ready'],
 294     }
 295     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 296     class { 'nova::db::mysql':
 297       user          => $nova_dsn[3],
 298       password      => $nova_dsn[4],
 299       host          => $nova_dsn[5],
 300       dbname        => $nova_dsn[6],
 301       allowed_hosts => $allowed_hosts,
 302       require       => Exec['galera-ready'],
 303     }
 304     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 305     class { 'neutron::db::mysql':
 306       user          => $neutron_dsn[3],
 307       password      => $neutron_dsn[4],
 308       host          => $neutron_dsn[5],
 309       dbname        => $neutron_dsn[6],
 310       allowed_hosts => $allowed_hosts,
 311       require       => Exec['galera-ready'],
 312     }
 313     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 314     class { 'cinder::db::mysql':
 315       user          => $cinder_dsn[3],
 316       password      => $cinder_dsn[4],
 317       host          => $cinder_dsn[5],
 318       dbname        => $cinder_dsn[6],
 319       allowed_hosts => $allowed_hosts,
 320       require       => Exec['galera-ready'],
 321     }
 322     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 323     class { 'heat::db::mysql':
 324       user          => $heat_dsn[3],
 325       password      => $heat_dsn[4],
 326       host          => $heat_dsn[5],
 327       dbname        => $heat_dsn[6],
 328       allowed_hosts => $allowed_hosts,
 329       require       => Exec['galera-ready'],
 330     }
 331     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 332       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 333       class { 'ceilometer::db::mysql':
 334         user          => $ceilometer_dsn[3],
 335         password      => $ceilometer_dsn[4],
 336         host          => $ceilometer_dsn[5],
 337         dbname        => $ceilometer_dsn[6],
 338         allowed_hosts => $allowed_hosts,
 339         require       => Exec['galera-ready'],
 340       }
 341     }
 342   }
 343
 344   # pre-install swift here so we can build rings
 345   include ::swift
 346
 347   # Ceph
 348   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 349   $enable_ceph = $cinder_enable_rbd_backend
 350
 351   if $enable_ceph {
 352     class { 'ceph::profile::params':
 353       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 354     }
 355     include ::ceph::profile::mon
 356   }
 357
 358   if str2bool(hiera('enable_ceph_storage', 'false')) {
 359     include ::ceph::profile::client
 360     include ::ceph::profile::osd
 361   }
 362
 363
 364 } #END STEP 2
 365
 366 if hiera('step') >= 3 {
 367
 368   class { '::keystone':
 369     sync_db => $sync_db,
 370     manage_service => false,
 371     enabled => false,
 372   }
 373
 374   #TODO: need a cleanup-keystone-tokens.sh solution here
 375   keystone_config {
 376     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 377   }
 378   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 379     ensure  => 'directory',
 380     owner   => 'keystone',
 381     group   => 'keystone',
 382     require => Package['keystone'],
 383   }
 384   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 385     content => hiera('keystone_signing_certificate'),
 386     owner   => 'keystone',
 387     group   => 'keystone',
 388     notify  => Service['keystone'],
 389     require => File['/etc/keystone/ssl/certs'],
 390   }
 391   file { '/etc/keystone/ssl/private/signing_key.pem':
 392     content => hiera('keystone_signing_key'),
 393     owner   => 'keystone',
 394     group   => 'keystone',
 395     notify  => Service['keystone'],
 396     require => File['/etc/keystone/ssl/private'],
 397   }
 398   file { '/etc/keystone/ssl/certs/ca.pem':
 399     content => hiera('keystone_ca_certificate'),
 400     owner   => 'keystone',
 401     group   => 'keystone',
 402     notify  => Service['keystone'],
 403     require => File['/etc/keystone/ssl/certs'],
 404   }
 405
 406   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 407   case $glance_backend {
 408       swift: { $glance_store = 'glance.store.swift.Store' }
 409       file: { $glance_store = 'glance.store.filesystem.Store' }
 410       rbd: { $glance_store = 'glance.store.rbd.Store' }
 411       default: { fail('Unrecognized glance_backend parameter.') }
 412   }
 413
 414   # TODO: notifications, scrubber, etc.
 415   include ::glance
 416   class { 'glance::api':
 417     known_stores => [$glance_store],
 418     manage_service => false,
 419     enabled => false,
 420   }
 421   class { '::glance::registry' :
 422     sync_db => $sync_db,
 423     manage_service => false,
 424     enabled => false,
 425   }
 426   include join(['::glance::backend::', $glance_backend])
 427
 428   class { 'nova':
 429     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 430   }
 431
 432   class { '::nova::api' :
 433     sync_db => $sync_db,
 434     manage_service => $non_pcmk_start,
 435     enabled => $non_pcmk_start,
 436   }
 437   class { '::nova::cert' :
 438     manage_service => $non_pcmk_start,
 439     enabled => $non_pcmk_start,
 440   }
 441   class { '::nova::conductor' :
 442     manage_service => $non_pcmk_start,
 443     enabled => $non_pcmk_start,
 444   }
 445   class { '::nova::consoleauth' :
 446     manage_service => $non_pcmk_start,
 447     enabled => $non_pcmk_start,
 448   }
 449   class { '::nova::vncproxy' :
 450     manage_service => $non_pcmk_start,
 451     enabled => $non_pcmk_start,
 452   }
 453   class { '::nova::scheduler' :
 454     manage_service => $non_pcmk_start,
 455     enabled => $non_pcmk_start,
 456   }
 457   include ::nova::network::neutron
 458
 459   include ::neutron
 460   class { '::neutron::server' :
 461     sync_db => $sync_db,
 462     manage_service => $non_pcmk_start,
 463     enabled => $non_pcmk_start,
 464   }
 465   class { '::neutron::agents::dhcp' :
 466     manage_service => $non_pcmk_start,
 467     enabled => $non_pcmk_start,
 468   }
 469   class { '::neutron::agents::l3' :
 470     manage_service => $non_pcmk_start,
 471     enabled => $non_pcmk_start,
 472   }
 473
 474   file { '/etc/neutron/dnsmasq-neutron.conf':
 475     content => hiera('neutron_dnsmasq_options'),
 476     owner   => 'neutron',
 477     group   => 'neutron',
 478     notify  => Service['neutron-dhcp-service'],
 479     require => Package['neutron'],
 480   }
 481
 482   class { 'neutron::plugins::ml2':
 483     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 484     tenant_network_types => [hiera('neutron_tenant_network_type')],
 485     type_drivers         => [hiera('neutron_tenant_network_type')],
 486   }
 487
 488   class { 'neutron::agents::ml2::ovs':
 489     # manage_service   => $non_pcmk_start,  -- not implemented
 490     enabled          => $non_pcmk_start,
 491     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 492     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 493   }
 494
 495   class { 'neutron::agents::metadata':
 496     manage_service   => $non_pcmk_start,
 497     enabled          => $non_pcmk_start,
 498     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 499   }
 500
 501   Service['neutron-server'] -> Service['neutron-dhcp-service']
 502   Service['neutron-server'] -> Service['neutron-l3']
 503   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 504   Service['neutron-server'] -> Service['neutron-metadata']
 505
 506   include ::cinder
 507   class { '::cinder::api':
 508     sync_db => $sync_db,
 509     manage_service => false,
 510     enabled => false,
 511   }
 512   class { '::cinder::scheduler' :
 513     manage_service => false,
 514     enabled => false,
 515   }
 516   class { '::cinder::volume' :
 517     manage_service => false,
 518     enabled => false,
 519   }
 520   include ::cinder::glance
 521   class {'cinder::setup_test_volume':
 522     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 523   }
 524
 525   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 526   if $cinder_enable_iscsi {
 527     $cinder_iscsi_backend = 'tripleo_iscsi'
 528
 529     cinder::backend::iscsi { $cinder_iscsi_backend :
 530       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 531       iscsi_helper     => hiera('cinder_iscsi_helper'),
 532     }
 533   }
 534
 535   if $enable_ceph {
 536
 537     Ceph_pool {
 538       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 539       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 540       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 541     }
 542
 543     $ceph_pools = hiera('ceph_pools')
 544     ceph::pool { $ceph_pools : }
 545   }
 546
 547   if $cinder_enable_rbd_backend {
 548     $cinder_rbd_backend = 'tripleo_ceph'
 549
 550     cinder_config {
 551       "${cinder_rbd_backend}/host": value => 'hostgroup';
 552     }
 553
 554     cinder::backend::rbd { $cinder_rbd_backend :
 555       rbd_pool        => 'volumes',
 556       rbd_user        => 'openstack',
 557       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 558       require         => Ceph::Pool['volumes'],
 559     }
 560   }
 561
 562   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 563   class { '::cinder::backends' :
 564     enabled_backends => $cinder_enabled_backends,
 565   }
 566
 567   # swift proxy
 568   class { '::swift::proxy' :
 569     manage_service => $non_pcmk_start,
 570     enabled => $non_pcmk_start,
 571   }
 572   include ::swift::proxy::proxy_logging
 573   include ::swift::proxy::healthcheck
 574   include ::swift::proxy::cache
 575   include ::swift::proxy::keystone
 576   include ::swift::proxy::authtoken
 577   include ::swift::proxy::staticweb
 578   include ::swift::proxy::ceilometer
 579   include ::swift::proxy::ratelimit
 580   include ::swift::proxy::catch_errors
 581   include ::swift::proxy::tempurl
 582   include ::swift::proxy::formpost
 583
 584   # swift storage
 585   if str2bool(hiera('enable_swift_storage', 'true')) {
 586     class {'::swift::storage::all':
 587       mount_check => str2bool(hiera('swift_mount_check'))
 588     }
 589     class {'::swift::storage::account':
 590       manage_service => $non_pcmk_start,
 591       enabled => $non_pcmk_start,
 592     }
 593     class {'::swift::storage::container':
 594       manage_service => $non_pcmk_start,
 595       enabled => $non_pcmk_start,
 596     }
 597     class {'::swift::storage::object':
 598       manage_service => $non_pcmk_start,
 599       enabled => $non_pcmk_start,
 600     }
 601     if(!defined(File['/srv/node'])) {
 602       file { '/srv/node':
 603         ensure  => directory,
 604         owner   => 'swift',
 605         group   => 'swift',
 606         require => Package['openstack-swift'],
 607       }
 608     }
 609     $swift_components = ['account', 'container', 'object']
 610     swift::storage::filter::recon { $swift_components : }
 611     swift::storage::filter::healthcheck { $swift_components : }
 612   }
 613
 614   # Ceilometer
 615   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 616   case $ceilometer_backend {
 617     /mysql/ : {
 618       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 619     }
 620     default : {
 621       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 622     }
 623   }
 624   include ::ceilometer
 625   class { '::ceilometer::api' :
 626     manage_service => $non_pcmk_start,
 627     enabled => $non_pcmk_start,
 628   }
 629   class { '::ceilometer::agent::notification' :
 630     manage_service => $non_pcmk_start,
 631     enabled => $non_pcmk_start,
 632   }
 633   class { '::ceilometer::agent::central' :
 634     manage_service => $non_pcmk_start,
 635     enabled => $non_pcmk_start,
 636   }
 637   class { '::ceilometer::alarm::notifier' :
 638     manage_service => $non_pcmk_start,
 639     enabled => $non_pcmk_start,
 640   }
 641   class { '::ceilometer::alarm::evaluator' :
 642     manage_service => $non_pcmk_start,
 643     enabled => $non_pcmk_start,
 644   }
 645   class { '::ceilometer::collector' :
 646     manage_service => $non_pcmk_start,
 647     enabled => $non_pcmk_start,
 648   }
 649   include ::ceilometer::expirer
 650   class { '::ceilometer::db' :
 651     database_connection => $ceilometer_database_connection,
 652     sync_db             => $sync_db,
 653   }
 654   class { 'ceilometer::agent::auth':
 655     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 656   }
 657
 658   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 659
 660   # Heat
 661   class { '::heat' :
 662     sync_db => $sync_db,
 663   }
 664   class { '::heat::api' :
 665     manage_service => $non_pcmk_start,
 666     enabled => $non_pcmk_start,
 667   }
 668   class { '::heat::api_cfn' :
 669     manage_service => $non_pcmk_start,
 670     enabled => $non_pcmk_start,
 671   }
 672   class { '::heat::api_cloudwatch' :
 673     manage_service => $non_pcmk_start,
 674     enabled => $non_pcmk_start,
 675   }
 676   class { '::heat::engine' :
 677     manage_service => $non_pcmk_start,
 678     enabled => $non_pcmk_start,
 679   }
 680
 681   # Horizon
 682   $vhost_params = { add_listen => false }
 683   class { 'horizon':
 684     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 685     vhost_extra_params => $vhost_params,
 686   }
 687
 688   $snmpd_user = hiera('snmpd_readonly_user_name')
 689   snmp::snmpv3_user { $snmpd_user:
 690     authtype => 'MD5',
 691     authpass => hiera('snmpd_readonly_user_password'),
 692   }
 693   class { 'snmp':
 694     agentaddress => ['udp:161','udp6:[::1]:161'],
 695     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 696   }
 697
 698 } #END STEP 3
 699
 700 if hiera('step') >= 4 {
 701   if $pacemaker_master {
 702
 703     # Keystone
 704     pacemaker::resource::service { $::keystone::params::service_name :
 705       clone_params => "interleave=true",
 706     }
 707
 708     # Cinder
 709     pacemaker::resource::service { $::cinder::params::api_service :
 710       clone_params => "interleave=true",
 711       require      => Pacemaker::Resource::Service[$::keystone::params::service_name],
 712     }
 713     pacemaker::resource::service { $::cinder::params::scheduler_service :
 714       clone_params => "interleave=true",
 715     }
 716     pacemaker::resource::service { $::cinder::params::volume_service : }
 717
 718     pacemaker::constraint::base { 'keystone-then-cinder-api-constraint':
 719       constraint_type => 'order',
 720       first_resource  => "${::keystone::params::service_name}-clone",
 721       second_resource => "${::cinder::params::api_service}-clone",
 722       first_action    => 'start',
 723       second_action   => 'start',
 724       require         => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 725                           Pacemaker::Resource::Service[$::keystone::params::service_name]],
 726     }
 727     pacemaker::constraint::base { 'cinder-api-then-cinder-scheduler-constraint':
 728       constraint_type => "order",
 729       first_resource => "${::cinder::params::api_service}-clone",
 730       second_resource => "${::cinder::params::scheduler_service}-clone",
 731       first_action => "start",
 732       second_action => "start",
 733       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 734                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 735     }
 736     pacemaker::constraint::colocation { 'cinder-scheduler-with-cinder-api-colocation':
 737       source => "${::cinder::params::scheduler_service}-clone",
 738       target => "${::cinder::params::api_service}-clone",
 739       score => "INFINITY",
 740       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 741                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 742     }
 743     pacemaker::constraint::base { 'cinder-scheduler-then-cinder-volume-constraint':
 744       constraint_type => "order",
 745       first_resource => "${::cinder::params::scheduler_service}-clone",
 746       second_resource => "${::cinder::params::volume_service}",
 747       first_action => "start",
 748       second_action => "start",
 749       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 750                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 751     }
 752     pacemaker::constraint::colocation { 'cinder-volume-with-cinder-scheduler-colocation':
 753       source => "${::cinder::params::volume_service}",
 754       target => "${::cinder::params::scheduler_service}-clone",
 755       score => "INFINITY",
 756       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 757                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 758     }
 759
 760     # Glance
 761     pacemaker::resource::service { $::glance::params::registry_service_name :
 762       clone_params => "interleave=true",
 763       require      => Pacemaker::Resource::Service[$::keystone::params::service_name],
 764     }
 765     pacemaker::resource::service { $::glance::params::api_service_name :
 766       clone_params => "interleave=true",
 767     }
 768
 769     pacemaker::constraint::base { 'keystone-then-glance-registry-constraint':
 770       constraint_type => 'order',
 771       first_resource  => "${::keystone::params::service_name}-clone",
 772       second_resource => "${::glance::params::registry_service_name}-clone",
 773       first_action    => 'start',
 774       second_action   => 'start',
 775       require         => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 776                           Pacemaker::Resource::Service[$::keystone::params::service_name]],
 777     }
 778     pacemaker::constraint::base { 'glance-registry-then-glance-api-constraint':
 779       constraint_type => "order",
 780       first_resource  => "${::glance::params::registry_service_name}-clone",
 781       second_resource => "${::glance::params::api_service_name}-clone",
 782       first_action    => "start",
 783       second_action   => "start",
 784       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 785                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 786     }
 787     pacemaker::constraint::colocation { 'glance-api-with-glance-registry-colocation':
 788       source  => "${::glance::params::api_service_name}-clone",
 789       target  => "${::glance::params::registry_service_name}-clone",
 790       score   => "INFINITY",
 791       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 792                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 793     }
 794   }
 795
 796 } #END STEP 4