puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  28
  29   if $enable_load_balancer {
  30     class { '::tripleo::loadbalancer' :
  31       controller_hosts => $controller_node_ips,
  32       manage_vip       => true,
  33     }
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   include ::timezone
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49
  50     include ::mongodb::server
  51     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  52     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  53
  54     $mongodb_replset = hiera('mongodb::server::replset')
  55     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  56     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  57       mongodb_replset { $mongodb_replset :
  58         members => $mongo_node_ips_with_port,
  59       }
  60     }
  61   }
  62
  63   # Redis
  64   $redis_node_ips = hiera('redis_node_ips')
  65   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  66
  67   if $redis_master_hostname == $::hostname {
  68     $slaveof = undef
  69   } else {
  70     $slaveof = "${redis_master_hostname} 6379"
  71   }
  72   class {'::redis' :
  73     slaveof => $slaveof,
  74   }
  75
  76   if count($redis_node_ips) > 1 {
  77     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  78     include ::redis::sentinel
  79     include ::tripleo::redis_notification
  80   }
  81
  82   if str2bool(hiera('enable_galera', true)) {
  83     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  84   } else {
  85     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  86   }
  87   # TODO Galara
  88   class { '::mysql::server':
  89     config_file             => $mysql_config_file,
  90     override_options        => {
  91       'mysqld' => {
  92         'bind-address'     => hiera('mysql_bind_host'),
  93         'max_connections'  => hiera('mysql_max_connections'),
  94         'open_files_limit' => '-1',
  95       },
  96     },
  97     remove_default_accounts => true,
  98   }
  99
 100   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 101   # Create all the database schemas
 102   include ::keystone::db::mysql
 103   include ::glance::db::mysql
 104   include ::nova::db::mysql
 105   include ::neutron::db::mysql
 106   include ::cinder::db::mysql
 107   include ::heat::db::mysql
 108   include ::sahara::db::mysql
 109   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 110     include ::ceilometer::db::mysql
 111   }
 112
 113   $rabbit_nodes = hiera('rabbit_node_ips')
 114   if count($rabbit_nodes) > 1 {
 115     class { '::rabbitmq':
 116       config_cluster          => true,
 117       cluster_nodes           => $rabbit_nodes,
 118       tcp_keepalive           => false,
 119       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 120       config_variables        => hiera('rabbitmq_config_variables'),
 121       environment_variables   => hiera('rabbitmq_environment'),
 122     }
 123     rabbitmq_policy { 'ha-all@/':
 124       pattern    => '^(?!amq\.).*',
 125       definition => {
 126         'ha-mode' => 'all',
 127       },
 128     }
 129   } else {
 130     include ::rabbitmq
 131   }
 132
 133   # pre-install swift here so we can build rings
 134   include ::swift
 135
 136   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 137
 138   if $enable_ceph {
 139     class { '::ceph::profile::params':
 140       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 141     }
 142     include ::ceph::conf
 143     include ::ceph::profile::mon
 144   }
 145
 146   if str2bool(hiera('enable_ceph_storage', false)) {
 147     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 148       exec { 'set selinux to permissive on boot':
 149         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 150         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 151         path    => ['/usr/bin', '/usr/sbin'],
 152       }
 153
 154       exec { 'set selinux to permissive':
 155         command => 'setenforce 0',
 156         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 157         path    => ['/usr/bin', '/usr/sbin'],
 158       } -> Class['ceph::profile::osd']
 159     }
 160
 161     include ::ceph::conf
 162     include ::ceph::profile::osd
 163   }
 164
 165   if str2bool(hiera('enable_external_ceph', false)) {
 166     include ::ceph::conf
 167     include ::ceph::profile::client
 168   }
 169
 170 } #END STEP 2
 171
 172 if hiera('step') >= 3 {
 173
 174   include ::keystone
 175   include ::keystone::config
 176   include ::keystone::roles::admin
 177   include ::keystone::endpoint
 178
 179   #TODO: need a cleanup-keystone-tokens.sh solution here
 180
 181   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 182     ensure  => 'directory',
 183     owner   => 'keystone',
 184     group   => 'keystone',
 185     require => Package['keystone'],
 186   }
 187   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 188     content => hiera('keystone_signing_certificate'),
 189     owner   => 'keystone',
 190     group   => 'keystone',
 191     notify  => Service['keystone'],
 192     require => File['/etc/keystone/ssl/certs'],
 193   }
 194   file { '/etc/keystone/ssl/private/signing_key.pem':
 195     content => hiera('keystone_signing_key'),
 196     owner   => 'keystone',
 197     group   => 'keystone',
 198     notify  => Service['keystone'],
 199     require => File['/etc/keystone/ssl/private'],
 200   }
 201   file { '/etc/keystone/ssl/certs/ca.pem':
 202     content => hiera('keystone_ca_certificate'),
 203     owner   => 'keystone',
 204     group   => 'keystone',
 205     notify  => Service['keystone'],
 206     require => File['/etc/keystone/ssl/certs'],
 207   }
 208
 209   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 210   case $glance_backend {
 211       'swift': { $backend_store = 'glance.store.swift.Store' }
 212       'file': { $backend_store = 'glance.store.filesystem.Store' }
 213       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 214       default: { fail('Unrecognized glance_backend parameter.') }
 215   }
 216   $http_store = ['glance.store.http.Store']
 217   $glance_store = concat($http_store, $backend_store)
 218
 219   # TODO: notifications, scrubber, etc.
 220   include ::glance
 221   include ::glance::config
 222   class { '::glance::api':
 223     known_stores => $glance_store,
 224   }
 225   include ::glance::registry
 226   include join(['::glance::backend::', $glance_backend])
 227
 228   class { '::nova' :
 229     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 230   }
 231   include ::nova::config
 232   include ::nova::api
 233   include ::nova::cert
 234   include ::nova::conductor
 235   include ::nova::consoleauth
 236   include ::nova::network::neutron
 237   include ::nova::vncproxy
 238   include ::nova::scheduler
 239   include ::nova::scheduler::filter
 240
 241   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 242
 243     # TODO(devvesa) provide non-controller ips for these services
 244     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 245     $cassandra_node_ips = hiera('neutron_api_node_ips')
 246
 247     # Run zookeeper in the controller if configured
 248     if hiera('enable_zookeeper_on_controller') {
 249       class {'::tripleo::cluster::zookeeper':
 250         zookeeper_server_ips => $zookeeper_node_ips,
 251         zookeeper_client_ip  => $ipaddress,
 252         zookeeper_hostnames  => hiera('controller_node_names')
 253       }
 254     }
 255
 256     # Run cassandra in the controller if configured
 257     if hiera('enable_cassandra_on_controller') {
 258       class {'::tripleo::cluster::cassandra':
 259         cassandra_servers => $cassandra_node_ips,
 260         cassandra_ip      => $ipaddress
 261       }
 262     }
 263
 264     class {'::tripleo::network::midonet::agent':
 265       zookeeper_servers => $zookeeper_node_ips,
 266       cassandra_seeds   => $cassandra_node_ips
 267     }
 268
 269     class {'::tripleo::network::midonet::api':
 270       zookeeper_servers    => $zookeeper_node_ips,
 271       vip                  => $ipaddress,
 272       keystone_ip          => $ipaddress,
 273       keystone_admin_token => hiera('keystone::admin_token'),
 274       bind_address         => $ipaddress,
 275       admin_password       => hiera('admin_password')
 276     }
 277
 278     # TODO: find a way to get an empty list from hiera
 279     class {'::neutron':
 280       service_plugins => []
 281     }
 282
 283   }
 284   else {
 285
 286     # ML2 plugin
 287     include ::neutron
 288   }
 289
 290   include ::neutron::config
 291   include ::neutron::server
 292   include ::neutron::server::notifications
 293
 294   # If the value of core plugin is set to 'nuage',
 295   # include nuage core plugin, and it does not
 296   # need the l3, dhcp and metadata agents
 297   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 298     include ::neutron::plugins::nuage
 299   } else {
 300     include ::neutron::agents::l3
 301     include ::neutron::agents::dhcp
 302     include ::neutron::agents::metadata
 303
 304     file { '/etc/neutron/dnsmasq-neutron.conf':
 305       content => hiera('neutron_dnsmasq_options'),
 306       owner   => 'neutron',
 307       group   => 'neutron',
 308       notify  => Service['neutron-dhcp-service'],
 309       require => Package['neutron'],
 310     }
 311
 312     # If the value of core plugin is set to 'midonet',
 313     # skip all the ML2 configuration
 314     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 315
 316       class {'::neutron::plugins::midonet':
 317         midonet_api_ip    => $ipaddress,
 318         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 319         keystone_password => hiera('neutron::server::auth_password')
 320       }
 321     } else {
 322
 323       include ::neutron::plugins::ml2
 324       include ::neutron::agents::ml2::ovs
 325
 326       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 327         include ::neutron::plugins::ml2::cisco::nexus1000v
 328
 329         class { '::neutron::agents::n1kv_vem':
 330           n1kv_source  => hiera('n1kv_vem_source', undef),
 331           n1kv_version => hiera('n1kv_vem_version', undef),
 332         }
 333
 334         class { '::n1k_vsm':
 335           n1kv_source       => hiera('n1kv_vsm_source', undef),
 336           n1kv_version      => hiera('n1kv_vsm_version', undef),
 337           pacemaker_control => false,
 338         }
 339       }
 340
 341       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 342         include ::neutron::plugins::ml2::cisco::ucsm
 343       }
 344       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 345         include ::neutron::plugins::ml2::cisco::nexus
 346         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 347       }
 348
 349       if hiera('neutron_enable_bigswitch_ml2', false) {
 350         include ::neutron::plugins::ml2::bigswitch::restproxy
 351       }
 352       neutron_l3_agent_config {
 353         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 354       }
 355       neutron_dhcp_agent_config {
 356         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 357       }
 358       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 359     }
 360
 361     Service['neutron-server'] -> Service['neutron-dhcp-service']
 362     Service['neutron-server'] -> Service['neutron-l3']
 363     Service['neutron-server'] -> Service['neutron-metadata']
 364   }
 365
 366   include ::cinder
 367   include ::cinder::config
 368   include ::cinder::api
 369   include ::cinder::glance
 370   include ::cinder::scheduler
 371   include ::cinder::volume
 372   class { '::cinder::setup_test_volume':
 373     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 374   }
 375
 376   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 377   if $cinder_enable_iscsi {
 378     $cinder_iscsi_backend = 'tripleo_iscsi'
 379
 380     cinder::backend::iscsi { $cinder_iscsi_backend :
 381       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 382       iscsi_helper     => hiera('cinder_iscsi_helper'),
 383     }
 384   }
 385
 386   if $enable_ceph {
 387
 388     $ceph_pools = hiera('ceph_pools')
 389     ceph::pool { $ceph_pools :
 390       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 391       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 392       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 393     }
 394
 395     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 396
 397   } else {
 398     $cinder_pool_requires = []
 399   }
 400
 401   if hiera('cinder_enable_rbd_backend', false) {
 402     $cinder_rbd_backend = 'tripleo_ceph'
 403
 404     cinder::backend::rbd { $cinder_rbd_backend :
 405       rbd_pool        => hiera('cinder_rbd_pool_name'),
 406       rbd_user        => hiera('ceph_client_user_name'),
 407       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 408       require         => $cinder_pool_requires,
 409     }
 410   }
 411
 412   if hiera('cinder_enable_eqlx_backend', false) {
 413     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 414
 415     cinder_config {
 416       "${cinder_eqlx_backend}/host": value => 'hostgroup';
 417     }
 418
 419     cinder::backend::eqlx { $cinder_eqlx_backend :
 420       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 421       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 422       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 423       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 424       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 425       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 426       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_lpool', undef),
 427       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 428       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 429       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 430     }
 431   }
 432
 433   if hiera('cinder_enable_dellsc_backend', false) {
 434     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 435
 436     cinder_config {
 437       "${cinder_dellsc_backend}/host": value => 'hostgroup';
 438     }
 439
 440     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 441       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 442       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 443       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 444       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 445       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 446       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 447       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 448       dell_sc_port          => hiera('cinder::backend::dellsc_iscsi::dell_sc_port', undef),
 449       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 450       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 451     }
 452   }
 453
 454   if hiera('cinder_enable_netapp_backend', false) {
 455     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 456
 457     cinder_config {
 458       "${cinder_netapp_backend}/host": value => 'hostgroup';
 459     }
 460
 461     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 462       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 463     }
 464
 465     cinder::backend::netapp { $cinder_netapp_backend :
 466       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 467       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 468       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 469       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 470       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 471       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 472       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 473       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 474       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 475       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 476       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 477       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 478       nfs_shares                   => $cinder_netapp_nfs_shares,
 479       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 480       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 481       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 482       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 483       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 484       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 485       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 486     }
 487   }
 488
 489   if hiera('cinder_enable_nfs_backend', false) {
 490     $cinder_nfs_backend = 'tripleo_nfs'
 491
 492     if str2bool($::selinux) {
 493       selboolean { 'virt_use_nfs':
 494         value      => on,
 495         persistent => true,
 496       } -> Package['nfs-utils']
 497     }
 498
 499     package {'nfs-utils': } ->
 500     cinder::backend::nfs { $cinder_nfs_backend :
 501       nfs_servers       => hiera('cinder_nfs_servers'),
 502       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 503       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 504     }
 505   }
 506
 507   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 508   class { '::cinder::backends' :
 509     enabled_backends => $cinder_enabled_backends,
 510   }
 511
 512   # swift proxy
 513   include ::memcached
 514   include ::swift::proxy
 515   include ::swift::proxy::proxy_logging
 516   include ::swift::proxy::healthcheck
 517   include ::swift::proxy::cache
 518   include ::swift::proxy::keystone
 519   include ::swift::proxy::authtoken
 520   include ::swift::proxy::staticweb
 521   include ::swift::proxy::ratelimit
 522   include ::swift::proxy::catch_errors
 523   include ::swift::proxy::tempurl
 524   include ::swift::proxy::formpost
 525
 526   # swift storage
 527   if str2bool(hiera('enable_swift_storage', true)) {
 528     class { '::swift::storage::all':
 529       mount_check => str2bool(hiera('swift_mount_check')),
 530     }
 531     if(!defined(File['/srv/node'])) {
 532       file { '/srv/node':
 533         ensure  => directory,
 534         owner   => 'swift',
 535         group   => 'swift',
 536         require => Package['openstack-swift'],
 537       }
 538     }
 539     $swift_components = ['account', 'container', 'object']
 540     swift::storage::filter::recon { $swift_components : }
 541     swift::storage::filter::healthcheck { $swift_components : }
 542   }
 543
 544   # Ceilometer
 545   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 546   case $ceilometer_backend {
 547     /mysql/ : {
 548       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 549     }
 550     default : {
 551       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 552     }
 553   }
 554   include ::ceilometer
 555   include ::ceilometer::config
 556   include ::ceilometer::api
 557   include ::ceilometer::agent::notification
 558   include ::ceilometer::agent::central
 559   include ::ceilometer::expirer
 560   include ::ceilometer::collector
 561   include ::ceilometer::agent::auth
 562   class { '::ceilometer::db' :
 563     database_connection => $ceilometer_database_connection,
 564   }
 565
 566   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 567
 568   # Heat
 569   include ::heat
 570   include ::heat::config
 571   include ::heat::api
 572   include ::heat::api_cfn
 573   include ::heat::api_cloudwatch
 574   include ::heat::engine
 575
 576   # Sahara
 577   include ::sahara
 578   include ::sahara::service::api
 579   include ::sahara::service::engine
 580
 581   # Horizon
 582   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 583     $_profile_support = 'cisco'
 584   } else {
 585     $_profile_support = 'None'
 586   }
 587   $neutron_options   = {'profile_support' => $_profile_support }
 588
 589   class { '::horizon':
 590     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 591     neutron_options => $neutron_options,
 592   }
 593
 594   $snmpd_user = hiera('snmpd_readonly_user_name')
 595   snmp::snmpv3_user { $snmpd_user:
 596     authtype => 'MD5',
 597     authpass => hiera('snmpd_readonly_user_password'),
 598   }
 599   class { '::snmp':
 600     agentaddress => ['udp:161','udp6:[::1]:161'],
 601     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 602   }
 603
 604   hiera_include('controller_classes')
 605
 606 } #END STEP 3
 607
 608 if hiera('step') >= 4 {
 609   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 610   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 611   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 612
 613   if $keystone_enable_db_purge {
 614     include ::keystone::cron::token_flush
 615   }
 616   if $nova_enable_db_purge {
 617     include ::nova::cron::archive_deleted_rows
 618   }
 619   if $cinder_enable_db_purge {
 620     include ::cinder::cron::db_purge
 621   }
 622 } #END STEP 4
 623
 624 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 625 package_manifest{$package_manifest_name: ensure => present}