puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if hiera('step') >= 1 {
  28
  29   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  30
  31   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  32
  33   class { '::tripleo::loadbalancer' :
  34     controller_hosts => $controller_node_ips,
  35     manage_vip       => true,
  36   }
  37
  38 }
  39
  40 if hiera('step') >= 2 {
  41
  42   if count(hiera('ntp::servers')) > 0 {
  43     include ::ntp
  44   }
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49
  50     include ::mongodb::server
  51     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  52     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  53
  54     $mongodb_replset = hiera('mongodb::server::replset')
  55     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  56     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  57       mongodb_replset { $mongodb_replset :
  58         members => $mongo_node_ips_with_port,
  59       }
  60     }
  61   }
  62
  63   # Redis
  64   $redis_node_ips = hiera('redis_node_ips')
  65   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  66
  67   if $redis_master_hostname == $::hostname {
  68     $slaveof = undef
  69   } else {
  70     $slaveof = "${redis_master_hostname} 6379"
  71   }
  72   class {'::redis' :
  73     slaveof => $slaveof,
  74   }
  75
  76   if count($redis_node_ips) > 1 {
  77     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  78     include ::redis::sentinel
  79     include ::tripleo::redis_notification
  80   }
  81
  82   if str2bool(hiera('enable_galera', 'true')) {
  83     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  84   } else {
  85     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  86   }
  87   # TODO Galara
  88   class { 'mysql::server':
  89     config_file => $mysql_config_file,
  90     override_options => {
  91       'mysqld' => {
  92         'bind-address' => hiera('mysql_bind_host'),
  93         'max_connections' => hiera('mysql_max_connections'),
  94         'open_files_limit' => '-1',
  95       },
  96     }
  97   }
  98
  99   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 100   # Create all the database schemas
 101   # Example DSN format: mysql://user:password@host/dbname
 102   $allowed_hosts = ['%',hiera('mysql_bind_host')]
 103   $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 104   class { 'keystone::db::mysql':
 105     user          => $keystone_dsn[3],
 106     password      => $keystone_dsn[4],
 107     host          => $keystone_dsn[5],
 108     dbname        => $keystone_dsn[6],
 109     allowed_hosts => $allowed_hosts,
 110   }
 111   $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 112   class { 'glance::db::mysql':
 113     user          => $glance_dsn[3],
 114     password      => $glance_dsn[4],
 115     host          => $glance_dsn[5],
 116     dbname        => $glance_dsn[6],
 117     allowed_hosts => $allowed_hosts,
 118   }
 119   $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 120   class { 'nova::db::mysql':
 121     user          => $nova_dsn[3],
 122     password      => $nova_dsn[4],
 123     host          => $nova_dsn[5],
 124     dbname        => $nova_dsn[6],
 125     allowed_hosts => $allowed_hosts,
 126   }
 127   $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 128   class { 'neutron::db::mysql':
 129     user          => $neutron_dsn[3],
 130     password      => $neutron_dsn[4],
 131     host          => $neutron_dsn[5],
 132     dbname        => $neutron_dsn[6],
 133     allowed_hosts => $allowed_hosts,
 134   }
 135   $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 136   class { 'cinder::db::mysql':
 137     user          => $cinder_dsn[3],
 138     password      => $cinder_dsn[4],
 139     host          => $cinder_dsn[5],
 140     dbname        => $cinder_dsn[6],
 141     allowed_hosts => $allowed_hosts,
 142   }
 143   $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 144   class { 'heat::db::mysql':
 145     user          => $heat_dsn[3],
 146     password      => $heat_dsn[4],
 147     host          => $heat_dsn[5],
 148     dbname        => $heat_dsn[6],
 149     allowed_hosts => $allowed_hosts,
 150   }
 151   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 152     $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 153     class { 'ceilometer::db::mysql':
 154       user          => $ceilometer_dsn[3],
 155       password      => $ceilometer_dsn[4],
 156       host          => $ceilometer_dsn[5],
 157       dbname        => $ceilometer_dsn[6],
 158       allowed_hosts => $allowed_hosts,
 159     }
 160   }
 161
 162   $rabbit_nodes = hiera('rabbit_node_ips')
 163   if count($rabbit_nodes) > 1 {
 164     class { '::rabbitmq':
 165       config_cluster          => true,
 166       cluster_nodes           => $rabbit_nodes,
 167       tcp_keepalive           => false,
 168       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 169       config_variables        => hiera('rabbitmq_config_variables'),
 170       environment_variables   => hiera('rabbitmq_environment'),
 171     }
 172     rabbitmq_policy { 'ha-all@/':
 173       pattern    => '^(?!amq\.).*',
 174       definition => {
 175         'ha-mode' => 'all',
 176       },
 177     }
 178   } else {
 179     include ::rabbitmq
 180   }
 181
 182   # pre-install swift here so we can build rings
 183   include ::swift
 184
 185   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 186   $enable_ceph = $cinder_enable_rbd_backend
 187
 188   if $enable_ceph {
 189     class { 'ceph::profile::params':
 190       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 191     }
 192     include ::ceph::profile::mon
 193   }
 194
 195   if str2bool(hiera('enable_ceph_storage', 'false')) {
 196     include ::ceph::profile::client
 197     include ::ceph::profile::osd
 198   }
 199
 200 } #END STEP 2
 201
 202 if hiera('step') >= 3 {
 203
 204   include ::keystone
 205
 206   #TODO: need a cleanup-keystone-tokens.sh solution here
 207   keystone_config {
 208     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 209   }
 210   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 211     ensure  => 'directory',
 212     owner   => 'keystone',
 213     group   => 'keystone',
 214     require => Package['keystone'],
 215   }
 216   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 217     content => hiera('keystone_signing_certificate'),
 218     owner   => 'keystone',
 219     group   => 'keystone',
 220     notify  => Service['keystone'],
 221     require => File['/etc/keystone/ssl/certs'],
 222   }
 223   file { '/etc/keystone/ssl/private/signing_key.pem':
 224     content => hiera('keystone_signing_key'),
 225     owner   => 'keystone',
 226     group   => 'keystone',
 227     notify  => Service['keystone'],
 228     require => File['/etc/keystone/ssl/private'],
 229   }
 230   file { '/etc/keystone/ssl/certs/ca.pem':
 231     content => hiera('keystone_ca_certificate'),
 232     owner   => 'keystone',
 233     group   => 'keystone',
 234     notify  => Service['keystone'],
 235     require => File['/etc/keystone/ssl/certs'],
 236   }
 237
 238   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 239   case $glance_backend {
 240       swift: { $backend_store = 'glance.store.swift.Store' }
 241       file: { $backend_store = 'glance.store.filesystem.Store' }
 242       rbd: { $backend_store = 'glance.store.rbd.Store' }
 243       default: { fail('Unrecognized glance_backend parameter.') }
 244   }
 245   $http_store = ['glance.store.http.Store']
 246   $glance_store = concat($http_store, $backend_store)
 247
 248   # TODO: notifications, scrubber, etc.
 249   include ::glance
 250   class { 'glance::api':
 251     known_stores => $glance_store
 252   }
 253   include ::glance::registry
 254   include join(['::glance::backend::', $glance_backend])
 255
 256   include ::nova
 257   include ::nova::api
 258   include ::nova::cert
 259   include ::nova::conductor
 260   include ::nova::consoleauth
 261   include ::nova::network::neutron
 262   include ::nova::vncproxy
 263   include ::nova::scheduler
 264
 265   include ::neutron
 266   include ::neutron::server
 267   include ::neutron::agents::l3
 268   include ::neutron::agents::dhcp
 269   include ::neutron::agents::metadata
 270
 271   file { '/etc/neutron/dnsmasq-neutron.conf':
 272     content => hiera('neutron_dnsmasq_options'),
 273     owner   => 'neutron',
 274     group   => 'neutron',
 275     notify  => Service['neutron-dhcp-service'],
 276     require => Package['neutron'],
 277   }
 278
 279   class { 'neutron::plugins::ml2':
 280     flat_networks => split(hiera('neutron_flat_networks'), ','),
 281     tenant_network_types => [hiera('neutron_tenant_network_type')],
 282   }
 283   class { 'neutron::agents::ml2::ovs':
 284     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 285     tunnel_types => split(hiera('neutron_tunnel_types'), ','),
 286   }
 287
 288   Service['neutron-server'] -> Service['neutron-dhcp-service']
 289   Service['neutron-server'] -> Service['neutron-l3']
 290   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 291   Service['neutron-server'] -> Service['neutron-metadata']
 292
 293   include ::cinder
 294   include ::cinder::api
 295   include ::cinder::glance
 296   include ::cinder::scheduler
 297   include ::cinder::volume
 298   class {'cinder::setup_test_volume':
 299     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 300   }
 301
 302   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 303   if $cinder_enable_iscsi {
 304     $cinder_iscsi_backend = 'tripleo_iscsi'
 305
 306     cinder::backend::iscsi { $cinder_iscsi_backend :
 307       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 308       iscsi_helper     => hiera('cinder_iscsi_helper'),
 309     }
 310   }
 311
 312   if $enable_ceph {
 313
 314     Ceph_pool {
 315       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 316       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 317       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 318     }
 319
 320     $ceph_pools = hiera('ceph_pools')
 321     ceph::pool { $ceph_pools : }
 322   }
 323
 324   if $cinder_enable_rbd_backend {
 325     $cinder_rbd_backend = 'tripleo_ceph'
 326
 327     cinder_config {
 328       "${cinder_rbd_backend}/host": value => 'hostgroup';
 329     }
 330
 331     cinder::backend::rbd { $cinder_rbd_backend :
 332       rbd_pool        => 'volumes',
 333       rbd_user        => 'openstack',
 334       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 335       require         => Ceph::Pool['volumes'],
 336     }
 337   }
 338
 339   if hiera('cinder_enable_netapp_backend', false) {
 340     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 341
 342     cinder_config {
 343       "${cinder_netapp_backend}/host": value => 'hostgroup';
 344     }
 345
 346     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 347       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 348     }
 349
 350     cinder::backend::netapp { $cinder_netapp_backend :
 351       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 352       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 353       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 354       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 355       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 356       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 357       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 358       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 359       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 360       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 361       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 362       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 363       nfs_shares                   => $cinder_netapp_nfs_shares,
 364       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 365       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 366       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 367       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 368       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 369       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 370       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 371     }
 372   }
 373
 374   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend])
 375   class { '::cinder::backends' :
 376     enabled_backends => $cinder_enabled_backends,
 377   }
 378
 379   # swift proxy
 380   include ::memcached
 381   include ::swift::proxy
 382   include ::swift::proxy::proxy_logging
 383   include ::swift::proxy::healthcheck
 384   include ::swift::proxy::cache
 385   include ::swift::proxy::keystone
 386   include ::swift::proxy::authtoken
 387   include ::swift::proxy::staticweb
 388   include ::swift::proxy::ratelimit
 389   include ::swift::proxy::catch_errors
 390   include ::swift::proxy::tempurl
 391   include ::swift::proxy::formpost
 392
 393   # swift storage
 394   if str2bool(hiera('enable_swift_storage', 'true')) {
 395     class {'swift::storage::all':
 396       mount_check => str2bool(hiera('swift_mount_check'))
 397     }
 398     if(!defined(File['/srv/node'])) {
 399       file { '/srv/node':
 400         ensure  => directory,
 401         owner   => 'swift',
 402         group   => 'swift',
 403         require => Package['openstack-swift'],
 404       }
 405     }
 406     $swift_components = ['account', 'container', 'object']
 407     swift::storage::filter::recon { $swift_components : }
 408     swift::storage::filter::healthcheck { $swift_components : }
 409   }
 410
 411   # Ceilometer
 412   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 413   case $ceilometer_backend {
 414     /mysql/ : {
 415       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 416     }
 417     default : {
 418       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 419     }
 420   }
 421   include ::ceilometer
 422   include ::ceilometer::api
 423   include ::ceilometer::agent::notification
 424   include ::ceilometer::agent::central
 425   include ::ceilometer::alarm::notifier
 426   include ::ceilometer::alarm::evaluator
 427   include ::ceilometer::expirer
 428   include ::ceilometer::collector
 429   include ceilometer::agent::auth
 430   class { '::ceilometer::db' :
 431     database_connection => $ceilometer_database_connection,
 432   }
 433
 434   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 435
 436   # Heat
 437   include ::heat
 438   include ::heat::api
 439   include ::heat::api_cfn
 440   include ::heat::api_cloudwatch
 441   include ::heat::engine
 442
 443   # Horizon
 444   $vhost_params = { add_listen => false }
 445   class { 'horizon':
 446     cache_server_ip    => hiera('memcache_node_ips', '127.0.0.1'),
 447     vhost_extra_params => $vhost_params,
 448   }
 449
 450   $snmpd_user = hiera('snmpd_readonly_user_name')
 451   snmp::snmpv3_user { $snmpd_user:
 452     authtype => 'MD5',
 453     authpass => hiera('snmpd_readonly_user_password'),
 454   }
 455   class { 'snmp':
 456     agentaddress => ['udp:161','udp6:[::1]:161'],
 457     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 458   }
 459
 460   hiera_include('controller_classes')
 461
 462 } #END STEP 3