puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  28
  29   if $enable_load_balancer {
  30     class { '::tripleo::loadbalancer' :
  31       controller_hosts => $controller_node_ips,
  32       manage_vip       => true,
  33     }
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   include ::timezone
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49     include ::mongodb::client
  50     include ::mongodb::server
  51     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  52     # without the brackets as 'members' argument for the 'mongodb_replset'
  53     # resource.
  54     if str2bool(hiera('mongodb::server::ipv6', false)) {
  55       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  56       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  57       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  58     } else {
  59       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  60       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  61     }
  62     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  63
  64     $mongodb_replset = hiera('mongodb::server::replset')
  65     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  66     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  67       mongodb_replset { $mongodb_replset :
  68         members => $mongo_node_ips_with_port_nobr,
  69       }
  70     }
  71   }
  72
  73   # Redis
  74   $redis_node_ips = hiera('redis_node_ips')
  75   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  76
  77   if $redis_master_hostname == $::hostname {
  78     $slaveof = undef
  79   } else {
  80     $slaveof = "${redis_master_hostname} 6379"
  81   }
  82   class {'::redis' :
  83     slaveof => $slaveof,
  84   }
  85
  86   if count($redis_node_ips) > 1 {
  87     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  88     include ::redis::sentinel
  89     include ::tripleo::redis_notification
  90   }
  91
  92   if str2bool(hiera('enable_galera', true)) {
  93     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  94   } else {
  95     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  96   }
  97   # TODO Galara
  98   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  99   # set bind-address to a hostname instead of an ip address; to move Mysql
 100   # from internal_api on another network we'll have to customize both
 101   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
 102   class { '::mysql::server':
 103     config_file             => $mysql_config_file,
 104     override_options        => {
 105       'mysqld' => {
 106         'bind-address'     => $::hostname,
 107         'max_connections'  => hiera('mysql_max_connections'),
 108         'open_files_limit' => '-1',
 109       },
 110     },
 111     remove_default_accounts => true,
 112   }
 113
 114   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 115   # Create all the database schemas
 116   include ::keystone::db::mysql
 117   include ::glance::db::mysql
 118   include ::nova::db::mysql
 119   include ::nova::db::mysql_api
 120   include ::neutron::db::mysql
 121   include ::cinder::db::mysql
 122   include ::heat::db::mysql
 123   include ::sahara::db::mysql
 124   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 125     include ::ceilometer::db::mysql
 126   }
 127
 128   $rabbit_nodes = hiera('rabbit_node_ips')
 129   if count($rabbit_nodes) > 1 {
 130
 131     $rabbit_ipv6 = str2bool(hiera('rabbit_ipv6', false))
 132     if $rabbit_ipv6 {
 133       $rabbit_env = merge(hiera('rabbitmq_environment'), {
 134         'RABBITMQ_SERVER_START_ARGS' => '"-proto_dist inet6_tcp"'
 135       })
 136     } else {
 137       $rabbit_env = hiera('rabbitmq_environment')
 138     }
 139
 140     class { '::rabbitmq':
 141       config_cluster          => true,
 142       cluster_nodes           => $rabbit_nodes,
 143       tcp_keepalive           => false,
 144       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 145       config_variables        => hiera('rabbitmq_config_variables'),
 146       environment_variables   => $rabbit_env,
 147     }
 148     rabbitmq_policy { 'ha-all@/':
 149       pattern    => '^(?!amq\.).*',
 150       definition => {
 151         'ha-mode' => 'all',
 152       },
 153     }
 154   } else {
 155     include ::rabbitmq
 156   }
 157
 158   # pre-install swift here so we can build rings
 159   include ::swift
 160
 161   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 162
 163   if $enable_ceph {
 164     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 165     if str2bool(hiera('ceph_ipv6', false)) {
 166       $mon_host = hiera('ceph_mon_host_v6')
 167     } else {
 168       $mon_host = hiera('ceph_mon_host')
 169     }
 170     class { '::ceph::profile::params':
 171       mon_initial_members => $mon_initial_members,
 172       mon_host            => $mon_host,
 173     }
 174     include ::ceph::conf
 175     include ::ceph::profile::mon
 176   }
 177
 178   if str2bool(hiera('enable_ceph_storage', false)) {
 179     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 180       exec { 'set selinux to permissive on boot':
 181         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 182         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 183         path    => ['/usr/bin', '/usr/sbin'],
 184       }
 185
 186       exec { 'set selinux to permissive':
 187         command => 'setenforce 0',
 188         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 189         path    => ['/usr/bin', '/usr/sbin'],
 190       } -> Class['ceph::profile::osd']
 191     }
 192
 193     include ::ceph::conf
 194     include ::ceph::profile::osd
 195   }
 196
 197   if str2bool(hiera('enable_external_ceph', false)) {
 198     if str2bool(hiera('ceph_ipv6', false)) {
 199       $mon_host = hiera('ceph_mon_host_v6')
 200     } else {
 201       $mon_host = hiera('ceph_mon_host')
 202     }
 203     class { '::ceph::profile::params':
 204       mon_host            => $mon_host,
 205     }
 206     include ::ceph::conf
 207     include ::ceph::profile::client
 208   }
 209
 210 } #END STEP 2
 211
 212 if hiera('step') >= 3 {
 213
 214   include ::keystone
 215   include ::keystone::config
 216   include ::keystone::roles::admin
 217   include ::keystone::endpoint
 218   include ::keystone::wsgi::apache
 219
 220   #TODO: need a cleanup-keystone-tokens.sh solution here
 221
 222   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 223     ensure  => 'directory',
 224     owner   => 'keystone',
 225     group   => 'keystone',
 226     require => Package['keystone'],
 227   }
 228   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 229     content => hiera('keystone_signing_certificate'),
 230     owner   => 'keystone',
 231     group   => 'keystone',
 232     notify  => Service['keystone'],
 233     require => File['/etc/keystone/ssl/certs'],
 234   }
 235   file { '/etc/keystone/ssl/private/signing_key.pem':
 236     content => hiera('keystone_signing_key'),
 237     owner   => 'keystone',
 238     group   => 'keystone',
 239     notify  => Service['keystone'],
 240     require => File['/etc/keystone/ssl/private'],
 241   }
 242   file { '/etc/keystone/ssl/certs/ca.pem':
 243     content => hiera('keystone_ca_certificate'),
 244     owner   => 'keystone',
 245     group   => 'keystone',
 246     notify  => Service['keystone'],
 247     require => File['/etc/keystone/ssl/certs'],
 248   }
 249
 250   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 251   case $glance_backend {
 252       'swift': { $backend_store = 'glance.store.swift.Store' }
 253       'file': { $backend_store = 'glance.store.filesystem.Store' }
 254       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 255       default: { fail('Unrecognized glance_backend parameter.') }
 256   }
 257   $http_store = ['glance.store.http.Store']
 258   $glance_store = concat($http_store, $backend_store)
 259
 260   # TODO: scrubber and other additional optional features
 261   include ::glance
 262   include ::glance::config
 263   class { '::glance::api':
 264     known_stores => $glance_store,
 265   }
 266   include ::glance::registry
 267   include ::glance::notify::rabbitmq
 268   include join(['::glance::backend::', $glance_backend])
 269
 270   class { '::nova' :
 271     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 272   }
 273   include ::nova::config
 274   include ::nova::api
 275   include ::nova::cert
 276   include ::nova::conductor
 277   include ::nova::consoleauth
 278   include ::nova::network::neutron
 279   include ::nova::vncproxy
 280   include ::nova::scheduler
 281   include ::nova::scheduler::filter
 282
 283   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 284
 285     # TODO(devvesa) provide non-controller ips for these services
 286     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 287     $cassandra_node_ips = hiera('neutron_api_node_ips')
 288
 289     # Run zookeeper in the controller if configured
 290     if hiera('enable_zookeeper_on_controller') {
 291       class {'::tripleo::cluster::zookeeper':
 292         zookeeper_server_ips => $zookeeper_node_ips,
 293         # TODO: create a 'bind' hiera key for zookeeper
 294         zookeeper_client_ip  => hiera('neutron::bind_host'),
 295         zookeeper_hostnames  => hiera('controller_node_names')
 296       }
 297     }
 298
 299     # Run cassandra in the controller if configured
 300     if hiera('enable_cassandra_on_controller') {
 301       class {'::tripleo::cluster::cassandra':
 302         cassandra_servers => $cassandra_node_ips,
 303         # TODO: create a 'bind' hiera key for cassandra
 304         cassandra_ip      => hiera('neutron::bind_host'),
 305       }
 306     }
 307
 308     class {'::tripleo::network::midonet::agent':
 309       zookeeper_servers => $zookeeper_node_ips,
 310       cassandra_seeds   => $cassandra_node_ips
 311     }
 312
 313     class {'::tripleo::network::midonet::api':
 314       zookeeper_servers    => $zookeeper_node_ips,
 315       vip                  => hiera('tripleo::loadbalancer::public_virtual_ip'),
 316       keystone_ip          => hiera('tripleo::loadbalancer::public_virtual_ip'),
 317       keystone_admin_token => hiera('keystone::admin_token'),
 318       # TODO: create a 'bind' hiera key for api
 319       bind_address         => hiera('neutron::bind_host'),
 320       admin_password       => hiera('admin_password')
 321     }
 322
 323     # TODO: find a way to get an empty list from hiera
 324     class {'::neutron':
 325       service_plugins => []
 326     }
 327
 328   }
 329   else {
 330
 331     # ML2 plugin
 332     include ::neutron
 333   }
 334
 335   include ::neutron::config
 336   include ::neutron::server
 337   include ::neutron::server::notifications
 338
 339   # If the value of core plugin is set to 'nuage' or'opencontrail' or 'plumgrid',
 340   # include nuage or opencontrail or plumgrid core plugins
 341   # else use the default value of 'ml2'
 342   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 343     include ::neutron::plugins::nuage
 344   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 345     include ::neutron::plugins::opencontrail
 346   }
 347   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 348     class { '::neutron::plugins::plumgrid' :
 349       connection                   => hiera('neutron::server::database_connection'),
 350       controller_priv_host         => hiera('keystone_admin_api_vip'),
 351       admin_password               => hiera('admin_password'),
 352       metadata_proxy_shared_secret => hiera('nova::api::neutron_metadata_proxy_shared_secret'),
 353     }
 354   } else {
 355     include ::neutron::agents::l3
 356     include ::neutron::agents::dhcp
 357     include ::neutron::agents::metadata
 358
 359     file { '/etc/neutron/dnsmasq-neutron.conf':
 360       content => hiera('neutron_dnsmasq_options'),
 361       owner   => 'neutron',
 362       group   => 'neutron',
 363       notify  => Service['neutron-dhcp-service'],
 364       require => Package['neutron'],
 365     }
 366
 367     # If the value of core plugin is set to 'midonet',
 368     # skip all the ML2 configuration
 369     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 370
 371       class {'::neutron::plugins::midonet':
 372         midonet_api_ip    => hiera('tripleo::loadbalancer::public_virtual_ip'),
 373         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 374         keystone_password => hiera('neutron::server::auth_password')
 375       }
 376     } else {
 377
 378       include ::neutron::plugins::ml2
 379       include ::neutron::agents::ml2::ovs
 380
 381       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 382         include ::neutron::plugins::ml2::cisco::nexus1000v
 383
 384         class { '::neutron::agents::n1kv_vem':
 385           n1kv_source  => hiera('n1kv_vem_source', undef),
 386           n1kv_version => hiera('n1kv_vem_version', undef),
 387         }
 388
 389         class { '::n1k_vsm':
 390           n1kv_source       => hiera('n1kv_vsm_source', undef),
 391           n1kv_version      => hiera('n1kv_vsm_version', undef),
 392           pacemaker_control => false,
 393         }
 394       }
 395
 396       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 397         include ::neutron::plugins::ml2::cisco::ucsm
 398       }
 399       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 400         include ::neutron::plugins::ml2::cisco::nexus
 401         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 402       }
 403
 404       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 405         include ::neutron::plugins::ml2::bigswitch::restproxy
 406         include ::neutron::agents::bigswitch
 407       }
 408       neutron_l3_agent_config {
 409         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 410       }
 411       neutron_dhcp_agent_config {
 412         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 413       }
 414       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 415     }
 416
 417     Service['neutron-server'] -> Service['neutron-dhcp-service']
 418     Service['neutron-server'] -> Service['neutron-l3']
 419     Service['neutron-server'] -> Service['neutron-metadata']
 420   }
 421
 422   include ::cinder
 423   include ::cinder::config
 424   include ::tripleo::ssl::cinder_config
 425   include ::cinder::api
 426   include ::cinder::glance
 427   include ::cinder::scheduler
 428   include ::cinder::volume
 429   include ::cinder::ceilometer
 430   class { '::cinder::setup_test_volume':
 431     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 432   }
 433
 434   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 435   if $cinder_enable_iscsi {
 436     $cinder_iscsi_backend = 'tripleo_iscsi'
 437
 438     cinder::backend::iscsi { $cinder_iscsi_backend :
 439       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 440       iscsi_helper     => hiera('cinder_iscsi_helper'),
 441     }
 442   }
 443
 444   if $enable_ceph {
 445
 446     $ceph_pools = hiera('ceph_pools')
 447     ceph::pool { $ceph_pools :
 448       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 449       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 450       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 451     }
 452
 453     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 454
 455   } else {
 456     $cinder_pool_requires = []
 457   }
 458
 459   if hiera('cinder_enable_rbd_backend', false) {
 460     $cinder_rbd_backend = 'tripleo_ceph'
 461
 462     cinder::backend::rbd { $cinder_rbd_backend :
 463       rbd_pool        => hiera('cinder_rbd_pool_name'),
 464       rbd_user        => hiera('ceph_client_user_name'),
 465       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 466       require         => $cinder_pool_requires,
 467     }
 468   }
 469
 470   if hiera('cinder_enable_eqlx_backend', false) {
 471     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 472
 473     cinder::backend::eqlx { $cinder_eqlx_backend :
 474       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 475       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 476       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 477       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 478       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 479       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 480       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 481       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 482       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 483       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 484     }
 485   }
 486
 487   if hiera('cinder_enable_dellsc_backend', false) {
 488     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 489
 490     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 491       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 492       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 493       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 494       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 495       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 496       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 497       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 498       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 499       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 500       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 501     }
 502   }
 503
 504   if hiera('cinder_enable_netapp_backend', false) {
 505     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 506
 507     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 508       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 509     }
 510
 511     cinder::backend::netapp { $cinder_netapp_backend :
 512       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 513       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 514       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 515       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 516       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 517       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 518       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 519       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 520       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 521       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 522       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 523       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 524       nfs_shares                   => $cinder_netapp_nfs_shares,
 525       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 526       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 527       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 528       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 529       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 530       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 531       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 532     }
 533   }
 534
 535   if hiera('cinder_enable_nfs_backend', false) {
 536     $cinder_nfs_backend = 'tripleo_nfs'
 537
 538     if str2bool($::selinux) {
 539       selboolean { 'virt_use_nfs':
 540         value      => on,
 541         persistent => true,
 542       } -> Package['nfs-utils']
 543     }
 544
 545     package {'nfs-utils': } ->
 546     cinder::backend::nfs { $cinder_nfs_backend :
 547       nfs_servers       => hiera('cinder_nfs_servers'),
 548       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 549       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 550     }
 551   }
 552
 553   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 554   class { '::cinder::backends' :
 555     enabled_backends => union($cinder_enabled_backends, hiera('cinder_user_enabled_backends')),
 556   }
 557
 558   # swift proxy
 559   include ::memcached
 560   include ::swift::proxy
 561   include ::swift::proxy::proxy_logging
 562   include ::swift::proxy::healthcheck
 563   include ::swift::proxy::cache
 564   include ::swift::proxy::keystone
 565   include ::swift::proxy::authtoken
 566   include ::swift::proxy::staticweb
 567   include ::swift::proxy::ratelimit
 568   include ::swift::proxy::catch_errors
 569   include ::swift::proxy::tempurl
 570   include ::swift::proxy::formpost
 571
 572   # swift storage
 573   if str2bool(hiera('enable_swift_storage', true)) {
 574     class { '::swift::storage::all':
 575       mount_check => str2bool(hiera('swift_mount_check')),
 576     }
 577     if(!defined(File['/srv/node'])) {
 578       file { '/srv/node':
 579         ensure  => directory,
 580         owner   => 'swift',
 581         group   => 'swift',
 582         require => Package['openstack-swift'],
 583       }
 584     }
 585     $swift_components = ['account', 'container', 'object']
 586     swift::storage::filter::recon { $swift_components : }
 587     swift::storage::filter::healthcheck { $swift_components : }
 588   }
 589
 590   # Ceilometer
 591   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 592   case $ceilometer_backend {
 593     /mysql/ : {
 594       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 595     }
 596     default : {
 597       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 598     }
 599   }
 600   include ::ceilometer
 601   include ::ceilometer::config
 602   include ::ceilometer::api
 603   include ::ceilometer::agent::notification
 604   include ::ceilometer::agent::central
 605   include ::ceilometer::expirer
 606   include ::ceilometer::collector
 607   include ::ceilometer::agent::auth
 608   class { '::ceilometer::db' :
 609     database_connection => $ceilometer_database_connection,
 610   }
 611
 612   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 613
 614   # Heat
 615   class { '::heat' :
 616     notification_driver => 'messaging',
 617   }
 618   include ::heat::config
 619   include ::heat::api
 620   include ::heat::api_cfn
 621   include ::heat::api_cloudwatch
 622   include ::heat::engine
 623
 624   # Sahara
 625   include ::sahara
 626   include ::sahara::service::api
 627   include ::sahara::service::engine
 628
 629   # Horizon
 630   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 631     $_profile_support = 'cisco'
 632   } else {
 633     $_profile_support = 'None'
 634   }
 635   $neutron_options   = {'profile_support' => $_profile_support }
 636
 637   class { '::horizon':
 638     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 639     neutron_options => $neutron_options,
 640   }
 641
 642   $snmpd_user = hiera('snmpd_readonly_user_name')
 643   snmp::snmpv3_user { $snmpd_user:
 644     authtype => 'MD5',
 645     authpass => hiera('snmpd_readonly_user_password'),
 646   }
 647   class { '::snmp':
 648     agentaddress => ['udp:161','udp6:[::1]:161'],
 649     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 650   }
 651
 652   hiera_include('controller_classes')
 653
 654 } #END STEP 3
 655
 656 if hiera('step') >= 4 {
 657   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 658   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 659   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 660   $heat_enable_db_purge = hiera('heat_enable_db_purge', true)
 661
 662   if $keystone_enable_db_purge {
 663     include ::keystone::cron::token_flush
 664   }
 665   if $nova_enable_db_purge {
 666     include ::nova::cron::archive_deleted_rows
 667   }
 668   if $cinder_enable_db_purge {
 669     include ::cinder::cron::db_purge
 670   }
 671   if $heat_enable_db_purge {
 672     include ::heat::cron::purge_deleted
 673   }
 674
 675   if downcase(hiera('bootstrap_nodeid')) == $::hostname {
 676     include ::keystone::roles::admin
 677     # Class ::heat::keystone::domain has to run on bootstrap node
 678     # because it creates DB entities via API calls.
 679     include ::heat::keystone::domain
 680
 681     Class['::keystone::roles::admin'] -> Class['::heat::keystone::domain']
 682   } else {
 683     # On non-bootstrap node we don't need to create Keystone resources again
 684     class { '::heat::keystone::domain':
 685       manage_domain => false,
 686       manage_user   => false,
 687       manage_role   => false,
 688     }
 689   }
 690
 691 } #END STEP 4
 692
 693 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 694 package_manifest{$package_manifest_name: ensure => present}