puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 if !str2bool(hiera('enable_package_install', 'false')) {
  22   case $::osfamily {
  23     'RedHat': {
  24       Package { provider => 'norpm' } # provided by tripleo-puppet
  25     }
  26     default: {
  27       warning('enable_package_install option not supported.')
  28     }
  29   }
  30 }
  31
  32 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  33   $pacemaker_master = true
  34   $sync_db = true
  35 } else {
  36   $pacemaker_master = false
  37   $sync_db = false
  38 }
  39
  40 if hiera('step') >= 1 {
  41
  42   if count(hiera('ntp::servers')) > 0 {
  43     include ::ntp
  44   }
  45
  46   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  47   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  48   class { '::tripleo::loadbalancer' :
  49     controller_hosts       => $controller_node_ips,
  50     controller_hosts_names => $controller_node_names,
  51     manage_vip             => false,
  52     haproxy_service_manage => false,
  53   }
  54
  55   $pacemaker_cluster_members = regsubst(hiera('controller_node_ips'), ',', ' ', 'G')
  56   user { 'hacluster':
  57    ensure => present,
  58   } ->
  59   class { '::pacemaker':
  60     hacluster_pwd => hiera('hacluster_pwd'),
  61   } ->
  62   class { '::pacemaker::corosync':
  63     cluster_members => $pacemaker_cluster_members,
  64     setup_cluster   => $pacemaker_master,
  65   }
  66   class { '::pacemaker::stonith':
  67     disable => true,
  68   }
  69
  70   # Only configure RabbitMQ in this step, don't start it yet to
  71   # avoid races where non-master nodes attempt to start without
  72   # config (eg. binding on 0.0.0.0)
  73   # The module ignores erlang_cookie if cluster_config is false
  74   class { '::rabbitmq':
  75     service_manage          => false,
  76     tcp_keepalive           => false,
  77     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
  78     config_variables        => hiera('rabbitmq_config_variables'),
  79     environment_variables   => hiera('rabbitmq_environment'),
  80   } ->
  81   file { '/var/lib/rabbitmq/.erlang.cookie':
  82     ensure  => 'present',
  83     owner   => 'rabbitmq',
  84     group   => 'rabbitmq',
  85     mode    => '0400',
  86     content => hiera('rabbitmq::erlang_cookie'),
  87     replace => true,
  88   }
  89
  90   # MongoDB
  91   include ::mongodb::globals
  92
  93   # FIXME: replace with service_manage => false on ::mongodb::server
  94   # when this is merged: https://github.com/puppetlabs/pupp etlabs-mongodb/pull/198
  95   class { '::mongodb::server' :
  96     service_ensure => undef,
  97     service_enable => false,
  98   }
  99
 100   # Galera
 101   if str2bool(hiera('enable_galera', 'true')) {
 102     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 103   } else {
 104     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 105   }
 106   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 107   $galera_nodes_count = count(split($galera_nodes, ','))
 108   $clustercheck_password = hiera('mysql_clustercheck_password')
 109   $mysql_root_password = hiera('mysql::server::root_password')
 110
 111   $mysqld_options = {
 112     'mysqld' => {
 113       'skip-name-resolve'             => '1',
 114       'binlog_format'                 => 'ROW',
 115       'default-storage-engine'        => 'innodb',
 116       'innodb_autoinc_lock_mode'      => '2',
 117       'innodb_locks_unsafe_for_binlog'=> '1',
 118       'query_cache_size'              => '0',
 119       'query_cache_type'              => '0',
 120       'bind-address'                  => hiera('controller_host'),
 121       'max_connections'               => '1024',
 122       'open_files_limit'              => '-1',
 123       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 124       'wsrep_cluster_name'            => 'galera_cluster',
 125       'wsrep_slave_threads'           => '1',
 126       'wsrep_certify_nonPK'           => '1',
 127       'wsrep_max_ws_rows'             => '131072',
 128       'wsrep_max_ws_size'             => '1073741824',
 129       'wsrep_debug'                   => '0',
 130       'wsrep_convert_LOCK_to_trx'     => '0',
 131       'wsrep_retry_autocommit'        => '1',
 132       'wsrep_auto_increment_control'  => '1',
 133       'wsrep_drupal_282555_workaround'=> '0',
 134       'wsrep_causal_reads'            => '0',
 135       'wsrep_notify_cmd'              => '',
 136       'wsrep_sst_method'              => 'rsync',
 137     }
 138   }
 139
 140   class { '::mysql::server':
 141     create_root_user   => false,
 142     create_root_my_cnf => false,
 143     config_file        => $mysql_config_file,
 144     override_options   => $mysqld_options,
 145     service_manage     => false,
 146   }
 147
 148 }
 149
 150 if hiera('step') >= 2 {
 151
 152   if $pacemaker_master {
 153     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
 154     pacemaker::resource::ip { 'control_vip':
 155       ip_address => $control_vip,
 156     }
 157     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
 158     pacemaker::resource::ip { 'public_vip':
 159       ip_address => $public_vip,
 160     }
 161     pacemaker::resource::service { 'haproxy':
 162       clone_params => true,
 163     }
 164
 165     pacemaker::resource::ocf { 'rabbitmq':
 166       ocf_agent_name  => 'heartbeat:rabbitmq-cluster',
 167       resource_params => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 168       clone_params    => 'ordered=true interleave=true',
 169       require         => Class['::rabbitmq'],
 170     }
 171
 172     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 173       pacemaker::resource::service { $::mongodb::params::service_name :
 174         op_params    => 'start timeout=120s',
 175         clone_params => true,
 176         require      => Class['::mongodb::server'],
 177         before       => Exec['mongodb-ready'],
 178       }
 179       # NOTE (spredzy) : The replset can only be run
 180       # once all the nodes have joined the cluster.
 181       $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
 182       $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
 183       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 184       $mongodb_replset = hiera('mongodb::server::replset')
 185       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 186       exec { 'mongodb-ready' :
 187         command   => $mongodb_cluster_ready_command,
 188         timeout   => 600,
 189         tries     => 60,
 190         try_sleep => 10,
 191       }
 192       mongodb_replset { $mongodb_replset :
 193         members => $mongo_node_ips_with_port,
 194         require => Exec['mongodb-ready'],
 195       }
 196     }
 197
 198     pacemaker::resource::ocf { 'galera' :
 199       ocf_agent_name  => 'heartbeat:galera',
 200       op_params       => 'promote timeout=300s on-fail=block --master',
 201       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 202       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 203       require         => Class['::mysql::server'],
 204       before          => Exec['galera-ready'],
 205     }
 206     mysql_user { 'clustercheckuser@localhost' :
 207       password_hash => mysql_password($clustercheck_password),
 208       require       => Exec['galera-ready'],
 209     }
 210   }
 211
 212   # Redis
 213   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 214   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 215
 216   if $redis_master_hostname == $::hostname {
 217     $slaveof = undef
 218   } else {
 219     $slaveof = "${redis_master_hostname} 6379"
 220   }
 221   class {'::redis' :
 222     slaveof => $slaveof,
 223   }
 224
 225   if count($redis_node_ips) > 1 {
 226     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 227     include ::redis::sentinel
 228     class {'::tripleo::redis_notification' :
 229       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 230     }
 231   }
 232
 233   exec { 'galera-ready' :
 234     command     => '/bin/mysql -e "SHOW GLOBAL VARIABLES LIKE \'read_only\'" | /bin/grep -i off',
 235     timeout     => 600,
 236     tries       => 60,
 237     try_sleep   => 10,
 238     environment => 'HOME=/root',
 239   }
 240
 241   file { '/etc/sysconfig/clustercheck' :
 242     ensure  => file,
 243     content => "MYSQL_USERNAME=clustercheckuser\n
 244 MYSQL_PASSWORD=${clustercheck_password}\n
 245 MYSQL_HOST=localhost\n",
 246     require       => Exec['galera-ready'],
 247   }
 248
 249   xinetd::service { 'galera-monitor' :
 250     port           => '9200',
 251     server         => '/usr/bin/clustercheck',
 252     per_source     => 'UNLIMITED',
 253     log_on_success => '',
 254     log_on_failure => 'HOST',
 255     flags          => 'REUSE',
 256     service_type   => 'UNLISTED',
 257     user           => 'root',
 258     group          => 'root',
 259     require        => File['/etc/sysconfig/clustercheck'],
 260   }
 261
 262   # Create all the database schemas
 263   # Example DSN format: mysql://user:password@host/dbname
 264   if $sync_db {
 265     $allowed_hosts = ['%',hiera('controller_host')]
 266     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 267     class { 'keystone::db::mysql':
 268       user          => $keystone_dsn[3],
 269       password      => $keystone_dsn[4],
 270       host          => $keystone_dsn[5],
 271       dbname        => $keystone_dsn[6],
 272       allowed_hosts => $allowed_hosts,
 273       require       => Exec['galera-ready'],
 274     }
 275     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 276     class { 'glance::db::mysql':
 277       user          => $glance_dsn[3],
 278       password      => $glance_dsn[4],
 279       host          => $glance_dsn[5],
 280       dbname        => $glance_dsn[6],
 281       allowed_hosts => $allowed_hosts,
 282       require       => Exec['galera-ready'],
 283     }
 284     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 285     class { 'nova::db::mysql':
 286       user          => $nova_dsn[3],
 287       password      => $nova_dsn[4],
 288       host          => $nova_dsn[5],
 289       dbname        => $nova_dsn[6],
 290       allowed_hosts => $allowed_hosts,
 291       require       => Exec['galera-ready'],
 292     }
 293     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 294     class { 'neutron::db::mysql':
 295       user          => $neutron_dsn[3],
 296       password      => $neutron_dsn[4],
 297       host          => $neutron_dsn[5],
 298       dbname        => $neutron_dsn[6],
 299       allowed_hosts => $allowed_hosts,
 300       require       => Exec['galera-ready'],
 301     }
 302     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 303     class { 'cinder::db::mysql':
 304       user          => $cinder_dsn[3],
 305       password      => $cinder_dsn[4],
 306       host          => $cinder_dsn[5],
 307       dbname        => $cinder_dsn[6],
 308       allowed_hosts => $allowed_hosts,
 309       require       => Exec['galera-ready'],
 310     }
 311     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 312     class { 'heat::db::mysql':
 313       user          => $heat_dsn[3],
 314       password      => $heat_dsn[4],
 315       host          => $heat_dsn[5],
 316       dbname        => $heat_dsn[6],
 317       allowed_hosts => $allowed_hosts,
 318       require       => Exec['galera-ready'],
 319     }
 320     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 321       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 322       class { 'ceilometer::db::mysql':
 323         user          => $ceilometer_dsn[3],
 324         password      => $ceilometer_dsn[4],
 325         host          => $ceilometer_dsn[5],
 326         dbname        => $ceilometer_dsn[6],
 327         allowed_hosts => $allowed_hosts,
 328         require       => Exec['galera-ready'],
 329       }
 330     }
 331   }
 332
 333   # pre-install swift here so we can build rings
 334   include ::swift
 335
 336   # Ceph
 337   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 338   $enable_ceph = $cinder_enable_rbd_backend
 339
 340   if $enable_ceph {
 341     class { 'ceph::profile::params':
 342       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 343     }
 344     include ::ceph::profile::mon
 345   }
 346
 347   if str2bool(hiera('enable_ceph_storage', 'false')) {
 348     include ::ceph::profile::client
 349     include ::ceph::profile::osd
 350   }
 351
 352   # Memcached
 353   include ::memcached
 354
 355 } #END STEP 2
 356
 357 if (hiera('step') >= 3 and $pacemaker_master) or hiera('step') >= 4 {
 358
 359   class { '::keystone':
 360     sync_db => $sync_db,
 361   }
 362
 363   #TODO: need a cleanup-keystone-tokens.sh solution here
 364   keystone_config {
 365     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 366   }
 367   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 368     ensure  => 'directory',
 369     owner   => 'keystone',
 370     group   => 'keystone',
 371     require => Package['keystone'],
 372   }
 373   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 374     content => hiera('keystone_signing_certificate'),
 375     owner   => 'keystone',
 376     group   => 'keystone',
 377     notify  => Service['keystone'],
 378     require => File['/etc/keystone/ssl/certs'],
 379   }
 380   file { '/etc/keystone/ssl/private/signing_key.pem':
 381     content => hiera('keystone_signing_key'),
 382     owner   => 'keystone',
 383     group   => 'keystone',
 384     notify  => Service['keystone'],
 385     require => File['/etc/keystone/ssl/private'],
 386   }
 387   file { '/etc/keystone/ssl/certs/ca.pem':
 388     content => hiera('keystone_ca_certificate'),
 389     owner   => 'keystone',
 390     group   => 'keystone',
 391     notify  => Service['keystone'],
 392     require => File['/etc/keystone/ssl/certs'],
 393   }
 394
 395   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 396   case $glance_backend {
 397       swift: { $glance_store = 'glance.store.swift.Store' }
 398       file: { $glance_store = 'glance.store.filesystem.Store' }
 399       rbd: { $glance_store = 'glance.store.rbd.Store' }
 400       default: { fail('Unrecognized glance_backend parameter.') }
 401   }
 402
 403   # TODO: notifications, scrubber, etc.
 404   include ::glance
 405   class { 'glance::api':
 406     known_stores => [$glance_store]
 407   }
 408   class { '::glance::registry' :
 409     sync_db => $sync_db,
 410   }
 411   include join(['::glance::backend::', $glance_backend])
 412
 413   class { 'nova':
 414     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 415   }
 416
 417   class { '::nova::api' :
 418     sync_db => $sync_db,
 419   }
 420   include ::nova::cert
 421   include ::nova::conductor
 422   include ::nova::consoleauth
 423   include ::nova::network::neutron
 424   include ::nova::vncproxy
 425   include ::nova::scheduler
 426
 427   include ::neutron
 428   class { '::neutron::server' :
 429     sync_db => $sync_db,
 430   }
 431   include ::neutron::agents::dhcp
 432   include ::neutron::agents::l3
 433
 434   file { '/etc/neutron/dnsmasq-neutron.conf':
 435     content => hiera('neutron_dnsmasq_options'),
 436     owner   => 'neutron',
 437     group   => 'neutron',
 438     notify  => Service['neutron-dhcp-service'],
 439     require => Package['neutron'],
 440   }
 441
 442   class { 'neutron::plugins::ml2':
 443     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 444     tenant_network_types => [hiera('neutron_tenant_network_type')],
 445     type_drivers         => [hiera('neutron_tenant_network_type')],
 446   }
 447
 448   class { 'neutron::agents::ml2::ovs':
 449     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 450     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 451   }
 452
 453   class { 'neutron::agents::metadata':
 454     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 455   }
 456
 457   Service['neutron-server'] -> Service['neutron-dhcp-service']
 458   Service['neutron-server'] -> Service['neutron-l3']
 459   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 460   Service['neutron-server'] -> Service['neutron-metadata']
 461
 462   include ::cinder
 463   class { '::cinder::api':
 464     sync_db => $sync_db,
 465   }
 466   include ::cinder::glance
 467   include ::cinder::scheduler
 468   include ::cinder::volume
 469   class {'cinder::setup_test_volume':
 470     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 471   }
 472
 473   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 474   if $cinder_enable_iscsi {
 475     $cinder_iscsi_backend = 'tripleo_iscsi'
 476
 477     cinder::backend::iscsi { $cinder_iscsi_backend :
 478       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 479       iscsi_helper     => hiera('cinder_iscsi_helper'),
 480     }
 481   }
 482
 483   if $enable_ceph {
 484
 485     Ceph_pool {
 486       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 487       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 488       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 489     }
 490
 491     $ceph_pools = hiera('ceph_pools')
 492     ceph::pool { $ceph_pools : }
 493   }
 494
 495   if $cinder_enable_rbd_backend {
 496     $cinder_rbd_backend = 'tripleo_ceph'
 497
 498     cinder_config {
 499       "${cinder_rbd_backend}/host": value => 'hostgroup';
 500     }
 501
 502     cinder::backend::rbd { $cinder_rbd_backend :
 503       rbd_pool        => 'volumes',
 504       rbd_user        => 'openstack',
 505       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 506       require         => Ceph::Pool['volumes'],
 507     }
 508   }
 509
 510   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 511   class { '::cinder::backends' :
 512     enabled_backends => $cinder_enabled_backends,
 513   }
 514
 515   # swift proxy
 516   include ::swift::proxy
 517   include ::swift::proxy::proxy_logging
 518   include ::swift::proxy::healthcheck
 519   include ::swift::proxy::cache
 520   include ::swift::proxy::keystone
 521   include ::swift::proxy::authtoken
 522   include ::swift::proxy::staticweb
 523   include ::swift::proxy::ceilometer
 524   include ::swift::proxy::ratelimit
 525   include ::swift::proxy::catch_errors
 526   include ::swift::proxy::tempurl
 527   include ::swift::proxy::formpost
 528
 529   # swift storage
 530   if str2bool(hiera('enable_swift_storage', 'true')) {
 531     class {'swift::storage::all':
 532       mount_check => str2bool(hiera('swift_mount_check'))
 533     }
 534     if(!defined(File['/srv/node'])) {
 535       file { '/srv/node':
 536         ensure  => directory,
 537         owner   => 'swift',
 538         group   => 'swift',
 539         require => Package['openstack-swift'],
 540       }
 541     }
 542     $swift_components = ['account', 'container', 'object']
 543     swift::storage::filter::recon { $swift_components : }
 544     swift::storage::filter::healthcheck { $swift_components : }
 545   }
 546
 547   # Ceilometer
 548   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 549   case $ceilometer_backend {
 550     /mysql/ : {
 551       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 552     }
 553     default : {
 554       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 555     }
 556   }
 557   include ::ceilometer
 558   include ::ceilometer::api
 559   include ::ceilometer::agent::notification
 560   include ::ceilometer::agent::central
 561   include ::ceilometer::alarm::notifier
 562   include ::ceilometer::alarm::evaluator
 563   include ::ceilometer::expirer
 564   include ::ceilometer::collector
 565   class { '::ceilometer::db' :
 566     database_connection => $ceilometer_database_connection,
 567     sync_db             => $sync_db,
 568   }
 569   class { 'ceilometer::agent::auth':
 570     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 571   }
 572
 573   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 574
 575   # Heat
 576   class { '::heat' :
 577     sync_db => $sync_db,
 578   }
 579   include ::heat::api
 580   include ::heat::api_cfn
 581   include ::heat::api_cloudwatch
 582   include ::heat::engine
 583
 584   # Horizon
 585   $vhost_params = { add_listen => false }
 586   class { 'horizon':
 587     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 588     vhost_extra_params => $vhost_params,
 589   }
 590
 591   $snmpd_user = hiera('snmpd_readonly_user_name')
 592   snmp::snmpv3_user { $snmpd_user:
 593     authtype => 'MD5',
 594     authpass => hiera('snmpd_readonly_user_password'),
 595   }
 596   class { 'snmp':
 597     agentaddress => ['udp:161','udp6:[::1]:161'],
 598     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 599   }
 600
 601 } #END STEP 3/4