puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  28   $pacemaker_master = true
  29 } else {
  30   $pacemaker_master = false
  31 }
  32
  33 if hiera('step') >= 1 {
  34
  35   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  36   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  37   class { '::tripleo::loadbalancer' :
  38     controller_hosts       => $controller_node_ips,
  39     controller_hosts_names => $controller_node_names,
  40     manage_vip             => false,
  41   }
  42
  43   $pacemaker_cluster_members = regsubst(hiera('controller_node_ips'), ',', ' ', 'G')
  44   user { 'hacluster':
  45    ensure => present,
  46   } ->
  47   class { '::pacemaker':
  48     hacluster_pwd => hiera('hacluster_pwd'),
  49   } ->
  50   class { '::pacemaker::corosync':
  51     cluster_members => $pacemaker_cluster_members,
  52     setup_cluster   => $pacemaker_master,
  53   }
  54   class { '::pacemaker::stonith':
  55     disable => true,
  56   }
  57   if $pacemaker_master {
  58     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
  59     pacemaker::resource::ip { 'control_vip':
  60       ip_address => $control_vip,
  61     }
  62     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
  63     pacemaker::resource::ip { 'public_vip':
  64       ip_address => $public_vip,
  65     }
  66     pacemaker::resource::systemd { 'haproxy':
  67       clone => true,
  68     }
  69   }
  70
  71   Class['::pacemaker::corosync'] -> Pacemaker::Resource::Systemd <| |>
  72
  73 }
  74
  75 if hiera('step') >= 2 {
  76
  77   if count(hiera('ntp::servers')) > 0 {
  78     include ::ntp
  79   }
  80
  81   # MongoDB
  82   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  83     include ::mongodb::globals
  84
  85     class {'::mongodb::server' :
  86       service_ensure => undef
  87     }
  88     $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
  89     $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
  90     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  91
  92     $mongodb_replset = hiera('mongodb::server::replset')
  93     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  94     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  95
  96       pacemaker::resource::systemd { 'mongod' :
  97         options => "op start timeout=120s",
  98         clone   => true,
  99         before  => Exec['mongodb-ready'],
 100       }
 101       # NOTE (spredzy) : The replset can only be run
 102       # once all the nodes have joined the cluster.
 103       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 104       exec { 'mongodb-ready' :
 105         command   => $mongodb_cluster_ready_command,
 106         timeout   => 600,
 107         tries     => 60,
 108         try_sleep => 10,
 109         before    => Mongodb_replset[$mongodb_replset],
 110       }
 111
 112       mongodb_replset { $mongodb_replset :
 113         members => $mongo_node_ips_with_port,
 114       }
 115     }
 116   }
 117
 118   # Redis
 119   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 120   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 121
 122   if $redis_master_hostname == $::hostname {
 123     $slaveof = undef
 124   } else {
 125     $slaveof = "${redis_master_hostname} 6379"
 126   }
 127   class {'::redis' :
 128     slaveof => $slaveof,
 129   }
 130
 131   if count($redis_node_ips) > 1 {
 132     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 133     include ::redis::sentinel
 134     class {'::tripleo::redis_notification' :
 135       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 136     }
 137   }
 138
 139   if str2bool(hiera('enable_galera', 'true')) {
 140     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 141   } else {
 142     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 143   }
 144   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 145   $galera_nodes_count = count(split($galera_nodes, ','))
 146   $clustercheck_password = hiera('mysql_clustercheck_password')
 147   $mysql_root_password = hiera('mysql::server::root_password')
 148
 149   $mysqld_options = {
 150     'mysqld' => {
 151       'skip-name-resolve'             => '1',
 152       'binlog_format'                 => 'ROW',
 153       'default-storage-engine'        => 'innodb',
 154       'innodb_autoinc_lock_mode'      => '2',
 155       'innodb_locks_unsafe_for_binlog'=> '1',
 156       'query_cache_size'              => '0',
 157       'query_cache_type'              => '0',
 158       'bind-address'                  => hiera('controller_host'),
 159       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 160       'wsrep_cluster_name'            => 'galera_cluster',
 161       'wsrep_slave_threads'           => '1',
 162       'wsrep_certify_nonPK'           => '1',
 163       'wsrep_max_ws_rows'             => '131072',
 164       'wsrep_max_ws_size'             => '1073741824',
 165       'wsrep_debug'                   => '0',
 166       'wsrep_convert_LOCK_to_trx'     => '0',
 167       'wsrep_retry_autocommit'        => '1',
 168       'wsrep_auto_increment_control'  => '1',
 169       'wsrep_drupal_282555_workaround'=> '0',
 170       'wsrep_causal_reads'            => '0',
 171       'wsrep_notify_cmd'              => '',
 172       'wsrep_sst_method'              => 'rsync',
 173     }
 174   }
 175
 176   class { '::mysql::server':
 177     create_root_user   => false,
 178     create_root_my_cnf => false,
 179     config_file        => $mysql_config_file,
 180     override_options   => $mysqld_options,
 181     service_manage     => false,
 182   }
 183
 184   if $pacemaker_master {
 185     $sync_db = true
 186
 187     pacemaker::resource::ocf { 'galera' :
 188       resource_name => 'heartbeat:galera',
 189       options       => "enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}' meta master-max=${galera_nodes_count} ordered=true op promote timeout=300s on-fail=block --master",
 190       require       => Class['::mysql::server'],
 191       before        => Exec['galera-ready'],
 192     }
 193
 194     mysql_user { 'clustercheckuser@localhost' :
 195       password_hash => mysql_password($clustercheck_password),
 196       require       => Exec['galera-ready'],
 197     }
 198   } else {
 199     $sync_db = false
 200   }
 201
 202   exec { 'galera-ready' :
 203     command     => '/bin/mysql -e "SHOW GLOBAL VARIABLES LIKE \'read_only\'" | /bin/grep -i off',
 204     timeout     => 3600,
 205     tries       => 60,
 206     try_sleep   => 60,
 207     environment => 'HOME=/root',
 208     require     => Class['::mysql::server'],
 209   }
 210
 211   file { '/etc/sysconfig/clustercheck' :
 212     ensure  => file,
 213     content => "MYSQL_USERNAME=clustercheckuser\n
 214 MYSQL_PASSWORD=${clustercheck_password}\n
 215 MYSQL_HOST=localhost\n",
 216     require       => Exec['galera-ready'],
 217   }
 218
 219   xinetd::service { 'galera-monitor' :
 220     port           => '9200',
 221     server         => '/usr/bin/clustercheck',
 222     per_source     => 'UNLIMITED',
 223     log_on_success => '',
 224     log_on_failure => 'HOST',
 225     flags          => 'REUSE',
 226     service_type   => 'UNLISTED',
 227     user           => 'root',
 228     group          => 'root',
 229     require        => File['/etc/sysconfig/clustercheck'],
 230   }
 231
 232   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 233   # Create all the database schemas
 234   # Example DSN format: mysql://user:password@host/dbname
 235   if $sync_db {
 236     $allowed_hosts = ['%',hiera('controller_host')]
 237     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 238     class { 'keystone::db::mysql':
 239       user          => $keystone_dsn[3],
 240       password      => $keystone_dsn[4],
 241       host          => $keystone_dsn[5],
 242       dbname        => $keystone_dsn[6],
 243       allowed_hosts => $allowed_hosts,
 244       require       => Exec['galera-ready'],
 245     }
 246     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 247     class { 'glance::db::mysql':
 248       user          => $glance_dsn[3],
 249       password      => $glance_dsn[4],
 250       host          => $glance_dsn[5],
 251       dbname        => $glance_dsn[6],
 252       allowed_hosts => $allowed_hosts,
 253       require       => Exec['galera-ready'],
 254     }
 255     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 256     class { 'nova::db::mysql':
 257       user          => $nova_dsn[3],
 258       password      => $nova_dsn[4],
 259       host          => $nova_dsn[5],
 260       dbname        => $nova_dsn[6],
 261       allowed_hosts => $allowed_hosts,
 262       require       => Exec['galera-ready'],
 263     }
 264     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 265     class { 'neutron::db::mysql':
 266       user          => $neutron_dsn[3],
 267       password      => $neutron_dsn[4],
 268       host          => $neutron_dsn[5],
 269       dbname        => $neutron_dsn[6],
 270       allowed_hosts => $allowed_hosts,
 271       require       => Exec['galera-ready'],
 272     }
 273     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 274     class { 'cinder::db::mysql':
 275       user          => $cinder_dsn[3],
 276       password      => $cinder_dsn[4],
 277       host          => $cinder_dsn[5],
 278       dbname        => $cinder_dsn[6],
 279       allowed_hosts => $allowed_hosts,
 280       require       => Exec['galera-ready'],
 281     }
 282     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 283     class { 'heat::db::mysql':
 284       user          => $heat_dsn[3],
 285       password      => $heat_dsn[4],
 286       host          => $heat_dsn[5],
 287       dbname        => $heat_dsn[6],
 288       allowed_hosts => $allowed_hosts,
 289       require       => Exec['galera-ready'],
 290     }
 291     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 292       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 293       class { 'ceilometer::db::mysql':
 294         user          => $ceilometer_dsn[3],
 295         password      => $ceilometer_dsn[4],
 296         host          => $ceilometer_dsn[5],
 297         dbname        => $ceilometer_dsn[6],
 298         allowed_hosts => $allowed_hosts,
 299         require       => Exec['galera-ready'],
 300       }
 301     }
 302   }
 303
 304   # the module ignores erlang_cookie if cluster_config is false
 305   file { '/var/lib/rabbitmq/.erlang.cookie':
 306     ensure  => 'present',
 307     owner   => 'rabbitmq',
 308     group   => 'rabbitmq',
 309     mode    => '0400',
 310     content => hiera('rabbitmq::erlang_cookie'),
 311     replace => true,
 312   } ->
 313   class { '::rabbitmq':
 314     service_manage          => false,
 315     tcp_keepalive           => false,
 316     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 317     config_variables        => hiera('rabbitmq_config_variables'),
 318     environment_variables   => hiera('rabbitmq_environment'),
 319   }
 320   if $pacemaker_master {
 321     pacemaker::resource::ocf { 'rabbitmq':
 322       resource_name => 'heartbeat:rabbitmq-cluster',
 323       options       => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 324       clone         => true,
 325       require       => Class['::rabbitmq'],
 326     }
 327   }
 328
 329   # pre-install swift here so we can build rings
 330   include ::swift
 331
 332   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 333   $enable_ceph = $cinder_enable_rbd_backend
 334
 335   if $enable_ceph {
 336     class { 'ceph::profile::params':
 337       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 338     }
 339     include ::ceph::profile::mon
 340   }
 341
 342   if str2bool(hiera('enable_ceph_storage', 'false')) {
 343     include ::ceph::profile::client
 344     include ::ceph::profile::osd
 345   }
 346
 347 } #END STEP 2
 348
 349 if (hiera('step') >= 3 and $::hostname == downcase(hiera('bootstrap_nodeid')))
 350    or hiera('step') >= 4 {
 351
 352   include ::keystone
 353
 354   #TODO: need a cleanup-keystone-tokens.sh solution here
 355   keystone_config {
 356     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 357   }
 358   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 359     ensure  => 'directory',
 360     owner   => 'keystone',
 361     group   => 'keystone',
 362     require => Package['keystone'],
 363   }
 364   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 365     content => hiera('keystone_signing_certificate'),
 366     owner   => 'keystone',
 367     group   => 'keystone',
 368     notify  => Service['keystone'],
 369     require => File['/etc/keystone/ssl/certs'],
 370   }
 371   file { '/etc/keystone/ssl/private/signing_key.pem':
 372     content => hiera('keystone_signing_key'),
 373     owner   => 'keystone',
 374     group   => 'keystone',
 375     notify  => Service['keystone'],
 376     require => File['/etc/keystone/ssl/private'],
 377   }
 378   file { '/etc/keystone/ssl/certs/ca.pem':
 379     content => hiera('keystone_ca_certificate'),
 380     owner   => 'keystone',
 381     group   => 'keystone',
 382     notify  => Service['keystone'],
 383     require => File['/etc/keystone/ssl/certs'],
 384   }
 385
 386   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 387   case $glance_backend {
 388       swift: { $glance_store = 'glance.store.swift.Store' }
 389       file: { $glance_store = 'glance.store.filesystem.Store' }
 390       rbd: { $glance_store = 'glance.store.rbd.Store' }
 391       default: { fail('Unrecognized glance_backend parameter.') }
 392   }
 393
 394   # TODO: notifications, scrubber, etc.
 395   include ::glance
 396   class { 'glance::api':
 397     known_stores => [$glance_store]
 398   }
 399   class { '::glance::registry' :
 400     sync_db => $sync_db,
 401   }
 402   include join(['::glance::backend::', $glance_backend])
 403
 404   class { 'nova':
 405     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 406   }
 407
 408   class { '::nova::api' :
 409     sync_db => $sync_db,
 410   }
 411   include ::nova::cert
 412   include ::nova::conductor
 413   include ::nova::consoleauth
 414   include ::nova::network::neutron
 415   include ::nova::vncproxy
 416   include ::nova::scheduler
 417
 418   include ::neutron
 419   class { '::neutron::server' :
 420     sync_db => $sync_db,
 421   }
 422   include ::neutron::agents::dhcp
 423   include ::neutron::agents::l3
 424
 425   file { '/etc/neutron/dnsmasq-neutron.conf':
 426     content => hiera('neutron_dnsmasq_options'),
 427     owner   => 'neutron',
 428     group   => 'neutron',
 429     notify  => Service['neutron-dhcp-service'],
 430     require => Package['neutron'],
 431   }
 432
 433   class { 'neutron::plugins::ml2':
 434     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 435     tenant_network_types => [hiera('neutron_tenant_network_type')],
 436     type_drivers         => [hiera('neutron_tenant_network_type')],
 437   }
 438
 439   class { 'neutron::agents::ml2::ovs':
 440     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 441     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 442   }
 443
 444   class { 'neutron::agents::metadata':
 445     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 446   }
 447
 448   Service['neutron-server'] -> Service['neutron-dhcp-service']
 449   Service['neutron-server'] -> Service['neutron-l3']
 450   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 451   Service['neutron-server'] -> Service['neutron-metadata']
 452
 453   include ::cinder
 454   include ::cinder::api
 455   include ::cinder::glance
 456   include ::cinder::scheduler
 457   include ::cinder::volume
 458   class {'cinder::setup_test_volume':
 459     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 460   }
 461
 462   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 463   if $cinder_enable_iscsi {
 464     $cinder_iscsi_backend = 'tripleo_iscsi'
 465
 466     cinder::backend::iscsi { $cinder_iscsi_backend :
 467       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 468       iscsi_helper     => hiera('cinder_iscsi_helper'),
 469     }
 470   }
 471
 472   if $enable_ceph {
 473
 474     Ceph_pool {
 475       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 476       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 477       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 478     }
 479
 480     $ceph_pools = hiera('ceph_pools')
 481     ceph::pool { $ceph_pools : }
 482   }
 483
 484   if $cinder_enable_rbd_backend {
 485     $cinder_rbd_backend = 'tripleo_ceph'
 486
 487     cinder_config {
 488       "${cinder_rbd_backend}/host": value => 'hostgroup';
 489     }
 490
 491     cinder::backend::rbd { $cinder_rbd_backend :
 492       rbd_pool        => 'volumes',
 493       rbd_user        => 'openstack',
 494       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 495       require         => Ceph::Pool['volumes'],
 496     }
 497   }
 498
 499   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 500   class { '::cinder::backends' :
 501     enabled_backends => $cinder_enabled_backends,
 502   }
 503
 504   # swift proxy
 505   include ::memcached
 506   include ::swift::proxy
 507   include ::swift::proxy::proxy_logging
 508   include ::swift::proxy::healthcheck
 509   include ::swift::proxy::cache
 510   include ::swift::proxy::keystone
 511   include ::swift::proxy::authtoken
 512   include ::swift::proxy::staticweb
 513   include ::swift::proxy::ceilometer
 514   include ::swift::proxy::ratelimit
 515   include ::swift::proxy::catch_errors
 516   include ::swift::proxy::tempurl
 517   include ::swift::proxy::formpost
 518
 519   # swift storage
 520   if str2bool(hiera('enable_swift_storage', 'true')) {
 521     class {'swift::storage::all':
 522       mount_check => str2bool(hiera('swift_mount_check'))
 523     }
 524     if(!defined(File['/srv/node'])) {
 525       file { '/srv/node':
 526         ensure  => directory,
 527         owner   => 'swift',
 528         group   => 'swift',
 529         require => Package['openstack-swift'],
 530       }
 531     }
 532     $swift_components = ['account', 'container', 'object']
 533     swift::storage::filter::recon { $swift_components : }
 534     swift::storage::filter::healthcheck { $swift_components : }
 535   }
 536
 537   # Ceilometer
 538   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 539   case $ceilometer_backend {
 540     /mysql/ : {
 541       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 542     }
 543     default : {
 544       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 545     }
 546   }
 547   include ::ceilometer
 548   include ::ceilometer::api
 549   include ::ceilometer::agent::notification
 550   include ::ceilometer::agent::central
 551   include ::ceilometer::alarm::notifier
 552   include ::ceilometer::alarm::evaluator
 553   include ::ceilometer::expirer
 554   include ::ceilometer::collector
 555   class { '::ceilometer::db' :
 556     database_connection => $ceilometer_database_connection,
 557     sync_db             => $sync_db,
 558   }
 559   class { 'ceilometer::agent::auth':
 560     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 561   }
 562
 563   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 564
 565   # Heat
 566   class { '::heat' :
 567     sync_db => $sync_db,
 568   }
 569   include ::heat::api
 570   include ::heat::api_cfn
 571   include ::heat::api_cloudwatch
 572   include ::heat::engine
 573
 574   # Horizon
 575   $vhost_params = { add_listen => false }
 576   class { 'horizon':
 577     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 578     vhost_extra_params => $vhost_params,
 579   }
 580
 581   $snmpd_user = hiera('snmpd_readonly_user_name')
 582   snmp::snmpv3_user { $snmpd_user:
 583     authtype => 'MD5',
 584     authpass => hiera('snmpd_readonly_user_password'),
 585   }
 586   class { 'snmp':
 587     agentaddress => ['udp:161','udp6:[::1]:161'],
 588     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 589   }
 590
 591 } #END STEP 3