puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 if !str2bool(hiera('enable_package_install', 'false')) {
  22   case $::osfamily {
  23     'RedHat': {
  24       Package { provider => 'norpm' } # provided by tripleo-puppet
  25     }
  26     default: {
  27       warning('enable_package_install option not supported.')
  28     }
  29   }
  30 }
  31
  32 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  33   $pacemaker_master = true
  34   $sync_db = true
  35 } else {
  36   $pacemaker_master = false
  37   $sync_db = false
  38 }
  39
  40 # When to start and enable services which haven't been Pacemakerized
  41 # FIXME: remove when we start all OpenStack services using Pacemaker
  42 # (occurences of this variable will be gradually replaced with false)
  43 $non_pcmk_start = hiera('step') >= 4
  44
  45 if hiera('step') >= 1 {
  46
  47   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  48
  49   if count(hiera('ntp::servers')) > 0 {
  50     include ::ntp
  51   }
  52
  53   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  54   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  55   class { '::tripleo::loadbalancer' :
  56     controller_hosts       => $controller_node_ips,
  57     controller_hosts_names => $controller_node_names,
  58     manage_vip             => false,
  59     haproxy_service_manage => false,
  60   }
  61
  62   $pacemaker_cluster_members = downcase(regsubst(hiera('controller_node_names'), ',', ' ', 'G'))
  63   user { 'hacluster':
  64    ensure => present,
  65   } ->
  66   class { '::pacemaker':
  67     hacluster_pwd => hiera('hacluster_pwd'),
  68   } ->
  69   class { '::pacemaker::corosync':
  70     cluster_members => $pacemaker_cluster_members,
  71     setup_cluster   => $pacemaker_master,
  72   }
  73   class { '::pacemaker::stonith':
  74     disable => true,
  75   }
  76
  77   # Only configure RabbitMQ in this step, don't start it yet to
  78   # avoid races where non-master nodes attempt to start without
  79   # config (eg. binding on 0.0.0.0)
  80   # The module ignores erlang_cookie if cluster_config is false
  81   class { '::rabbitmq':
  82     service_manage          => false,
  83     tcp_keepalive           => false,
  84     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
  85     config_variables        => hiera('rabbitmq_config_variables'),
  86     environment_variables   => hiera('rabbitmq_environment'),
  87   } ->
  88   file { '/var/lib/rabbitmq/.erlang.cookie':
  89     ensure  => 'present',
  90     owner   => 'rabbitmq',
  91     group   => 'rabbitmq',
  92     mode    => '0400',
  93     content => hiera('rabbitmq::erlang_cookie'),
  94     replace => true,
  95   }
  96
  97   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  98     include ::mongodb::globals
  99     # FIXME: replace with service_manage => false on ::mongodb::server
 100     # when this is merged: https://github.com/puppetlabs/pupp etlabs-mongodb/pull/198
 101     class { '::mongodb::server' :
 102       service_ensure => undef,
 103       service_enable => false,
 104     }
 105   }
 106
 107   # Memcached
 108   class {'::memcached' :
 109     service_manage => false,
 110   }
 111
 112   # Galera
 113   if str2bool(hiera('enable_galera', 'true')) {
 114     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 115   } else {
 116     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 117   }
 118   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 119   $galera_nodes_count = count(split($galera_nodes, ','))
 120
 121   $mysqld_options = {
 122     'mysqld' => {
 123       'skip-name-resolve'             => '1',
 124       'binlog_format'                 => 'ROW',
 125       'default-storage-engine'        => 'innodb',
 126       'innodb_autoinc_lock_mode'      => '2',
 127       'innodb_locks_unsafe_for_binlog'=> '1',
 128       'query_cache_size'              => '0',
 129       'query_cache_type'              => '0',
 130       'bind-address'                  => hiera('controller_host'),
 131       'max_connections'               => '1024',
 132       'open_files_limit'              => '-1',
 133       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 134       'wsrep_cluster_name'            => 'galera_cluster',
 135       'wsrep_slave_threads'           => '1',
 136       'wsrep_certify_nonPK'           => '1',
 137       'wsrep_max_ws_rows'             => '131072',
 138       'wsrep_max_ws_size'             => '1073741824',
 139       'wsrep_debug'                   => '0',
 140       'wsrep_convert_LOCK_to_trx'     => '0',
 141       'wsrep_retry_autocommit'        => '1',
 142       'wsrep_auto_increment_control'  => '1',
 143       'wsrep_drupal_282555_workaround'=> '0',
 144       'wsrep_causal_reads'            => '0',
 145       'wsrep_notify_cmd'              => '',
 146       'wsrep_sst_method'              => 'rsync',
 147     }
 148   }
 149
 150   class { '::mysql::server':
 151     create_root_user   => false,
 152     create_root_my_cnf => false,
 153     config_file        => $mysql_config_file,
 154     override_options   => $mysqld_options,
 155     service_manage     => false,
 156   }
 157
 158 }
 159
 160 if hiera('step') >= 2 {
 161
 162   if $pacemaker_master {
 163     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
 164     pacemaker::resource::ip { 'control_vip':
 165       ip_address => $control_vip,
 166     }
 167     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
 168     pacemaker::resource::ip { 'public_vip':
 169       ip_address => $public_vip,
 170     }
 171     pacemaker::resource::service { 'haproxy':
 172       clone_params => true,
 173     }
 174     pacemaker::resource::service { $::memcached::params::service_name :
 175       clone_params => true,
 176       require      => Class['::memcached'],
 177     }
 178
 179     pacemaker::resource::ocf { 'rabbitmq':
 180       ocf_agent_name  => 'heartbeat:rabbitmq-cluster',
 181       resource_params => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 182       clone_params    => 'ordered=true interleave=true',
 183       require         => Class['::rabbitmq'],
 184     }
 185
 186     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 187       pacemaker::resource::service { $::mongodb::params::service_name :
 188         op_params    => 'start timeout=120s',
 189         clone_params => true,
 190         require      => Class['::mongodb::server'],
 191         before       => Exec['mongodb-ready'],
 192       }
 193       # NOTE (spredzy) : The replset can only be run
 194       # once all the nodes have joined the cluster.
 195       $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
 196       $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
 197       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 198       $mongodb_replset = hiera('mongodb::server::replset')
 199       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 200       exec { 'mongodb-ready' :
 201         command   => $mongodb_cluster_ready_command,
 202         timeout   => 30,
 203         tries     => 180,
 204         try_sleep => 10,
 205       }
 206       mongodb_replset { $mongodb_replset :
 207         members => $mongo_node_ips_with_port,
 208         require => Exec['mongodb-ready'],
 209       }
 210     }
 211
 212     pacemaker::resource::ocf { 'galera' :
 213       ocf_agent_name  => 'heartbeat:galera',
 214       op_params       => 'promote timeout=300s on-fail=block --master',
 215       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 216       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 217       require         => Class['::mysql::server'],
 218       before          => Exec['galera-ready'],
 219     }
 220   }
 221
 222   # Redis
 223   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 224   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 225
 226   if $redis_master_hostname == $::hostname {
 227     $slaveof = undef
 228   } else {
 229     $slaveof = "${redis_master_hostname} 6379"
 230   }
 231   class {'::redis' :
 232     slaveof => $slaveof,
 233   }
 234
 235   if count($redis_node_ips) > 1 {
 236     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 237     include ::redis::sentinel
 238     class {'::tripleo::redis_notification' :
 239       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 240     }
 241   }
 242
 243   exec { 'galera-ready' :
 244     command     => '/usr/bin/clustercheck >/dev/null',
 245     timeout     => 30,
 246     tries       => 180,
 247     try_sleep   => 10,
 248     environment => ["AVAILABLE_WHEN_READONLY=0"],
 249     require     => File['/etc/sysconfig/clustercheck'],
 250   }
 251
 252   file { '/etc/sysconfig/clustercheck' :
 253     ensure  => file,
 254     content => "MYSQL_USERNAME=root\n
 255 MYSQL_PASSWORD=''\n
 256 MYSQL_HOST=localhost\n",
 257   }
 258
 259   xinetd::service { 'galera-monitor' :
 260     port           => '9200',
 261     server         => '/usr/bin/clustercheck',
 262     per_source     => 'UNLIMITED',
 263     log_on_success => '',
 264     log_on_failure => 'HOST',
 265     flags          => 'REUSE',
 266     service_type   => 'UNLISTED',
 267     user           => 'root',
 268     group          => 'root',
 269     require        => File['/etc/sysconfig/clustercheck'],
 270   }
 271
 272   # Create all the database schemas
 273   # Example DSN format: mysql://user:password@host/dbname
 274   if $sync_db {
 275     $allowed_hosts = ['%',hiera('controller_host')]
 276     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 277     class { 'keystone::db::mysql':
 278       user          => $keystone_dsn[3],
 279       password      => $keystone_dsn[4],
 280       host          => $keystone_dsn[5],
 281       dbname        => $keystone_dsn[6],
 282       allowed_hosts => $allowed_hosts,
 283       require       => Exec['galera-ready'],
 284     }
 285     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 286     class { 'glance::db::mysql':
 287       user          => $glance_dsn[3],
 288       password      => $glance_dsn[4],
 289       host          => $glance_dsn[5],
 290       dbname        => $glance_dsn[6],
 291       allowed_hosts => $allowed_hosts,
 292       require       => Exec['galera-ready'],
 293     }
 294     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 295     class { 'nova::db::mysql':
 296       user          => $nova_dsn[3],
 297       password      => $nova_dsn[4],
 298       host          => $nova_dsn[5],
 299       dbname        => $nova_dsn[6],
 300       allowed_hosts => $allowed_hosts,
 301       require       => Exec['galera-ready'],
 302     }
 303     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 304     class { 'neutron::db::mysql':
 305       user          => $neutron_dsn[3],
 306       password      => $neutron_dsn[4],
 307       host          => $neutron_dsn[5],
 308       dbname        => $neutron_dsn[6],
 309       allowed_hosts => $allowed_hosts,
 310       require       => Exec['galera-ready'],
 311     }
 312     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 313     class { 'cinder::db::mysql':
 314       user          => $cinder_dsn[3],
 315       password      => $cinder_dsn[4],
 316       host          => $cinder_dsn[5],
 317       dbname        => $cinder_dsn[6],
 318       allowed_hosts => $allowed_hosts,
 319       require       => Exec['galera-ready'],
 320     }
 321     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 322     class { 'heat::db::mysql':
 323       user          => $heat_dsn[3],
 324       password      => $heat_dsn[4],
 325       host          => $heat_dsn[5],
 326       dbname        => $heat_dsn[6],
 327       allowed_hosts => $allowed_hosts,
 328       require       => Exec['galera-ready'],
 329     }
 330     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 331       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 332       class { 'ceilometer::db::mysql':
 333         user          => $ceilometer_dsn[3],
 334         password      => $ceilometer_dsn[4],
 335         host          => $ceilometer_dsn[5],
 336         dbname        => $ceilometer_dsn[6],
 337         allowed_hosts => $allowed_hosts,
 338         require       => Exec['galera-ready'],
 339       }
 340     }
 341   }
 342
 343   # pre-install swift here so we can build rings
 344   include ::swift
 345
 346   # Ceph
 347   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 348   $enable_ceph = $cinder_enable_rbd_backend
 349
 350   if $enable_ceph {
 351     class { 'ceph::profile::params':
 352       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 353     }
 354     include ::ceph::profile::mon
 355   }
 356
 357   if str2bool(hiera('enable_ceph_storage', 'false')) {
 358     include ::ceph::profile::client
 359     include ::ceph::profile::osd
 360   }
 361
 362
 363 } #END STEP 2
 364
 365 if hiera('step') >= 3 {
 366
 367   class { '::keystone':
 368     sync_db => $sync_db,
 369     manage_service => false,
 370     enabled => false,
 371   }
 372
 373   #TODO: need a cleanup-keystone-tokens.sh solution here
 374   keystone_config {
 375     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 376   }
 377   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 378     ensure  => 'directory',
 379     owner   => 'keystone',
 380     group   => 'keystone',
 381     require => Package['keystone'],
 382   }
 383   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 384     content => hiera('keystone_signing_certificate'),
 385     owner   => 'keystone',
 386     group   => 'keystone',
 387     notify  => Service['keystone'],
 388     require => File['/etc/keystone/ssl/certs'],
 389   }
 390   file { '/etc/keystone/ssl/private/signing_key.pem':
 391     content => hiera('keystone_signing_key'),
 392     owner   => 'keystone',
 393     group   => 'keystone',
 394     notify  => Service['keystone'],
 395     require => File['/etc/keystone/ssl/private'],
 396   }
 397   file { '/etc/keystone/ssl/certs/ca.pem':
 398     content => hiera('keystone_ca_certificate'),
 399     owner   => 'keystone',
 400     group   => 'keystone',
 401     notify  => Service['keystone'],
 402     require => File['/etc/keystone/ssl/certs'],
 403   }
 404
 405   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 406   case $glance_backend {
 407       swift: { $glance_store = 'glance.store.swift.Store' }
 408       file: { $glance_store = 'glance.store.filesystem.Store' }
 409       rbd: { $glance_store = 'glance.store.rbd.Store' }
 410       default: { fail('Unrecognized glance_backend parameter.') }
 411   }
 412
 413   # TODO: notifications, scrubber, etc.
 414   include ::glance
 415   class { 'glance::api':
 416     known_stores => [$glance_store],
 417     manage_service => false,
 418     enabled => false,
 419   }
 420   class { '::glance::registry' :
 421     sync_db => $sync_db,
 422     manage_service => false,
 423     enabled => false,
 424   }
 425   include join(['::glance::backend::', $glance_backend])
 426
 427   class { 'nova':
 428     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 429   }
 430
 431   class { '::nova::api' :
 432     sync_db => $sync_db,
 433     manage_service => $non_pcmk_start,
 434     enabled => $non_pcmk_start,
 435   }
 436   class { '::nova::cert' :
 437     manage_service => $non_pcmk_start,
 438     enabled => $non_pcmk_start,
 439   }
 440   class { '::nova::conductor' :
 441     manage_service => $non_pcmk_start,
 442     enabled => $non_pcmk_start,
 443   }
 444   class { '::nova::consoleauth' :
 445     manage_service => $non_pcmk_start,
 446     enabled => $non_pcmk_start,
 447   }
 448   class { '::nova::vncproxy' :
 449     manage_service => $non_pcmk_start,
 450     enabled => $non_pcmk_start,
 451   }
 452   class { '::nova::scheduler' :
 453     manage_service => $non_pcmk_start,
 454     enabled => $non_pcmk_start,
 455   }
 456   include ::nova::network::neutron
 457
 458   include ::neutron
 459   class { '::neutron::server' :
 460     sync_db => $sync_db,
 461     manage_service => $non_pcmk_start,
 462     enabled => $non_pcmk_start,
 463   }
 464   class { '::neutron::agents::dhcp' :
 465     manage_service => $non_pcmk_start,
 466     enabled => $non_pcmk_start,
 467   }
 468   class { '::neutron::agents::l3' :
 469     manage_service => $non_pcmk_start,
 470     enabled => $non_pcmk_start,
 471   }
 472
 473   file { '/etc/neutron/dnsmasq-neutron.conf':
 474     content => hiera('neutron_dnsmasq_options'),
 475     owner   => 'neutron',
 476     group   => 'neutron',
 477     notify  => Service['neutron-dhcp-service'],
 478     require => Package['neutron'],
 479   }
 480
 481   class { 'neutron::plugins::ml2':
 482     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 483     tenant_network_types => [hiera('neutron_tenant_network_type')],
 484     type_drivers         => [hiera('neutron_tenant_network_type')],
 485   }
 486
 487   class { 'neutron::agents::ml2::ovs':
 488     # manage_service   => $non_pcmk_start,  -- not implemented
 489     enabled          => $non_pcmk_start,
 490     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 491     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 492   }
 493
 494   class { 'neutron::agents::metadata':
 495     manage_service   => $non_pcmk_start,
 496     enabled          => $non_pcmk_start,
 497     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 498   }
 499
 500   Service['neutron-server'] -> Service['neutron-dhcp-service']
 501   Service['neutron-server'] -> Service['neutron-l3']
 502   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 503   Service['neutron-server'] -> Service['neutron-metadata']
 504
 505   include ::cinder
 506   class { '::cinder::api':
 507     sync_db => $sync_db,
 508     manage_service => false,
 509     enabled => false,
 510   }
 511   class { '::cinder::scheduler' :
 512     manage_service => false,
 513     enabled => false,
 514   }
 515   class { '::cinder::volume' :
 516     manage_service => false,
 517     enabled => false,
 518   }
 519   include ::cinder::glance
 520   class {'cinder::setup_test_volume':
 521     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 522   }
 523
 524   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 525   if $cinder_enable_iscsi {
 526     $cinder_iscsi_backend = 'tripleo_iscsi'
 527
 528     cinder::backend::iscsi { $cinder_iscsi_backend :
 529       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 530       iscsi_helper     => hiera('cinder_iscsi_helper'),
 531     }
 532   }
 533
 534   if $enable_ceph {
 535
 536     Ceph_pool {
 537       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 538       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 539       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 540     }
 541
 542     $ceph_pools = hiera('ceph_pools')
 543     ceph::pool { $ceph_pools : }
 544   }
 545
 546   if $cinder_enable_rbd_backend {
 547     $cinder_rbd_backend = 'tripleo_ceph'
 548
 549     cinder_config {
 550       "${cinder_rbd_backend}/host": value => 'hostgroup';
 551     }
 552
 553     cinder::backend::rbd { $cinder_rbd_backend :
 554       rbd_pool        => 'volumes',
 555       rbd_user        => 'openstack',
 556       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 557       require         => Ceph::Pool['volumes'],
 558     }
 559   }
 560
 561   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 562   class { '::cinder::backends' :
 563     enabled_backends => $cinder_enabled_backends,
 564   }
 565
 566   # swift proxy
 567   class { '::swift::proxy' :
 568     manage_service => $non_pcmk_start,
 569     enabled => $non_pcmk_start,
 570   }
 571   include ::swift::proxy::proxy_logging
 572   include ::swift::proxy::healthcheck
 573   include ::swift::proxy::cache
 574   include ::swift::proxy::keystone
 575   include ::swift::proxy::authtoken
 576   include ::swift::proxy::staticweb
 577   include ::swift::proxy::ceilometer
 578   include ::swift::proxy::ratelimit
 579   include ::swift::proxy::catch_errors
 580   include ::swift::proxy::tempurl
 581   include ::swift::proxy::formpost
 582
 583   # swift storage
 584   if str2bool(hiera('enable_swift_storage', 'true')) {
 585     class {'::swift::storage::all':
 586       mount_check => str2bool(hiera('swift_mount_check'))
 587     }
 588     class {'::swift::storage::account':
 589       manage_service => $non_pcmk_start,
 590       enabled => $non_pcmk_start,
 591     }
 592     class {'::swift::storage::container':
 593       manage_service => $non_pcmk_start,
 594       enabled => $non_pcmk_start,
 595     }
 596     class {'::swift::storage::object':
 597       manage_service => $non_pcmk_start,
 598       enabled => $non_pcmk_start,
 599     }
 600     if(!defined(File['/srv/node'])) {
 601       file { '/srv/node':
 602         ensure  => directory,
 603         owner   => 'swift',
 604         group   => 'swift',
 605         require => Package['openstack-swift'],
 606       }
 607     }
 608     $swift_components = ['account', 'container', 'object']
 609     swift::storage::filter::recon { $swift_components : }
 610     swift::storage::filter::healthcheck { $swift_components : }
 611   }
 612
 613   # Ceilometer
 614   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 615   case $ceilometer_backend {
 616     /mysql/ : {
 617       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 618     }
 619     default : {
 620       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 621     }
 622   }
 623   include ::ceilometer
 624   class { '::ceilometer::api' :
 625     manage_service => $non_pcmk_start,
 626     enabled => $non_pcmk_start,
 627   }
 628   class { '::ceilometer::agent::notification' :
 629     manage_service => $non_pcmk_start,
 630     enabled => $non_pcmk_start,
 631   }
 632   class { '::ceilometer::agent::central' :
 633     manage_service => $non_pcmk_start,
 634     enabled => $non_pcmk_start,
 635   }
 636   class { '::ceilometer::alarm::notifier' :
 637     manage_service => $non_pcmk_start,
 638     enabled => $non_pcmk_start,
 639   }
 640   class { '::ceilometer::alarm::evaluator' :
 641     manage_service => $non_pcmk_start,
 642     enabled => $non_pcmk_start,
 643   }
 644   class { '::ceilometer::collector' :
 645     manage_service => $non_pcmk_start,
 646     enabled => $non_pcmk_start,
 647   }
 648   include ::ceilometer::expirer
 649   class { '::ceilometer::db' :
 650     database_connection => $ceilometer_database_connection,
 651     sync_db             => $sync_db,
 652   }
 653   class { 'ceilometer::agent::auth':
 654     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 655   }
 656
 657   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 658
 659   # Heat
 660   class { '::heat' :
 661     sync_db => $sync_db,
 662   }
 663   class { '::heat::api' :
 664     manage_service => $non_pcmk_start,
 665     enabled => $non_pcmk_start,
 666   }
 667   class { '::heat::api_cfn' :
 668     manage_service => $non_pcmk_start,
 669     enabled => $non_pcmk_start,
 670   }
 671   class { '::heat::api_cloudwatch' :
 672     manage_service => $non_pcmk_start,
 673     enabled => $non_pcmk_start,
 674   }
 675   class { '::heat::engine' :
 676     manage_service => $non_pcmk_start,
 677     enabled => $non_pcmk_start,
 678   }
 679
 680   # Horizon
 681   $vhost_params = { add_listen => false }
 682   class { 'horizon':
 683     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 684     vhost_extra_params => $vhost_params,
 685   }
 686
 687   $snmpd_user = hiera('snmpd_readonly_user_name')
 688   snmp::snmpv3_user { $snmpd_user:
 689     authtype => 'MD5',
 690     authpass => hiera('snmpd_readonly_user_password'),
 691   }
 692   class { 'snmp':
 693     agentaddress => ['udp:161','udp6:[::1]:161'],
 694     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 695   }
 696
 697 } #END STEP 3
 698
 699 if hiera('step') >= 4 {
 700   if $pacemaker_master {
 701
 702     # Keystone
 703     pacemaker::resource::service { $::keystone::params::service_name :
 704       clone_params => "interleave=true",
 705     }
 706
 707     # Cinder
 708     pacemaker::resource::service { $::cinder::params::api_service :
 709       clone_params => "interleave=true",
 710     }
 711     pacemaker::resource::service { $::cinder::params::scheduler_service :
 712       clone_params => "interleave=true",
 713     }
 714     pacemaker::resource::service { $::cinder::params::volume_service : }
 715
 716     pacemaker::constraint::base { 'cinder-api-then-cinder-scheduler-constraint':
 717       constraint_type => "order",
 718       first_resource => "${::cinder::params::api_service}-clone",
 719       second_resource => "${::cinder::params::scheduler_service}-clone",
 720       first_action => "start",
 721       second_action => "start",
 722       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 723                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 724     }
 725     pacemaker::constraint::colocation { 'cinder-scheduler-with-cinder-api-colocation':
 726       source => "${::cinder::params::scheduler_service}-clone",
 727       target => "${::cinder::params::api_service}-clone",
 728       score => "INFINITY",
 729       require => [Pacemaker::Resource::Service[$::cinder::params::api_service],
 730                   Pacemaker::Resource::Service[$::cinder::params::scheduler_service]],
 731     }
 732     pacemaker::constraint::base { 'cinder-scheduler-then-cinder-volume-constraint':
 733       constraint_type => "order",
 734       first_resource => "${::cinder::params::scheduler_service}-clone",
 735       second_resource => "${::cinder::params::volume_service}",
 736       first_action => "start",
 737       second_action => "start",
 738       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 739                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 740     }
 741     pacemaker::constraint::colocation { 'cinder-volume-with-cinder-scheduler-colocation':
 742       source => "${::cinder::params::volume_service}",
 743       target => "${::cinder::params::scheduler_service}-clone",
 744       score => "INFINITY",
 745       require => [Pacemaker::Resource::Service[$::cinder::params::scheduler_service],
 746                   Pacemaker::Resource::Service[$::cinder::params::volume_service]],
 747     }
 748
 749     # Glance
 750     pacemaker::resource::service { $::glance::params::registry_service_name :
 751       clone_params => "interleave=true",
 752     }
 753     pacemaker::resource::service { $::glance::params::api_service_name :
 754       clone_params => "interleave=true",
 755     }
 756
 757     pacemaker::constraint::base { 'glance-registry-then-glance-api-constraint':
 758       constraint_type => "order",
 759       first_resource  => "${::glance::params::registry_service_name}-clone",
 760       second_resource => "${::glance::params::api_service_name}-clone",
 761       first_action    => "start",
 762       second_action   => "start",
 763       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 764                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 765     }
 766     pacemaker::constraint::colocation { 'glance-registry-with-glance-api-colocation':
 767       source  => "${::glance::params::registry_service_name}-clone",
 768       target  => "${::glance::params::api_service_name}-clone",
 769       score   => "INFINITY",
 770       require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
 771                   Pacemaker::Resource::Service[$::glance::params::api_service_name]],
 772     }
 773   }
 774
 775 } #END STEP 4