puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include tripleo::packages
  17
  18 if hiera('step') >= 1 {
  19
  20   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  21
  22   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  23
  24   class { '::tripleo::loadbalancer' :
  25     controller_hosts => $controller_node_ips,
  26     manage_vip       => true,
  27   }
  28
  29 }
  30
  31 if hiera('step') >= 2 {
  32
  33   if count(hiera('ntp::servers')) > 0 {
  34     include ::ntp
  35   }
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40
  41     include ::mongodb::server
  42     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  43     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  44
  45     $mongodb_replset = hiera('mongodb::server::replset')
  46     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  47     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  48       mongodb_replset { $mongodb_replset :
  49         members => $mongo_node_ips_with_port,
  50       }
  51     }
  52   }
  53
  54   # Redis
  55   $redis_node_ips = hiera('redis_node_ips')
  56   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  57
  58   if $redis_master_hostname == $::hostname {
  59     $slaveof = undef
  60   } else {
  61     $slaveof = "${redis_master_hostname} 6379"
  62   }
  63   class {'::redis' :
  64     slaveof => $slaveof,
  65   }
  66
  67   if count($redis_node_ips) > 1 {
  68     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  69     include ::redis::sentinel
  70     include ::tripleo::redis_notification
  71   }
  72
  73   if str2bool(hiera('enable_galera', 'true')) {
  74     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  75   } else {
  76     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  77   }
  78   # TODO Galara
  79   class { 'mysql::server':
  80     config_file => $mysql_config_file,
  81     override_options => {
  82       'mysqld' => {
  83         'bind-address' => hiera('mysql_bind_host'),
  84         'max_connections' => hiera('mysql_max_connections'),
  85         'open_files_limit' => '-1',
  86       },
  87     },
  88     remove_default_accounts => true,
  89   }
  90
  91   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  92   # Create all the database schemas
  93   include ::keystone::db::mysql
  94   include ::glance::db::mysql
  95   include ::nova::db::mysql
  96   include ::neutron::db::mysql
  97   include ::cinder::db::mysql
  98   include ::heat::db::mysql
  99   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 100     include ::ceilometer::db::mysql
 101   }
 102
 103   $rabbit_nodes = hiera('rabbit_node_ips')
 104   if count($rabbit_nodes) > 1 {
 105     class { '::rabbitmq':
 106       config_cluster          => true,
 107       cluster_nodes           => $rabbit_nodes,
 108       tcp_keepalive           => false,
 109       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 110       config_variables        => hiera('rabbitmq_config_variables'),
 111       environment_variables   => hiera('rabbitmq_environment'),
 112     }
 113     rabbitmq_policy { 'ha-all@/':
 114       pattern    => '^(?!amq\.).*',
 115       definition => {
 116         'ha-mode' => 'all',
 117       },
 118     }
 119   } else {
 120     include ::rabbitmq
 121   }
 122
 123   # pre-install swift here so we can build rings
 124   include ::swift
 125
 126   $enable_ceph = hiera('ceph_storage_count', 0) > 0
 127
 128   if $enable_ceph {
 129     class { 'ceph::profile::params':
 130       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 131     }
 132     include ::ceph::profile::mon
 133   }
 134
 135   if str2bool(hiera('enable_ceph_storage', 'false')) {
 136     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 137       exec { 'set selinux to permissive on boot':
 138         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 139         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 140         path    => ["/usr/bin", "/usr/sbin"],
 141       }
 142
 143       exec { 'set selinux to permissive':
 144         command => "setenforce 0",
 145         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 146         path    => ["/usr/bin", "/usr/sbin"],
 147       } -> Class['ceph::profile::osd']
 148     }
 149
 150     include ::ceph::profile::osd
 151   }
 152
 153   if str2bool(hiera('enable_external_ceph', 'false')) {
 154     include ::ceph::profile::client
 155   }
 156
 157 } #END STEP 2
 158
 159 if hiera('step') >= 3 {
 160
 161   include ::keystone
 162
 163   #TODO: need a cleanup-keystone-tokens.sh solution here
 164   keystone_config {
 165     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 166   }
 167   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 168     ensure  => 'directory',
 169     owner   => 'keystone',
 170     group   => 'keystone',
 171     require => Package['keystone'],
 172   }
 173   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 174     content => hiera('keystone_signing_certificate'),
 175     owner   => 'keystone',
 176     group   => 'keystone',
 177     notify  => Service['keystone'],
 178     require => File['/etc/keystone/ssl/certs'],
 179   }
 180   file { '/etc/keystone/ssl/private/signing_key.pem':
 181     content => hiera('keystone_signing_key'),
 182     owner   => 'keystone',
 183     group   => 'keystone',
 184     notify  => Service['keystone'],
 185     require => File['/etc/keystone/ssl/private'],
 186   }
 187   file { '/etc/keystone/ssl/certs/ca.pem':
 188     content => hiera('keystone_ca_certificate'),
 189     owner   => 'keystone',
 190     group   => 'keystone',
 191     notify  => Service['keystone'],
 192     require => File['/etc/keystone/ssl/certs'],
 193   }
 194
 195   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 196   case $glance_backend {
 197       swift: { $backend_store = 'glance.store.swift.Store' }
 198       file: { $backend_store = 'glance.store.filesystem.Store' }
 199       rbd: { $backend_store = 'glance.store.rbd.Store' }
 200       default: { fail('Unrecognized glance_backend parameter.') }
 201   }
 202   $http_store = ['glance.store.http.Store']
 203   $glance_store = concat($http_store, $backend_store)
 204
 205   # TODO: notifications, scrubber, etc.
 206   include ::glance
 207   class { 'glance::api':
 208     known_stores => $glance_store
 209   }
 210   include ::glance::registry
 211   include join(['::glance::backend::', $glance_backend])
 212
 213   class { '::nova' :
 214     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 215   }
 216   include ::nova::config
 217   include ::nova::api
 218   include ::nova::cert
 219   include ::nova::conductor
 220   include ::nova::consoleauth
 221   include ::nova::network::neutron
 222   include ::nova::vncproxy
 223   include ::nova::scheduler
 224   include ::nova::scheduler::filter
 225
 226   include ::neutron
 227   include ::neutron::server
 228   include ::neutron::agents::l3
 229   include ::neutron::agents::dhcp
 230   include ::neutron::agents::metadata
 231
 232   file { '/etc/neutron/dnsmasq-neutron.conf':
 233     content => hiera('neutron_dnsmasq_options'),
 234     owner   => 'neutron',
 235     group   => 'neutron',
 236     notify  => Service['neutron-dhcp-service'],
 237     require => Package['neutron'],
 238   }
 239
 240   class { 'neutron::plugins::ml2':
 241     flat_networks => split(hiera('neutron_flat_networks'), ','),
 242     tenant_network_types => [hiera('neutron_tenant_network_type')],
 243     mechanism_drivers   => [hiera('neutron_mechanism_drivers')],
 244   }
 245   class { 'neutron::agents::ml2::ovs':
 246     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 247     tunnel_types => split(hiera('neutron_tunnel_types'), ','),
 248   }
 249
 250   if 'cisco_ucsm' in hiera('neutron_mechanism_drivers') {
 251     include ::neutron::plugins::ml2::cisco::ucsm
 252   }
 253   if 'cisco_nexus' in hiera('neutron_mechanism_drivers') {
 254     include ::neutron::plugins::ml2::cisco::nexus
 255     include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 256   }
 257
 258   if hiera('neutron_enable_bigswitch_ml2', false) {
 259     include neutron::plugins::ml2::bigswitch::restproxy
 260   }
 261   neutron_l3_agent_config {
 262     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 263   }
 264   neutron_dhcp_agent_config {
 265     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 266   }
 267
 268   Service['neutron-server'] -> Service['neutron-dhcp-service']
 269   Service['neutron-server'] -> Service['neutron-l3']
 270   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 271   Service['neutron-server'] -> Service['neutron-metadata']
 272
 273   include ::cinder
 274   include ::cinder::api
 275   include ::cinder::glance
 276   include ::cinder::scheduler
 277   include ::cinder::volume
 278   class {'cinder::setup_test_volume':
 279     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 280   }
 281
 282   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 283   if $cinder_enable_iscsi {
 284     $cinder_iscsi_backend = 'tripleo_iscsi'
 285
 286     cinder::backend::iscsi { $cinder_iscsi_backend :
 287       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 288       iscsi_helper     => hiera('cinder_iscsi_helper'),
 289     }
 290   }
 291
 292   if $enable_ceph {
 293
 294     Ceph_pool {
 295       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 296       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 297       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 298     }
 299
 300     $ceph_pools = hiera('ceph_pools')
 301     ceph::pool { $ceph_pools : }
 302
 303     $cinder_pool_requires = [Ceph::Pool['volumes']]
 304
 305   } else {
 306     $cinder_pool_requires = []
 307   }
 308
 309   if hiera('cinder_enable_rbd_backend', false) {
 310     $cinder_rbd_backend = 'tripleo_ceph'
 311
 312     cinder::backend::rbd { $cinder_rbd_backend :
 313       rbd_pool        => 'volumes',
 314       rbd_user        => 'openstack',
 315       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 316       require         => $cinder_pool_requires,
 317     }
 318   }
 319
 320   if hiera('cinder_enable_netapp_backend', false) {
 321     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 322
 323     cinder_config {
 324       "${cinder_netapp_backend}/host": value => 'hostgroup';
 325     }
 326
 327     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 328       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 329     }
 330
 331     cinder::backend::netapp { $cinder_netapp_backend :
 332       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 333       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 334       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 335       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 336       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 337       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 338       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 339       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 340       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 341       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 342       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 343       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 344       nfs_shares                   => $cinder_netapp_nfs_shares,
 345       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 346       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 347       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 348       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 349       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 350       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 351       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 352     }
 353   }
 354
 355   if hiera('cinder_enable_nfs_backend', false) {
 356     $cinder_nfs_backend = 'tripleo_nfs'
 357
 358     if ($::selinux != "false") {
 359       selboolean { 'virt_use_nfs':
 360           value => on,
 361           persistent => true,
 362       } -> Package['nfs-utils']
 363     }
 364
 365     package {'nfs-utils': } ->
 366     cinder::backend::nfs { $cinder_nfs_backend :
 367       nfs_servers         => hiera('cinder_nfs_servers'),
 368       nfs_mount_options   => hiera('cinder_nfs_mount_options'),
 369       nfs_shares_config   => '/etc/cinder/shares-nfs.conf',
 370     }
 371   }
 372
 373   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 374   class { '::cinder::backends' :
 375     enabled_backends => $cinder_enabled_backends,
 376   }
 377
 378   # swift proxy
 379   include ::memcached
 380   include ::swift::proxy
 381   include ::swift::proxy::proxy_logging
 382   include ::swift::proxy::healthcheck
 383   include ::swift::proxy::cache
 384   include ::swift::proxy::keystone
 385   include ::swift::proxy::authtoken
 386   include ::swift::proxy::staticweb
 387   include ::swift::proxy::ratelimit
 388   include ::swift::proxy::catch_errors
 389   include ::swift::proxy::tempurl
 390   include ::swift::proxy::formpost
 391
 392   # swift storage
 393   if str2bool(hiera('enable_swift_storage', 'true')) {
 394     class {'swift::storage::all':
 395       mount_check => str2bool(hiera('swift_mount_check'))
 396     }
 397     if(!defined(File['/srv/node'])) {
 398       file { '/srv/node':
 399         ensure  => directory,
 400         owner   => 'swift',
 401         group   => 'swift',
 402         require => Package['openstack-swift'],
 403       }
 404     }
 405     $swift_components = ['account', 'container', 'object']
 406     swift::storage::filter::recon { $swift_components : }
 407     swift::storage::filter::healthcheck { $swift_components : }
 408   }
 409
 410   # Ceilometer
 411   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 412   case $ceilometer_backend {
 413     /mysql/ : {
 414       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 415     }
 416     default : {
 417       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 418     }
 419   }
 420   include ::ceilometer
 421   include ::ceilometer::api
 422   include ::ceilometer::agent::notification
 423   include ::ceilometer::agent::central
 424   include ::ceilometer::alarm::notifier
 425   include ::ceilometer::alarm::evaluator
 426   include ::ceilometer::expirer
 427   include ::ceilometer::collector
 428   include ceilometer::agent::auth
 429   class { '::ceilometer::db' :
 430     database_connection => $ceilometer_database_connection,
 431   }
 432
 433   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 434
 435   # Heat
 436   include ::heat
 437   include ::heat::api
 438   include ::heat::api_cfn
 439   include ::heat::api_cloudwatch
 440   include ::heat::engine
 441
 442   # Horizon
 443   $vhost_params = { add_listen => false }
 444   class { 'horizon':
 445     cache_server_ip    => hiera('memcache_node_ips', '127.0.0.1'),
 446     vhost_extra_params => $vhost_params,
 447   }
 448
 449   $snmpd_user = hiera('snmpd_readonly_user_name')
 450   snmp::snmpv3_user { $snmpd_user:
 451     authtype => 'MD5',
 452     authpass => hiera('snmpd_readonly_user_password'),
 453   }
 454   class { 'snmp':
 455     agentaddress => ['udp:161','udp6:[::1]:161'],
 456     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 457   }
 458
 459   hiera_include('controller_classes')
 460
 461 } #END STEP 3
 462
 463 if hiera('step') >= 4 {
 464   include ::keystone::cron::token_flush
 465 } #END STEP 4
 466
 467 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 468 package_manifest{$package_manifest_name: ensure => present}