puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  28
  29   if $enable_load_balancer {
  30     class { '::tripleo::loadbalancer' :
  31       controller_hosts => $controller_node_ips,
  32       manage_vip       => true,
  33     }
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   include ::timezone
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49
  50     include ::mongodb::server
  51     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  52     # without the brackets as 'members' argument for the 'mongodb_replset'
  53     # resource.
  54     if str2bool(hiera('mongodb::server::ipv6', false)) {
  55       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  56       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  57       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  58     } else {
  59       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  60       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  61     }
  62     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  63
  64     $mongodb_replset = hiera('mongodb::server::replset')
  65     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  66     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  67       mongodb_replset { $mongodb_replset :
  68         members => $mongo_node_ips_with_port_nobr,
  69       }
  70     }
  71   }
  72
  73   # Redis
  74   $redis_node_ips = hiera('redis_node_ips')
  75   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  76
  77   if $redis_master_hostname == $::hostname {
  78     $slaveof = undef
  79   } else {
  80     $slaveof = "${redis_master_hostname} 6379"
  81   }
  82   class {'::redis' :
  83     slaveof => $slaveof,
  84   }
  85
  86   if count($redis_node_ips) > 1 {
  87     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  88     include ::redis::sentinel
  89     include ::tripleo::redis_notification
  90   }
  91
  92   if str2bool(hiera('enable_galera', true)) {
  93     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  94   } else {
  95     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  96   }
  97   # TODO Galara
  98   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  99   # set bind-address to a hostname instead of an ip address; to move Mysql
 100   # from internal_api on another network we'll have to customize both
 101   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
 102   class { '::mysql::server':
 103     config_file             => $mysql_config_file,
 104     override_options        => {
 105       'mysqld' => {
 106         'bind-address'     => $::hostname,
 107         'max_connections'  => hiera('mysql_max_connections'),
 108         'open_files_limit' => '-1',
 109       },
 110     },
 111     remove_default_accounts => true,
 112   }
 113
 114   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 115   # Create all the database schemas
 116   include ::keystone::db::mysql
 117   include ::glance::db::mysql
 118   include ::nova::db::mysql
 119   include ::nova::db::mysql_api
 120   include ::neutron::db::mysql
 121   include ::cinder::db::mysql
 122   include ::heat::db::mysql
 123   include ::sahara::db::mysql
 124   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 125     include ::ceilometer::db::mysql
 126   }
 127
 128   $rabbit_nodes = hiera('rabbit_node_ips')
 129   if count($rabbit_nodes) > 1 {
 130
 131     $rabbit_ipv6 = str2bool(hiera('rabbit_ipv6', false))
 132     if $rabbit_ipv6 {
 133       $rabbit_env = merge(hiera('rabbitmq_environment'), {
 134         'RABBITMQ_SERVER_START_ARGS' => '"-proto_dist inet6_tcp"'
 135       })
 136     } else {
 137       $rabbit_env = hiera('rabbitmq_environment')
 138     }
 139
 140     class { '::rabbitmq':
 141       config_cluster          => true,
 142       cluster_nodes           => $rabbit_nodes,
 143       tcp_keepalive           => false,
 144       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 145       config_variables        => hiera('rabbitmq_config_variables'),
 146       environment_variables   => $rabbit_env,
 147     }
 148     rabbitmq_policy { 'ha-all@/':
 149       pattern    => '^(?!amq\.).*',
 150       definition => {
 151         'ha-mode' => 'all',
 152       },
 153     }
 154   } else {
 155     include ::rabbitmq
 156   }
 157
 158   # pre-install swift here so we can build rings
 159   include ::swift
 160
 161   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 162
 163   if $enable_ceph {
 164     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 165     if str2bool(hiera('ceph_ipv6', false)) {
 166       $mon_host = hiera('ceph_mon_host_v6')
 167     } else {
 168       $mon_host = hiera('ceph_mon_host')
 169     }
 170     class { '::ceph::profile::params':
 171       mon_initial_members => $mon_initial_members,
 172       mon_host            => $mon_host,
 173     }
 174     include ::ceph::conf
 175     include ::ceph::profile::mon
 176   }
 177
 178   if str2bool(hiera('enable_ceph_storage', false)) {
 179     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 180       exec { 'set selinux to permissive on boot':
 181         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 182         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 183         path    => ['/usr/bin', '/usr/sbin'],
 184       }
 185
 186       exec { 'set selinux to permissive':
 187         command => 'setenforce 0',
 188         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 189         path    => ['/usr/bin', '/usr/sbin'],
 190       } -> Class['ceph::profile::osd']
 191     }
 192
 193     include ::ceph::conf
 194     include ::ceph::profile::osd
 195   }
 196
 197   if str2bool(hiera('enable_external_ceph', false)) {
 198     if str2bool(hiera('ceph_ipv6', false)) {
 199       $mon_host = hiera('ceph_mon_host_v6')
 200     } else {
 201       $mon_host = hiera('ceph_mon_host')
 202     }
 203     class { '::ceph::profile::params':
 204       mon_host            => $mon_host,
 205     }
 206     include ::ceph::conf
 207     include ::ceph::profile::client
 208   }
 209
 210 } #END STEP 2
 211
 212 if hiera('step') >= 3 {
 213
 214   include ::keystone
 215   include ::keystone::config
 216   include ::keystone::roles::admin
 217   include ::keystone::endpoint
 218   include ::keystone::wsgi::apache
 219
 220   #TODO: need a cleanup-keystone-tokens.sh solution here
 221
 222   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 223     ensure  => 'directory',
 224     owner   => 'keystone',
 225     group   => 'keystone',
 226     require => Package['keystone'],
 227   }
 228   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 229     content => hiera('keystone_signing_certificate'),
 230     owner   => 'keystone',
 231     group   => 'keystone',
 232     notify  => Service['keystone'],
 233     require => File['/etc/keystone/ssl/certs'],
 234   }
 235   file { '/etc/keystone/ssl/private/signing_key.pem':
 236     content => hiera('keystone_signing_key'),
 237     owner   => 'keystone',
 238     group   => 'keystone',
 239     notify  => Service['keystone'],
 240     require => File['/etc/keystone/ssl/private'],
 241   }
 242   file { '/etc/keystone/ssl/certs/ca.pem':
 243     content => hiera('keystone_ca_certificate'),
 244     owner   => 'keystone',
 245     group   => 'keystone',
 246     notify  => Service['keystone'],
 247     require => File['/etc/keystone/ssl/certs'],
 248   }
 249
 250   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 251   case $glance_backend {
 252       'swift': { $backend_store = 'glance.store.swift.Store' }
 253       'file': { $backend_store = 'glance.store.filesystem.Store' }
 254       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 255       default: { fail('Unrecognized glance_backend parameter.') }
 256   }
 257   $http_store = ['glance.store.http.Store']
 258   $glance_store = concat($http_store, $backend_store)
 259
 260   # TODO: scrubber and other additional optional features
 261   include ::glance
 262   include ::glance::config
 263   class { '::glance::api':
 264     known_stores => $glance_store,
 265   }
 266   include ::glance::registry
 267   include ::glance::notify::rabbitmq
 268   include join(['::glance::backend::', $glance_backend])
 269
 270   class { '::nova' :
 271     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 272   }
 273   include ::nova::config
 274   include ::nova::api
 275   include ::nova::cert
 276   include ::nova::conductor
 277   include ::nova::consoleauth
 278   include ::nova::network::neutron
 279   include ::nova::vncproxy
 280   include ::nova::scheduler
 281   include ::nova::scheduler::filter
 282
 283   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 284
 285     # TODO(devvesa) provide non-controller ips for these services
 286     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 287     $cassandra_node_ips = hiera('neutron_api_node_ips')
 288
 289     # Run zookeeper in the controller if configured
 290     if hiera('enable_zookeeper_on_controller') {
 291       class {'::tripleo::cluster::zookeeper':
 292         zookeeper_server_ips => $zookeeper_node_ips,
 293         # TODO: create a 'bind' hiera key for zookeeper
 294         zookeeper_client_ip  => hiera('neutron::bind_host'),
 295         zookeeper_hostnames  => hiera('controller_node_names')
 296       }
 297     }
 298
 299     # Run cassandra in the controller if configured
 300     if hiera('enable_cassandra_on_controller') {
 301       class {'::tripleo::cluster::cassandra':
 302         cassandra_servers => $cassandra_node_ips,
 303         # TODO: create a 'bind' hiera key for cassandra
 304         cassandra_ip      => hiera('neutron::bind_host'),
 305       }
 306     }
 307
 308     class {'::tripleo::network::midonet::agent':
 309       zookeeper_servers => $zookeeper_node_ips,
 310       cassandra_seeds   => $cassandra_node_ips
 311     }
 312
 313     class {'::tripleo::network::midonet::api':
 314       zookeeper_servers    => $zookeeper_node_ips,
 315       vip                  => hiera('tripleo::loadbalancer::public_virtual_ip'),
 316       keystone_ip          => hiera('tripleo::loadbalancer::public_virtual_ip'),
 317       keystone_admin_token => hiera('keystone::admin_token'),
 318       # TODO: create a 'bind' hiera key for api
 319       bind_address         => hiera('neutron::bind_host'),
 320       admin_password       => hiera('admin_password')
 321     }
 322
 323     # TODO: find a way to get an empty list from hiera
 324     class {'::neutron':
 325       service_plugins => []
 326     }
 327
 328   }
 329   else {
 330
 331     # ML2 plugin
 332     include ::neutron
 333   }
 334
 335   include ::neutron::config
 336   include ::neutron::server
 337   include ::neutron::server::notifications
 338
 339   # If the value of core plugin is set to 'nuage' or 'opencontrail',
 340   # include nuage or opencontrail core plugins, and it does not
 341   # need the l3, dhcp and metadata agents
 342   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 343     include ::neutron::plugins::nuage
 344   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 345     include ::neutron::plugins::opencontrail
 346   } else {
 347     include ::neutron::agents::l3
 348     include ::neutron::agents::dhcp
 349     include ::neutron::agents::metadata
 350
 351     file { '/etc/neutron/dnsmasq-neutron.conf':
 352       content => hiera('neutron_dnsmasq_options'),
 353       owner   => 'neutron',
 354       group   => 'neutron',
 355       notify  => Service['neutron-dhcp-service'],
 356       require => Package['neutron'],
 357     }
 358
 359     # If the value of core plugin is set to 'midonet',
 360     # skip all the ML2 configuration
 361     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 362
 363       class {'::neutron::plugins::midonet':
 364         midonet_api_ip    => hiera('tripleo::loadbalancer::public_virtual_ip'),
 365         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 366         keystone_password => hiera('neutron::server::auth_password')
 367       }
 368     } else {
 369
 370       include ::neutron::plugins::ml2
 371       include ::neutron::agents::ml2::ovs
 372
 373       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 374         include ::neutron::plugins::ml2::cisco::nexus1000v
 375
 376         class { '::neutron::agents::n1kv_vem':
 377           n1kv_source  => hiera('n1kv_vem_source', undef),
 378           n1kv_version => hiera('n1kv_vem_version', undef),
 379         }
 380
 381         class { '::n1k_vsm':
 382           n1kv_source       => hiera('n1kv_vsm_source', undef),
 383           n1kv_version      => hiera('n1kv_vsm_version', undef),
 384           pacemaker_control => false,
 385         }
 386       }
 387
 388       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 389         include ::neutron::plugins::ml2::cisco::ucsm
 390       }
 391       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 392         include ::neutron::plugins::ml2::cisco::nexus
 393         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 394       }
 395
 396       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 397         include ::neutron::plugins::ml2::bigswitch::restproxy
 398         include ::neutron::agents::bigswitch
 399       }
 400       neutron_l3_agent_config {
 401         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 402       }
 403       neutron_dhcp_agent_config {
 404         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 405       }
 406       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 407     }
 408
 409     Service['neutron-server'] -> Service['neutron-dhcp-service']
 410     Service['neutron-server'] -> Service['neutron-l3']
 411     Service['neutron-server'] -> Service['neutron-metadata']
 412   }
 413
 414   include ::cinder
 415   include ::cinder::config
 416   include ::tripleo::ssl::cinder_config
 417   include ::cinder::api
 418   include ::cinder::glance
 419   include ::cinder::scheduler
 420   include ::cinder::volume
 421   include ::cinder::ceilometer
 422   class { '::cinder::setup_test_volume':
 423     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 424   }
 425
 426   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 427   if $cinder_enable_iscsi {
 428     $cinder_iscsi_backend = 'tripleo_iscsi'
 429
 430     cinder::backend::iscsi { $cinder_iscsi_backend :
 431       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 432       iscsi_helper     => hiera('cinder_iscsi_helper'),
 433     }
 434   }
 435
 436   if $enable_ceph {
 437
 438     $ceph_pools = hiera('ceph_pools')
 439     ceph::pool { $ceph_pools :
 440       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 441       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 442       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 443     }
 444
 445     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 446
 447   } else {
 448     $cinder_pool_requires = []
 449   }
 450
 451   if hiera('cinder_enable_rbd_backend', false) {
 452     $cinder_rbd_backend = 'tripleo_ceph'
 453
 454     cinder::backend::rbd { $cinder_rbd_backend :
 455       rbd_pool        => hiera('cinder_rbd_pool_name'),
 456       rbd_user        => hiera('ceph_client_user_name'),
 457       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 458       require         => $cinder_pool_requires,
 459     }
 460   }
 461
 462   if hiera('cinder_enable_eqlx_backend', false) {
 463     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 464
 465     cinder::backend::eqlx { $cinder_eqlx_backend :
 466       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 467       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 468       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 469       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 470       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 471       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 472       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 473       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 474       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 475       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 476     }
 477   }
 478
 479   if hiera('cinder_enable_dellsc_backend', false) {
 480     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 481
 482     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 483       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 484       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 485       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 486       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 487       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 488       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 489       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 490       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 491       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 492       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 493     }
 494   }
 495
 496   if hiera('cinder_enable_netapp_backend', false) {
 497     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 498
 499     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 500       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 501     }
 502
 503     cinder::backend::netapp { $cinder_netapp_backend :
 504       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 505       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 506       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 507       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 508       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 509       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 510       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 511       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 512       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 513       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 514       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 515       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 516       nfs_shares                   => $cinder_netapp_nfs_shares,
 517       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 518       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 519       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 520       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 521       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 522       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 523       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 524     }
 525   }
 526
 527   if hiera('cinder_enable_nfs_backend', false) {
 528     $cinder_nfs_backend = 'tripleo_nfs'
 529
 530     if str2bool($::selinux) {
 531       selboolean { 'virt_use_nfs':
 532         value      => on,
 533         persistent => true,
 534       } -> Package['nfs-utils']
 535     }
 536
 537     package {'nfs-utils': } ->
 538     cinder::backend::nfs { $cinder_nfs_backend :
 539       nfs_servers       => hiera('cinder_nfs_servers'),
 540       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 541       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 542     }
 543   }
 544
 545   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 546   class { '::cinder::backends' :
 547     enabled_backends => union($cinder_enabled_backends, hiera('cinder_user_enabled_backends')),
 548   }
 549
 550   # swift proxy
 551   include ::memcached
 552   include ::swift::proxy
 553   include ::swift::proxy::proxy_logging
 554   include ::swift::proxy::healthcheck
 555   include ::swift::proxy::cache
 556   include ::swift::proxy::keystone
 557   include ::swift::proxy::authtoken
 558   include ::swift::proxy::staticweb
 559   include ::swift::proxy::ratelimit
 560   include ::swift::proxy::catch_errors
 561   include ::swift::proxy::tempurl
 562   include ::swift::proxy::formpost
 563
 564   # swift storage
 565   if str2bool(hiera('enable_swift_storage', true)) {
 566     class { '::swift::storage::all':
 567       mount_check => str2bool(hiera('swift_mount_check')),
 568     }
 569     if(!defined(File['/srv/node'])) {
 570       file { '/srv/node':
 571         ensure  => directory,
 572         owner   => 'swift',
 573         group   => 'swift',
 574         require => Package['openstack-swift'],
 575       }
 576     }
 577     $swift_components = ['account', 'container', 'object']
 578     swift::storage::filter::recon { $swift_components : }
 579     swift::storage::filter::healthcheck { $swift_components : }
 580   }
 581
 582   # Ceilometer
 583   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 584   case $ceilometer_backend {
 585     /mysql/ : {
 586       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 587     }
 588     default : {
 589       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 590     }
 591   }
 592   include ::ceilometer
 593   include ::ceilometer::config
 594   include ::ceilometer::api
 595   include ::ceilometer::agent::notification
 596   include ::ceilometer::agent::central
 597   include ::ceilometer::expirer
 598   include ::ceilometer::collector
 599   include ::ceilometer::agent::auth
 600   class { '::ceilometer::db' :
 601     database_connection => $ceilometer_database_connection,
 602   }
 603
 604   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 605
 606   # Heat
 607   class { '::heat' :
 608     notification_driver => 'messaging',
 609   }
 610   include ::heat::config
 611   include ::heat::api
 612   include ::heat::api_cfn
 613   include ::heat::api_cloudwatch
 614   include ::heat::engine
 615
 616   # Sahara
 617   include ::sahara
 618   include ::sahara::service::api
 619   include ::sahara::service::engine
 620
 621   # Horizon
 622   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 623     $_profile_support = 'cisco'
 624   } else {
 625     $_profile_support = 'None'
 626   }
 627   $neutron_options   = {'profile_support' => $_profile_support }
 628
 629   class { '::horizon':
 630     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 631     neutron_options => $neutron_options,
 632   }
 633
 634   $snmpd_user = hiera('snmpd_readonly_user_name')
 635   snmp::snmpv3_user { $snmpd_user:
 636     authtype => 'MD5',
 637     authpass => hiera('snmpd_readonly_user_password'),
 638   }
 639   class { '::snmp':
 640     agentaddress => ['udp:161','udp6:[::1]:161'],
 641     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 642   }
 643
 644   hiera_include('controller_classes')
 645
 646 } #END STEP 3
 647
 648 if hiera('step') >= 4 {
 649   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 650   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 651   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 652   $heat_enable_db_purge = hiera('heat_enable_db_purge', true)
 653
 654   if $keystone_enable_db_purge {
 655     include ::keystone::cron::token_flush
 656   }
 657   if $nova_enable_db_purge {
 658     include ::nova::cron::archive_deleted_rows
 659   }
 660   if $cinder_enable_db_purge {
 661     include ::cinder::cron::db_purge
 662   }
 663   if $heat_enable_db_purge {
 664     include ::heat::cron::purge_deleted
 665   }
 666 } #END STEP 4
 667
 668 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 669 package_manifest{$package_manifest_name: ensure => present}