puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  28   $pacemaker_master = true
  29 } else {
  30   $pacemaker_master = false
  31 }
  32
  33 if hiera('step') >= 1 {
  34
  35   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  36   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  37   class { '::tripleo::loadbalancer' :
  38     controller_hosts       => $controller_node_ips,
  39     controller_hosts_names => $controller_node_names,
  40     manage_vip             => false,
  41     haproxy_service_manage => false,
  42   }
  43
  44   $pacemaker_cluster_members = regsubst(hiera('controller_node_ips'), ',', ' ', 'G')
  45   user { 'hacluster':
  46    ensure => present,
  47   } ->
  48   class { '::pacemaker':
  49     hacluster_pwd => hiera('hacluster_pwd'),
  50   } ->
  51   class { '::pacemaker::corosync':
  52     cluster_members => $pacemaker_cluster_members,
  53     setup_cluster   => $pacemaker_master,
  54   }
  55   class { '::pacemaker::stonith':
  56     disable => true,
  57   }
  58   if $pacemaker_master {
  59     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
  60     pacemaker::resource::ip { 'control_vip':
  61       ip_address => $control_vip,
  62     }
  63     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
  64     pacemaker::resource::ip { 'public_vip':
  65       ip_address => $public_vip,
  66     }
  67     pacemaker::resource::service { 'haproxy':
  68       clone => true,
  69     }
  70   }
  71
  72   Class['::pacemaker::corosync'] -> Pacemaker::Resource::Service <| |>
  73
  74 }
  75
  76 if hiera('step') >= 2 {
  77
  78   if count(hiera('ntp::servers')) > 0 {
  79     include ::ntp
  80   }
  81
  82   # MongoDB
  83   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  84     include ::mongodb::globals
  85
  86     class {'::mongodb::server' :
  87       service_ensure => undef
  88     }
  89     $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
  90     $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
  91     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  92
  93     $mongodb_replset = hiera('mongodb::server::replset')
  94     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  95     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  96
  97       pacemaker::resource::service { 'mongod' :
  98         options => "op start timeout=120s",
  99         clone   => true,
 100         before  => Exec['mongodb-ready'],
 101       }
 102       # NOTE (spredzy) : The replset can only be run
 103       # once all the nodes have joined the cluster.
 104       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 105       exec { 'mongodb-ready' :
 106         command   => $mongodb_cluster_ready_command,
 107         timeout   => 600,
 108         tries     => 60,
 109         try_sleep => 10,
 110         before    => Mongodb_replset[$mongodb_replset],
 111       }
 112
 113       mongodb_replset { $mongodb_replset :
 114         members => $mongo_node_ips_with_port,
 115       }
 116     }
 117   }
 118
 119   # Redis
 120   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 121   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 122
 123   if $redis_master_hostname == $::hostname {
 124     $slaveof = undef
 125   } else {
 126     $slaveof = "${redis_master_hostname} 6379"
 127   }
 128   class {'::redis' :
 129     slaveof => $slaveof,
 130   }
 131
 132   if count($redis_node_ips) > 1 {
 133     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 134     include ::redis::sentinel
 135     class {'::tripleo::redis_notification' :
 136       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 137     }
 138   }
 139
 140   if str2bool(hiera('enable_galera', 'true')) {
 141     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 142   } else {
 143     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 144   }
 145   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 146   $galera_nodes_count = count(split($galera_nodes, ','))
 147   $clustercheck_password = hiera('mysql_clustercheck_password')
 148   $mysql_root_password = hiera('mysql::server::root_password')
 149
 150   $mysqld_options = {
 151     'mysqld' => {
 152       'skip-name-resolve'             => '1',
 153       'binlog_format'                 => 'ROW',
 154       'default-storage-engine'        => 'innodb',
 155       'innodb_autoinc_lock_mode'      => '2',
 156       'innodb_locks_unsafe_for_binlog'=> '1',
 157       'query_cache_size'              => '0',
 158       'query_cache_type'              => '0',
 159       'bind-address'                  => hiera('controller_host'),
 160       'max_connections'               => '1024',
 161       'open_files_limit'              => '-1',
 162       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 163       'wsrep_cluster_name'            => 'galera_cluster',
 164       'wsrep_slave_threads'           => '1',
 165       'wsrep_certify_nonPK'           => '1',
 166       'wsrep_max_ws_rows'             => '131072',
 167       'wsrep_max_ws_size'             => '1073741824',
 168       'wsrep_debug'                   => '0',
 169       'wsrep_convert_LOCK_to_trx'     => '0',
 170       'wsrep_retry_autocommit'        => '1',
 171       'wsrep_auto_increment_control'  => '1',
 172       'wsrep_drupal_282555_workaround'=> '0',
 173       'wsrep_causal_reads'            => '0',
 174       'wsrep_notify_cmd'              => '',
 175       'wsrep_sst_method'              => 'rsync',
 176     }
 177   }
 178
 179   class { '::mysql::server':
 180     create_root_user   => false,
 181     create_root_my_cnf => false,
 182     config_file        => $mysql_config_file,
 183     override_options   => $mysqld_options,
 184     service_manage     => false,
 185   }
 186
 187   if $pacemaker_master {
 188     $sync_db = true
 189
 190     pacemaker::resource::ocf { 'galera' :
 191       resource_name => 'heartbeat:galera',
 192       options       => "enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}' meta master-max=${galera_nodes_count} ordered=true op promote timeout=300s on-fail=block --master",
 193       require       => Class['::mysql::server'],
 194       before        => Exec['galera-ready'],
 195     }
 196
 197     mysql_user { 'clustercheckuser@localhost' :
 198       password_hash => mysql_password($clustercheck_password),
 199       require       => Exec['galera-ready'],
 200     }
 201   } else {
 202     $sync_db = false
 203   }
 204
 205   exec { 'galera-ready' :
 206     command     => '/bin/mysql -e "SHOW GLOBAL VARIABLES LIKE \'read_only\'" | /bin/grep -i off',
 207     timeout     => 3600,
 208     tries       => 60,
 209     try_sleep   => 60,
 210     environment => 'HOME=/root',
 211     require     => Class['::mysql::server'],
 212   }
 213
 214   file { '/etc/sysconfig/clustercheck' :
 215     ensure  => file,
 216     content => "MYSQL_USERNAME=clustercheckuser\n
 217 MYSQL_PASSWORD=${clustercheck_password}\n
 218 MYSQL_HOST=localhost\n",
 219     require       => Exec['galera-ready'],
 220   }
 221
 222   xinetd::service { 'galera-monitor' :
 223     port           => '9200',
 224     server         => '/usr/bin/clustercheck',
 225     per_source     => 'UNLIMITED',
 226     log_on_success => '',
 227     log_on_failure => 'HOST',
 228     flags          => 'REUSE',
 229     service_type   => 'UNLISTED',
 230     user           => 'root',
 231     group          => 'root',
 232     require        => File['/etc/sysconfig/clustercheck'],
 233   }
 234
 235   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 236   # Create all the database schemas
 237   # Example DSN format: mysql://user:password@host/dbname
 238   if $sync_db {
 239     $allowed_hosts = ['%',hiera('controller_host')]
 240     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 241     class { 'keystone::db::mysql':
 242       user          => $keystone_dsn[3],
 243       password      => $keystone_dsn[4],
 244       host          => $keystone_dsn[5],
 245       dbname        => $keystone_dsn[6],
 246       allowed_hosts => $allowed_hosts,
 247       require       => Exec['galera-ready'],
 248     }
 249     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 250     class { 'glance::db::mysql':
 251       user          => $glance_dsn[3],
 252       password      => $glance_dsn[4],
 253       host          => $glance_dsn[5],
 254       dbname        => $glance_dsn[6],
 255       allowed_hosts => $allowed_hosts,
 256       require       => Exec['galera-ready'],
 257     }
 258     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 259     class { 'nova::db::mysql':
 260       user          => $nova_dsn[3],
 261       password      => $nova_dsn[4],
 262       host          => $nova_dsn[5],
 263       dbname        => $nova_dsn[6],
 264       allowed_hosts => $allowed_hosts,
 265       require       => Exec['galera-ready'],
 266     }
 267     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 268     class { 'neutron::db::mysql':
 269       user          => $neutron_dsn[3],
 270       password      => $neutron_dsn[4],
 271       host          => $neutron_dsn[5],
 272       dbname        => $neutron_dsn[6],
 273       allowed_hosts => $allowed_hosts,
 274       require       => Exec['galera-ready'],
 275     }
 276     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 277     class { 'cinder::db::mysql':
 278       user          => $cinder_dsn[3],
 279       password      => $cinder_dsn[4],
 280       host          => $cinder_dsn[5],
 281       dbname        => $cinder_dsn[6],
 282       allowed_hosts => $allowed_hosts,
 283       require       => Exec['galera-ready'],
 284     }
 285     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 286     class { 'heat::db::mysql':
 287       user          => $heat_dsn[3],
 288       password      => $heat_dsn[4],
 289       host          => $heat_dsn[5],
 290       dbname        => $heat_dsn[6],
 291       allowed_hosts => $allowed_hosts,
 292       require       => Exec['galera-ready'],
 293     }
 294     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 295       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 296       class { 'ceilometer::db::mysql':
 297         user          => $ceilometer_dsn[3],
 298         password      => $ceilometer_dsn[4],
 299         host          => $ceilometer_dsn[5],
 300         dbname        => $ceilometer_dsn[6],
 301         allowed_hosts => $allowed_hosts,
 302         require       => Exec['galera-ready'],
 303       }
 304     }
 305   }
 306
 307   # the module ignores erlang_cookie if cluster_config is false
 308   file { '/var/lib/rabbitmq/.erlang.cookie':
 309     ensure  => 'present',
 310     owner   => 'rabbitmq',
 311     group   => 'rabbitmq',
 312     mode    => '0400',
 313     content => hiera('rabbitmq::erlang_cookie'),
 314     replace => true,
 315   } ->
 316   class { '::rabbitmq':
 317     service_manage          => false,
 318     tcp_keepalive           => false,
 319     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 320     config_variables        => hiera('rabbitmq_config_variables'),
 321     environment_variables   => hiera('rabbitmq_environment'),
 322   }
 323   if $pacemaker_master {
 324     pacemaker::resource::ocf { 'rabbitmq':
 325       resource_name => 'heartbeat:rabbitmq-cluster',
 326       options       => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 327       clone         => true,
 328       require       => Class['::rabbitmq'],
 329     }
 330   }
 331
 332   # pre-install swift here so we can build rings
 333   include ::swift
 334
 335   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 336   $enable_ceph = $cinder_enable_rbd_backend
 337
 338   if $enable_ceph {
 339     class { 'ceph::profile::params':
 340       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 341     }
 342     include ::ceph::profile::mon
 343   }
 344
 345   if str2bool(hiera('enable_ceph_storage', 'false')) {
 346     include ::ceph::profile::client
 347     include ::ceph::profile::osd
 348   }
 349
 350 } #END STEP 2
 351
 352 if (hiera('step') >= 3 and $::hostname == downcase(hiera('bootstrap_nodeid')))
 353    or hiera('step') >= 4 {
 354
 355   include ::keystone
 356
 357   #TODO: need a cleanup-keystone-tokens.sh solution here
 358   keystone_config {
 359     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 360   }
 361   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 362     ensure  => 'directory',
 363     owner   => 'keystone',
 364     group   => 'keystone',
 365     require => Package['keystone'],
 366   }
 367   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 368     content => hiera('keystone_signing_certificate'),
 369     owner   => 'keystone',
 370     group   => 'keystone',
 371     notify  => Service['keystone'],
 372     require => File['/etc/keystone/ssl/certs'],
 373   }
 374   file { '/etc/keystone/ssl/private/signing_key.pem':
 375     content => hiera('keystone_signing_key'),
 376     owner   => 'keystone',
 377     group   => 'keystone',
 378     notify  => Service['keystone'],
 379     require => File['/etc/keystone/ssl/private'],
 380   }
 381   file { '/etc/keystone/ssl/certs/ca.pem':
 382     content => hiera('keystone_ca_certificate'),
 383     owner   => 'keystone',
 384     group   => 'keystone',
 385     notify  => Service['keystone'],
 386     require => File['/etc/keystone/ssl/certs'],
 387   }
 388
 389   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 390   case $glance_backend {
 391       swift: { $glance_store = 'glance.store.swift.Store' }
 392       file: { $glance_store = 'glance.store.filesystem.Store' }
 393       rbd: { $glance_store = 'glance.store.rbd.Store' }
 394       default: { fail('Unrecognized glance_backend parameter.') }
 395   }
 396
 397   # TODO: notifications, scrubber, etc.
 398   include ::glance
 399   class { 'glance::api':
 400     known_stores => [$glance_store]
 401   }
 402   class { '::glance::registry' :
 403     sync_db => $sync_db,
 404   }
 405   include join(['::glance::backend::', $glance_backend])
 406
 407   class { 'nova':
 408     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 409   }
 410
 411   class { '::nova::api' :
 412     sync_db => $sync_db,
 413   }
 414   include ::nova::cert
 415   include ::nova::conductor
 416   include ::nova::consoleauth
 417   include ::nova::network::neutron
 418   include ::nova::vncproxy
 419   include ::nova::scheduler
 420
 421   include ::neutron
 422   class { '::neutron::server' :
 423     sync_db => $sync_db,
 424   }
 425   include ::neutron::agents::dhcp
 426   include ::neutron::agents::l3
 427
 428   file { '/etc/neutron/dnsmasq-neutron.conf':
 429     content => hiera('neutron_dnsmasq_options'),
 430     owner   => 'neutron',
 431     group   => 'neutron',
 432     notify  => Service['neutron-dhcp-service'],
 433     require => Package['neutron'],
 434   }
 435
 436   class { 'neutron::plugins::ml2':
 437     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 438     tenant_network_types => [hiera('neutron_tenant_network_type')],
 439     type_drivers         => [hiera('neutron_tenant_network_type')],
 440   }
 441
 442   class { 'neutron::agents::ml2::ovs':
 443     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 444     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 445   }
 446
 447   class { 'neutron::agents::metadata':
 448     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 449   }
 450
 451   Service['neutron-server'] -> Service['neutron-dhcp-service']
 452   Service['neutron-server'] -> Service['neutron-l3']
 453   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 454   Service['neutron-server'] -> Service['neutron-metadata']
 455
 456   include ::cinder
 457   include ::cinder::api
 458   include ::cinder::glance
 459   include ::cinder::scheduler
 460   include ::cinder::volume
 461   class {'cinder::setup_test_volume':
 462     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 463   }
 464
 465   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 466   if $cinder_enable_iscsi {
 467     $cinder_iscsi_backend = 'tripleo_iscsi'
 468
 469     cinder::backend::iscsi { $cinder_iscsi_backend :
 470       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 471       iscsi_helper     => hiera('cinder_iscsi_helper'),
 472     }
 473   }
 474
 475   if $enable_ceph {
 476
 477     Ceph_pool {
 478       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 479       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 480       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 481     }
 482
 483     $ceph_pools = hiera('ceph_pools')
 484     ceph::pool { $ceph_pools : }
 485   }
 486
 487   if $cinder_enable_rbd_backend {
 488     $cinder_rbd_backend = 'tripleo_ceph'
 489
 490     cinder_config {
 491       "${cinder_rbd_backend}/host": value => 'hostgroup';
 492     }
 493
 494     cinder::backend::rbd { $cinder_rbd_backend :
 495       rbd_pool        => 'volumes',
 496       rbd_user        => 'openstack',
 497       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 498       require         => Ceph::Pool['volumes'],
 499     }
 500   }
 501
 502   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 503   class { '::cinder::backends' :
 504     enabled_backends => $cinder_enabled_backends,
 505   }
 506
 507   # swift proxy
 508   include ::memcached
 509   include ::swift::proxy
 510   include ::swift::proxy::proxy_logging
 511   include ::swift::proxy::healthcheck
 512   include ::swift::proxy::cache
 513   include ::swift::proxy::keystone
 514   include ::swift::proxy::authtoken
 515   include ::swift::proxy::staticweb
 516   include ::swift::proxy::ceilometer
 517   include ::swift::proxy::ratelimit
 518   include ::swift::proxy::catch_errors
 519   include ::swift::proxy::tempurl
 520   include ::swift::proxy::formpost
 521
 522   # swift storage
 523   if str2bool(hiera('enable_swift_storage', 'true')) {
 524     class {'swift::storage::all':
 525       mount_check => str2bool(hiera('swift_mount_check'))
 526     }
 527     if(!defined(File['/srv/node'])) {
 528       file { '/srv/node':
 529         ensure  => directory,
 530         owner   => 'swift',
 531         group   => 'swift',
 532         require => Package['openstack-swift'],
 533       }
 534     }
 535     $swift_components = ['account', 'container', 'object']
 536     swift::storage::filter::recon { $swift_components : }
 537     swift::storage::filter::healthcheck { $swift_components : }
 538   }
 539
 540   # Ceilometer
 541   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 542   case $ceilometer_backend {
 543     /mysql/ : {
 544       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 545     }
 546     default : {
 547       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 548     }
 549   }
 550   include ::ceilometer
 551   include ::ceilometer::api
 552   include ::ceilometer::agent::notification
 553   include ::ceilometer::agent::central
 554   include ::ceilometer::alarm::notifier
 555   include ::ceilometer::alarm::evaluator
 556   include ::ceilometer::expirer
 557   include ::ceilometer::collector
 558   class { '::ceilometer::db' :
 559     database_connection => $ceilometer_database_connection,
 560     sync_db             => $sync_db,
 561   }
 562   class { 'ceilometer::agent::auth':
 563     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 564   }
 565
 566   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 567
 568   # Heat
 569   class { '::heat' :
 570     sync_db => $sync_db,
 571   }
 572   include ::heat::api
 573   include ::heat::api_cfn
 574   include ::heat::api_cloudwatch
 575   include ::heat::engine
 576
 577   # Horizon
 578   $vhost_params = { add_listen => false }
 579   class { 'horizon':
 580     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 581     vhost_extra_params => $vhost_params,
 582   }
 583
 584   $snmpd_user = hiera('snmpd_readonly_user_name')
 585   snmp::snmpv3_user { $snmpd_user:
 586     authtype => 'MD5',
 587     authpass => hiera('snmpd_readonly_user_password'),
 588   }
 589   class { 'snmp':
 590     agentaddress => ['udp:161','udp6:[::1]:161'],
 591     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 592   }
 593
 594 } #END STEP 3