puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  28
  29   if $enable_load_balancer {
  30     class { '::tripleo::loadbalancer' :
  31       controller_hosts => $controller_node_ips,
  32       manage_vip       => true,
  33     }
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   include ::timezone
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49     include ::mongodb::client
  50     include ::mongodb::server
  51     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  52     # without the brackets as 'members' argument for the 'mongodb_replset'
  53     # resource.
  54     if str2bool(hiera('mongodb::server::ipv6', false)) {
  55       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  56       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  57       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  58     } else {
  59       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  60       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  61     }
  62     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  63
  64     $mongodb_replset = hiera('mongodb::server::replset')
  65     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  66     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  67       mongodb_replset { $mongodb_replset :
  68         members => $mongo_node_ips_with_port_nobr,
  69       }
  70     }
  71   }
  72
  73   # Redis
  74   $redis_node_ips = hiera('redis_node_ips')
  75   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  76
  77   if $redis_master_hostname == $::hostname {
  78     $slaveof = undef
  79   } else {
  80     $slaveof = "${redis_master_hostname} 6379"
  81   }
  82   class {'::redis' :
  83     slaveof => $slaveof,
  84   }
  85
  86   if count($redis_node_ips) > 1 {
  87     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  88     include ::redis::sentinel
  89     include ::tripleo::redis_notification
  90   }
  91
  92   if str2bool(hiera('enable_galera', true)) {
  93     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  94   } else {
  95     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  96   }
  97   # TODO Galara
  98   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  99   # set bind-address to a hostname instead of an ip address; to move Mysql
 100   # from internal_api on another network we'll have to customize both
 101   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
 102   class { '::mysql::server':
 103     config_file             => $mysql_config_file,
 104     override_options        => {
 105       'mysqld' => {
 106         'bind-address'     => $::hostname,
 107         'max_connections'  => hiera('mysql_max_connections'),
 108         'open_files_limit' => '-1',
 109       },
 110     },
 111     remove_default_accounts => true,
 112   }
 113
 114   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 115   # Create all the database schemas
 116   include ::keystone::db::mysql
 117   include ::glance::db::mysql
 118   include ::nova::db::mysql
 119   include ::nova::db::mysql_api
 120   include ::neutron::db::mysql
 121   include ::cinder::db::mysql
 122   include ::heat::db::mysql
 123   include ::sahara::db::mysql
 124   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 125     include ::ceilometer::db::mysql
 126   }
 127
 128   $rabbit_nodes = hiera('rabbit_node_ips')
 129   if count($rabbit_nodes) > 1 {
 130
 131     $rabbit_ipv6 = str2bool(hiera('rabbit_ipv6', false))
 132     if $rabbit_ipv6 {
 133       $rabbit_env = merge(hiera('rabbitmq_environment'), {
 134         'RABBITMQ_SERVER_START_ARGS' => '"-proto_dist inet6_tcp"'
 135       })
 136     } else {
 137       $rabbit_env = hiera('rabbitmq_environment')
 138     }
 139
 140     class { '::rabbitmq':
 141       config_cluster          => true,
 142       cluster_nodes           => $rabbit_nodes,
 143       tcp_keepalive           => false,
 144       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 145       config_variables        => hiera('rabbitmq_config_variables'),
 146       environment_variables   => $rabbit_env,
 147     }
 148     rabbitmq_policy { 'ha-all@/':
 149       pattern    => '^(?!amq\.).*',
 150       definition => {
 151         'ha-mode' => 'all',
 152       },
 153     }
 154   } else {
 155     include ::rabbitmq
 156   }
 157
 158   # pre-install swift here so we can build rings
 159   include ::swift
 160
 161   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 162
 163   if $enable_ceph {
 164     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 165     if str2bool(hiera('ceph_ipv6', false)) {
 166       $mon_host = hiera('ceph_mon_host_v6')
 167     } else {
 168       $mon_host = hiera('ceph_mon_host')
 169     }
 170     class { '::ceph::profile::params':
 171       mon_initial_members => $mon_initial_members,
 172       mon_host            => $mon_host,
 173     }
 174     include ::ceph::conf
 175     include ::ceph::profile::mon
 176   }
 177
 178   if str2bool(hiera('enable_ceph_storage', false)) {
 179     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 180       exec { 'set selinux to permissive on boot':
 181         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 182         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 183         path    => ['/usr/bin', '/usr/sbin'],
 184       }
 185
 186       exec { 'set selinux to permissive':
 187         command => 'setenforce 0',
 188         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 189         path    => ['/usr/bin', '/usr/sbin'],
 190       } -> Class['ceph::profile::osd']
 191     }
 192
 193     include ::ceph::conf
 194     include ::ceph::profile::osd
 195   }
 196
 197   if str2bool(hiera('enable_external_ceph', false)) {
 198     if str2bool(hiera('ceph_ipv6', false)) {
 199       $mon_host = hiera('ceph_mon_host_v6')
 200     } else {
 201       $mon_host = hiera('ceph_mon_host')
 202     }
 203     class { '::ceph::profile::params':
 204       mon_host            => $mon_host,
 205     }
 206     include ::ceph::conf
 207     include ::ceph::profile::client
 208   }
 209
 210 } #END STEP 2
 211
 212 if hiera('step') >= 3 {
 213
 214   include ::keystone
 215   include ::keystone::config
 216   include ::keystone::roles::admin
 217   include ::keystone::endpoint
 218   include ::keystone::wsgi::apache
 219
 220   #TODO: need a cleanup-keystone-tokens.sh solution here
 221
 222   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 223     ensure  => 'directory',
 224     owner   => 'keystone',
 225     group   => 'keystone',
 226     require => Package['keystone'],
 227   }
 228   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 229     content => hiera('keystone_signing_certificate'),
 230     owner   => 'keystone',
 231     group   => 'keystone',
 232     notify  => Service['keystone'],
 233     require => File['/etc/keystone/ssl/certs'],
 234   }
 235   file { '/etc/keystone/ssl/private/signing_key.pem':
 236     content => hiera('keystone_signing_key'),
 237     owner   => 'keystone',
 238     group   => 'keystone',
 239     notify  => Service['keystone'],
 240     require => File['/etc/keystone/ssl/private'],
 241   }
 242   file { '/etc/keystone/ssl/certs/ca.pem':
 243     content => hiera('keystone_ca_certificate'),
 244     owner   => 'keystone',
 245     group   => 'keystone',
 246     notify  => Service['keystone'],
 247     require => File['/etc/keystone/ssl/certs'],
 248   }
 249
 250   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 251   case $glance_backend {
 252       'swift': { $backend_store = 'glance.store.swift.Store' }
 253       'file': { $backend_store = 'glance.store.filesystem.Store' }
 254       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 255       default: { fail('Unrecognized glance_backend parameter.') }
 256   }
 257   $http_store = ['glance.store.http.Store']
 258   $glance_store = concat($http_store, $backend_store)
 259
 260   # TODO: scrubber and other additional optional features
 261   include ::glance
 262   include ::glance::config
 263   class { '::glance::api':
 264     known_stores => $glance_store,
 265   }
 266   include ::glance::registry
 267   include ::glance::notify::rabbitmq
 268   include join(['::glance::backend::', $glance_backend])
 269
 270   $nova_ipv6 = hiera('nova::use_ipv6', false)
 271   if $nova_ipv6 {
 272     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 273   } else {
 274     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 275   }
 276
 277   class { '::nova' :
 278     memcached_servers => $memcached_servers
 279   }
 280   include ::nova::config
 281   include ::nova::api
 282   include ::nova::cert
 283   include ::nova::conductor
 284   include ::nova::consoleauth
 285   include ::nova::network::neutron
 286   include ::nova::vncproxy
 287   include ::nova::scheduler
 288   include ::nova::scheduler::filter
 289
 290   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 291
 292     # TODO(devvesa) provide non-controller ips for these services
 293     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 294     $cassandra_node_ips = hiera('neutron_api_node_ips')
 295
 296     # Run zookeeper in the controller if configured
 297     if hiera('enable_zookeeper_on_controller') {
 298       class {'::tripleo::cluster::zookeeper':
 299         zookeeper_server_ips => $zookeeper_node_ips,
 300         # TODO: create a 'bind' hiera key for zookeeper
 301         zookeeper_client_ip  => hiera('neutron::bind_host'),
 302         zookeeper_hostnames  => hiera('controller_node_names')
 303       }
 304     }
 305
 306     # Run cassandra in the controller if configured
 307     if hiera('enable_cassandra_on_controller') {
 308       class {'::tripleo::cluster::cassandra':
 309         cassandra_servers => $cassandra_node_ips,
 310         # TODO: create a 'bind' hiera key for cassandra
 311         cassandra_ip      => hiera('neutron::bind_host'),
 312       }
 313     }
 314
 315     class {'::tripleo::network::midonet::agent':
 316       zookeeper_servers => $zookeeper_node_ips,
 317       cassandra_seeds   => $cassandra_node_ips
 318     }
 319
 320     class {'::tripleo::network::midonet::api':
 321       zookeeper_servers    => $zookeeper_node_ips,
 322       vip                  => hiera('tripleo::loadbalancer::public_virtual_ip'),
 323       keystone_ip          => hiera('tripleo::loadbalancer::public_virtual_ip'),
 324       keystone_admin_token => hiera('keystone::admin_token'),
 325       # TODO: create a 'bind' hiera key for api
 326       bind_address         => hiera('neutron::bind_host'),
 327       admin_password       => hiera('admin_password')
 328     }
 329
 330     # TODO: find a way to get an empty list from hiera
 331     class {'::neutron':
 332       service_plugins => []
 333     }
 334
 335   }
 336   else {
 337
 338     # ML2 plugin
 339     include ::neutron
 340   }
 341
 342   include ::neutron::config
 343   include ::neutron::server
 344   include ::neutron::server::notifications
 345
 346   # If the value of core plugin is set to 'nuage' or 'opencontrail',
 347   # include nuage or opencontrail core plugins, and it does not
 348   # need the l3, dhcp and metadata agents
 349   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 350     include ::neutron::plugins::nuage
 351   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 352     include ::neutron::plugins::opencontrail
 353   } else {
 354     include ::neutron::agents::l3
 355     include ::neutron::agents::dhcp
 356     include ::neutron::agents::metadata
 357
 358     file { '/etc/neutron/dnsmasq-neutron.conf':
 359       content => hiera('neutron_dnsmasq_options'),
 360       owner   => 'neutron',
 361       group   => 'neutron',
 362       notify  => Service['neutron-dhcp-service'],
 363       require => Package['neutron'],
 364     }
 365
 366     # If the value of core plugin is set to 'midonet',
 367     # skip all the ML2 configuration
 368     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 369
 370       class {'::neutron::plugins::midonet':
 371         midonet_api_ip    => hiera('tripleo::loadbalancer::public_virtual_ip'),
 372         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 373         keystone_password => hiera('neutron::server::auth_password')
 374       }
 375     } else {
 376
 377       include ::neutron::plugins::ml2
 378       include ::neutron::agents::ml2::ovs
 379
 380       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 381         include ::neutron::plugins::ml2::cisco::nexus1000v
 382
 383         class { '::neutron::agents::n1kv_vem':
 384           n1kv_source  => hiera('n1kv_vem_source', undef),
 385           n1kv_version => hiera('n1kv_vem_version', undef),
 386         }
 387
 388         class { '::n1k_vsm':
 389           n1kv_source       => hiera('n1kv_vsm_source', undef),
 390           n1kv_version      => hiera('n1kv_vsm_version', undef),
 391           pacemaker_control => false,
 392         }
 393       }
 394
 395       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 396         include ::neutron::plugins::ml2::cisco::ucsm
 397       }
 398       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 399         include ::neutron::plugins::ml2::cisco::nexus
 400         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 401       }
 402
 403       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 404         include ::neutron::plugins::ml2::bigswitch::restproxy
 405         include ::neutron::agents::bigswitch
 406       }
 407       neutron_l3_agent_config {
 408         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 409       }
 410       neutron_dhcp_agent_config {
 411         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 412       }
 413       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 414     }
 415
 416     Service['neutron-server'] -> Service['neutron-dhcp-service']
 417     Service['neutron-server'] -> Service['neutron-l3']
 418     Service['neutron-server'] -> Service['neutron-metadata']
 419   }
 420
 421   include ::cinder
 422   include ::cinder::config
 423   include ::tripleo::ssl::cinder_config
 424   include ::cinder::api
 425   include ::cinder::glance
 426   include ::cinder::scheduler
 427   include ::cinder::volume
 428   include ::cinder::ceilometer
 429   class { '::cinder::setup_test_volume':
 430     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 431   }
 432
 433   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 434   if $cinder_enable_iscsi {
 435     $cinder_iscsi_backend = 'tripleo_iscsi'
 436
 437     cinder::backend::iscsi { $cinder_iscsi_backend :
 438       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 439       iscsi_helper     => hiera('cinder_iscsi_helper'),
 440     }
 441   }
 442
 443   if $enable_ceph {
 444
 445     $ceph_pools = hiera('ceph_pools')
 446     ceph::pool { $ceph_pools :
 447       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 448       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 449       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 450     }
 451
 452     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 453
 454   } else {
 455     $cinder_pool_requires = []
 456   }
 457
 458   if hiera('cinder_enable_rbd_backend', false) {
 459     $cinder_rbd_backend = 'tripleo_ceph'
 460
 461     cinder::backend::rbd { $cinder_rbd_backend :
 462       rbd_pool        => hiera('cinder_rbd_pool_name'),
 463       rbd_user        => hiera('ceph_client_user_name'),
 464       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 465       require         => $cinder_pool_requires,
 466     }
 467   }
 468
 469   if hiera('cinder_enable_eqlx_backend', false) {
 470     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 471
 472     cinder::backend::eqlx { $cinder_eqlx_backend :
 473       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 474       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 475       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 476       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 477       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 478       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 479       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 480       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 481       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 482       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 483     }
 484   }
 485
 486   if hiera('cinder_enable_dellsc_backend', false) {
 487     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 488
 489     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 490       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 491       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 492       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 493       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 494       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 495       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 496       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 497       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 498       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 499       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 500     }
 501   }
 502
 503   if hiera('cinder_enable_netapp_backend', false) {
 504     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 505
 506     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 507       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 508     }
 509
 510     cinder::backend::netapp { $cinder_netapp_backend :
 511       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 512       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 513       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 514       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 515       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 516       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 517       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 518       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 519       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 520       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 521       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 522       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 523       nfs_shares                   => $cinder_netapp_nfs_shares,
 524       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 525       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 526       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 527       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 528       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 529       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 530       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 531     }
 532   }
 533
 534   if hiera('cinder_enable_nfs_backend', false) {
 535     $cinder_nfs_backend = 'tripleo_nfs'
 536
 537     if str2bool($::selinux) {
 538       selboolean { 'virt_use_nfs':
 539         value      => on,
 540         persistent => true,
 541       } -> Package['nfs-utils']
 542     }
 543
 544     package {'nfs-utils': } ->
 545     cinder::backend::nfs { $cinder_nfs_backend :
 546       nfs_servers       => hiera('cinder_nfs_servers'),
 547       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 548       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 549     }
 550   }
 551
 552   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 553   class { '::cinder::backends' :
 554     enabled_backends => union($cinder_enabled_backends, hiera('cinder_user_enabled_backends')),
 555   }
 556
 557   # swift proxy
 558   include ::memcached
 559   include ::swift::proxy
 560   include ::swift::proxy::proxy_logging
 561   include ::swift::proxy::healthcheck
 562   include ::swift::proxy::cache
 563   include ::swift::proxy::keystone
 564   include ::swift::proxy::authtoken
 565   include ::swift::proxy::staticweb
 566   include ::swift::proxy::ratelimit
 567   include ::swift::proxy::catch_errors
 568   include ::swift::proxy::tempurl
 569   include ::swift::proxy::formpost
 570
 571   # swift storage
 572   if str2bool(hiera('enable_swift_storage', true)) {
 573     class { '::swift::storage::all':
 574       mount_check => str2bool(hiera('swift_mount_check')),
 575     }
 576     if(!defined(File['/srv/node'])) {
 577       file { '/srv/node':
 578         ensure  => directory,
 579         owner   => 'swift',
 580         group   => 'swift',
 581         require => Package['openstack-swift'],
 582       }
 583     }
 584     $swift_components = ['account', 'container', 'object']
 585     swift::storage::filter::recon { $swift_components : }
 586     swift::storage::filter::healthcheck { $swift_components : }
 587   }
 588
 589   # Ceilometer
 590   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 591   case $ceilometer_backend {
 592     /mysql/ : {
 593       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 594     }
 595     default : {
 596       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 597     }
 598   }
 599   include ::ceilometer
 600   include ::ceilometer::config
 601   include ::ceilometer::api
 602   include ::ceilometer::agent::notification
 603   include ::ceilometer::agent::central
 604   include ::ceilometer::expirer
 605   include ::ceilometer::collector
 606   include ::ceilometer::agent::auth
 607   class { '::ceilometer::db' :
 608     database_connection => $ceilometer_database_connection,
 609   }
 610
 611   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 612
 613   # Heat
 614   class { '::heat' :
 615     notification_driver => 'messaging',
 616   }
 617   include ::heat::config
 618   include ::heat::api
 619   include ::heat::api_cfn
 620   include ::heat::api_cloudwatch
 621   include ::heat::engine
 622
 623   # Sahara
 624   include ::sahara
 625   include ::sahara::service::api
 626   include ::sahara::service::engine
 627
 628   # Horizon
 629   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 630     $_profile_support = 'cisco'
 631   } else {
 632     $_profile_support = 'None'
 633   }
 634   $neutron_options   = {'profile_support' => $_profile_support }
 635
 636   $memcached_ipv6 = hiera('memcached_ipv6', false)
 637   if $memcached_ipv6 {
 638     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 639   } else {
 640     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 641   }
 642
 643   class { '::horizon':
 644     cache_server_ip => $horizon_memcached_servers,
 645     neutron_options => $neutron_options,
 646   }
 647
 648   $snmpd_user = hiera('snmpd_readonly_user_name')
 649   snmp::snmpv3_user { $snmpd_user:
 650     authtype => 'MD5',
 651     authpass => hiera('snmpd_readonly_user_password'),
 652   }
 653   class { '::snmp':
 654     agentaddress => ['udp:161','udp6:[::1]:161'],
 655     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 656   }
 657
 658   hiera_include('controller_classes')
 659
 660 } #END STEP 3
 661
 662 if hiera('step') >= 4 {
 663   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 664   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 665   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 666   $heat_enable_db_purge = hiera('heat_enable_db_purge', true)
 667
 668   if $keystone_enable_db_purge {
 669     include ::keystone::cron::token_flush
 670   }
 671   if $nova_enable_db_purge {
 672     include ::nova::cron::archive_deleted_rows
 673   }
 674   if $cinder_enable_db_purge {
 675     include ::cinder::cron::db_purge
 676   }
 677   if $heat_enable_db_purge {
 678     include ::heat::cron::purge_deleted
 679   }
 680
 681   if downcase(hiera('bootstrap_nodeid')) == $::hostname {
 682     include ::keystone::roles::admin
 683     # Class ::heat::keystone::domain has to run on bootstrap node
 684     # because it creates DB entities via API calls.
 685     include ::heat::keystone::domain
 686
 687     Class['::keystone::roles::admin'] -> Class['::heat::keystone::domain']
 688   } else {
 689     # On non-bootstrap node we don't need to create Keystone resources again
 690     class { '::heat::keystone::domain':
 691       manage_domain => false,
 692       manage_user   => false,
 693       manage_role   => false,
 694     }
 695   }
 696
 697 } #END STEP 4
 698
 699 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 700 package_manifest{$package_manifest_name: ensure => present}