puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include tripleo::packages
  17
  18 if hiera('step') >= 1 {
  19
  20   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  21
  22   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  23
  24   class { '::tripleo::loadbalancer' :
  25     controller_hosts => $controller_node_ips,
  26     manage_vip       => true,
  27   }
  28
  29 }
  30
  31 if hiera('step') >= 2 {
  32
  33   if count(hiera('ntp::servers')) > 0 {
  34     include ::ntp
  35   }
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40
  41     include ::mongodb::server
  42     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  43     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  44
  45     $mongodb_replset = hiera('mongodb::server::replset')
  46     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  47     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  48       mongodb_replset { $mongodb_replset :
  49         members => $mongo_node_ips_with_port,
  50       }
  51     }
  52   }
  53
  54   # Redis
  55   $redis_node_ips = hiera('redis_node_ips')
  56   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  57
  58   if $redis_master_hostname == $::hostname {
  59     $slaveof = undef
  60   } else {
  61     $slaveof = "${redis_master_hostname} 6379"
  62   }
  63   class {'::redis' :
  64     slaveof => $slaveof,
  65   }
  66
  67   if count($redis_node_ips) > 1 {
  68     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  69     include ::redis::sentinel
  70     include ::tripleo::redis_notification
  71   }
  72
  73   if str2bool(hiera('enable_galera', 'true')) {
  74     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  75   } else {
  76     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  77   }
  78   # TODO Galara
  79   class { 'mysql::server':
  80     config_file => $mysql_config_file,
  81     override_options => {
  82       'mysqld' => {
  83         'bind-address' => hiera('mysql_bind_host'),
  84         'max_connections' => hiera('mysql_max_connections'),
  85         'open_files_limit' => '-1',
  86       },
  87     }
  88   }
  89
  90   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  91   # Create all the database schemas
  92   include ::keystone::db::mysql
  93   include ::glance::db::mysql
  94   include ::nova::db::mysql
  95   include ::neutron::db::mysql
  96   include ::cinder::db::mysql
  97   include ::heat::db::mysql
  98   if downcase(hiera('ceilometer_backend')) == 'mysql' {
  99     include ::ceilometer::db::mysql
 100   }
 101
 102   $rabbit_nodes = hiera('rabbit_node_ips')
 103   if count($rabbit_nodes) > 1 {
 104     class { '::rabbitmq':
 105       config_cluster          => true,
 106       cluster_nodes           => $rabbit_nodes,
 107       tcp_keepalive           => false,
 108       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 109       config_variables        => hiera('rabbitmq_config_variables'),
 110       environment_variables   => hiera('rabbitmq_environment'),
 111     }
 112     rabbitmq_policy { 'ha-all@/':
 113       pattern    => '^(?!amq\.).*',
 114       definition => {
 115         'ha-mode' => 'all',
 116       },
 117     }
 118   } else {
 119     include ::rabbitmq
 120   }
 121
 122   # pre-install swift here so we can build rings
 123   include ::swift
 124
 125   $enable_ceph = hiera('ceph_storage_count', 0) > 0
 126
 127   if $enable_ceph {
 128     class { 'ceph::profile::params':
 129       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 130     }
 131     include ::ceph::profile::mon
 132   }
 133
 134   if str2bool(hiera('enable_ceph_storage', 'false')) {
 135     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 136       exec { 'set selinux to permissive on boot':
 137         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 138         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 139         path    => ["/usr/bin", "/usr/sbin"],
 140       }
 141
 142       exec { 'set selinux to permissive':
 143         command => "setenforce 0",
 144         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 145         path    => ["/usr/bin", "/usr/sbin"],
 146       } -> Class['ceph::profile::osd']
 147     }
 148
 149     include ::ceph::profile::osd
 150   }
 151
 152   if str2bool(hiera('enable_external_ceph', 'false')) {
 153     include ::ceph::profile::client
 154   }
 155
 156 } #END STEP 2
 157
 158 if hiera('step') >= 3 {
 159
 160   include ::keystone
 161
 162   #TODO: need a cleanup-keystone-tokens.sh solution here
 163   keystone_config {
 164     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 165   }
 166   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 167     ensure  => 'directory',
 168     owner   => 'keystone',
 169     group   => 'keystone',
 170     require => Package['keystone'],
 171   }
 172   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 173     content => hiera('keystone_signing_certificate'),
 174     owner   => 'keystone',
 175     group   => 'keystone',
 176     notify  => Service['keystone'],
 177     require => File['/etc/keystone/ssl/certs'],
 178   }
 179   file { '/etc/keystone/ssl/private/signing_key.pem':
 180     content => hiera('keystone_signing_key'),
 181     owner   => 'keystone',
 182     group   => 'keystone',
 183     notify  => Service['keystone'],
 184     require => File['/etc/keystone/ssl/private'],
 185   }
 186   file { '/etc/keystone/ssl/certs/ca.pem':
 187     content => hiera('keystone_ca_certificate'),
 188     owner   => 'keystone',
 189     group   => 'keystone',
 190     notify  => Service['keystone'],
 191     require => File['/etc/keystone/ssl/certs'],
 192   }
 193
 194   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 195   case $glance_backend {
 196       swift: { $backend_store = 'glance.store.swift.Store' }
 197       file: { $backend_store = 'glance.store.filesystem.Store' }
 198       rbd: { $backend_store = 'glance.store.rbd.Store' }
 199       default: { fail('Unrecognized glance_backend parameter.') }
 200   }
 201   $http_store = ['glance.store.http.Store']
 202   $glance_store = concat($http_store, $backend_store)
 203
 204   # TODO: notifications, scrubber, etc.
 205   include ::glance
 206   class { 'glance::api':
 207     known_stores => $glance_store
 208   }
 209   include ::glance::registry
 210   include join(['::glance::backend::', $glance_backend])
 211
 212   class { '::nova' :
 213     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 214   }
 215   include ::nova::config
 216   include ::nova::api
 217   include ::nova::cert
 218   include ::nova::conductor
 219   include ::nova::consoleauth
 220   include ::nova::network::neutron
 221   include ::nova::vncproxy
 222   include ::nova::scheduler
 223
 224   include ::neutron
 225   include ::neutron::server
 226   include ::neutron::agents::l3
 227   include ::neutron::agents::dhcp
 228   include ::neutron::agents::metadata
 229
 230   file { '/etc/neutron/dnsmasq-neutron.conf':
 231     content => hiera('neutron_dnsmasq_options'),
 232     owner   => 'neutron',
 233     group   => 'neutron',
 234     notify  => Service['neutron-dhcp-service'],
 235     require => Package['neutron'],
 236   }
 237
 238   class { 'neutron::plugins::ml2':
 239     flat_networks => split(hiera('neutron_flat_networks'), ','),
 240     tenant_network_types => [hiera('neutron_tenant_network_type')],
 241   }
 242   class { 'neutron::agents::ml2::ovs':
 243     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 244     tunnel_types => split(hiera('neutron_tunnel_types'), ','),
 245   }
 246
 247   Service['neutron-server'] -> Service['neutron-dhcp-service']
 248   Service['neutron-server'] -> Service['neutron-l3']
 249   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 250   Service['neutron-server'] -> Service['neutron-metadata']
 251
 252   include ::cinder
 253   include ::cinder::api
 254   include ::cinder::glance
 255   include ::cinder::scheduler
 256   include ::cinder::volume
 257   class {'cinder::setup_test_volume':
 258     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 259   }
 260
 261   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 262   if $cinder_enable_iscsi {
 263     $cinder_iscsi_backend = 'tripleo_iscsi'
 264
 265     cinder::backend::iscsi { $cinder_iscsi_backend :
 266       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 267       iscsi_helper     => hiera('cinder_iscsi_helper'),
 268     }
 269   }
 270
 271   if $enable_ceph {
 272
 273     Ceph_pool {
 274       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 275       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 276       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 277     }
 278
 279     $ceph_pools = hiera('ceph_pools')
 280     ceph::pool { $ceph_pools : }
 281
 282     $cinder_pool_requires = [Ceph::Pool['volumes']]
 283
 284   } else {
 285     $cinder_pool_requires = []
 286   }
 287
 288   if hiera('cinder_enable_rbd_backend', false) {
 289     $cinder_rbd_backend = 'tripleo_ceph'
 290
 291     cinder_config {
 292       "${cinder_rbd_backend}/host": value => 'hostgroup';
 293     }
 294
 295     cinder::backend::rbd { $cinder_rbd_backend :
 296       rbd_pool        => 'volumes',
 297       rbd_user        => 'openstack',
 298       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 299       require         => $cinder_pool_requires,
 300     }
 301   }
 302
 303   if hiera('cinder_enable_netapp_backend', false) {
 304     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 305
 306     cinder_config {
 307       "${cinder_netapp_backend}/host": value => 'hostgroup';
 308     }
 309
 310     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 311       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 312     }
 313
 314     cinder::backend::netapp { $cinder_netapp_backend :
 315       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 316       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 317       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 318       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 319       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 320       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 321       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 322       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 323       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 324       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 325       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 326       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 327       nfs_shares                   => $cinder_netapp_nfs_shares,
 328       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 329       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 330       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 331       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 332       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 333       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 334       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 335     }
 336   }
 337
 338   if hiera('cinder_enable_nfs_backend', false) {
 339     $cinder_nfs_backend = 'tripleo_nfs'
 340
 341     if ($::selinux != "false") {
 342       selboolean { 'virt_use_nfs':
 343           value => on,
 344           persistent => true,
 345       } -> Package['nfs-utils']
 346     }
 347
 348     package {'nfs-utils': } ->
 349     cinder::backend::nfs { $cinder_nfs_backend :
 350       nfs_servers         => hiera('cinder_nfs_servers'),
 351       nfs_mount_options   => hiera('cinder_nfs_mount_options'),
 352       nfs_shares_config   => '/etc/cinder/shares-nfs.conf',
 353     }
 354   }
 355
 356   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 357   class { '::cinder::backends' :
 358     enabled_backends => $cinder_enabled_backends,
 359   }
 360
 361   # swift proxy
 362   include ::memcached
 363   include ::swift::proxy
 364   include ::swift::proxy::proxy_logging
 365   include ::swift::proxy::healthcheck
 366   include ::swift::proxy::cache
 367   include ::swift::proxy::keystone
 368   include ::swift::proxy::authtoken
 369   include ::swift::proxy::staticweb
 370   include ::swift::proxy::ratelimit
 371   include ::swift::proxy::catch_errors
 372   include ::swift::proxy::tempurl
 373   include ::swift::proxy::formpost
 374
 375   # swift storage
 376   if str2bool(hiera('enable_swift_storage', 'true')) {
 377     class {'swift::storage::all':
 378       mount_check => str2bool(hiera('swift_mount_check'))
 379     }
 380     if(!defined(File['/srv/node'])) {
 381       file { '/srv/node':
 382         ensure  => directory,
 383         owner   => 'swift',
 384         group   => 'swift',
 385         require => Package['openstack-swift'],
 386       }
 387     }
 388     $swift_components = ['account', 'container', 'object']
 389     swift::storage::filter::recon { $swift_components : }
 390     swift::storage::filter::healthcheck { $swift_components : }
 391   }
 392
 393   # Ceilometer
 394   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 395   case $ceilometer_backend {
 396     /mysql/ : {
 397       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 398     }
 399     default : {
 400       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 401     }
 402   }
 403   include ::ceilometer
 404   include ::ceilometer::api
 405   include ::ceilometer::agent::notification
 406   include ::ceilometer::agent::central
 407   include ::ceilometer::alarm::notifier
 408   include ::ceilometer::alarm::evaluator
 409   include ::ceilometer::expirer
 410   include ::ceilometer::collector
 411   include ceilometer::agent::auth
 412   class { '::ceilometer::db' :
 413     database_connection => $ceilometer_database_connection,
 414   }
 415
 416   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 417
 418   # Heat
 419   include ::heat
 420   include ::heat::api
 421   include ::heat::api_cfn
 422   include ::heat::api_cloudwatch
 423   include ::heat::engine
 424
 425   # Horizon
 426   $vhost_params = { add_listen => false }
 427   class { 'horizon':
 428     cache_server_ip    => hiera('memcache_node_ips', '127.0.0.1'),
 429     vhost_extra_params => $vhost_params,
 430   }
 431
 432   $snmpd_user = hiera('snmpd_readonly_user_name')
 433   snmp::snmpv3_user { $snmpd_user:
 434     authtype => 'MD5',
 435     authpass => hiera('snmpd_readonly_user_password'),
 436   }
 437   class { 'snmp':
 438     agentaddress => ['udp:161','udp6:[::1]:161'],
 439     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 440   }
 441
 442   hiera_include('controller_classes')
 443
 444 } #END STEP 3
 445
 446 if hiera('step') >= 4 {
 447   include ::keystone::cron::token_flush
 448 } #END STEP 4