puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 # TODO(jistr): use pcs resource provider instead of just no-ops
  22 Service <|
  23   tag == 'aodh-service' or
  24   tag == 'ceilometer-service' or
  25   tag == 'gnocchi-service' or
  26   tag == 'neutron-service' or
  27   tag == 'nova-service'
  28 |> {
  29   hasrestart => true,
  30   restart    => '/bin/true',
  31   start      => '/bin/true',
  32   stop       => '/bin/true',
  33 }
  34
  35 include ::tripleo::packages
  36 include ::tripleo::firewall
  37
  38 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  39   $pacemaker_master = true
  40   $sync_db = true
  41 } else {
  42   $pacemaker_master = false
  43   $sync_db = false
  44 }
  45
  46 $enable_fencing = str2bool(hiera('enable_fencing', false)) and hiera('step') >= 5
  47 $enable_load_balancer = hiera('enable_load_balancer', true)
  48
  49 # When to start and enable services which haven't been Pacemakerized
  50 # FIXME: remove when we start all OpenStack services using Pacemaker
  51 # (occurrences of this variable will be gradually replaced with false)
  52 $non_pcmk_start = hiera('step') >= 5
  53
  54 if hiera('step') >= 1 {
  55
  56   create_resources(kmod::load, hiera('kernel_modules'), {})
  57   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  58   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  59
  60   include ::timezone
  61
  62   if count(hiera('ntp::servers')) > 0 {
  63     include ::ntp
  64   }
  65
  66   $pacemaker_cluster_members = downcase(regsubst(hiera('controller_node_names'), ',', ' ', 'G'))
  67   $corosync_ipv6 = str2bool(hiera('corosync_ipv6', false))
  68   if $corosync_ipv6 {
  69     $cluster_setup_extras = { '--token' => hiera('corosync_token_timeout', 1000), '--ipv6' => '' }
  70   } else {
  71     $cluster_setup_extras = { '--token' => hiera('corosync_token_timeout', 1000) }
  72   }
  73   class { '::pacemaker':
  74     hacluster_pwd => hiera('hacluster_pwd'),
  75   } ->
  76   class { '::pacemaker::corosync':
  77     cluster_members      => $pacemaker_cluster_members,
  78     setup_cluster        => $pacemaker_master,
  79     cluster_setup_extras => $cluster_setup_extras,
  80   }
  81   class { '::pacemaker::stonith':
  82     disable => !$enable_fencing,
  83   }
  84   if $enable_fencing {
  85     include ::tripleo::fencing
  86
  87     # enable stonith after all Pacemaker resources have been created
  88     Pcmk_resource<||> -> Class['tripleo::fencing']
  89     Pcmk_constraint<||> -> Class['tripleo::fencing']
  90     Exec <| tag == 'pacemaker_constraint' |> -> Class['tripleo::fencing']
  91     # enable stonith after all fencing devices have been created
  92     Class['tripleo::fencing'] -> Class['pacemaker::stonith']
  93   }
  94
  95   # FIXME(gfidente): sets 200secs as default start timeout op
  96   # param; until we can use pcmk global defaults we'll still
  97   # need to add it to every resource which redefines op params
  98   Pacemaker::Resource::Service {
  99     op_params => 'start timeout=200s stop timeout=200s',
 100   }
 101
 102   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 103     include ::mongodb::params
 104   }
 105
 106   # Galera
 107   if str2bool(hiera('enable_galera', true)) {
 108     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 109   } else {
 110     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 111   }
 112   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 113   $galera_nodes_count = count(split($galera_nodes, ','))
 114
 115   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
 116   # set bind-address to a hostname instead of an ip address; to move Mysql
 117   # from internal_api on another network we'll have to customize both
 118   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
 119   $mysql_bind_host = hiera('mysql_bind_host')
 120   $mysqld_options = {
 121     'mysqld' => {
 122       'skip-name-resolve'             => '1',
 123       'binlog_format'                 => 'ROW',
 124       'default-storage-engine'        => 'innodb',
 125       'innodb_autoinc_lock_mode'      => '2',
 126       'innodb_locks_unsafe_for_binlog'=> '1',
 127       'query_cache_size'              => '0',
 128       'query_cache_type'              => '0',
 129       'bind-address'                  => $::hostname,
 130       'max_connections'               => hiera('mysql_max_connections'),
 131       'open_files_limit'              => '-1',
 132       'wsrep_on'                      => 'ON',
 133       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 134       'wsrep_cluster_name'            => 'galera_cluster',
 135       'wsrep_cluster_address'         => "gcomm://${galera_nodes}",
 136       'wsrep_slave_threads'           => '1',
 137       'wsrep_certify_nonPK'           => '1',
 138       'wsrep_max_ws_rows'             => '131072',
 139       'wsrep_max_ws_size'             => '1073741824',
 140       'wsrep_debug'                   => '0',
 141       'wsrep_convert_LOCK_to_trx'     => '0',
 142       'wsrep_retry_autocommit'        => '1',
 143       'wsrep_auto_increment_control'  => '1',
 144       'wsrep_drupal_282555_workaround'=> '0',
 145       'wsrep_causal_reads'            => '0',
 146       'wsrep_sst_method'              => 'rsync',
 147       'wsrep_provider_options'        => "gmcast.listen_addr=tcp://[${mysql_bind_host}]:4567;",
 148     },
 149   }
 150
 151   class { '::mysql::server':
 152     create_root_user        => false,
 153     create_root_my_cnf      => false,
 154     config_file             => $mysql_config_file,
 155     override_options        => $mysqld_options,
 156     remove_default_accounts => $pacemaker_master,
 157     service_manage          => false,
 158     service_enabled         => false,
 159   }
 160
 161 }
 162
 163 if hiera('step') >= 2 {
 164
 165
 166   # NOTE(gfidente): the following vars are needed on all nodes so they
 167   # need to stay out of pacemaker_master conditional.
 168   # The addresses mangling will hopefully go away when we'll be able to
 169   # configure the connection string via hostnames, until then, we need to pass
 170   # the list of IPv6 addresses *with* port and without the brackets as 'members'
 171   # argument for the 'mongodb_replset' resource.
 172   if str2bool(hiera('mongodb::server::ipv6', false)) {
 173     $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
 174     $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
 175     $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
 176   } else {
 177     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
 178     $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
 179   }
 180   $mongodb_replset = hiera('mongodb::server::replset')
 181
 182   if $pacemaker_master {
 183
 184     include ::pacemaker::resource_defaults
 185
 186     # Create an openstack-core dummy resource. See RHBZ 1290121
 187     pacemaker::resource::ocf { 'openstack-core':
 188       ocf_agent_name => 'heartbeat:Dummy',
 189       clone_params   => true,
 190     }
 191
 192     pacemaker::resource::ocf { 'galera' :
 193       ocf_agent_name  => 'heartbeat:galera',
 194       op_params       => 'promote timeout=300s on-fail=block',
 195       master_params   => '',
 196       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 197       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 198       require         => Class['::mysql::server'],
 199       before          => Exec['galera-ready'],
 200     }
 201   }
 202   $mysql_root_password = hiera('mysql::server::root_password')
 203   $mysql_clustercheck_password = hiera('mysql_clustercheck_password')
 204   # This step is to create a sysconfig clustercheck file with the root user and empty password
 205   # on the first install only (because later on the clustercheck db user will be used)
 206   # We are using exec and not file in order to not have duplicate definition errors in puppet
 207   # when we later set the the file to contain the clustercheck data
 208   exec { 'create-root-sysconfig-clustercheck':
 209     command => "/bin/echo 'MYSQL_USERNAME=root\nMYSQL_PASSWORD=\'\'\nMYSQL_HOST=localhost\n' > /etc/sysconfig/clustercheck",
 210     unless  => '/bin/test -e /etc/sysconfig/clustercheck && grep -q clustercheck /etc/sysconfig/clustercheck',
 211   }
 212
 213   exec { 'galera-ready' :
 214     command     => '/usr/bin/clustercheck >/dev/null',
 215     timeout     => 30,
 216     tries       => 180,
 217     try_sleep   => 10,
 218     environment => ['AVAILABLE_WHEN_READONLY=0'],
 219     require     => Exec['create-root-sysconfig-clustercheck'],
 220   }
 221
 222   xinetd::service { 'galera-monitor' :
 223     port           => '9200',
 224     server         => '/usr/bin/clustercheck',
 225     per_source     => 'UNLIMITED',
 226     log_on_success => '',
 227     log_on_failure => 'HOST',
 228     flags          => 'REUSE',
 229     service_type   => 'UNLISTED',
 230     user           => 'root',
 231     group          => 'root',
 232     require        => Exec['create-root-sysconfig-clustercheck'],
 233   }
 234   # We add a clustercheck db user and we will switch /etc/sysconfig/clustercheck
 235   # to it in a later step. We do this only on one node as it will replicate on
 236   # the other members. We also make sure that the permissions are the minimum necessary
 237   if $pacemaker_master {
 238     mysql_user { 'clustercheck@localhost':
 239       ensure        => 'present',
 240       password_hash => mysql_password($mysql_clustercheck_password),
 241       require       => Exec['galera-ready'],
 242     }
 243     mysql_grant { 'clustercheck@localhost/*.*':
 244       ensure     => 'present',
 245       options    => ['GRANT'],
 246       privileges => ['PROCESS'],
 247       table      => '*.*',
 248       user       => 'clustercheck@localhost',
 249     }
 250   }
 251
 252   # Create all the database schemas
 253   if $sync_db {
 254     class { '::nova::db::mysql':
 255       require => Exec['galera-ready'],
 256     }
 257     class { '::nova::db::mysql_api':
 258       require => Exec['galera-ready'],
 259     }
 260
 261     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 262       class { '::ceilometer::db::mysql':
 263         require => Exec['galera-ready'],
 264       }
 265     }
 266
 267     if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
 268       class { '::gnocchi::db::mysql':
 269         require => Exec['galera-ready'],
 270       }
 271     }
 272   }
 273
 274   # Ceph
 275   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 276
 277   if $enable_ceph {
 278     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 279     if str2bool(hiera('ceph_ipv6', false)) {
 280       $mon_host = hiera('ceph_mon_host_v6')
 281     } else {
 282       $mon_host = hiera('ceph_mon_host')
 283     }
 284     class { '::ceph::profile::params':
 285       mon_initial_members => $mon_initial_members,
 286       mon_host            => $mon_host,
 287     }
 288     include ::ceph::conf
 289     include ::ceph::profile::mon
 290   }
 291
 292   if str2bool(hiera('enable_ceph_storage', false)) {
 293     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 294       exec { 'set selinux to permissive on boot':
 295         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 296         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 297         path    => ['/usr/bin', '/usr/sbin'],
 298       }
 299
 300       exec { 'set selinux to permissive':
 301         command => 'setenforce 0',
 302         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 303         path    => ['/usr/bin', '/usr/sbin'],
 304       } -> Class['ceph::profile::osd']
 305     }
 306
 307     include ::ceph::conf
 308     include ::ceph::profile::osd
 309   }
 310
 311   if str2bool(hiera('enable_external_ceph', false)) {
 312     if str2bool(hiera('ceph_ipv6', false)) {
 313       $mon_host = hiera('ceph_mon_host_v6')
 314     } else {
 315       $mon_host = hiera('ceph_mon_host')
 316     }
 317     class { '::ceph::profile::params':
 318       mon_host            => $mon_host,
 319     }
 320     include ::ceph::conf
 321     include ::ceph::profile::client
 322   }
 323
 324
 325 } #END STEP 2
 326
 327 if hiera('step') >= 4 or ( hiera('step') >= 3 and $sync_db ) {
 328   # At this stage we are guaranteed that the clustercheck db user exists
 329   # so we switch the resource agent to use it.
 330   file { '/etc/sysconfig/clustercheck' :
 331     ensure  => file,
 332     mode    => '0600',
 333     owner   => 'root',
 334     group   => 'root',
 335     content => "MYSQL_USERNAME=clustercheck\n
 336 MYSQL_PASSWORD='${mysql_clustercheck_password}'\n
 337 MYSQL_HOST=localhost\n",
 338   }
 339
 340   $nova_ipv6 = hiera('nova::use_ipv6', false)
 341   if $nova_ipv6 {
 342     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 343   } else {
 344     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 345   }
 346
 347   class { '::nova' :
 348     memcached_servers => $memcached_servers
 349   }
 350
 351   include ::nova::config
 352
 353   class { '::nova::api' :
 354     sync_db        => $sync_db,
 355     sync_db_api    => $sync_db,
 356     manage_service => false,
 357     enabled        => false,
 358   }
 359   class { '::nova::consoleauth' :
 360     manage_service => false,
 361     enabled        => false,
 362   }
 363   class { '::nova::vncproxy' :
 364     manage_service => false,
 365     enabled        => false,
 366   }
 367   include ::nova::scheduler::filter
 368   class { '::nova::scheduler' :
 369     manage_service => false,
 370     enabled        => false,
 371   }
 372   include ::nova::network::neutron
 373
 374   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 375
 376     # TODO(devvesa) provide non-controller ips for these services
 377     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 378     $cassandra_node_ips = hiera('neutron_api_node_ips')
 379
 380     # Run zookeeper in the controller if configured
 381     if hiera('enable_zookeeper_on_controller') {
 382       class {'::tripleo::cluster::zookeeper':
 383         zookeeper_server_ips => $zookeeper_node_ips,
 384         # TODO: create a 'bind' hiera key for zookeeper
 385         zookeeper_client_ip  => hiera('neutron::bind_host'),
 386         zookeeper_hostnames  => split(hiera('controller_node_names'), ',')
 387       }
 388     }
 389
 390     # Run cassandra in the controller if configured
 391     if hiera('enable_cassandra_on_controller') {
 392       class {'::tripleo::cluster::cassandra':
 393         cassandra_servers => $cassandra_node_ips,
 394         # TODO: create a 'bind' hiera key for cassandra
 395         cassandra_ip      => hiera('neutron::bind_host'),
 396       }
 397     }
 398
 399     class {'::tripleo::network::midonet::agent':
 400       zookeeper_servers => $zookeeper_node_ips,
 401       cassandra_seeds   => $cassandra_node_ips
 402     }
 403
 404     class {'::tripleo::network::midonet::api':
 405       zookeeper_servers    => $zookeeper_node_ips,
 406       vip                  => hiera('public_virtual_ip'),
 407       keystone_ip          => hiera('public_virtual_ip'),
 408       keystone_admin_token => hiera('keystone::admin_token'),
 409       # TODO: create a 'bind' hiera key for api
 410       bind_address         => hiera('neutron::bind_host'),
 411       admin_password       => hiera('admin_password')
 412     }
 413
 414     # Configure Neutron
 415     # TODO: when doing the composable midonet plugin, don't forget to
 416     # set service_plugins to an empty array in Hiera.
 417     class {'::neutron':
 418       service_plugins => []
 419     }
 420
 421   }
 422
 423   if  hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 424     include ::neutron::plugins::nuage
 425   }
 426   if  hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 427     include ::neutron::plugins::opencontrail
 428   }
 429   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 430     class {'::neutron::plugins::midonet':
 431       midonet_api_ip    => hiera('public_virtual_ip'),
 432       keystone_tenant   => hiera('neutron::server::auth_tenant'),
 433       keystone_password => hiera('neutron::server::password')
 434     }
 435   }
 436   if hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 437     class { '::neutron::plugins::plumgrid' :
 438       connection                   => hiera('neutron::server::database_connection'),
 439       controller_priv_host         => hiera('keystone_admin_api_vip'),
 440       admin_password               => hiera('admin_password'),
 441       metadata_proxy_shared_secret => hiera('nova::api::neutron_metadata_proxy_shared_secret'),
 442     }
 443   }
 444
 445   if $enable_ceph {
 446     $ceph_pools = hiera('ceph_pools')
 447     ceph::pool { $ceph_pools :
 448       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 449       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 450       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 451     }
 452   }
 453
 454   # swift storage
 455   if str2bool(hiera('enable_swift_storage', true)) {
 456     class {'::swift::storage::all':
 457       mount_check => str2bool(hiera('swift_mount_check')),
 458     }
 459     class {'::swift::storage::account':
 460       manage_service => $non_pcmk_start,
 461       enabled        => $non_pcmk_start,
 462     }
 463     class {'::swift::storage::container':
 464       manage_service => $non_pcmk_start,
 465       enabled        => $non_pcmk_start,
 466     }
 467     class {'::swift::storage::object':
 468       manage_service => $non_pcmk_start,
 469       enabled        => $non_pcmk_start,
 470     }
 471     if(!defined(File['/srv/node'])) {
 472       file { '/srv/node':
 473         ensure  => directory,
 474         owner   => 'swift',
 475         group   => 'swift',
 476         require => Package['openstack-swift'],
 477       }
 478     }
 479     $swift_components = ['account', 'container', 'object']
 480     swift::storage::filter::recon { $swift_components : }
 481     swift::storage::filter::healthcheck { $swift_components : }
 482   }
 483
 484   # Ceilometer
 485   case downcase(hiera('ceilometer_backend')) {
 486     /mysql/: {
 487       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 488     }
 489     default: {
 490       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 491       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 492     }
 493   }
 494   include ::ceilometer
 495   include ::ceilometer::config
 496   class { '::ceilometer::api' :
 497     manage_service => false,
 498     enabled        => false,
 499   }
 500   class { '::ceilometer::agent::notification' :
 501     manage_service => false,
 502     enabled        => false,
 503   }
 504   class { '::ceilometer::agent::central' :
 505     manage_service => false,
 506     enabled        => false,
 507   }
 508   class { '::ceilometer::collector' :
 509     manage_service => false,
 510     enabled        => false,
 511   }
 512   include ::ceilometer::expirer
 513   class { '::ceilometer::db' :
 514     database_connection => $ceilometer_database_connection,
 515     sync_db             => $sync_db,
 516   }
 517   include ::ceilometer::agent::auth
 518   include ::ceilometer::dispatcher::gnocchi
 519
 520   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 521
 522   # httpd/apache and horizon
 523   # NOTE(gfidente): server-status can be consumed by the pacemaker resource agent
 524   class { '::apache' :
 525     service_enable => false,
 526     # service_manage => false, # <-- not supported with horizon&apache mod_wsgi?
 527   }
 528   include ::apache::mod::remoteip
 529   include ::apache::mod::status
 530   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 531     $_profile_support = 'cisco'
 532   } else {
 533     $_profile_support = 'None'
 534   }
 535   $neutron_options   = {'profile_support' => $_profile_support }
 536
 537   $memcached_ipv6 = hiera('memcached_ipv6', false)
 538   if $memcached_ipv6 {
 539     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 540   } else {
 541     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 542   }
 543
 544   class { '::horizon':
 545     cache_server_ip => $horizon_memcached_servers,
 546     neutron_options => $neutron_options,
 547   }
 548
 549   # Aodh
 550   class { '::aodh' :
 551     database_connection => $ceilometer_database_connection,
 552   }
 553   include ::aodh::config
 554   include ::aodh::auth
 555   include ::aodh::client
 556   include ::aodh::wsgi::apache
 557   class { '::aodh::api':
 558     manage_service => false,
 559     enabled        => false,
 560     service_name   => 'httpd',
 561   }
 562   class { '::aodh::evaluator':
 563     manage_service => false,
 564     enabled        => false,
 565   }
 566   class { '::aodh::notifier':
 567     manage_service => false,
 568     enabled        => false,
 569   }
 570   class { '::aodh::listener':
 571     manage_service => false,
 572     enabled        => false,
 573   }
 574
 575   # Gnocchi
 576   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 577   include ::gnocchi::client
 578   if $sync_db {
 579     include ::gnocchi::db::sync
 580   }
 581   include ::gnocchi::storage
 582   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 583   case $gnocchi_backend {
 584       'swift': { include ::gnocchi::storage::swift }
 585       'file': { include ::gnocchi::storage::file }
 586       'rbd': { include ::gnocchi::storage::ceph }
 587       default: { fail('Unrecognized gnocchi_backend parameter.') }
 588   }
 589   class { '::gnocchi':
 590     database_connection => $gnocchi_database_connection,
 591   }
 592   class { '::gnocchi::api' :
 593     manage_service => false,
 594     enabled        => false,
 595     service_name   => 'httpd',
 596   }
 597   class { '::gnocchi::wsgi::apache' :
 598     ssl => false,
 599   }
 600   class { '::gnocchi::metricd' :
 601     manage_service => false,
 602     enabled        => false,
 603   }
 604   class { '::gnocchi::statsd' :
 605     manage_service => false,
 606     enabled        => false,
 607   }
 608
 609   $snmpd_user = hiera('snmpd_readonly_user_name')
 610   snmp::snmpv3_user { $snmpd_user:
 611     authtype => 'MD5',
 612     authpass => hiera('snmpd_readonly_user_password'),
 613   }
 614   class { '::snmp':
 615     agentaddress => ['udp:161','udp6:[::1]:161'],
 616     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 617   }
 618
 619   hiera_include('controller_classes')
 620
 621 } #END STEP 4
 622
 623 if hiera('step') >= 5 {
 624   # We now make sure that the root db password is set to a random one
 625   # At first installation /root/.my.cnf will be empty and we connect without a root
 626   # password. On second runs or updates /root/.my.cnf will already be populated
 627   # with proper credentials. This step happens on every node because this sql
 628   # statement does not automatically replicate across nodes.
 629   exec { 'galera-set-root-password':
 630     command => "/bin/touch /root/.my.cnf && /bin/echo \"UPDATE mysql.user SET Password = PASSWORD('${mysql_root_password}') WHERE user = 'root'; flush privileges;\" | /bin/mysql --defaults-extra-file=/root/.my.cnf -u root",
 631   }
 632   file { '/root/.my.cnf' :
 633     ensure  => file,
 634     mode    => '0600',
 635     owner   => 'root',
 636     group   => 'root',
 637     content => "[client]
 638 user=root
 639 password=\"${mysql_root_password}\"
 640
 641 [mysql]
 642 user=root
 643 password=\"${mysql_root_password}\"",
 644     require => Exec['galera-set-root-password'],
 645   }
 646
 647   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 648
 649   if $nova_enable_db_purge {
 650     include ::nova::cron::archive_deleted_rows
 651   }
 652
 653   if $pacemaker_master {
 654
 655     pacemaker::constraint::base { 'openstack-core-then-httpd-constraint':
 656       constraint_type => 'order',
 657       first_resource  => 'openstack-core-clone',
 658       second_resource => "${::apache::params::service_name}-clone",
 659       first_action    => 'start',
 660       second_action   => 'start',
 661       require         => [Pacemaker::Resource::Service[$::apache::params::service_name],
 662                           Pacemaker::Resource::Ocf['openstack-core']],
 663     }
 664     pacemaker::constraint::base { 'galera-then-openstack-core-constraint':
 665       constraint_type => 'order',
 666       first_resource  => 'galera-master',
 667       second_resource => 'openstack-core-clone',
 668       first_action    => 'promote',
 669       second_action   => 'start',
 670       require         => [Pacemaker::Resource::Ocf['galera'],
 671                           Pacemaker::Resource::Ocf['openstack-core']],
 672     }
 673
 674     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 675       pacemaker::resource::service {'tomcat':
 676         clone_params => 'interleave=true',
 677       }
 678     }
 679     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 680       #midonet-chain chain keystone-->neutron-server-->dhcp-->metadata->tomcat
 681       pacemaker::constraint::base { 'neutron-server-to-dhcp-agent-constraint':
 682         constraint_type => 'order',
 683         first_resource  => "${::neutron::params::server_service}-clone",
 684         second_resource => "${::neutron::params::dhcp_agent_service}-clone",
 685         first_action    => 'start',
 686         second_action   => 'start',
 687         require         => [Pacemaker::Resource::Service[$::neutron::params::server_service],
 688                             Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service]],
 689       }
 690       pacemaker::constraint::base { 'neutron-dhcp-agent-to-metadata-agent-constraint':
 691         constraint_type => 'order',
 692         first_resource  => "${::neutron::params::dhcp_agent_service}-clone",
 693         second_resource => "${::neutron::params::metadata_agent_service}-clone",
 694         first_action    => 'start',
 695         second_action   => 'start',
 696         require         => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
 697                             Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]],
 698       }
 699       pacemaker::constraint::base { 'neutron-metadata-agent-to-tomcat-constraint':
 700         constraint_type => 'order',
 701         first_resource  => "${::neutron::params::metadata_agent_service}-clone",
 702         second_resource => 'tomcat-clone',
 703         first_action    => 'start',
 704         second_action   => 'start',
 705         require         => [Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service],
 706                             Pacemaker::Resource::Service['tomcat']],
 707       }
 708       pacemaker::constraint::colocation { 'neutron-dhcp-agent-to-metadata-agent-colocation':
 709         source  => "${::neutron::params::metadata_agent_service}-clone",
 710         target  => "${::neutron::params::dhcp_agent_service}-clone",
 711         score   => 'INFINITY',
 712         require => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
 713                     Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]],
 714       }
 715     }
 716
 717     # Nova
 718     pacemaker::resource::service { $::nova::params::api_service_name :
 719       clone_params => 'interleave=true',
 720     }
 721     pacemaker::resource::service { $::nova::params::consoleauth_service_name :
 722       clone_params => 'interleave=true',
 723       require      => Pacemaker::Resource::Ocf['openstack-core'],
 724     }
 725     pacemaker::resource::service { $::nova::params::vncproxy_service_name :
 726       clone_params => 'interleave=true',
 727     }
 728     pacemaker::resource::service { $::nova::params::scheduler_service_name :
 729       clone_params => 'interleave=true',
 730     }
 731
 732     pacemaker::constraint::base { 'keystone-then-nova-consoleauth-constraint':
 733       constraint_type => 'order',
 734       first_resource  => 'openstack-core-clone',
 735       second_resource => "${::nova::params::consoleauth_service_name}-clone",
 736       first_action    => 'start',
 737       second_action   => 'start',
 738       require         => [Pacemaker::Resource::Service[$::nova::params::consoleauth_service_name],
 739                           Pacemaker::Resource::Ocf['openstack-core']],
 740     }
 741     pacemaker::constraint::base { 'nova-consoleauth-then-nova-vncproxy-constraint':
 742       constraint_type => 'order',
 743       first_resource  => "${::nova::params::consoleauth_service_name}-clone",
 744       second_resource => "${::nova::params::vncproxy_service_name}-clone",
 745       first_action    => 'start',
 746       second_action   => 'start',
 747       require         => [Pacemaker::Resource::Service[$::nova::params::consoleauth_service_name],
 748                           Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name]],
 749     }
 750     pacemaker::constraint::colocation { 'nova-vncproxy-with-nova-consoleauth-colocation':
 751       source  => "${::nova::params::vncproxy_service_name}-clone",
 752       target  => "${::nova::params::consoleauth_service_name}-clone",
 753       score   => 'INFINITY',
 754       require => [Pacemaker::Resource::Service[$::nova::params::consoleauth_service_name],
 755                   Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name]],
 756     }
 757     pacemaker::constraint::base { 'nova-vncproxy-then-nova-api-constraint':
 758       constraint_type => 'order',
 759       first_resource  => "${::nova::params::vncproxy_service_name}-clone",
 760       second_resource => "${::nova::params::api_service_name}-clone",
 761       first_action    => 'start',
 762       second_action   => 'start',
 763       require         => [Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name],
 764                           Pacemaker::Resource::Service[$::nova::params::api_service_name]],
 765     }
 766     pacemaker::constraint::colocation { 'nova-api-with-nova-vncproxy-colocation':
 767       source  => "${::nova::params::api_service_name}-clone",
 768       target  => "${::nova::params::vncproxy_service_name}-clone",
 769       score   => 'INFINITY',
 770       require => [Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name],
 771                   Pacemaker::Resource::Service[$::nova::params::api_service_name]],
 772     }
 773     pacemaker::constraint::base { 'nova-api-then-nova-scheduler-constraint':
 774       constraint_type => 'order',
 775       first_resource  => "${::nova::params::api_service_name}-clone",
 776       second_resource => "${::nova::params::scheduler_service_name}-clone",
 777       first_action    => 'start',
 778       second_action   => 'start',
 779       require         => [Pacemaker::Resource::Service[$::nova::params::api_service_name],
 780                           Pacemaker::Resource::Service[$::nova::params::scheduler_service_name]],
 781     }
 782     pacemaker::constraint::colocation { 'nova-scheduler-with-nova-api-colocation':
 783       source  => "${::nova::params::scheduler_service_name}-clone",
 784       target  => "${::nova::params::api_service_name}-clone",
 785       score   => 'INFINITY',
 786       require => [Pacemaker::Resource::Service[$::nova::params::api_service_name],
 787                   Pacemaker::Resource::Service[$::nova::params::scheduler_service_name]],
 788     }
 789     pacemaker::constraint::base { 'nova-scheduler-then-nova-conductor-constraint':
 790       constraint_type => 'order',
 791       first_resource  => "${::nova::params::scheduler_service_name}-clone",
 792       second_resource => "${::nova::params::conductor_service_name}-clone",
 793       first_action    => 'start',
 794       second_action   => 'start',
 795       require         => [Pacemaker::Resource::Service[$::nova::params::scheduler_service_name],
 796                           Pacemaker::Resource::Service[$::nova::params::conductor_service_name]],
 797     }
 798     pacemaker::constraint::colocation { 'nova-conductor-with-nova-scheduler-colocation':
 799       source  => "${::nova::params::conductor_service_name}-clone",
 800       target  => "${::nova::params::scheduler_service_name}-clone",
 801       score   => 'INFINITY',
 802       require => [Pacemaker::Resource::Service[$::nova::params::scheduler_service_name],
 803                   Pacemaker::Resource::Service[$::nova::params::conductor_service_name]],
 804     }
 805
 806     # Ceilometer and Aodh
 807     case downcase(hiera('ceilometer_backend')) {
 808       /mysql/: {
 809         pacemaker::resource::service { $::ceilometer::params::agent_central_service_name:
 810           clone_params => 'interleave=true',
 811           require      => Pacemaker::Resource::Ocf['openstack-core'],
 812         }
 813       }
 814       default: {
 815         pacemaker::resource::service { $::ceilometer::params::agent_central_service_name:
 816           clone_params => 'interleave=true',
 817           require      => [Pacemaker::Resource::Ocf['openstack-core'],
 818                           Pacemaker::Resource::Service[$::mongodb::params::service_name]],
 819         }
 820       }
 821     }
 822     pacemaker::resource::service { $::ceilometer::params::collector_service_name :
 823       clone_params => 'interleave=true',
 824     }
 825     pacemaker::resource::service { $::ceilometer::params::api_service_name :
 826       clone_params => 'interleave=true',
 827     }
 828     pacemaker::resource::service { $::ceilometer::params::agent_notification_service_name :
 829       clone_params => 'interleave=true',
 830     }
 831     # Fedora doesn't know `require-all` parameter for constraints yet
 832     if $::operatingsystem == 'Fedora' {
 833       $redis_ceilometer_constraint_params = undef
 834       $redis_aodh_constraint_params = undef
 835     } else {
 836       $redis_ceilometer_constraint_params = 'require-all=false'
 837       $redis_aodh_constraint_params = 'require-all=false'
 838     }
 839     pacemaker::constraint::base { 'redis-then-ceilometer-central-constraint':
 840       constraint_type   => 'order',
 841       first_resource    => 'redis-master',
 842       second_resource   => "${::ceilometer::params::agent_central_service_name}-clone",
 843       first_action      => 'promote',
 844       second_action     => 'start',
 845       constraint_params => $redis_ceilometer_constraint_params,
 846       require           => [Pacemaker::Resource::Ocf['redis'],
 847                             Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name]],
 848     }
 849     pacemaker::constraint::base { 'redis-then-aodh-evaluator-constraint':
 850       constraint_type   => 'order',
 851       first_resource    => 'redis-master',
 852       second_resource   => "${::aodh::params::evaluator_service_name}-clone",
 853       first_action      => 'promote',
 854       second_action     => 'start',
 855       constraint_params => $redis_aodh_constraint_params,
 856       require           => [Pacemaker::Resource::Ocf['redis'],
 857                             Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name]],
 858     }
 859     pacemaker::constraint::base { 'keystone-then-ceilometer-central-constraint':
 860       constraint_type => 'order',
 861       first_resource  => 'openstack-core-clone',
 862       second_resource => "${::ceilometer::params::agent_central_service_name}-clone",
 863       first_action    => 'start',
 864       second_action   => 'start',
 865       require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 866                           Pacemaker::Resource::Ocf['openstack-core']],
 867     }
 868     pacemaker::constraint::base { 'keystone-then-ceilometer-notification-constraint':
 869       constraint_type => 'order',
 870       first_resource  => 'openstack-core-clone',
 871       second_resource => "${::ceilometer::params::agent_notification_service_name}-clone",
 872       first_action    => 'start',
 873       second_action   => 'start',
 874       require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 875                           Pacemaker::Resource::Ocf['openstack-core']],
 876     }
 877     pacemaker::constraint::base { 'ceilometer-central-then-ceilometer-collector-constraint':
 878       constraint_type => 'order',
 879       first_resource  => "${::ceilometer::params::agent_central_service_name}-clone",
 880       second_resource => "${::ceilometer::params::collector_service_name}-clone",
 881       first_action    => 'start',
 882       second_action   => 'start',
 883       require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 884                           Pacemaker::Resource::Service[$::ceilometer::params::collector_service_name]],
 885     }
 886     pacemaker::constraint::base { 'ceilometer-collector-then-ceilometer-api-constraint':
 887       constraint_type => 'order',
 888       first_resource  => "${::ceilometer::params::collector_service_name}-clone",
 889       second_resource => "${::ceilometer::params::api_service_name}-clone",
 890       first_action    => 'start',
 891       second_action   => 'start',
 892       require         => [Pacemaker::Resource::Service[$::ceilometer::params::collector_service_name],
 893                           Pacemaker::Resource::Service[$::ceilometer::params::api_service_name]],
 894     }
 895     pacemaker::constraint::colocation { 'ceilometer-api-with-ceilometer-collector-colocation':
 896       source  => "${::ceilometer::params::api_service_name}-clone",
 897       target  => "${::ceilometer::params::collector_service_name}-clone",
 898       score   => 'INFINITY',
 899       require => [Pacemaker::Resource::Service[$::ceilometer::params::api_service_name],
 900                   Pacemaker::Resource::Service[$::ceilometer::params::collector_service_name]],
 901     }
 902     # Aodh
 903     pacemaker::resource::service { $::aodh::params::evaluator_service_name :
 904       clone_params => 'interleave=true',
 905     }
 906     pacemaker::resource::service { $::aodh::params::notifier_service_name :
 907       clone_params => 'interleave=true',
 908     }
 909     pacemaker::resource::service { $::aodh::params::listener_service_name :
 910       clone_params => 'interleave=true',
 911     }
 912     pacemaker::constraint::base { 'aodh-evaluator-then-aodh-notifier-constraint':
 913       constraint_type => 'order',
 914       first_resource  => "${::aodh::params::evaluator_service_name}-clone",
 915       second_resource => "${::aodh::params::notifier_service_name}-clone",
 916       first_action    => 'start',
 917       second_action   => 'start',
 918       require         => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 919                           Pacemaker::Resource::Service[$::aodh::params::notifier_service_name]],
 920     }
 921     pacemaker::constraint::colocation { 'aodh-notifier-with-aodh-evaluator-colocation':
 922       source  => "${::aodh::params::notifier_service_name}-clone",
 923       target  => "${::aodh::params::evaluator_service_name}-clone",
 924       score   => 'INFINITY',
 925       require => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 926                   Pacemaker::Resource::Service[$::aodh::params::notifier_service_name]],
 927     }
 928     pacemaker::constraint::base { 'aodh-evaluator-then-aodh-listener-constraint':
 929       constraint_type => 'order',
 930       first_resource  => "${::aodh::params::evaluator_service_name}-clone",
 931       second_resource => "${::aodh::params::listener_service_name}-clone",
 932       first_action    => 'start',
 933       second_action   => 'start',
 934       require         => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 935                           Pacemaker::Resource::Service[$::aodh::params::listener_service_name]],
 936     }
 937     pacemaker::constraint::colocation { 'aodh-listener-with-aodh-evaluator-colocation':
 938       source  => "${::aodh::params::listener_service_name}-clone",
 939       target  => "${::aodh::params::evaluator_service_name}-clone",
 940       score   => 'INFINITY',
 941       require => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 942                   Pacemaker::Resource::Service[$::aodh::params::listener_service_name]],
 943     }
 944     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 945       pacemaker::constraint::base { 'mongodb-then-ceilometer-central-constraint':
 946         constraint_type => 'order',
 947         first_resource  => "${::mongodb::params::service_name}-clone",
 948         second_resource => "${::ceilometer::params::agent_central_service_name}-clone",
 949         first_action    => 'start',
 950         second_action   => 'start',
 951         require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 952                             Pacemaker::Resource::Service[$::mongodb::params::service_name]],
 953       }
 954     }
 955
 956     # gnocchi
 957     pacemaker::resource::service { $::gnocchi::params::metricd_service_name :
 958       clone_params => 'interleave=true',
 959     }
 960     pacemaker::resource::service { $::gnocchi::params::statsd_service_name :
 961       clone_params => 'interleave=true',
 962     }
 963     pacemaker::constraint::base { 'gnocchi-metricd-then-gnocchi-statsd-constraint':
 964       constraint_type => 'order',
 965       first_resource  => "${::gnocchi::params::metricd_service_name}-clone",
 966       second_resource => "${::gnocchi::params::statsd_service_name}-clone",
 967       first_action    => 'start',
 968       second_action   => 'start',
 969       require         => [Pacemaker::Resource::Service[$::gnocchi::params::metricd_service_name],
 970                           Pacemaker::Resource::Service[$::gnocchi::params::statsd_service_name]],
 971     }
 972     pacemaker::constraint::colocation { 'gnocchi-statsd-with-metricd-colocation':
 973       source  => "${::gnocchi::params::statsd_service_name}-clone",
 974       target  => "${::gnocchi::params::metricd_service_name}-clone",
 975       score   => 'INFINITY',
 976       require => [Pacemaker::Resource::Service[$::gnocchi::params::metricd_service_name],
 977                   Pacemaker::Resource::Service[$::gnocchi::params::statsd_service_name]],
 978     }
 979
 980     # Horizon and Keystone
 981     pacemaker::resource::service { $::apache::params::service_name:
 982       clone_params     => 'interleave=true',
 983       verify_on_create => true,
 984       require          => [File['/etc/keystone/ssl/certs/ca.pem'],
 985       File['/etc/keystone/ssl/private/signing_key.pem'],
 986       File['/etc/keystone/ssl/certs/signing_cert.pem']],
 987     }
 988
 989     #VSM
 990     if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 991       pacemaker::resource::ocf { 'vsm-p' :
 992         ocf_agent_name  => 'heartbeat:VirtualDomain',
 993         resource_params => 'force_stop=true config=/var/spool/cisco/vsm/vsm_primary_deploy.xml',
 994         require         => Class['n1k_vsm'],
 995         meta_params     => 'resource-stickiness=INFINITY',
 996       }
 997       if str2bool(hiera('n1k_vsm::pacemaker_control', true)) {
 998         pacemaker::resource::ocf { 'vsm-s' :
 999           ocf_agent_name  => 'heartbeat:VirtualDomain',
1000           resource_params => 'force_stop=true config=/var/spool/cisco/vsm/vsm_secondary_deploy.xml',
1001           require         => Class['n1k_vsm'],
1002           meta_params     => 'resource-stickiness=INFINITY',
1003         }
1004         pacemaker::constraint::colocation { 'vsm-colocation-contraint':
1005           source  => 'vsm-p',
1006           target  => 'vsm-s',
1007           score   => '-INFINITY',
1008           require => [Pacemaker::Resource::Ocf['vsm-p'],
1009                       Pacemaker::Resource::Ocf['vsm-s']],
1010         }
1011       }
1012     }
1013
1014   }
1015
1016 } #END STEP 5
1017
1018 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller_pacemaker', hiera('step')])
1019 package_manifest{$package_manifest_name: ensure => present}