puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 if !str2bool(hiera('enable_package_install', 'false')) {
  22   case $::osfamily {
  23     'RedHat': {
  24       Package { provider => 'norpm' } # provided by tripleo-puppet
  25     }
  26     default: {
  27       warning('enable_package_install option not supported.')
  28     }
  29   }
  30 }
  31
  32 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  33   $pacemaker_master = true
  34 } else {
  35   $pacemaker_master = false
  36 }
  37
  38 if hiera('step') >= 1 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  45   $controller_node_names = split(downcase(hiera('controller_node_names')), ',')
  46   class { '::tripleo::loadbalancer' :
  47     controller_hosts       => $controller_node_ips,
  48     controller_hosts_names => $controller_node_names,
  49     manage_vip             => false,
  50     haproxy_service_manage => false,
  51   }
  52
  53   $pacemaker_cluster_members = regsubst(hiera('controller_node_ips'), ',', ' ', 'G')
  54   user { 'hacluster':
  55    ensure => present,
  56   } ->
  57   class { '::pacemaker':
  58     hacluster_pwd => hiera('hacluster_pwd'),
  59   } ->
  60   class { '::pacemaker::corosync':
  61     cluster_members => $pacemaker_cluster_members,
  62     setup_cluster   => $pacemaker_master,
  63   }
  64   class { '::pacemaker::stonith':
  65     disable => true,
  66   }
  67   if $pacemaker_master {
  68     $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
  69     pacemaker::resource::ip { 'control_vip':
  70       ip_address => $control_vip,
  71     }
  72     $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
  73     pacemaker::resource::ip { 'public_vip':
  74       ip_address => $public_vip,
  75     }
  76   }
  77
  78   Class['::pacemaker::corosync'] -> Pacemaker::Resource::Ip <| |>
  79   Class['::pacemaker::corosync'] -> Pacemaker::Resource::Ocf <| |>
  80   Class['::pacemaker::corosync'] -> Pacemaker::Resource::Service <| |>
  81
  82   # Only configure RabbitMQ in this step, don't start it yet to
  83   # avoid races where non-master nodes attempt to start without
  84   # config (eg. binding on 0.0.0.0)
  85   # The module ignores erlang_cookie if cluster_config is false
  86   class { '::rabbitmq':
  87     service_manage          => false,
  88     tcp_keepalive           => false,
  89     config_kernel_variables => hiera('rabbitmq_kernel_variables'),
  90     config_variables        => hiera('rabbitmq_config_variables'),
  91     environment_variables   => hiera('rabbitmq_environment'),
  92   } ->
  93   file { '/var/lib/rabbitmq/.erlang.cookie':
  94     ensure  => 'present',
  95     owner   => 'rabbitmq',
  96     group   => 'rabbitmq',
  97     mode    => '0400',
  98     content => hiera('rabbitmq::erlang_cookie'),
  99     replace => true,
 100   }
 101
 102   # MongoDB
 103   include ::mongodb::globals
 104
 105   # FIXME: replace with service_manage => false on ::mongodb::server
 106   # when this is merged: https://github.com/puppetlabs/pupp etlabs-mongodb/pull/198
 107   class { '::mongodb::server' :
 108     service_ensure => undef,
 109     service_enable => false,
 110   }
 111
 112   # Galera
 113   if str2bool(hiera('enable_galera', 'true')) {
 114     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 115   } else {
 116     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 117   }
 118   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 119   $galera_nodes_count = count(split($galera_nodes, ','))
 120   $clustercheck_password = hiera('mysql_clustercheck_password')
 121   $mysql_root_password = hiera('mysql::server::root_password')
 122
 123   $mysqld_options = {
 124     'mysqld' => {
 125       'skip-name-resolve'             => '1',
 126       'binlog_format'                 => 'ROW',
 127       'default-storage-engine'        => 'innodb',
 128       'innodb_autoinc_lock_mode'      => '2',
 129       'innodb_locks_unsafe_for_binlog'=> '1',
 130       'query_cache_size'              => '0',
 131       'query_cache_type'              => '0',
 132       'bind-address'                  => hiera('controller_host'),
 133       'max_connections'               => '1024',
 134       'open_files_limit'              => '-1',
 135       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 136       'wsrep_cluster_name'            => 'galera_cluster',
 137       'wsrep_slave_threads'           => '1',
 138       'wsrep_certify_nonPK'           => '1',
 139       'wsrep_max_ws_rows'             => '131072',
 140       'wsrep_max_ws_size'             => '1073741824',
 141       'wsrep_debug'                   => '0',
 142       'wsrep_convert_LOCK_to_trx'     => '0',
 143       'wsrep_retry_autocommit'        => '1',
 144       'wsrep_auto_increment_control'  => '1',
 145       'wsrep_drupal_282555_workaround'=> '0',
 146       'wsrep_causal_reads'            => '0',
 147       'wsrep_notify_cmd'              => '',
 148       'wsrep_sst_method'              => 'rsync',
 149     }
 150   }
 151
 152   class { '::mysql::server':
 153     create_root_user   => false,
 154     create_root_my_cnf => false,
 155     config_file        => $mysql_config_file,
 156     override_options   => $mysqld_options,
 157     service_manage     => false,
 158   }
 159
 160 }
 161
 162 if hiera('step') >= 2 {
 163
 164   if $pacemaker_master {
 165     pacemaker::resource::service { 'haproxy':
 166       clone_params => true,
 167     }
 168   }
 169
 170   # MongoDB
 171   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 172     $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
 173     $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
 174     $mongo_node_string = join($mongo_node_ips_with_port, ',')
 175
 176     $mongodb_replset = hiera('mongodb::server::replset')
 177     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 178     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
 179
 180       pacemaker::resource::service { $::mongodb::params::service_name :
 181         op_params    => 'start timeout=120s',
 182         clone_params => true,
 183         require      => Class['::mongodb::server'],
 184         before       => Exec['mongodb-ready'],
 185       }
 186       # NOTE (spredzy) : The replset can only be run
 187       # once all the nodes have joined the cluster.
 188       $mongodb_cluster_ready_command = join(suffix(prefix($mongo_node_ips, '/bin/nc -w1 '), ' 27017 < /dev/null'), ' && ')
 189       exec { 'mongodb-ready' :
 190         command   => $mongodb_cluster_ready_command,
 191         timeout   => 600,
 192         tries     => 60,
 193         try_sleep => 10,
 194         before    => Mongodb_replset[$mongodb_replset],
 195       }
 196
 197       mongodb_replset { $mongodb_replset :
 198         members => $mongo_node_ips_with_port,
 199       }
 200     }
 201   }
 202
 203   # Redis
 204   $redis_node_ips = split(hiera('redis_node_ips'), ',')
 205   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
 206
 207   if $redis_master_hostname == $::hostname {
 208     $slaveof = undef
 209   } else {
 210     $slaveof = "${redis_master_hostname} 6379"
 211   }
 212   class {'::redis' :
 213     slaveof => $slaveof,
 214   }
 215
 216   if count($redis_node_ips) > 1 {
 217     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 218     include ::redis::sentinel
 219     class {'::tripleo::redis_notification' :
 220       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 221     }
 222   }
 223
 224   # Galera
 225   if $pacemaker_master {
 226     $sync_db = true
 227
 228     pacemaker::resource::ocf { 'galera' :
 229       ocf_agent_name  => 'heartbeat:galera',
 230       op_params       => 'promote timeout=300s on-fail=block --master',
 231       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 232       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 233       require         => Class['::mysql::server'],
 234       before          => Exec['galera-ready'],
 235     }
 236
 237     mysql_user { 'clustercheckuser@localhost' :
 238       password_hash => mysql_password($clustercheck_password),
 239       require       => Exec['galera-ready'],
 240     }
 241   } else {
 242     $sync_db = false
 243   }
 244
 245   exec { 'galera-ready' :
 246     command     => '/bin/mysql -e "SHOW GLOBAL VARIABLES LIKE \'read_only\'" | /bin/grep -i off',
 247     timeout     => 3600,
 248     tries       => 60,
 249     try_sleep   => 60,
 250     environment => 'HOME=/root',
 251     require     => Class['::mysql::server'],
 252   }
 253
 254   file { '/etc/sysconfig/clustercheck' :
 255     ensure  => file,
 256     content => "MYSQL_USERNAME=clustercheckuser\n
 257 MYSQL_PASSWORD=${clustercheck_password}\n
 258 MYSQL_HOST=localhost\n",
 259     require       => Exec['galera-ready'],
 260   }
 261
 262   xinetd::service { 'galera-monitor' :
 263     port           => '9200',
 264     server         => '/usr/bin/clustercheck',
 265     per_source     => 'UNLIMITED',
 266     log_on_success => '',
 267     log_on_failure => 'HOST',
 268     flags          => 'REUSE',
 269     service_type   => 'UNLISTED',
 270     user           => 'root',
 271     group          => 'root',
 272     require        => File['/etc/sysconfig/clustercheck'],
 273   }
 274
 275   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 276   # Create all the database schemas
 277   # Example DSN format: mysql://user:password@host/dbname
 278   if $sync_db {
 279     $allowed_hosts = ['%',hiera('controller_host')]
 280     $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 281     class { 'keystone::db::mysql':
 282       user          => $keystone_dsn[3],
 283       password      => $keystone_dsn[4],
 284       host          => $keystone_dsn[5],
 285       dbname        => $keystone_dsn[6],
 286       allowed_hosts => $allowed_hosts,
 287       require       => Exec['galera-ready'],
 288     }
 289     $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 290     class { 'glance::db::mysql':
 291       user          => $glance_dsn[3],
 292       password      => $glance_dsn[4],
 293       host          => $glance_dsn[5],
 294       dbname        => $glance_dsn[6],
 295       allowed_hosts => $allowed_hosts,
 296       require       => Exec['galera-ready'],
 297     }
 298     $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 299     class { 'nova::db::mysql':
 300       user          => $nova_dsn[3],
 301       password      => $nova_dsn[4],
 302       host          => $nova_dsn[5],
 303       dbname        => $nova_dsn[6],
 304       allowed_hosts => $allowed_hosts,
 305       require       => Exec['galera-ready'],
 306     }
 307     $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 308     class { 'neutron::db::mysql':
 309       user          => $neutron_dsn[3],
 310       password      => $neutron_dsn[4],
 311       host          => $neutron_dsn[5],
 312       dbname        => $neutron_dsn[6],
 313       allowed_hosts => $allowed_hosts,
 314       require       => Exec['galera-ready'],
 315     }
 316     $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 317     class { 'cinder::db::mysql':
 318       user          => $cinder_dsn[3],
 319       password      => $cinder_dsn[4],
 320       host          => $cinder_dsn[5],
 321       dbname        => $cinder_dsn[6],
 322       allowed_hosts => $allowed_hosts,
 323       require       => Exec['galera-ready'],
 324     }
 325     $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 326     class { 'heat::db::mysql':
 327       user          => $heat_dsn[3],
 328       password      => $heat_dsn[4],
 329       host          => $heat_dsn[5],
 330       dbname        => $heat_dsn[6],
 331       allowed_hosts => $allowed_hosts,
 332       require       => Exec['galera-ready'],
 333     }
 334     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 335       $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 336       class { 'ceilometer::db::mysql':
 337         user          => $ceilometer_dsn[3],
 338         password      => $ceilometer_dsn[4],
 339         host          => $ceilometer_dsn[5],
 340         dbname        => $ceilometer_dsn[6],
 341         allowed_hosts => $allowed_hosts,
 342         require       => Exec['galera-ready'],
 343       }
 344     }
 345   }
 346
 347   # RabbitMQ
 348   if $pacemaker_master {
 349     pacemaker::resource::ocf { 'rabbitmq':
 350       ocf_agent_name  => 'heartbeat:rabbitmq-cluster',
 351       resource_params => 'set_policy=\'ha-all ^(?!amq\.).* {"ha-mode":"all"}\'',
 352       clone_params    => true,
 353       require         => Class['::rabbitmq'],
 354     }
 355   }
 356
 357   # pre-install swift here so we can build rings
 358   include ::swift
 359
 360   # Ceph
 361   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 362   $enable_ceph = $cinder_enable_rbd_backend
 363
 364   if $enable_ceph {
 365     class { 'ceph::profile::params':
 366       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 367     }
 368     include ::ceph::profile::mon
 369   }
 370
 371   if str2bool(hiera('enable_ceph_storage', 'false')) {
 372     include ::ceph::profile::client
 373     include ::ceph::profile::osd
 374   }
 375
 376   # Memcached
 377   include ::memcached
 378
 379 } #END STEP 2
 380
 381 if (hiera('step') >= 3 and $pacemaker_master) or hiera('step') >= 4 {
 382
 383   class { '::keystone':
 384     sync_db => $sync_db,
 385   }
 386
 387   #TODO: need a cleanup-keystone-tokens.sh solution here
 388   keystone_config {
 389     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 390   }
 391   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 392     ensure  => 'directory',
 393     owner   => 'keystone',
 394     group   => 'keystone',
 395     require => Package['keystone'],
 396   }
 397   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 398     content => hiera('keystone_signing_certificate'),
 399     owner   => 'keystone',
 400     group   => 'keystone',
 401     notify  => Service['keystone'],
 402     require => File['/etc/keystone/ssl/certs'],
 403   }
 404   file { '/etc/keystone/ssl/private/signing_key.pem':
 405     content => hiera('keystone_signing_key'),
 406     owner   => 'keystone',
 407     group   => 'keystone',
 408     notify  => Service['keystone'],
 409     require => File['/etc/keystone/ssl/private'],
 410   }
 411   file { '/etc/keystone/ssl/certs/ca.pem':
 412     content => hiera('keystone_ca_certificate'),
 413     owner   => 'keystone',
 414     group   => 'keystone',
 415     notify  => Service['keystone'],
 416     require => File['/etc/keystone/ssl/certs'],
 417   }
 418
 419   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 420   case $glance_backend {
 421       swift: { $glance_store = 'glance.store.swift.Store' }
 422       file: { $glance_store = 'glance.store.filesystem.Store' }
 423       rbd: { $glance_store = 'glance.store.rbd.Store' }
 424       default: { fail('Unrecognized glance_backend parameter.') }
 425   }
 426
 427   # TODO: notifications, scrubber, etc.
 428   include ::glance
 429   class { 'glance::api':
 430     known_stores => [$glance_store]
 431   }
 432   class { '::glance::registry' :
 433     sync_db => $sync_db,
 434   }
 435   include join(['::glance::backend::', $glance_backend])
 436
 437   class { 'nova':
 438     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 439   }
 440
 441   class { '::nova::api' :
 442     sync_db => $sync_db,
 443   }
 444   include ::nova::cert
 445   include ::nova::conductor
 446   include ::nova::consoleauth
 447   include ::nova::network::neutron
 448   include ::nova::vncproxy
 449   include ::nova::scheduler
 450
 451   include ::neutron
 452   class { '::neutron::server' :
 453     sync_db => $sync_db,
 454   }
 455   include ::neutron::agents::dhcp
 456   include ::neutron::agents::l3
 457
 458   file { '/etc/neutron/dnsmasq-neutron.conf':
 459     content => hiera('neutron_dnsmasq_options'),
 460     owner   => 'neutron',
 461     group   => 'neutron',
 462     notify  => Service['neutron-dhcp-service'],
 463     require => Package['neutron'],
 464   }
 465
 466   class { 'neutron::plugins::ml2':
 467     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 468     tenant_network_types => [hiera('neutron_tenant_network_type')],
 469     type_drivers         => [hiera('neutron_tenant_network_type')],
 470   }
 471
 472   class { 'neutron::agents::ml2::ovs':
 473     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 474     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 475   }
 476
 477   class { 'neutron::agents::metadata':
 478     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 479   }
 480
 481   Service['neutron-server'] -> Service['neutron-dhcp-service']
 482   Service['neutron-server'] -> Service['neutron-l3']
 483   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 484   Service['neutron-server'] -> Service['neutron-metadata']
 485
 486   include ::cinder
 487   class { '::cinder::api':
 488     sync_db => $sync_db,
 489   }
 490   include ::cinder::glance
 491   include ::cinder::scheduler
 492   include ::cinder::volume
 493   class {'cinder::setup_test_volume':
 494     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 495   }
 496
 497   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 498   if $cinder_enable_iscsi {
 499     $cinder_iscsi_backend = 'tripleo_iscsi'
 500
 501     cinder::backend::iscsi { $cinder_iscsi_backend :
 502       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 503       iscsi_helper     => hiera('cinder_iscsi_helper'),
 504     }
 505   }
 506
 507   if $enable_ceph {
 508
 509     Ceph_pool {
 510       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 511       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 512       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 513     }
 514
 515     $ceph_pools = hiera('ceph_pools')
 516     ceph::pool { $ceph_pools : }
 517   }
 518
 519   if $cinder_enable_rbd_backend {
 520     $cinder_rbd_backend = 'tripleo_ceph'
 521
 522     cinder_config {
 523       "${cinder_rbd_backend}/host": value => 'hostgroup';
 524     }
 525
 526     cinder::backend::rbd { $cinder_rbd_backend :
 527       rbd_pool        => 'volumes',
 528       rbd_user        => 'openstack',
 529       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 530       require         => Ceph::Pool['volumes'],
 531     }
 532   }
 533
 534   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 535   class { '::cinder::backends' :
 536     enabled_backends => $cinder_enabled_backends,
 537   }
 538
 539   # swift proxy
 540   include ::swift::proxy
 541   include ::swift::proxy::proxy_logging
 542   include ::swift::proxy::healthcheck
 543   include ::swift::proxy::cache
 544   include ::swift::proxy::keystone
 545   include ::swift::proxy::authtoken
 546   include ::swift::proxy::staticweb
 547   include ::swift::proxy::ceilometer
 548   include ::swift::proxy::ratelimit
 549   include ::swift::proxy::catch_errors
 550   include ::swift::proxy::tempurl
 551   include ::swift::proxy::formpost
 552
 553   # swift storage
 554   if str2bool(hiera('enable_swift_storage', 'true')) {
 555     class {'swift::storage::all':
 556       mount_check => str2bool(hiera('swift_mount_check'))
 557     }
 558     if(!defined(File['/srv/node'])) {
 559       file { '/srv/node':
 560         ensure  => directory,
 561         owner   => 'swift',
 562         group   => 'swift',
 563         require => Package['openstack-swift'],
 564       }
 565     }
 566     $swift_components = ['account', 'container', 'object']
 567     swift::storage::filter::recon { $swift_components : }
 568     swift::storage::filter::healthcheck { $swift_components : }
 569   }
 570
 571   # Ceilometer
 572   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 573   case $ceilometer_backend {
 574     /mysql/ : {
 575       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 576     }
 577     default : {
 578       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 579     }
 580   }
 581   include ::ceilometer
 582   include ::ceilometer::api
 583   include ::ceilometer::agent::notification
 584   include ::ceilometer::agent::central
 585   include ::ceilometer::alarm::notifier
 586   include ::ceilometer::alarm::evaluator
 587   include ::ceilometer::expirer
 588   include ::ceilometer::collector
 589   class { '::ceilometer::db' :
 590     database_connection => $ceilometer_database_connection,
 591     sync_db             => $sync_db,
 592   }
 593   class { 'ceilometer::agent::auth':
 594     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 595   }
 596
 597   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 598
 599   # Heat
 600   class { '::heat' :
 601     sync_db => $sync_db,
 602   }
 603   include ::heat::api
 604   include ::heat::api_cfn
 605   include ::heat::api_cloudwatch
 606   include ::heat::engine
 607
 608   # Horizon
 609   $vhost_params = { add_listen => false }
 610   class { 'horizon':
 611     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 612     vhost_extra_params => $vhost_params,
 613   }
 614
 615   $snmpd_user = hiera('snmpd_readonly_user_name')
 616   snmp::snmpv3_user { $snmpd_user:
 617     authtype => 'MD5',
 618     authpass => hiera('snmpd_readonly_user_password'),
 619   }
 620   class { 'snmp':
 621     agentaddress => ['udp:161','udp6:[::1]:161'],
 622     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 623   }
 624
 625 } #END STEP 3