puppet/manifests/overcloud_controller_pacemaker.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 Pcmk_resource <| |> {
  17   tries     => 10,
  18   try_sleep => 3,
  19 }
  20
  21 # TODO(jistr): use pcs resource provider instead of just no-ops
  22 Service <|
  23   tag == 'aodh-service' or
  24   tag == 'ceilometer-service' or
  25   tag == 'gnocchi-service' or
  26   tag == 'neutron-service' or
  27   tag == 'nova-service'
  28 |> {
  29   hasrestart => true,
  30   restart    => '/bin/true',
  31   start      => '/bin/true',
  32   stop       => '/bin/true',
  33 }
  34
  35 include ::tripleo::packages
  36 include ::tripleo::firewall
  37
  38 if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  39   $pacemaker_master = true
  40   $sync_db = true
  41 } else {
  42   $pacemaker_master = false
  43   $sync_db = false
  44 }
  45
  46 $enable_fencing = str2bool(hiera('enable_fencing', false)) and hiera('step') >= 5
  47 $enable_load_balancer = hiera('enable_load_balancer', true)
  48
  49 # When to start and enable services which haven't been Pacemakerized
  50 # FIXME: remove when we start all OpenStack services using Pacemaker
  51 # (occurrences of this variable will be gradually replaced with false)
  52 $non_pcmk_start = hiera('step') >= 5
  53
  54 if hiera('step') >= 1 {
  55
  56   create_resources(kmod::load, hiera('kernel_modules'), {})
  57   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  58   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  59
  60   include ::timezone
  61
  62   if count(hiera('ntp::servers')) > 0 {
  63     include ::ntp
  64   }
  65
  66   $pacemaker_cluster_members = downcase(regsubst(hiera('controller_node_names'), ',', ' ', 'G'))
  67   $corosync_ipv6 = str2bool(hiera('corosync_ipv6', false))
  68   if $corosync_ipv6 {
  69     $cluster_setup_extras = { '--token' => hiera('corosync_token_timeout', 1000), '--ipv6' => '' }
  70   } else {
  71     $cluster_setup_extras = { '--token' => hiera('corosync_token_timeout', 1000) }
  72   }
  73   class { '::pacemaker':
  74     hacluster_pwd => hiera('hacluster_pwd'),
  75   } ->
  76   class { '::pacemaker::corosync':
  77     cluster_members      => $pacemaker_cluster_members,
  78     setup_cluster        => $pacemaker_master,
  79     cluster_setup_extras => $cluster_setup_extras,
  80   }
  81   class { '::pacemaker::stonith':
  82     disable => !$enable_fencing,
  83   }
  84   if $enable_fencing {
  85     include ::tripleo::fencing
  86
  87     # enable stonith after all Pacemaker resources have been created
  88     Pcmk_resource<||> -> Class['tripleo::fencing']
  89     Pcmk_constraint<||> -> Class['tripleo::fencing']
  90     Exec <| tag == 'pacemaker_constraint' |> -> Class['tripleo::fencing']
  91     # enable stonith after all fencing devices have been created
  92     Class['tripleo::fencing'] -> Class['pacemaker::stonith']
  93   }
  94
  95   # FIXME(gfidente): sets 200secs as default start timeout op
  96   # param; until we can use pcmk global defaults we'll still
  97   # need to add it to every resource which redefines op params
  98   Pacemaker::Resource::Service {
  99     op_params => 'start timeout=200s stop timeout=200s',
 100   }
 101
 102   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 103     include ::mongodb::params
 104   }
 105
 106   # Galera
 107   if str2bool(hiera('enable_galera', true)) {
 108     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 109   } else {
 110     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 111   }
 112   $galera_nodes = downcase(hiera('galera_node_names', $::hostname))
 113   $galera_nodes_count = count(split($galera_nodes, ','))
 114
 115   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
 116   # set bind-address to a hostname instead of an ip address; to move Mysql
 117   # from internal_api on another network we'll have to customize both
 118   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
 119   $mysql_bind_host = hiera('mysql_bind_host')
 120   $mysqld_options = {
 121     'mysqld' => {
 122       'skip-name-resolve'             => '1',
 123       'binlog_format'                 => 'ROW',
 124       'default-storage-engine'        => 'innodb',
 125       'innodb_autoinc_lock_mode'      => '2',
 126       'innodb_locks_unsafe_for_binlog'=> '1',
 127       'query_cache_size'              => '0',
 128       'query_cache_type'              => '0',
 129       'bind-address'                  => $::hostname,
 130       'max_connections'               => hiera('mysql_max_connections'),
 131       'open_files_limit'              => '-1',
 132       'wsrep_on'                      => 'ON',
 133       'wsrep_provider'                => '/usr/lib64/galera/libgalera_smm.so',
 134       'wsrep_cluster_name'            => 'galera_cluster',
 135       'wsrep_cluster_address'         => "gcomm://${galera_nodes}",
 136       'wsrep_slave_threads'           => '1',
 137       'wsrep_certify_nonPK'           => '1',
 138       'wsrep_max_ws_rows'             => '131072',
 139       'wsrep_max_ws_size'             => '1073741824',
 140       'wsrep_debug'                   => '0',
 141       'wsrep_convert_LOCK_to_trx'     => '0',
 142       'wsrep_retry_autocommit'        => '1',
 143       'wsrep_auto_increment_control'  => '1',
 144       'wsrep_drupal_282555_workaround'=> '0',
 145       'wsrep_causal_reads'            => '0',
 146       'wsrep_sst_method'              => 'rsync',
 147       'wsrep_provider_options'        => "gmcast.listen_addr=tcp://[${mysql_bind_host}]:4567;",
 148     },
 149   }
 150
 151   class { '::mysql::server':
 152     create_root_user        => false,
 153     create_root_my_cnf      => false,
 154     config_file             => $mysql_config_file,
 155     override_options        => $mysqld_options,
 156     remove_default_accounts => $pacemaker_master,
 157     service_manage          => false,
 158     service_enabled         => false,
 159   }
 160
 161 }
 162
 163 if hiera('step') >= 2 {
 164
 165
 166   # NOTE(gfidente): the following vars are needed on all nodes so they
 167   # need to stay out of pacemaker_master conditional.
 168   # The addresses mangling will hopefully go away when we'll be able to
 169   # configure the connection string via hostnames, until then, we need to pass
 170   # the list of IPv6 addresses *with* port and without the brackets as 'members'
 171   # argument for the 'mongodb_replset' resource.
 172   if str2bool(hiera('mongodb::server::ipv6', false)) {
 173     $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
 174     $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
 175     $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
 176   } else {
 177     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
 178     $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
 179   }
 180   $mongodb_replset = hiera('mongodb::server::replset')
 181
 182   if $pacemaker_master {
 183
 184     include ::pacemaker::resource_defaults
 185
 186     # Create an openstack-core dummy resource. See RHBZ 1290121
 187     pacemaker::resource::ocf { 'openstack-core':
 188       ocf_agent_name => 'heartbeat:Dummy',
 189       clone_params   => true,
 190     }
 191
 192     pacemaker::resource::ocf { 'galera' :
 193       ocf_agent_name  => 'heartbeat:galera',
 194       op_params       => 'promote timeout=300s on-fail=block',
 195       master_params   => '',
 196       meta_params     => "master-max=${galera_nodes_count} ordered=true",
 197       resource_params => "additional_parameters='--open-files-limit=16384' enable_creation=true wsrep_cluster_address='gcomm://${galera_nodes}'",
 198       require         => Class['::mysql::server'],
 199       before          => Exec['galera-ready'],
 200     }
 201   }
 202   $mysql_root_password = hiera('mysql::server::root_password')
 203   $mysql_clustercheck_password = hiera('mysql_clustercheck_password')
 204   # This step is to create a sysconfig clustercheck file with the root user and empty password
 205   # on the first install only (because later on the clustercheck db user will be used)
 206   # We are using exec and not file in order to not have duplicate definition errors in puppet
 207   # when we later set the the file to contain the clustercheck data
 208   exec { 'create-root-sysconfig-clustercheck':
 209     command => "/bin/echo 'MYSQL_USERNAME=root\nMYSQL_PASSWORD=\'\'\nMYSQL_HOST=localhost\n' > /etc/sysconfig/clustercheck",
 210     unless  => '/bin/test -e /etc/sysconfig/clustercheck && grep -q clustercheck /etc/sysconfig/clustercheck',
 211   }
 212
 213   exec { 'galera-ready' :
 214     command     => '/usr/bin/clustercheck >/dev/null',
 215     timeout     => 30,
 216     tries       => 180,
 217     try_sleep   => 10,
 218     environment => ['AVAILABLE_WHEN_READONLY=0'],
 219     require     => Exec['create-root-sysconfig-clustercheck'],
 220   }
 221
 222   xinetd::service { 'galera-monitor' :
 223     port           => '9200',
 224     server         => '/usr/bin/clustercheck',
 225     per_source     => 'UNLIMITED',
 226     log_on_success => '',
 227     log_on_failure => 'HOST',
 228     flags          => 'REUSE',
 229     service_type   => 'UNLISTED',
 230     user           => 'root',
 231     group          => 'root',
 232     require        => Exec['create-root-sysconfig-clustercheck'],
 233   }
 234   # We add a clustercheck db user and we will switch /etc/sysconfig/clustercheck
 235   # to it in a later step. We do this only on one node as it will replicate on
 236   # the other members. We also make sure that the permissions are the minimum necessary
 237   if $pacemaker_master {
 238     mysql_user { 'clustercheck@localhost':
 239       ensure        => 'present',
 240       password_hash => mysql_password($mysql_clustercheck_password),
 241       require       => Exec['galera-ready'],
 242     }
 243     mysql_grant { 'clustercheck@localhost/*.*':
 244       ensure     => 'present',
 245       options    => ['GRANT'],
 246       privileges => ['PROCESS'],
 247       table      => '*.*',
 248       user       => 'clustercheck@localhost',
 249     }
 250   }
 251
 252   # Create all the database schemas
 253   if $sync_db {
 254     class { '::nova::db::mysql':
 255       require => Exec['galera-ready'],
 256     }
 257     class { '::nova::db::mysql_api':
 258       require => Exec['galera-ready'],
 259     }
 260
 261     if downcase(hiera('ceilometer_backend')) == 'mysql' {
 262       class { '::ceilometer::db::mysql':
 263         require => Exec['galera-ready'],
 264       }
 265     }
 266
 267     if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
 268       class { '::gnocchi::db::mysql':
 269         require => Exec['galera-ready'],
 270       }
 271     }
 272   }
 273
 274   # Ceph
 275   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 276
 277   if $enable_ceph {
 278     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 279     if str2bool(hiera('ceph_ipv6', false)) {
 280       $mon_host = hiera('ceph_mon_host_v6')
 281     } else {
 282       $mon_host = hiera('ceph_mon_host')
 283     }
 284     class { '::ceph::profile::params':
 285       mon_initial_members => $mon_initial_members,
 286       mon_host            => $mon_host,
 287     }
 288     include ::ceph::conf
 289     include ::ceph::profile::mon
 290   }
 291
 292   if str2bool(hiera('enable_ceph_storage', false)) {
 293     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 294       exec { 'set selinux to permissive on boot':
 295         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 296         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 297         path    => ['/usr/bin', '/usr/sbin'],
 298       }
 299
 300       exec { 'set selinux to permissive':
 301         command => 'setenforce 0',
 302         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 303         path    => ['/usr/bin', '/usr/sbin'],
 304       } -> Class['ceph::profile::osd']
 305     }
 306
 307     include ::ceph::conf
 308     include ::ceph::profile::osd
 309   }
 310
 311   if str2bool(hiera('enable_external_ceph', false)) {
 312     if str2bool(hiera('ceph_ipv6', false)) {
 313       $mon_host = hiera('ceph_mon_host_v6')
 314     } else {
 315       $mon_host = hiera('ceph_mon_host')
 316     }
 317     class { '::ceph::profile::params':
 318       mon_host            => $mon_host,
 319     }
 320     include ::ceph::conf
 321     include ::ceph::profile::client
 322   }
 323
 324
 325 } #END STEP 2
 326
 327 if hiera('step') >= 4 or ( hiera('step') >= 3 and $sync_db ) {
 328   # At this stage we are guaranteed that the clustercheck db user exists
 329   # so we switch the resource agent to use it.
 330   file { '/etc/sysconfig/clustercheck' :
 331     ensure  => file,
 332     mode    => '0600',
 333     owner   => 'root',
 334     group   => 'root',
 335     content => "MYSQL_USERNAME=clustercheck\n
 336 MYSQL_PASSWORD='${mysql_clustercheck_password}'\n
 337 MYSQL_HOST=localhost\n",
 338   }
 339
 340   $nova_ipv6 = hiera('nova::use_ipv6', false)
 341   if $nova_ipv6 {
 342     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 343   } else {
 344     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 345   }
 346
 347   class { '::nova' :
 348     memcached_servers => $memcached_servers
 349   }
 350
 351   include ::nova::config
 352   include ::nova::network::neutron
 353
 354   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 355
 356     # TODO(devvesa) provide non-controller ips for these services
 357     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 358     $cassandra_node_ips = hiera('neutron_api_node_ips')
 359
 360     # Run zookeeper in the controller if configured
 361     if hiera('enable_zookeeper_on_controller') {
 362       class {'::tripleo::cluster::zookeeper':
 363         zookeeper_server_ips => $zookeeper_node_ips,
 364         # TODO: create a 'bind' hiera key for zookeeper
 365         zookeeper_client_ip  => hiera('neutron::bind_host'),
 366         zookeeper_hostnames  => split(hiera('controller_node_names'), ',')
 367       }
 368     }
 369
 370     # Run cassandra in the controller if configured
 371     if hiera('enable_cassandra_on_controller') {
 372       class {'::tripleo::cluster::cassandra':
 373         cassandra_servers => $cassandra_node_ips,
 374         # TODO: create a 'bind' hiera key for cassandra
 375         cassandra_ip      => hiera('neutron::bind_host'),
 376       }
 377     }
 378
 379     class {'::tripleo::network::midonet::agent':
 380       zookeeper_servers => $zookeeper_node_ips,
 381       cassandra_seeds   => $cassandra_node_ips
 382     }
 383
 384     class {'::tripleo::network::midonet::api':
 385       zookeeper_servers    => $zookeeper_node_ips,
 386       vip                  => hiera('public_virtual_ip'),
 387       keystone_ip          => hiera('public_virtual_ip'),
 388       keystone_admin_token => hiera('keystone::admin_token'),
 389       # TODO: create a 'bind' hiera key for api
 390       bind_address         => hiera('neutron::bind_host'),
 391       admin_password       => hiera('admin_password')
 392     }
 393
 394     # Configure Neutron
 395     # TODO: when doing the composable midonet plugin, don't forget to
 396     # set service_plugins to an empty array in Hiera.
 397     class {'::neutron':
 398       service_plugins => []
 399     }
 400
 401   }
 402
 403   if  hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 404     include ::neutron::plugins::nuage
 405   }
 406   if  hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 407     include ::neutron::plugins::opencontrail
 408   }
 409   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 410     class {'::neutron::plugins::midonet':
 411       midonet_api_ip    => hiera('public_virtual_ip'),
 412       keystone_tenant   => hiera('neutron::server::auth_tenant'),
 413       keystone_password => hiera('neutron::server::password')
 414     }
 415   }
 416
 417   if $enable_ceph {
 418     $ceph_pools = hiera('ceph_pools')
 419     ceph::pool { $ceph_pools :
 420       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 421       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 422       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 423     }
 424   }
 425
 426   # swift storage
 427   if str2bool(hiera('enable_swift_storage', true)) {
 428     class {'::swift::storage::all':
 429       mount_check => str2bool(hiera('swift_mount_check')),
 430     }
 431     class {'::swift::storage::account':
 432       manage_service => $non_pcmk_start,
 433       enabled        => $non_pcmk_start,
 434     }
 435     class {'::swift::storage::container':
 436       manage_service => $non_pcmk_start,
 437       enabled        => $non_pcmk_start,
 438     }
 439     class {'::swift::storage::object':
 440       manage_service => $non_pcmk_start,
 441       enabled        => $non_pcmk_start,
 442     }
 443     if(!defined(File['/srv/node'])) {
 444       file { '/srv/node':
 445         ensure  => directory,
 446         owner   => 'swift',
 447         group   => 'swift',
 448         require => Package['openstack-swift'],
 449       }
 450     }
 451     $swift_components = ['account', 'container', 'object']
 452     swift::storage::filter::recon { $swift_components : }
 453     swift::storage::filter::healthcheck { $swift_components : }
 454   }
 455
 456   # Ceilometer
 457   case downcase(hiera('ceilometer_backend')) {
 458     /mysql/: {
 459       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 460     }
 461     default: {
 462       $mongo_node_string = join($mongo_node_ips_with_port, ',')
 463       $ceilometer_database_connection = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
 464     }
 465   }
 466   include ::ceilometer
 467   include ::ceilometer::config
 468   class { '::ceilometer::api' :
 469     manage_service => false,
 470     enabled        => false,
 471   }
 472   class { '::ceilometer::agent::notification' :
 473     manage_service => false,
 474     enabled        => false,
 475   }
 476   class { '::ceilometer::agent::central' :
 477     manage_service => false,
 478     enabled        => false,
 479   }
 480   class { '::ceilometer::collector' :
 481     manage_service => false,
 482     enabled        => false,
 483   }
 484   include ::ceilometer::expirer
 485   class { '::ceilometer::db' :
 486     database_connection => $ceilometer_database_connection,
 487     sync_db             => $sync_db,
 488   }
 489   include ::ceilometer::agent::auth
 490   include ::ceilometer::dispatcher::gnocchi
 491
 492   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 493
 494   # httpd/apache and horizon
 495   # NOTE(gfidente): server-status can be consumed by the pacemaker resource agent
 496   class { '::apache' :
 497     service_enable => false,
 498     # service_manage => false, # <-- not supported with horizon&apache mod_wsgi?
 499   }
 500   include ::apache::mod::remoteip
 501   include ::apache::mod::status
 502   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 503     $_profile_support = 'cisco'
 504   } else {
 505     $_profile_support = 'None'
 506   }
 507   $neutron_options   = {'profile_support' => $_profile_support }
 508
 509   $memcached_ipv6 = hiera('memcached_ipv6', false)
 510   if $memcached_ipv6 {
 511     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 512   } else {
 513     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 514   }
 515
 516   class { '::horizon':
 517     cache_server_ip => $horizon_memcached_servers,
 518     neutron_options => $neutron_options,
 519   }
 520
 521   # Aodh
 522   class { '::aodh' :
 523     database_connection => $ceilometer_database_connection,
 524   }
 525   include ::aodh::config
 526   include ::aodh::auth
 527   include ::aodh::client
 528   include ::aodh::wsgi::apache
 529   class { '::aodh::api':
 530     manage_service => false,
 531     enabled        => false,
 532     service_name   => 'httpd',
 533   }
 534   class { '::aodh::evaluator':
 535     manage_service => false,
 536     enabled        => false,
 537   }
 538   class { '::aodh::notifier':
 539     manage_service => false,
 540     enabled        => false,
 541   }
 542   class { '::aodh::listener':
 543     manage_service => false,
 544     enabled        => false,
 545   }
 546
 547   # Gnocchi
 548   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 549   include ::gnocchi::client
 550   if $sync_db {
 551     include ::gnocchi::db::sync
 552   }
 553   include ::gnocchi::storage
 554   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 555   case $gnocchi_backend {
 556       'swift': { include ::gnocchi::storage::swift }
 557       'file': { include ::gnocchi::storage::file }
 558       'rbd': { include ::gnocchi::storage::ceph }
 559       default: { fail('Unrecognized gnocchi_backend parameter.') }
 560   }
 561   class { '::gnocchi':
 562     database_connection => $gnocchi_database_connection,
 563   }
 564   class { '::gnocchi::api' :
 565     manage_service => false,
 566     enabled        => false,
 567     service_name   => 'httpd',
 568   }
 569   class { '::gnocchi::wsgi::apache' :
 570     ssl => false,
 571   }
 572   class { '::gnocchi::metricd' :
 573     manage_service => false,
 574     enabled        => false,
 575   }
 576   class { '::gnocchi::statsd' :
 577     manage_service => false,
 578     enabled        => false,
 579   }
 580
 581   $snmpd_user = hiera('snmpd_readonly_user_name')
 582   snmp::snmpv3_user { $snmpd_user:
 583     authtype => 'MD5',
 584     authpass => hiera('snmpd_readonly_user_password'),
 585   }
 586   class { '::snmp':
 587     agentaddress => ['udp:161','udp6:[::1]:161'],
 588     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 589   }
 590
 591   hiera_include('controller_classes')
 592
 593 } #END STEP 4
 594
 595 if hiera('step') >= 5 {
 596   # We now make sure that the root db password is set to a random one
 597   # At first installation /root/.my.cnf will be empty and we connect without a root
 598   # password. On second runs or updates /root/.my.cnf will already be populated
 599   # with proper credentials. This step happens on every node because this sql
 600   # statement does not automatically replicate across nodes.
 601   exec { 'galera-set-root-password':
 602     command => "/bin/touch /root/.my.cnf && /bin/echo \"UPDATE mysql.user SET Password = PASSWORD('${mysql_root_password}') WHERE user = 'root'; flush privileges;\" | /bin/mysql --defaults-extra-file=/root/.my.cnf -u root",
 603   }
 604   file { '/root/.my.cnf' :
 605     ensure  => file,
 606     mode    => '0600',
 607     owner   => 'root',
 608     group   => 'root',
 609     content => "[client]
 610 user=root
 611 password=\"${mysql_root_password}\"
 612
 613 [mysql]
 614 user=root
 615 password=\"${mysql_root_password}\"",
 616     require => Exec['galera-set-root-password'],
 617   }
 618
 619   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 620
 621   if $nova_enable_db_purge {
 622     include ::nova::cron::archive_deleted_rows
 623   }
 624
 625   if $pacemaker_master {
 626
 627     pacemaker::constraint::base { 'openstack-core-then-httpd-constraint':
 628       constraint_type => 'order',
 629       first_resource  => 'openstack-core-clone',
 630       second_resource => "${::apache::params::service_name}-clone",
 631       first_action    => 'start',
 632       second_action   => 'start',
 633       require         => [Pacemaker::Resource::Service[$::apache::params::service_name],
 634                           Pacemaker::Resource::Ocf['openstack-core']],
 635     }
 636     pacemaker::constraint::base { 'galera-then-openstack-core-constraint':
 637       constraint_type => 'order',
 638       first_resource  => 'galera-master',
 639       second_resource => 'openstack-core-clone',
 640       first_action    => 'promote',
 641       second_action   => 'start',
 642       require         => [Pacemaker::Resource::Ocf['galera'],
 643                           Pacemaker::Resource::Ocf['openstack-core']],
 644     }
 645
 646     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 647       pacemaker::resource::service {'tomcat':
 648         clone_params => 'interleave=true',
 649       }
 650     }
 651     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 652       #midonet-chain chain keystone-->neutron-server-->dhcp-->metadata->tomcat
 653       pacemaker::constraint::base { 'neutron-server-to-dhcp-agent-constraint':
 654         constraint_type => 'order',
 655         first_resource  => "${::neutron::params::server_service}-clone",
 656         second_resource => "${::neutron::params::dhcp_agent_service}-clone",
 657         first_action    => 'start',
 658         second_action   => 'start',
 659         require         => [Pacemaker::Resource::Service[$::neutron::params::server_service],
 660                             Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service]],
 661       }
 662       pacemaker::constraint::base { 'neutron-dhcp-agent-to-metadata-agent-constraint':
 663         constraint_type => 'order',
 664         first_resource  => "${::neutron::params::dhcp_agent_service}-clone",
 665         second_resource => "${::neutron::params::metadata_agent_service}-clone",
 666         first_action    => 'start',
 667         second_action   => 'start',
 668         require         => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
 669                             Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]],
 670       }
 671       pacemaker::constraint::base { 'neutron-metadata-agent-to-tomcat-constraint':
 672         constraint_type => 'order',
 673         first_resource  => "${::neutron::params::metadata_agent_service}-clone",
 674         second_resource => 'tomcat-clone',
 675         first_action    => 'start',
 676         second_action   => 'start',
 677         require         => [Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service],
 678                             Pacemaker::Resource::Service['tomcat']],
 679       }
 680       pacemaker::constraint::colocation { 'neutron-dhcp-agent-to-metadata-agent-colocation':
 681         source  => "${::neutron::params::metadata_agent_service}-clone",
 682         target  => "${::neutron::params::dhcp_agent_service}-clone",
 683         score   => 'INFINITY',
 684         require => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
 685                     Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]],
 686       }
 687     }
 688
 689     # Nova
 690     pacemaker::constraint::base { 'keystone-then-nova-consoleauth-constraint':
 691       constraint_type => 'order',
 692       first_resource  => 'openstack-core-clone',
 693       second_resource => "${::nova::params::consoleauth_service_name}-clone",
 694       first_action    => 'start',
 695       second_action   => 'start',
 696       require         => [Pacemaker::Resource::Service[$::nova::params::consoleauth_service_name],
 697                           Pacemaker::Resource::Ocf['openstack-core']],
 698     }
 699     pacemaker::constraint::base { 'nova-consoleauth-then-nova-vncproxy-constraint':
 700       constraint_type => 'order',
 701       first_resource  => "${::nova::params::consoleauth_service_name}-clone",
 702       second_resource => "${::nova::params::vncproxy_service_name}-clone",
 703       first_action    => 'start',
 704       second_action   => 'start',
 705       require         => [Pacemaker::Resource::Service[$::nova::params::consoleauth_service_name],
 706                           Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name]],
 707     }
 708     pacemaker::constraint::colocation { 'nova-vncproxy-with-nova-consoleauth-colocation':
 709       source  => "${::nova::params::vncproxy_service_name}-clone",
 710       target  => "${::nova::params::consoleauth_service_name}-clone",
 711       score   => 'INFINITY',
 712       require => [Pacemaker::Resource::Service[$::nova::params::consoleauth_service_name],
 713                   Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name]],
 714     }
 715     pacemaker::constraint::base { 'nova-vncproxy-then-nova-api-constraint':
 716       constraint_type => 'order',
 717       first_resource  => "${::nova::params::vncproxy_service_name}-clone",
 718       second_resource => "${::nova::params::api_service_name}-clone",
 719       first_action    => 'start',
 720       second_action   => 'start',
 721       require         => [Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name],
 722                           Pacemaker::Resource::Service[$::nova::params::api_service_name]],
 723     }
 724     pacemaker::constraint::colocation { 'nova-api-with-nova-vncproxy-colocation':
 725       source  => "${::nova::params::api_service_name}-clone",
 726       target  => "${::nova::params::vncproxy_service_name}-clone",
 727       score   => 'INFINITY',
 728       require => [Pacemaker::Resource::Service[$::nova::params::vncproxy_service_name],
 729                   Pacemaker::Resource::Service[$::nova::params::api_service_name]],
 730     }
 731     pacemaker::constraint::base { 'nova-api-then-nova-scheduler-constraint':
 732       constraint_type => 'order',
 733       first_resource  => "${::nova::params::api_service_name}-clone",
 734       second_resource => "${::nova::params::scheduler_service_name}-clone",
 735       first_action    => 'start',
 736       second_action   => 'start',
 737       require         => [Pacemaker::Resource::Service[$::nova::params::api_service_name],
 738                           Pacemaker::Resource::Service[$::nova::params::scheduler_service_name]],
 739     }
 740     pacemaker::constraint::colocation { 'nova-scheduler-with-nova-api-colocation':
 741       source  => "${::nova::params::scheduler_service_name}-clone",
 742       target  => "${::nova::params::api_service_name}-clone",
 743       score   => 'INFINITY',
 744       require => [Pacemaker::Resource::Service[$::nova::params::api_service_name],
 745                   Pacemaker::Resource::Service[$::nova::params::scheduler_service_name]],
 746     }
 747     pacemaker::constraint::base { 'nova-scheduler-then-nova-conductor-constraint':
 748       constraint_type => 'order',
 749       first_resource  => "${::nova::params::scheduler_service_name}-clone",
 750       second_resource => "${::nova::params::conductor_service_name}-clone",
 751       first_action    => 'start',
 752       second_action   => 'start',
 753       require         => [Pacemaker::Resource::Service[$::nova::params::scheduler_service_name],
 754                           Pacemaker::Resource::Service[$::nova::params::conductor_service_name]],
 755     }
 756     pacemaker::constraint::colocation { 'nova-conductor-with-nova-scheduler-colocation':
 757       source  => "${::nova::params::conductor_service_name}-clone",
 758       target  => "${::nova::params::scheduler_service_name}-clone",
 759       score   => 'INFINITY',
 760       require => [Pacemaker::Resource::Service[$::nova::params::scheduler_service_name],
 761                   Pacemaker::Resource::Service[$::nova::params::conductor_service_name]],
 762     }
 763
 764     # Ceilometer and Aodh
 765     case downcase(hiera('ceilometer_backend')) {
 766       /mysql/: {
 767         pacemaker::resource::service { $::ceilometer::params::agent_central_service_name:
 768           clone_params => 'interleave=true',
 769           require      => Pacemaker::Resource::Ocf['openstack-core'],
 770         }
 771       }
 772       default: {
 773         pacemaker::resource::service { $::ceilometer::params::agent_central_service_name:
 774           clone_params => 'interleave=true',
 775           require      => [Pacemaker::Resource::Ocf['openstack-core'],
 776                           Pacemaker::Resource::Service[$::mongodb::params::service_name]],
 777         }
 778       }
 779     }
 780     pacemaker::resource::service { $::ceilometer::params::collector_service_name :
 781       clone_params => 'interleave=true',
 782     }
 783     pacemaker::resource::service { $::ceilometer::params::api_service_name :
 784       clone_params => 'interleave=true',
 785     }
 786     pacemaker::resource::service { $::ceilometer::params::agent_notification_service_name :
 787       clone_params => 'interleave=true',
 788     }
 789     # Fedora doesn't know `require-all` parameter for constraints yet
 790     if $::operatingsystem == 'Fedora' {
 791       $redis_ceilometer_constraint_params = undef
 792       $redis_aodh_constraint_params = undef
 793     } else {
 794       $redis_ceilometer_constraint_params = 'require-all=false'
 795       $redis_aodh_constraint_params = 'require-all=false'
 796     }
 797     pacemaker::constraint::base { 'redis-then-ceilometer-central-constraint':
 798       constraint_type   => 'order',
 799       first_resource    => 'redis-master',
 800       second_resource   => "${::ceilometer::params::agent_central_service_name}-clone",
 801       first_action      => 'promote',
 802       second_action     => 'start',
 803       constraint_params => $redis_ceilometer_constraint_params,
 804       require           => [Pacemaker::Resource::Ocf['redis'],
 805                             Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name]],
 806     }
 807     pacemaker::constraint::base { 'redis-then-aodh-evaluator-constraint':
 808       constraint_type   => 'order',
 809       first_resource    => 'redis-master',
 810       second_resource   => "${::aodh::params::evaluator_service_name}-clone",
 811       first_action      => 'promote',
 812       second_action     => 'start',
 813       constraint_params => $redis_aodh_constraint_params,
 814       require           => [Pacemaker::Resource::Ocf['redis'],
 815                             Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name]],
 816     }
 817     pacemaker::constraint::base { 'keystone-then-ceilometer-central-constraint':
 818       constraint_type => 'order',
 819       first_resource  => 'openstack-core-clone',
 820       second_resource => "${::ceilometer::params::agent_central_service_name}-clone",
 821       first_action    => 'start',
 822       second_action   => 'start',
 823       require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 824                           Pacemaker::Resource::Ocf['openstack-core']],
 825     }
 826     pacemaker::constraint::base { 'keystone-then-ceilometer-notification-constraint':
 827       constraint_type => 'order',
 828       first_resource  => 'openstack-core-clone',
 829       second_resource => "${::ceilometer::params::agent_notification_service_name}-clone",
 830       first_action    => 'start',
 831       second_action   => 'start',
 832       require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 833                           Pacemaker::Resource::Ocf['openstack-core']],
 834     }
 835     pacemaker::constraint::base { 'ceilometer-central-then-ceilometer-collector-constraint':
 836       constraint_type => 'order',
 837       first_resource  => "${::ceilometer::params::agent_central_service_name}-clone",
 838       second_resource => "${::ceilometer::params::collector_service_name}-clone",
 839       first_action    => 'start',
 840       second_action   => 'start',
 841       require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 842                           Pacemaker::Resource::Service[$::ceilometer::params::collector_service_name]],
 843     }
 844     pacemaker::constraint::base { 'ceilometer-collector-then-ceilometer-api-constraint':
 845       constraint_type => 'order',
 846       first_resource  => "${::ceilometer::params::collector_service_name}-clone",
 847       second_resource => "${::ceilometer::params::api_service_name}-clone",
 848       first_action    => 'start',
 849       second_action   => 'start',
 850       require         => [Pacemaker::Resource::Service[$::ceilometer::params::collector_service_name],
 851                           Pacemaker::Resource::Service[$::ceilometer::params::api_service_name]],
 852     }
 853     pacemaker::constraint::colocation { 'ceilometer-api-with-ceilometer-collector-colocation':
 854       source  => "${::ceilometer::params::api_service_name}-clone",
 855       target  => "${::ceilometer::params::collector_service_name}-clone",
 856       score   => 'INFINITY',
 857       require => [Pacemaker::Resource::Service[$::ceilometer::params::api_service_name],
 858                   Pacemaker::Resource::Service[$::ceilometer::params::collector_service_name]],
 859     }
 860     # Aodh
 861     pacemaker::resource::service { $::aodh::params::evaluator_service_name :
 862       clone_params => 'interleave=true',
 863     }
 864     pacemaker::resource::service { $::aodh::params::notifier_service_name :
 865       clone_params => 'interleave=true',
 866     }
 867     pacemaker::resource::service { $::aodh::params::listener_service_name :
 868       clone_params => 'interleave=true',
 869     }
 870     pacemaker::constraint::base { 'aodh-evaluator-then-aodh-notifier-constraint':
 871       constraint_type => 'order',
 872       first_resource  => "${::aodh::params::evaluator_service_name}-clone",
 873       second_resource => "${::aodh::params::notifier_service_name}-clone",
 874       first_action    => 'start',
 875       second_action   => 'start',
 876       require         => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 877                           Pacemaker::Resource::Service[$::aodh::params::notifier_service_name]],
 878     }
 879     pacemaker::constraint::colocation { 'aodh-notifier-with-aodh-evaluator-colocation':
 880       source  => "${::aodh::params::notifier_service_name}-clone",
 881       target  => "${::aodh::params::evaluator_service_name}-clone",
 882       score   => 'INFINITY',
 883       require => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 884                   Pacemaker::Resource::Service[$::aodh::params::notifier_service_name]],
 885     }
 886     pacemaker::constraint::base { 'aodh-evaluator-then-aodh-listener-constraint':
 887       constraint_type => 'order',
 888       first_resource  => "${::aodh::params::evaluator_service_name}-clone",
 889       second_resource => "${::aodh::params::listener_service_name}-clone",
 890       first_action    => 'start',
 891       second_action   => 'start',
 892       require         => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 893                           Pacemaker::Resource::Service[$::aodh::params::listener_service_name]],
 894     }
 895     pacemaker::constraint::colocation { 'aodh-listener-with-aodh-evaluator-colocation':
 896       source  => "${::aodh::params::listener_service_name}-clone",
 897       target  => "${::aodh::params::evaluator_service_name}-clone",
 898       score   => 'INFINITY',
 899       require => [Pacemaker::Resource::Service[$::aodh::params::evaluator_service_name],
 900                   Pacemaker::Resource::Service[$::aodh::params::listener_service_name]],
 901     }
 902     if downcase(hiera('ceilometer_backend')) == 'mongodb' {
 903       pacemaker::constraint::base { 'mongodb-then-ceilometer-central-constraint':
 904         constraint_type => 'order',
 905         first_resource  => "${::mongodb::params::service_name}-clone",
 906         second_resource => "${::ceilometer::params::agent_central_service_name}-clone",
 907         first_action    => 'start',
 908         second_action   => 'start',
 909         require         => [Pacemaker::Resource::Service[$::ceilometer::params::agent_central_service_name],
 910                             Pacemaker::Resource::Service[$::mongodb::params::service_name]],
 911       }
 912     }
 913
 914     # gnocchi
 915     pacemaker::resource::service { $::gnocchi::params::metricd_service_name :
 916       clone_params => 'interleave=true',
 917     }
 918     pacemaker::resource::service { $::gnocchi::params::statsd_service_name :
 919       clone_params => 'interleave=true',
 920     }
 921     pacemaker::constraint::base { 'gnocchi-metricd-then-gnocchi-statsd-constraint':
 922       constraint_type => 'order',
 923       first_resource  => "${::gnocchi::params::metricd_service_name}-clone",
 924       second_resource => "${::gnocchi::params::statsd_service_name}-clone",
 925       first_action    => 'start',
 926       second_action   => 'start',
 927       require         => [Pacemaker::Resource::Service[$::gnocchi::params::metricd_service_name],
 928                           Pacemaker::Resource::Service[$::gnocchi::params::statsd_service_name]],
 929     }
 930     pacemaker::constraint::colocation { 'gnocchi-statsd-with-metricd-colocation':
 931       source  => "${::gnocchi::params::statsd_service_name}-clone",
 932       target  => "${::gnocchi::params::metricd_service_name}-clone",
 933       score   => 'INFINITY',
 934       require => [Pacemaker::Resource::Service[$::gnocchi::params::metricd_service_name],
 935                   Pacemaker::Resource::Service[$::gnocchi::params::statsd_service_name]],
 936     }
 937
 938     # Horizon and Keystone
 939     pacemaker::resource::service { $::apache::params::service_name:
 940       clone_params     => 'interleave=true',
 941       verify_on_create => true,
 942       require          => [File['/etc/keystone/ssl/certs/ca.pem'],
 943       File['/etc/keystone/ssl/private/signing_key.pem'],
 944       File['/etc/keystone/ssl/certs/signing_cert.pem']],
 945     }
 946
 947     #VSM
 948     if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 949       pacemaker::resource::ocf { 'vsm-p' :
 950         ocf_agent_name  => 'heartbeat:VirtualDomain',
 951         resource_params => 'force_stop=true config=/var/spool/cisco/vsm/vsm_primary_deploy.xml',
 952         require         => Class['n1k_vsm'],
 953         meta_params     => 'resource-stickiness=INFINITY',
 954       }
 955       if str2bool(hiera('n1k_vsm::pacemaker_control', true)) {
 956         pacemaker::resource::ocf { 'vsm-s' :
 957           ocf_agent_name  => 'heartbeat:VirtualDomain',
 958           resource_params => 'force_stop=true config=/var/spool/cisco/vsm/vsm_secondary_deploy.xml',
 959           require         => Class['n1k_vsm'],
 960           meta_params     => 'resource-stickiness=INFINITY',
 961         }
 962         pacemaker::constraint::colocation { 'vsm-colocation-contraint':
 963           source  => 'vsm-p',
 964           target  => 'vsm-s',
 965           score   => '-INFINITY',
 966           require => [Pacemaker::Resource::Ocf['vsm-p'],
 967                       Pacemaker::Resource::Ocf['vsm-s']],
 968         }
 969       }
 970     }
 971
 972   }
 973
 974 } #END STEP 5
 975
 976 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller_pacemaker', hiera('step')])
 977 package_manifest{$package_manifest_name: ensure => present}