puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 if !str2bool(hiera('enable_package_install', 'false')) {
  22   case $::osfamily {
  23     'RedHat': {
  24       Package { provider => 'norpm' } # provided by tripleo-puppet
  25     }
  26     default: {
  27       warning('enable_package_install option not supported.')
  28     }
  29   }
  30 }
  31
  32 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  33   $pacemaker_master = true
  34   $sync_db = true
  35 } else {
  36   $pacemaker_master = false
  37   $sync_db = false
  38 }
  39
  40 # When to start and enable services which haven't been Pacemakerized
  41 # FIXME: remove when we start all OpenStack services using Pacemaker
  42 # (occurences of this variable will be gradually replaced with false)
  43 $non_pcmk_start = hiera('step') >= 4
  44
  45 if hiera('step') >= 1 {
  46
  47   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  48
  49   if count(hiera('ntp::servers')) > 0 {
  50     include ::ntp
  51   }
  52
  53   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  54   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  55   class { '::tripleo::loadbalancer' :
  56     controller_hosts       => $controller_node_ips,
  57     controller_hosts_names => $controller_node_names,
  58     manage_vip             => false,
  59     haproxy_service_manage => false,
  60   }
  61
  62   $pacemaker_cluster_members = downcase(regsubst(hiera('controller_node_names'), ',', ' ', 'G'))
  63   user { 'hacluster':
  64    ensure => present,
  65   } ->
  66   class { '::pacemaker':
  67     hacluster_pwd => hiera('hacluster_pwd'),
  68   } ->
  69   class { '::pacemaker::corosync':
  70     cluster_members => $pacemaker_cluster_members,
  71     setup_cluster   => $pacemaker_master,
  72   }
  73   class { '::pacemaker::stonith':
  74     disable => true,
  75   }
  76
  77   # Only configure RabbitMQ in this step, don't start it yet to
  78   # avoid races where non-master nodes attempt to start without
  79   # config (eg. binding on 0.0.0.0)
  80   # The module ignores erlang_cookie if cluster_config is false
  81   class { '::rabbitmq':
  82     service_manage          => false,
  83     tcp_keepalive           => false,
  84     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
  85     config_variables        => hiera('rabbitmq_config_variables'),
  86     environment_variables   => hiera('rabbitmq_environment'),
  87   } ->
  88   file { '/var/lib/rabbitmq/.erlang.cookie':
  89     ensure  => 'present',
  90     owner   => 'rabbitmq',
  91     group   => 'rabbitmq',
  92     mode    => '0400',
  93     content => hiera('rabbitmq::erlang_cookie'),
  94     replace => true,
  95   }
  96
  97   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  98     include ::mongodb::globals
  99     # FIXME: replace with service_manage => false on ::mongodb::server
 100     # when this is merged: https://github.com/puppetlabs/pupp etlabs-mongodb/pull/198
 101     class { '::mongodb::server' :
 102       service_ensure => undef,
 103       service_enable => false,
 104     }
 105   }
 106
 107   # Galera
 108   if str2bool(hiera('enable_galera', 'true')) {
 109     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 110   } else {
 111     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 112   }
 113   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 114   $galera_nodes_count = count(split($galera_nodes, ','))
 115
 116   $mysqld_options = {
 117     'mysqld' => {
 118       'skip-name-resolve'             => '1',
 119       'binlog_format'                 => 'ROW',
 120       'default-storage-engine'        => 'innodb',
 121       'innodb_autoinc_lock_mode'      => '2',
 122       'innodb_locks_unsafe_for_binlog'=> '1',
 123       'query_cache_size'              => '0',
 124       'query_cache_type'              => '0',
 125       'bind-address'                  => hiera('controller_host'),
 126       'max_connections'               => '1024',
 127       'open_files_limit'              => '-1',
 128       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 129       'wsrep_cluster_name'            => 'galera_cluster',
 130       'wsrep_slave_threads'           => '1',
 131       'wsrep_certify_nonPK'           => '1',
 132       'wsrep_max_ws_rows'             => '131072',
 133       'wsrep_max_ws_size'             => '1073741824',
 134       'wsrep_debug'                   => '0',
 135       'wsrep_convert_LOCK_to_trx'     => '0',
 136       'wsrep_retry_autocommit'        => '1',
 137       'wsrep_auto_increment_control'  => '1',
 138       'wsrep_drupal_282555_workaround'=> '0',
 139       'wsrep_causal_reads'            => '0',
 140       'wsrep_notify_cmd'              => '',
 141       'wsrep_sst_method'              => 'rsync',
 142     }
 143   }
 144
 145   class { '::mysql::server':
 146     create_root_user   => false,
 147     create_root_my_cnf => false,
 148     config_file        => $mysql_config_file,
 149     override_options   => $mysqld_options,
 150     service_manage     => false,
 151   }
 152
 153 }
 154
 155 if hiera('step') >= 2 {
 156
 157   if $pacemaker_master {
 158     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
 159     pacemaker::resource::ip { 'control_vip':
 160       ip_address => $control_vip,
 161     }
 162     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
 163     pacemaker::resource::ip { 'public_vip':
 164       ip_address => $public_vip,
 165     }
 166     pacemaker::resource::service { 'haproxy':
 167       clone_params => true,
 168     }
 169
 170     pacemaker::resource::ocf { 'rabbitmq':
 171       ocf_agent_name  => 'heartbeat:rabbitmq-cluster',
 172       resource_params => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 173       clone_params    => 'ordered=true interleave=true',
 174       require         => Class['::rabbitmq'],
 175     }
 176
 177     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 178       pacemaker::resource::service { $::mongodb::params::service_name :
 179         op_params    => 'start timeout=120s',
 180         clone_params => true,
 181         require      => Class['::mongodb::server'],
 182         before       => Exec['mongodb-ready'],
 183       }
 184       # NOTE (spredzy) : The replset can only be run
 185       # once all the nodes have joined the cluster.
 186       $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
 187       $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
 188       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 189       $mongodb_replset = hiera('mongodb::server::replset')
 190       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 191       exec { 'mongodb-ready' :
 192         command   => $mongodb_cluster_ready_command,
 193         timeout   => 30,
 194         tries     => 180,
 195         try_sleep => 10,
 196       }
 197       mongodb_replset { $mongodb_replset :
 198         members => $mongo_node_ips_with_port,
 199         require => Exec['mongodb-ready'],
 200       }
 201     }
 202
 203     pacemaker::resource::ocf { 'galera' :
 204       ocf_agent_name  => 'heartbeat:galera',
 205       op_params       => 'promote timeout=300s on-fail=block --master',
 206       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 207       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 208       require         => Class['::mysql::server'],
 209       before          => Exec['galera-ready'],
 210     }
 211   }
 212
 213   # Redis
 214   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 215   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 216
 217   if $redis_master_hostname == $::hostname {
 218     $slaveof = undef
 219   } else {
 220     $slaveof = "${redis_master_hostname} 6379"
 221   }
 222   class {'::redis' :
 223     slaveof => $slaveof,
 224   }
 225
 226   if count($redis_node_ips) > 1 {
 227     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 228     include ::redis::sentinel
 229     class {'::tripleo::redis_notification' :
 230       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 231     }
 232   }
 233
 234   exec { 'galera-ready' :
 235     command     => '/usr/bin/clustercheck >/dev/null',
 236     timeout     => 30,
 237     tries       => 180,
 238     try_sleep   => 10,
 239     environment => ["AVAILABLE_WHEN_READONLY=0"],
 240     require     => File['/etc/sysconfig/clustercheck'],
 241   }
 242
 243   file { '/etc/sysconfig/clustercheck' :
 244     ensure  => file,
 245     content => "MYSQL_USERNAME=root\n
 246 MYSQL_PASSWORD=''\n
 247 MYSQL_HOST=localhost\n",
 248   }
 249
 250   xinetd::service { 'galera-monitor' :
 251     port           => '9200',
 252     server         => '/usr/bin/clustercheck',
 253     per_source     => 'UNLIMITED',
 254     log_on_success => '',
 255     log_on_failure => 'HOST',
 256     flags          => 'REUSE',
 257     service_type   => 'UNLISTED',
 258     user           => 'root',
 259     group          => 'root',
 260     require        => File['/etc/sysconfig/clustercheck'],
 261   }
 262
 263   # Create all the database schemas
 264   # Example DSN format: mysql://user:password@host/dbname
 265   if $sync_db {
 266     $allowed_hosts = ['%',hiera('controller_host')]
 267     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 268     class { 'keystone::db::mysql':
 269       user          => $keystone_dsn[3],
 270       password      => $keystone_dsn[4],
 271       host          => $keystone_dsn[5],
 272       dbname        => $keystone_dsn[6],
 273       allowed_hosts => $allowed_hosts,
 274       require       => Exec['galera-ready'],
 275     }
 276     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 277     class { 'glance::db::mysql':
 278       user          => $glance_dsn[3],
 279       password      => $glance_dsn[4],
 280       host          => $glance_dsn[5],
 281       dbname        => $glance_dsn[6],
 282       allowed_hosts => $allowed_hosts,
 283       require       => Exec['galera-ready'],
 284     }
 285     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 286     class { 'nova::db::mysql':
 287       user          => $nova_dsn[3],
 288       password      => $nova_dsn[4],
 289       host          => $nova_dsn[5],
 290       dbname        => $nova_dsn[6],
 291       allowed_hosts => $allowed_hosts,
 292       require       => Exec['galera-ready'],
 293     }
 294     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 295     class { 'neutron::db::mysql':
 296       user          => $neutron_dsn[3],
 297       password      => $neutron_dsn[4],
 298       host          => $neutron_dsn[5],
 299       dbname        => $neutron_dsn[6],
 300       allowed_hosts => $allowed_hosts,
 301       require       => Exec['galera-ready'],
 302     }
 303     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 304     class { 'cinder::db::mysql':
 305       user          => $cinder_dsn[3],
 306       password      => $cinder_dsn[4],
 307       host          => $cinder_dsn[5],
 308       dbname        => $cinder_dsn[6],
 309       allowed_hosts => $allowed_hosts,
 310       require       => Exec['galera-ready'],
 311     }
 312     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 313     class { 'heat::db::mysql':
 314       user          => $heat_dsn[3],
 315       password      => $heat_dsn[4],
 316       host          => $heat_dsn[5],
 317       dbname        => $heat_dsn[6],
 318       allowed_hosts => $allowed_hosts,
 319       require       => Exec['galera-ready'],
 320     }
 321     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 322       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 323       class { 'ceilometer::db::mysql':
 324         user          => $ceilometer_dsn[3],
 325         password      => $ceilometer_dsn[4],
 326         host          => $ceilometer_dsn[5],
 327         dbname        => $ceilometer_dsn[6],
 328         allowed_hosts => $allowed_hosts,
 329         require       => Exec['galera-ready'],
 330       }
 331     }
 332   }
 333
 334   # pre-install swift here so we can build rings
 335   include ::swift
 336
 337   # Ceph
 338   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 339   $enable_ceph = $cinder_enable_rbd_backend
 340
 341   if $enable_ceph {
 342     class { 'ceph::profile::params':
 343       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 344     }
 345     include ::ceph::profile::mon
 346   }
 347
 348   if str2bool(hiera('enable_ceph_storage', 'false')) {
 349     include ::ceph::profile::client
 350     include ::ceph::profile::osd
 351   }
 352
 353   # Memcached
 354   include ::memcached
 355
 356 } #END STEP 2
 357
 358 if hiera('step') >= 3 {
 359
 360   class { '::keystone':
 361     sync_db => $sync_db,
 362     manage_service => false,
 363     enabled => false,
 364   }
 365
 366   #TODO: need a cleanup-keystone-tokens.sh solution here
 367   keystone_config {
 368     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 369   }
 370   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 371     ensure  => 'directory',
 372     owner   => 'keystone',
 373     group   => 'keystone',
 374     require => Package['keystone'],
 375   }
 376   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 377     content => hiera('keystone_signing_certificate'),
 378     owner   => 'keystone',
 379     group   => 'keystone',
 380     notify  => Service['keystone'],
 381     require => File['/etc/keystone/ssl/certs'],
 382   }
 383   file { '/etc/keystone/ssl/private/signing_key.pem':
 384     content => hiera('keystone_signing_key'),
 385     owner   => 'keystone',
 386     group   => 'keystone',
 387     notify  => Service['keystone'],
 388     require => File['/etc/keystone/ssl/private'],
 389   }
 390   file { '/etc/keystone/ssl/certs/ca.pem':
 391     content => hiera('keystone_ca_certificate'),
 392     owner   => 'keystone',
 393     group   => 'keystone',
 394     notify  => Service['keystone'],
 395     require => File['/etc/keystone/ssl/certs'],
 396   }
 397
 398   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 399   case $glance_backend {
 400       swift: { $glance_store = 'glance.store.swift.Store' }
 401       file: { $glance_store = 'glance.store.filesystem.Store' }
 402       rbd: { $glance_store = 'glance.store.rbd.Store' }
 403       default: { fail('Unrecognized glance_backend parameter.') }
 404   }
 405
 406   # TODO: notifications, scrubber, etc.
 407   include ::glance
 408   class { 'glance::api':
 409     known_stores => [$glance_store],
 410     manage_service => false,
 411     enabled => false,
 412   }
 413   class { '::glance::registry' :
 414     sync_db => $sync_db,
 415     manage_service => false,
 416     enabled => false,
 417   }
 418   include join(['::glance::backend::', $glance_backend])
 419
 420   class { 'nova':
 421     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 422   }
 423
 424   class { '::nova::api' :
 425     sync_db => $sync_db,
 426     manage_service => $non_pcmk_start,
 427     enabled => $non_pcmk_start,
 428   }
 429   class { '::nova::cert' :
 430     manage_service => $non_pcmk_start,
 431     enabled => $non_pcmk_start,
 432   }
 433   class { '::nova::conductor' :
 434     manage_service => $non_pcmk_start,
 435     enabled => $non_pcmk_start,
 436   }
 437   class { '::nova::consoleauth' :
 438     manage_service => $non_pcmk_start,
 439     enabled => $non_pcmk_start,
 440   }
 441   class { '::nova::vncproxy' :
 442     manage_service => $non_pcmk_start,
 443     enabled => $non_pcmk_start,
 444   }
 445   class { '::nova::scheduler' :
 446     manage_service => $non_pcmk_start,
 447     enabled => $non_pcmk_start,
 448   }
 449   include ::nova::network::neutron
 450
 451   include ::neutron
 452   class { '::neutron::server' :
 453     sync_db => $sync_db,
 454     manage_service => $non_pcmk_start,
 455     enabled => $non_pcmk_start,
 456   }
 457   class { '::neutron::agents::dhcp' :
 458     manage_service => $non_pcmk_start,
 459     enabled => $non_pcmk_start,
 460   }
 461   class { '::neutron::agents::l3' :
 462     manage_service => $non_pcmk_start,
 463     enabled => $non_pcmk_start,
 464   }
 465
 466   file { '/etc/neutron/dnsmasq-neutron.conf':
 467     content => hiera('neutron_dnsmasq_options'),
 468     owner   => 'neutron',
 469     group   => 'neutron',
 470     notify  => Service['neutron-dhcp-service'],
 471     require => Package['neutron'],
 472   }
 473
 474   class { 'neutron::plugins::ml2':
 475     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 476     tenant_network_types => [hiera('neutron_tenant_network_type')],
 477     type_drivers         => [hiera('neutron_tenant_network_type')],
 478   }
 479
 480   class { 'neutron::agents::ml2::ovs':
 481     # manage_service   => $non_pcmk_start,  -- not implemented
 482     enabled          => $non_pcmk_start,
 483     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 484     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 485   }
 486
 487   class { 'neutron::agents::metadata':
 488     manage_service   => $non_pcmk_start,
 489     enabled          => $non_pcmk_start,
 490     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 491   }
 492
 493   Service['neutron-server'] -> Service['neutron-dhcp-service']
 494   Service['neutron-server'] -> Service['neutron-l3']
 495   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 496   Service['neutron-server'] -> Service['neutron-metadata']
 497
 498   include ::cinder
 499   class { '::cinder::api':
 500     sync_db => $sync_db,
 501     manage_service => false,
 502     enabled => false,
 503   }
 504   class { '::cinder::scheduler' :
 505     manage_service => false,
 506     enabled => false,
 507   }
 508   class { '::cinder::volume' :
 509     manage_service => false,
 510     enabled => false,
 511   }
 512   include ::cinder::glance
 513   class {'cinder::setup_test_volume':
 514     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 515   }
 516
 517   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 518   if $cinder_enable_iscsi {
 519     $cinder_iscsi_backend = 'tripleo_iscsi'
 520
 521     cinder::backend::iscsi { $cinder_iscsi_backend :
 522       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 523       iscsi_helper     => hiera('cinder_iscsi_helper'),
 524     }
 525   }
 526
 527   if $enable_ceph {
 528
 529     Ceph_pool {
 530       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 531       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 532       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 533     }
 534
 535     $ceph_pools = hiera('ceph_pools')
 536     ceph::pool { $ceph_pools : }
 537   }
 538
 539   if $cinder_enable_rbd_backend {
 540     $cinder_rbd_backend = 'tripleo_ceph'
 541
 542     cinder_config {
 543       "${cinder_rbd_backend}/host": value => 'hostgroup';
 544     }
 545
 546     cinder::backend::rbd { $cinder_rbd_backend :
 547       rbd_pool        => 'volumes',
 548       rbd_user        => 'openstack',
 549       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 550       require         => Ceph::Pool['volumes'],
 551     }
 552   }
 553
 554   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 555   class { '::cinder::backends' :
 556     enabled_backends => $cinder_enabled_backends,
 557   }
 558
 559   # swift proxy
 560   class { '::swift::proxy' :
 561     manage_service => $non_pcmk_start,
 562     enabled => $non_pcmk_start,
 563   }
 564   include ::swift::proxy::proxy_logging
 565   include ::swift::proxy::healthcheck
 566   include ::swift::proxy::cache
 567   include ::swift::proxy::keystone
 568   include ::swift::proxy::authtoken
 569   include ::swift::proxy::staticweb
 570   include ::swift::proxy::ceilometer
 571   include ::swift::proxy::ratelimit
 572   include ::swift::proxy::catch_errors
 573   include ::swift::proxy::tempurl
 574   include ::swift::proxy::formpost
 575
 576   # swift storage
 577   if str2bool(hiera('enable_swift_storage', 'true')) {
 578     class {'::swift::storage::all':
 579       mount_check => str2bool(hiera('swift_mount_check'))
 580     }
 581     class {'::swift::storage::account':
 582       manage_service => $non_pcmk_start,
 583       enabled => $non_pcmk_start,
 584     }
 585     class {'::swift::storage::container':
 586       manage_service => $non_pcmk_start,
 587       enabled => $non_pcmk_start,
 588     }
 589     class {'::swift::storage::object':
 590       manage_service => $non_pcmk_start,
 591       enabled => $non_pcmk_start,
 592     }
 593     if(!defined(File['/srv/node'])) {
 594       file { '/srv/node':
 595         ensure  => directory,
 596         owner   => 'swift',
 597         group   => 'swift',
 598         require => Package['openstack-swift'],
 599       }
 600     }
 601     $swift_components = ['account', 'container', 'object']
 602     swift::storage::filter::recon { $swift_components : }
 603     swift::storage::filter::healthcheck { $swift_components : }
 604   }
 605
 606   # Ceilometer
 607   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 608   case $ceilometer_backend {
 609     /mysql/ : {
 610       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 611     }
 612     default : {
 613       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 614     }
 615   }
 616   include ::ceilometer
 617   class { '::ceilometer::api' :
 618     manage_service => $non_pcmk_start,
 619     enabled => $non_pcmk_start,
 620   }
 621   class { '::ceilometer::agent::notification' :
 622     manage_service => $non_pcmk_start,
 623     enabled => $non_pcmk_start,
 624   }
 625   class { '::ceilometer::agent::central' :
 626     manage_service => $non_pcmk_start,
 627     enabled => $non_pcmk_start,
 628   }
 629   class { '::ceilometer::alarm::notifier' :
 630     manage_service => $non_pcmk_start,
 631     enabled => $non_pcmk_start,
 632   }
 633   class { '::ceilometer::alarm::evaluator' :
 634     manage_service => $non_pcmk_start,
 635     enabled => $non_pcmk_start,
 636   }
 637   class { '::ceilometer::collector' :
 638     manage_service => $non_pcmk_start,
 639     enabled => $non_pcmk_start,
 640   }
 641   include ::ceilometer::expirer
 642   class { '::ceilometer::db' :
 643     database_connection => $ceilometer_database_connection,
 644     sync_db             => $sync_db,
 645   }
 646   class { 'ceilometer::agent::auth':
 647     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 648   }
 649
 650   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 651
 652   # Heat
 653   class { '::heat' :
 654     sync_db => $sync_db,
 655   }
 656   class { '::heat::api' :
 657     manage_service => $non_pcmk_start,
 658     enabled => $non_pcmk_start,
 659   }
 660   class { '::heat::api_cfn' :
 661     manage_service => $non_pcmk_start,
 662     enabled => $non_pcmk_start,
 663   }
 664   class { '::heat::api_cloudwatch' :
 665     manage_service => $non_pcmk_start,
 666     enabled => $non_pcmk_start,
 667   }
 668   class { '::heat::engine' :
 669     manage_service => $non_pcmk_start,
 670     enabled => $non_pcmk_start,
 671   }
 672
 673   # Horizon
 674   $vhost_params = { add_listen => false }
 675   class { 'horizon':
 676     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 677     vhost_extra_params => $vhost_params,
 678   }
 679
 680   $snmpd_user = hiera('snmpd_readonly_user_name')
 681   snmp::snmpv3_user { $snmpd_user:
 682     authtype => 'MD5',
 683     authpass => hiera('snmpd_readonly_user_password'),
 684   }
 685   class { 'snmp':
 686     agentaddress => ['udp:161','udp6:[::1]:161'],
 687     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 688   }
 689
 690 } #END STEP 3
 691
 692 if hiera('step') >= 4 {
 693   if $pacemaker_master {
 694
 695     # Keystone
 696     pacemaker::resource::service { $::keystone::params::service_name :
 697       clone_params => "interleave=true",
 698     }
 699
 700     # Cinder
 701     pacemaker::resource::service { $::cinder::params::api_service :
 702       clone_params => "interleave=true",
 703       require      => Pacemaker::Resource::Service[$::keystone::params::service_name],
 704     }
 705     pacemaker::resource::service { $::cinder::params::scheduler_service :
 706       clone_params => "interleave=true",
 707     }
 708     pacemaker::resource::service { $::cinder::params::volume_service : }
 709
 710     pacemaker::constraint::base { 'keystone-then-cinder-api-constraint':
 711       constraint_type => 'order',
 712       first_resource  => "${::keystone::params::service_name}-clone",
 713       second_resource => "${::cinder::params::api_service}-clone",
 714       first_action    => 'start',
 715       second_action   => 'start',
 716       require         => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 717                           Pacemaker::Resource::Service[$::keystone::params::service_name]],
 718     }
 719     pacemaker::constraint::base { 'cinder-api-then-cinder-scheduler-constraint':
 720       constraint_type => "order",
 721       first_resource => "${::cinder::params::api_service}-clone",
 722       second_resource => "${::cinder::params::scheduler_service}-clone",
 723       first_action => "start",
 724       second_action => "start",
 725       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 726                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 727     }
 728     pacemaker::constraint::colocation { 'cinder-scheduler-with-cinder-api-colocation':
 729       source => "${::cinder::params::scheduler_service}-clone",
 730       target => "${::cinder::params::api_service}-clone",
 731       score => "INFINITY",
 732       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 733                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 734     }
 735     pacemaker::constraint::base { 'cinder-scheduler-then-cinder-volume-constraint':
 736       constraint_type => "order",
 737       first_resource => "${::cinder::params::scheduler_service}-clone",
 738       second_resource => "${::cinder::params::volume_service}",
 739       first_action => "start",
 740       second_action => "start",
 741       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 742                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 743     }
 744     pacemaker::constraint::colocation { 'cinder-volume-with-cinder-scheduler-colocation':
 745       source => "${::cinder::params::volume_service}",
 746       target => "${::cinder::params::scheduler_service}-clone",
 747       score => "INFINITY",
 748       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 749                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 750     }
 751
 752     # Glance
 753     pacemaker::resource::service { $::glance::params::registry_service_name :
 754       clone_params => "interleave=true",
 755     }
 756     pacemaker::resource::service { $::glance::params::api_service_name :
 757       clone_params => "interleave=true",
 758     }
 759
 760     pacemaker::constraint::base { 'glance-registry-then-glance-api-constraint':
 761       constraint_type => "order",
 762       first_resource  => "${::glance::params::registry_service_name}-clone",
 763       second_resource => "${::glance::params::api_service_name}-clone",
 764       first_action    => "start",
 765       second_action   => "start",
 766       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 767                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 768     }
 769     pacemaker::constraint::colocation { 'glance-registry-with-glance-api-colocation':
 770       source  => "${::glance::params::registry_service_name}-clone",
 771       target  => "${::glance::params::api_service_name}-clone",
 772       score   => "INFINITY",
 773       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 774                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 775     }
 776   }
 777
 778 } #END STEP 4