puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27 }
  28
  29 if hiera('step') >= 2 {
  30
  31   if count(hiera('ntp::servers')) > 0 {
  32     include ::ntp
  33   }
  34
  35   include ::timezone
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40     include ::mongodb::client
  41     include ::mongodb::server
  42     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  43     # without the brackets as 'members' argument for the 'mongodb_replset'
  44     # resource.
  45     if str2bool(hiera('mongodb::server::ipv6', false)) {
  46       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  47       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  48       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  49     } else {
  50       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  51       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  52     }
  53     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  54
  55     $mongodb_replset = hiera('mongodb::server::replset')
  56     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  57     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  58       mongodb_replset { $mongodb_replset :
  59         members => $mongo_node_ips_with_port_nobr,
  60       }
  61     }
  62   }
  63
  64   # Redis
  65   $redis_node_ips = hiera('redis_node_ips')
  66   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  67
  68   if $redis_master_hostname == $::hostname {
  69     $slaveof = undef
  70   } else {
  71     $slaveof = "${redis_master_hostname} 6379"
  72   }
  73   class {'::redis' :
  74     slaveof => $slaveof,
  75   }
  76
  77   if count($redis_node_ips) > 1 {
  78     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  79     include ::redis::sentinel
  80     include ::tripleo::redis_notification
  81   }
  82
  83   if str2bool(hiera('enable_galera', true)) {
  84     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  85   } else {
  86     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  87   }
  88   # TODO Galara
  89   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  90   # set bind-address to a hostname instead of an ip address; to move Mysql
  91   # from internal_api on another network we'll have to customize both
  92   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
  93   class { '::mysql::server':
  94     config_file             => $mysql_config_file,
  95     override_options        => {
  96       'mysqld' => {
  97         'bind-address'     => $::hostname,
  98         'max_connections'  => hiera('mysql_max_connections'),
  99         'open_files_limit' => '-1',
 100       },
 101     },
 102     remove_default_accounts => true,
 103   }
 104
 105   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 106   # Create all the database schemas
 107   include ::nova::db::mysql
 108   include ::nova::db::mysql_api
 109   include ::neutron::db::mysql
 110   include ::cinder::db::mysql
 111   if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
 112     include ::gnocchi::db::mysql
 113   }
 114   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 115     include ::ceilometer::db::mysql
 116     include ::aodh::db::mysql
 117   }
 118
 119   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 120
 121   if $enable_ceph {
 122     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 123     if str2bool(hiera('ceph_ipv6', false)) {
 124       $mon_host = hiera('ceph_mon_host_v6')
 125     } else {
 126       $mon_host = hiera('ceph_mon_host')
 127     }
 128     class { '::ceph::profile::params':
 129       mon_initial_members => $mon_initial_members,
 130       mon_host            => $mon_host,
 131     }
 132     include ::ceph::conf
 133     include ::ceph::profile::mon
 134   }
 135
 136   if str2bool(hiera('enable_ceph_storage', false)) {
 137     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 138       exec { 'set selinux to permissive on boot':
 139         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 140         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 141         path    => ['/usr/bin', '/usr/sbin'],
 142       }
 143
 144       exec { 'set selinux to permissive':
 145         command => 'setenforce 0',
 146         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 147         path    => ['/usr/bin', '/usr/sbin'],
 148       } -> Class['ceph::profile::osd']
 149     }
 150
 151     include ::ceph::conf
 152     include ::ceph::profile::osd
 153   }
 154
 155   if str2bool(hiera('enable_external_ceph', false)) {
 156     if str2bool(hiera('ceph_ipv6', false)) {
 157       $mon_host = hiera('ceph_mon_host_v6')
 158     } else {
 159       $mon_host = hiera('ceph_mon_host')
 160     }
 161     class { '::ceph::profile::params':
 162       mon_host            => $mon_host,
 163     }
 164     include ::ceph::conf
 165     include ::ceph::profile::client
 166   }
 167
 168 } #END STEP 2
 169
 170 if hiera('step') >= 4 {
 171
 172   $nova_ipv6 = hiera('nova::use_ipv6', false)
 173   if $nova_ipv6 {
 174     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 175   } else {
 176     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 177   }
 178
 179   class { '::nova' :
 180     memcached_servers => $memcached_servers
 181   }
 182   include ::nova::config
 183   include ::nova::api
 184   include ::nova::cert
 185   include ::nova::conductor
 186   include ::nova::consoleauth
 187   include ::nova::network::neutron
 188   include ::nova::vncproxy
 189   include ::nova::scheduler
 190   include ::nova::scheduler::filter
 191
 192   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 193
 194     # TODO(devvesa) provide non-controller ips for these services
 195     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 196     $cassandra_node_ips = hiera('neutron_api_node_ips')
 197
 198     # Run zookeeper in the controller if configured
 199     if hiera('enable_zookeeper_on_controller') {
 200       class {'::tripleo::cluster::zookeeper':
 201         zookeeper_server_ips => $zookeeper_node_ips,
 202         # TODO: create a 'bind' hiera key for zookeeper
 203         zookeeper_client_ip  => hiera('neutron::bind_host'),
 204         zookeeper_hostnames  => hiera('controller_node_names')
 205       }
 206     }
 207
 208     # Run cassandra in the controller if configured
 209     if hiera('enable_cassandra_on_controller') {
 210       class {'::tripleo::cluster::cassandra':
 211         cassandra_servers => $cassandra_node_ips,
 212         # TODO: create a 'bind' hiera key for cassandra
 213         cassandra_ip      => hiera('neutron::bind_host'),
 214       }
 215     }
 216
 217     class {'::tripleo::network::midonet::agent':
 218       zookeeper_servers => $zookeeper_node_ips,
 219       cassandra_seeds   => $cassandra_node_ips
 220     }
 221
 222     class {'::tripleo::network::midonet::api':
 223       zookeeper_servers    => $zookeeper_node_ips,
 224       vip                  => hiera('tripleo::loadbalancer::public_virtual_ip'),
 225       keystone_ip          => hiera('tripleo::loadbalancer::public_virtual_ip'),
 226       keystone_admin_token => hiera('keystone::admin_token'),
 227       # TODO: create a 'bind' hiera key for api
 228       bind_address         => hiera('neutron::bind_host'),
 229       admin_password       => hiera('admin_password')
 230     }
 231
 232     # TODO: find a way to get an empty list from hiera
 233     class {'::neutron':
 234       service_plugins => []
 235     }
 236
 237   }
 238   else {
 239
 240     # ML2 plugin
 241     include ::neutron
 242   }
 243
 244   include ::neutron::config
 245   include ::neutron::server
 246   include ::neutron::server::notifications
 247
 248   # If the value of core plugin is set to 'nuage' or'opencontrail' or 'plumgrid',
 249   # include nuage or opencontrail or plumgrid core plugins
 250   # else use the default value of 'ml2'
 251   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 252     include ::neutron::plugins::nuage
 253   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 254     include ::neutron::plugins::opencontrail
 255   }
 256   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 257     class { '::neutron::plugins::plumgrid' :
 258       connection                   => hiera('neutron::server::database_connection'),
 259       controller_priv_host         => hiera('keystone_admin_api_vip'),
 260       admin_password               => hiera('admin_password'),
 261       metadata_proxy_shared_secret => hiera('nova::api::neutron_metadata_proxy_shared_secret'),
 262     }
 263   } else {
 264
 265     # If the value of core plugin is set to 'midonet',
 266     # skip all the ML2 configuration
 267     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 268
 269       class {'::neutron::plugins::midonet':
 270         midonet_api_ip    => hiera('tripleo::loadbalancer::public_virtual_ip'),
 271         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 272         keystone_password => hiera('neutron::server::auth_password')
 273       }
 274     } else {
 275
 276       include ::neutron::plugins::ml2
 277       include ::neutron::agents::ml2::ovs
 278
 279       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 280         include ::neutron::plugins::ml2::cisco::nexus1000v
 281
 282         class { '::neutron::agents::n1kv_vem':
 283           n1kv_source  => hiera('n1kv_vem_source', undef),
 284           n1kv_version => hiera('n1kv_vem_version', undef),
 285         }
 286
 287         class { '::n1k_vsm':
 288           n1kv_source       => hiera('n1kv_vsm_source', undef),
 289           n1kv_version      => hiera('n1kv_vsm_version', undef),
 290           pacemaker_control => false,
 291         }
 292       }
 293
 294       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 295         include ::neutron::plugins::ml2::cisco::ucsm
 296       }
 297       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 298         include ::neutron::plugins::ml2::cisco::nexus
 299         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 300       }
 301
 302       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 303         include ::neutron::plugins::ml2::bigswitch::restproxy
 304         include ::neutron::agents::bigswitch
 305       }
 306       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 307     }
 308
 309     Service['neutron-server'] -> Service['neutron-metadata']
 310   }
 311
 312   include ::cinder
 313   include ::cinder::config
 314   include ::cinder::api
 315   include ::cinder::glance
 316   include ::cinder::scheduler
 317   include ::cinder::volume
 318   include ::cinder::ceilometer
 319   class { '::cinder::setup_test_volume':
 320     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 321   }
 322
 323   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 324   if $cinder_enable_iscsi {
 325     $cinder_iscsi_backend = 'tripleo_iscsi'
 326
 327     cinder::backend::iscsi { $cinder_iscsi_backend :
 328       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 329       iscsi_helper     => hiera('cinder_iscsi_helper'),
 330     }
 331   }
 332
 333   if $enable_ceph {
 334
 335     $ceph_pools = hiera('ceph_pools')
 336     ceph::pool { $ceph_pools :
 337       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 338       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 339       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 340     }
 341
 342     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 343
 344   } else {
 345     $cinder_pool_requires = []
 346   }
 347
 348   if hiera('cinder_enable_rbd_backend', false) {
 349     $cinder_rbd_backend = 'tripleo_ceph'
 350
 351     cinder::backend::rbd { $cinder_rbd_backend :
 352       backend_host    => hiera('cinder::host'),
 353       rbd_pool        => hiera('cinder_rbd_pool_name'),
 354       rbd_user        => hiera('ceph_client_user_name'),
 355       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 356       require         => $cinder_pool_requires,
 357     }
 358   }
 359
 360   if hiera('cinder_enable_eqlx_backend', false) {
 361     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 362
 363     cinder::backend::eqlx { $cinder_eqlx_backend :
 364       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 365       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 366       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 367       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 368       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 369       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 370       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 371       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 372       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 373       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 374     }
 375   }
 376
 377   if hiera('cinder_enable_dellsc_backend', false) {
 378     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 379
 380     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 381       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 382       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 383       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 384       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 385       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 386       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 387       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 388       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 389       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 390       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 391     }
 392   }
 393
 394   if hiera('cinder_enable_netapp_backend', false) {
 395     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 396
 397     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 398       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 399     }
 400
 401     cinder::backend::netapp { $cinder_netapp_backend :
 402       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 403       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 404       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 405       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 406       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 407       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 408       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 409       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 410       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 411       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 412       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 413       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 414       nfs_shares                   => $cinder_netapp_nfs_shares,
 415       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 416       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 417       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 418       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 419       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 420       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 421       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 422     }
 423   }
 424
 425   if hiera('cinder_enable_nfs_backend', false) {
 426     $cinder_nfs_backend = 'tripleo_nfs'
 427
 428     if str2bool($::selinux) {
 429       selboolean { 'virt_use_nfs':
 430         value      => on,
 431         persistent => true,
 432       } -> Package['nfs-utils']
 433     }
 434
 435     package {'nfs-utils': } ->
 436     cinder::backend::nfs { $cinder_nfs_backend :
 437       nfs_servers       => hiera('cinder_nfs_servers'),
 438       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 439       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 440     }
 441   }
 442
 443   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 444   class { '::cinder::backends' :
 445     enabled_backends => union($cinder_enabled_backends, hiera('cinder_user_enabled_backends')),
 446   }
 447
 448   # swift storage
 449   if str2bool(hiera('enable_swift_storage', true)) {
 450     class { '::swift::storage::all':
 451       mount_check => str2bool(hiera('swift_mount_check')),
 452     }
 453     if(!defined(File['/srv/node'])) {
 454       file { '/srv/node':
 455         ensure  => directory,
 456         owner   => 'swift',
 457         group   => 'swift',
 458         require => Package['openstack-swift'],
 459       }
 460     }
 461     $swift_components = ['account', 'container', 'object']
 462     swift::storage::filter::recon { $swift_components : }
 463     swift::storage::filter::healthcheck { $swift_components : }
 464   }
 465
 466   # Ceilometer
 467   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 468   case $ceilometer_backend {
 469     /mysql/ : {
 470       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 471     }
 472     default : {
 473       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 474     }
 475   }
 476   include ::ceilometer
 477   include ::ceilometer::config
 478   include ::ceilometer::api
 479   include ::ceilometer::agent::notification
 480   include ::ceilometer::agent::central
 481   include ::ceilometer::expirer
 482   include ::ceilometer::collector
 483   include ::ceilometer::agent::auth
 484   include ::ceilometer::dispatcher::gnocchi
 485   class { '::ceilometer::db' :
 486     database_connection => $ceilometer_database_connection,
 487   }
 488
 489   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 490
 491   # Aodh
 492   class { '::aodh' :
 493     database_connection => $ceilometer_database_connection,
 494   }
 495   include ::aodh::db::sync
 496   # To manage the upgrade:
 497   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 498   include ::aodh::auth
 499   include ::aodh::api
 500   include ::aodh::wsgi::apache
 501   include ::aodh::evaluator
 502   include ::aodh::notifier
 503   include ::aodh::listener
 504   include ::aodh::client
 505
 506   # Horizon
 507   include ::apache::mod::remoteip
 508   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 509     $_profile_support = 'cisco'
 510   } else {
 511     $_profile_support = 'None'
 512   }
 513   $neutron_options   = {'profile_support' => $_profile_support }
 514
 515   $memcached_ipv6 = hiera('memcached_ipv6', false)
 516   if $memcached_ipv6 {
 517     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 518   } else {
 519     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 520   }
 521
 522   class { '::horizon':
 523     cache_server_ip => $horizon_memcached_servers,
 524     neutron_options => $neutron_options,
 525   }
 526
 527   # Gnocchi
 528   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 529   class { '::gnocchi':
 530     database_connection => $gnocchi_database_connection,
 531   }
 532   include ::gnocchi::api
 533   include ::gnocchi::wsgi::apache
 534   include ::gnocchi::client
 535   include ::gnocchi::db::sync
 536   include ::gnocchi::storage
 537   include ::gnocchi::metricd
 538   include ::gnocchi::statsd
 539   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 540   case $gnocchi_backend {
 541       'swift': { include ::gnocchi::storage::swift }
 542       'file': { include ::gnocchi::storage::file }
 543       'rbd': { include ::gnocchi::storage::ceph }
 544       default: { fail('Unrecognized gnocchi_backend parameter.') }
 545   }
 546
 547   $snmpd_user = hiera('snmpd_readonly_user_name')
 548   snmp::snmpv3_user { $snmpd_user:
 549     authtype => 'MD5',
 550     authpass => hiera('snmpd_readonly_user_password'),
 551   }
 552   class { '::snmp':
 553     agentaddress => ['udp:161','udp6:[::1]:161'],
 554     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 555   }
 556
 557   hiera_include('controller_classes')
 558
 559 } #END STEP 4
 560
 561 if hiera('step') >= 5 {
 562   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 563   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 564
 565   if $nova_enable_db_purge {
 566     include ::nova::cron::archive_deleted_rows
 567   }
 568   if $cinder_enable_db_purge {
 569     include ::cinder::cron::db_purge
 570   }
 571 } #END STEP 5
 572
 573 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 574 package_manifest{$package_manifest_name: ensure => present}