puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  24
  25   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  26
  27   if $enable_load_balancer {
  28     class { '::tripleo::loadbalancer' :
  29       controller_hosts => $controller_node_ips,
  30       manage_vip       => true,
  31     }
  32   }
  33
  34 }
  35
  36 if hiera('step') >= 2 {
  37
  38   if count(hiera('ntp::servers')) > 0 {
  39     include ::ntp
  40   }
  41
  42   include ::timezone
  43
  44   # MongoDB
  45   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  46     include ::mongodb::globals
  47
  48     include ::mongodb::server
  49     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  50     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  51
  52     $mongodb_replset = hiera('mongodb::server::replset')
  53     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  54     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  55       mongodb_replset { $mongodb_replset :
  56         members => $mongo_node_ips_with_port,
  57       }
  58     }
  59   }
  60
  61   # Redis
  62   $redis_node_ips = hiera('redis_node_ips')
  63   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  64
  65   if $redis_master_hostname == $::hostname {
  66     $slaveof = undef
  67   } else {
  68     $slaveof = "${redis_master_hostname} 6379"
  69   }
  70   class {'::redis' :
  71     slaveof => $slaveof,
  72   }
  73
  74   if count($redis_node_ips) > 1 {
  75     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  76     include ::redis::sentinel
  77     include ::tripleo::redis_notification
  78   }
  79
  80   if str2bool(hiera('enable_galera', true)) {
  81     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  82   } else {
  83     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  84   }
  85   # TODO Galara
  86   class { '::mysql::server':
  87     config_file             => $mysql_config_file,
  88     override_options        => {
  89       'mysqld' => {
  90         'bind-address'     => hiera('mysql_bind_host'),
  91         'max_connections'  => hiera('mysql_max_connections'),
  92         'open_files_limit' => '-1',
  93       },
  94     },
  95     remove_default_accounts => true,
  96   }
  97
  98   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  99   # Create all the database schemas
 100   include ::keystone::db::mysql
 101   include ::glance::db::mysql
 102   include ::nova::db::mysql
 103   include ::neutron::db::mysql
 104   include ::cinder::db::mysql
 105   include ::heat::db::mysql
 106   include ::sahara::db::mysql
 107   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 108     include ::ceilometer::db::mysql
 109   }
 110
 111   $rabbit_nodes = hiera('rabbit_node_ips')
 112   if count($rabbit_nodes) > 1 {
 113     class { '::rabbitmq':
 114       config_cluster          => true,
 115       cluster_nodes           => $rabbit_nodes,
 116       tcp_keepalive           => false,
 117       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 118       config_variables        => hiera('rabbitmq_config_variables'),
 119       environment_variables   => hiera('rabbitmq_environment'),
 120     }
 121     rabbitmq_policy { 'ha-all@/':
 122       pattern    => '^(?!amq\.).*',
 123       definition => {
 124         'ha-mode' => 'all',
 125       },
 126     }
 127   } else {
 128     include ::rabbitmq
 129   }
 130
 131   # pre-install swift here so we can build rings
 132   include ::swift
 133
 134   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 135
 136   if $enable_ceph {
 137     class { '::ceph::profile::params':
 138       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 139     }
 140     include ::ceph::conf
 141     include ::ceph::profile::mon
 142   }
 143
 144   if str2bool(hiera('enable_ceph_storage', false)) {
 145     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 146       exec { 'set selinux to permissive on boot':
 147         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 148         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 149         path    => ['/usr/bin', '/usr/sbin'],
 150       }
 151
 152       exec { 'set selinux to permissive':
 153         command => 'setenforce 0',
 154         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 155         path    => ['/usr/bin', '/usr/sbin'],
 156       } -> Class['ceph::profile::osd']
 157     }
 158
 159     include ::ceph::conf
 160     include ::ceph::profile::osd
 161   }
 162
 163   if str2bool(hiera('enable_external_ceph', false)) {
 164     include ::ceph::conf
 165     include ::ceph::profile::client
 166   }
 167
 168 } #END STEP 2
 169
 170 if hiera('step') >= 3 {
 171
 172   include ::keystone
 173   include ::keystone::config
 174   include ::keystone::roles::admin
 175   include ::keystone::endpoint
 176
 177   #TODO: need a cleanup-keystone-tokens.sh solution here
 178
 179   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 180     ensure  => 'directory',
 181     owner   => 'keystone',
 182     group   => 'keystone',
 183     require => Package['keystone'],
 184   }
 185   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 186     content => hiera('keystone_signing_certificate'),
 187     owner   => 'keystone',
 188     group   => 'keystone',
 189     notify  => Service['keystone'],
 190     require => File['/etc/keystone/ssl/certs'],
 191   }
 192   file { '/etc/keystone/ssl/private/signing_key.pem':
 193     content => hiera('keystone_signing_key'),
 194     owner   => 'keystone',
 195     group   => 'keystone',
 196     notify  => Service['keystone'],
 197     require => File['/etc/keystone/ssl/private'],
 198   }
 199   file { '/etc/keystone/ssl/certs/ca.pem':
 200     content => hiera('keystone_ca_certificate'),
 201     owner   => 'keystone',
 202     group   => 'keystone',
 203     notify  => Service['keystone'],
 204     require => File['/etc/keystone/ssl/certs'],
 205   }
 206
 207   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 208   case $glance_backend {
 209       'swift': { $backend_store = 'glance.store.swift.Store' }
 210       'file': { $backend_store = 'glance.store.filesystem.Store' }
 211       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 212       default: { fail('Unrecognized glance_backend parameter.') }
 213   }
 214   $http_store = ['glance.store.http.Store']
 215   $glance_store = concat($http_store, $backend_store)
 216
 217   # TODO: notifications, scrubber, etc.
 218   include ::glance
 219   class { '::glance::api':
 220     known_stores => $glance_store,
 221   }
 222   include ::glance::registry
 223   include join(['::glance::backend::', $glance_backend])
 224
 225   class { '::nova' :
 226     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 227   }
 228   include ::nova::config
 229   include ::nova::api
 230   include ::nova::cert
 231   include ::nova::conductor
 232   include ::nova::consoleauth
 233   include ::nova::network::neutron
 234   include ::nova::vncproxy
 235   include ::nova::scheduler
 236   include ::nova::scheduler::filter
 237
 238   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 239
 240     # TODO(devvesa) provide non-controller ips for these services
 241     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 242     $cassandra_node_ips = hiera('neutron_api_node_ips')
 243
 244     # Run zookeeper in the controller if configured
 245     if hiera('enable_zookeeper_on_controller') {
 246       class {'::tripleo::cluster::zookeeper':
 247         zookeeper_server_ips => $zookeeper_node_ips,
 248         zookeeper_client_ip  => $ipaddress,
 249         zookeeper_hostnames  => hiera('controller_node_names')
 250       }
 251     }
 252
 253     # Run cassandra in the controller if configured
 254     if hiera('enable_cassandra_on_controller') {
 255       class {'::tripleo::cluster::cassandra':
 256         cassandra_servers => $cassandra_node_ips,
 257         cassandra_ip      => $ipaddress
 258       }
 259     }
 260
 261     class {'::tripleo::network::midonet::agent':
 262       zookeeper_servers => $zookeeper_node_ips,
 263       cassandra_seeds   => $cassandra_node_ips
 264     }
 265
 266     class {'::tripleo::network::midonet::api':
 267       zookeeper_servers    => $zookeeper_node_ips,
 268       vip                  => $ipaddress,
 269       keystone_ip          => $ipaddress,
 270       keystone_admin_token => hiera('keystone::admin_token'),
 271       bind_address         => $ipaddress,
 272       admin_password       => hiera('admin_password')
 273     }
 274
 275     # TODO: find a way to get an empty list from hiera
 276     class {'::neutron':
 277       service_plugins => []
 278     }
 279
 280   }
 281   else {
 282
 283     # ML2 plugin
 284     include ::neutron
 285   }
 286
 287   include ::neutron::server
 288   include ::neutron::server::notifications
 289
 290   # If the value of core plugin is set to 'nuage',
 291   # include nuage core plugin, and it does not
 292   # need the l3, dhcp and metadata agents
 293   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 294     include ::neutron::plugins::nuage
 295   } else {
 296     include ::neutron::agents::l3
 297     include ::neutron::agents::dhcp
 298     include ::neutron::agents::metadata
 299
 300     file { '/etc/neutron/dnsmasq-neutron.conf':
 301       content => hiera('neutron_dnsmasq_options'),
 302       owner   => 'neutron',
 303       group   => 'neutron',
 304       notify  => Service['neutron-dhcp-service'],
 305       require => Package['neutron'],
 306     }
 307
 308     # If the value of core plugin is set to 'midonet',
 309     # skip all the ML2 configuration
 310     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 311
 312       class {'::neutron::plugins::midonet':
 313         midonet_api_ip    => $ipaddress,
 314         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 315         keystone_password => hiera('neutron::server::auth_password')
 316       }
 317     } else {
 318
 319       include ::neutron::plugins::ml2
 320       include ::neutron::agents::ml2::ovs
 321
 322       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 323         include ::neutron::plugins::ml2::cisco::nexus1000v
 324
 325         class { '::neutron::agents::n1kv_vem':
 326           n1kv_source  => hiera('n1kv_vem_source', undef),
 327           n1kv_version => hiera('n1kv_vem_version', undef),
 328         }
 329
 330         class { '::n1k_vsm':
 331           n1kv_source       => hiera('n1kv_vsm_source', undef),
 332           n1kv_version      => hiera('n1kv_vsm_version', undef),
 333           pacemaker_control => false,
 334         }
 335       }
 336
 337       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 338         include ::neutron::plugins::ml2::cisco::ucsm
 339       }
 340       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 341         include ::neutron::plugins::ml2::cisco::nexus
 342         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 343       }
 344
 345       if hiera('neutron_enable_bigswitch_ml2', false) {
 346         include ::neutron::plugins::ml2::bigswitch::restproxy
 347       }
 348       neutron_l3_agent_config {
 349         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 350       }
 351       neutron_dhcp_agent_config {
 352         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 353       }
 354       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 355     }
 356
 357     Service['neutron-server'] -> Service['neutron-dhcp-service']
 358     Service['neutron-server'] -> Service['neutron-l3']
 359     Service['neutron-server'] -> Service['neutron-metadata']
 360   }
 361
 362   include ::cinder
 363   include ::cinder::api
 364   include ::cinder::glance
 365   include ::cinder::scheduler
 366   include ::cinder::volume
 367   class { '::cinder::setup_test_volume':
 368     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 369   }
 370
 371   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 372   if $cinder_enable_iscsi {
 373     $cinder_iscsi_backend = 'tripleo_iscsi'
 374
 375     cinder::backend::iscsi { $cinder_iscsi_backend :
 376       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 377       iscsi_helper     => hiera('cinder_iscsi_helper'),
 378     }
 379   }
 380
 381   if $enable_ceph {
 382
 383     $ceph_pools = hiera('ceph_pools')
 384     ceph::pool { $ceph_pools :
 385       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 386       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 387       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 388     }
 389
 390     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 391
 392   } else {
 393     $cinder_pool_requires = []
 394   }
 395
 396   if hiera('cinder_enable_rbd_backend', false) {
 397     $cinder_rbd_backend = 'tripleo_ceph'
 398
 399     cinder::backend::rbd { $cinder_rbd_backend :
 400       rbd_pool        => hiera('cinder_rbd_pool_name'),
 401       rbd_user        => hiera('ceph_client_user_name'),
 402       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 403       require         => $cinder_pool_requires,
 404     }
 405   }
 406
 407   if hiera('cinder_enable_eqlx_backend', false) {
 408     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 409
 410     cinder_config {
 411       "${cinder_eqlx_backend}/host": value => 'hostgroup';
 412     }
 413
 414     cinder::backend::eqlx { $cinder_eqlx_backend :
 415       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 416       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 417       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 418       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 419       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 420       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 421       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_lpool', undef),
 422       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 423       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 424       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 425     }
 426   }
 427
 428   if hiera('cinder_enable_dellsc_backend', false) {
 429     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 430
 431     cinder_config {
 432       "${cinder_dellsc_backend}/host": value => 'hostgroup';
 433     }
 434
 435     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 436       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 437       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 438       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 439       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 440       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 441       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 442       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 443       dell_sc_port          => hiera('cinder::backend::dellsc_iscsi::dell_sc_port', undef),
 444       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 445       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 446     }
 447   }
 448
 449   if hiera('cinder_enable_netapp_backend', false) {
 450     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 451
 452     cinder_config {
 453       "${cinder_netapp_backend}/host": value => 'hostgroup';
 454     }
 455
 456     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 457       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 458     }
 459
 460     cinder::backend::netapp { $cinder_netapp_backend :
 461       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 462       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 463       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 464       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 465       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 466       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 467       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 468       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 469       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 470       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 471       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 472       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 473       nfs_shares                   => $cinder_netapp_nfs_shares,
 474       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 475       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 476       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 477       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 478       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 479       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 480       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 481     }
 482   }
 483
 484   if hiera('cinder_enable_nfs_backend', false) {
 485     $cinder_nfs_backend = 'tripleo_nfs'
 486
 487     if str2bool($::selinux) {
 488       selboolean { 'virt_use_nfs':
 489         value      => on,
 490         persistent => true,
 491       } -> Package['nfs-utils']
 492     }
 493
 494     package {'nfs-utils': } ->
 495     cinder::backend::nfs { $cinder_nfs_backend :
 496       nfs_servers       => hiera('cinder_nfs_servers'),
 497       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 498       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 499     }
 500   }
 501
 502   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 503   class { '::cinder::backends' :
 504     enabled_backends => $cinder_enabled_backends,
 505   }
 506
 507   # swift proxy
 508   include ::memcached
 509   include ::swift::proxy
 510   include ::swift::proxy::proxy_logging
 511   include ::swift::proxy::healthcheck
 512   include ::swift::proxy::cache
 513   include ::swift::proxy::keystone
 514   include ::swift::proxy::authtoken
 515   include ::swift::proxy::staticweb
 516   include ::swift::proxy::ratelimit
 517   include ::swift::proxy::catch_errors
 518   include ::swift::proxy::tempurl
 519   include ::swift::proxy::formpost
 520
 521   # swift storage
 522   if str2bool(hiera('enable_swift_storage', true)) {
 523     class { '::swift::storage::all':
 524       mount_check => str2bool(hiera('swift_mount_check')),
 525     }
 526     if(!defined(File['/srv/node'])) {
 527       file { '/srv/node':
 528         ensure  => directory,
 529         owner   => 'swift',
 530         group   => 'swift',
 531         require => Package['openstack-swift'],
 532       }
 533     }
 534     $swift_components = ['account', 'container', 'object']
 535     swift::storage::filter::recon { $swift_components : }
 536     swift::storage::filter::healthcheck { $swift_components : }
 537   }
 538
 539   # Ceilometer
 540   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 541   case $ceilometer_backend {
 542     /mysql/ : {
 543       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 544     }
 545     default : {
 546       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 547     }
 548   }
 549   include ::ceilometer
 550   include ::ceilometer::config
 551   include ::ceilometer::api
 552   include ::ceilometer::agent::notification
 553   include ::ceilometer::agent::central
 554   include ::ceilometer::expirer
 555   include ::ceilometer::collector
 556   include ::ceilometer::agent::auth
 557   class { '::ceilometer::db' :
 558     database_connection => $ceilometer_database_connection,
 559   }
 560
 561   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 562
 563   # Heat
 564   include ::heat
 565   include ::heat::api
 566   include ::heat::api_cfn
 567   include ::heat::api_cloudwatch
 568   include ::heat::engine
 569
 570   # Sahara
 571   include ::sahara
 572   include ::sahara::service::api
 573   include ::sahara::service::engine
 574
 575   # Horizon
 576   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 577     $_profile_support = 'cisco'
 578   } else {
 579     $_profile_support = 'None'
 580   }
 581   $neutron_options   = {'profile_support' => $_profile_support }
 582
 583   class { '::horizon':
 584     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 585     neutron_options => $neutron_options,
 586   }
 587
 588   $snmpd_user = hiera('snmpd_readonly_user_name')
 589   snmp::snmpv3_user { $snmpd_user:
 590     authtype => 'MD5',
 591     authpass => hiera('snmpd_readonly_user_password'),
 592   }
 593   class { '::snmp':
 594     agentaddress => ['udp:161','udp6:[::1]:161'],
 595     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 596   }
 597
 598   hiera_include('controller_classes')
 599
 600 } #END STEP 3
 601
 602 if hiera('step') >= 4 {
 603   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 604   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 605   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 606
 607   if $keystone_enable_db_purge {
 608     include ::keystone::cron::token_flush
 609   }
 610   if $nova_enable_db_purge {
 611     include ::nova::cron::archive_deleted_rows
 612   }
 613   if $cinder_enable_db_purge {
 614     include ::cinder::cron::db_purge
 615   }
 616 } #END STEP 4
 617
 618 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 619 package_manifest{$package_manifest_name: ensure => present}