puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  24
  25   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  26
  27   if $enable_load_balancer {
  28     class { '::tripleo::loadbalancer' :
  29       controller_hosts => $controller_node_ips,
  30       manage_vip       => true,
  31     }
  32   }
  33
  34 }
  35
  36 if hiera('step') >= 2 {
  37
  38   if count(hiera('ntp::servers')) > 0 {
  39     include ::ntp
  40   }
  41
  42   # MongoDB
  43   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  44     include ::mongodb::globals
  45
  46     include ::mongodb::server
  47     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  48     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  49
  50     $mongodb_replset = hiera('mongodb::server::replset')
  51     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  52     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  53       mongodb_replset { $mongodb_replset :
  54         members => $mongo_node_ips_with_port,
  55       }
  56     }
  57   }
  58
  59   # Redis
  60   $redis_node_ips = hiera('redis_node_ips')
  61   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  62
  63   if $redis_master_hostname == $::hostname {
  64     $slaveof = undef
  65   } else {
  66     $slaveof = "${redis_master_hostname} 6379"
  67   }
  68   class {'::redis' :
  69     slaveof => $slaveof,
  70   }
  71
  72   if count($redis_node_ips) > 1 {
  73     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  74     include ::redis::sentinel
  75     include ::tripleo::redis_notification
  76   }
  77
  78   if str2bool(hiera('enable_galera', true)) {
  79     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  80   } else {
  81     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  82   }
  83   # TODO Galara
  84   class { '::mysql::server':
  85     config_file             => $mysql_config_file,
  86     override_options        => {
  87       'mysqld' => {
  88         'bind-address'     => hiera('mysql_bind_host'),
  89         'max_connections'  => hiera('mysql_max_connections'),
  90         'open_files_limit' => '-1',
  91       },
  92     },
  93     remove_default_accounts => true,
  94   }
  95
  96   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  97   # Create all the database schemas
  98   include ::keystone::db::mysql
  99   include ::glance::db::mysql
 100   include ::nova::db::mysql
 101   include ::neutron::db::mysql
 102   include ::cinder::db::mysql
 103   include ::heat::db::mysql
 104   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 105     include ::ceilometer::db::mysql
 106   }
 107
 108   $rabbit_nodes = hiera('rabbit_node_ips')
 109   if count($rabbit_nodes) > 1 {
 110     class { '::rabbitmq':
 111       config_cluster          => true,
 112       cluster_nodes           => $rabbit_nodes,
 113       tcp_keepalive           => false,
 114       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 115       config_variables        => hiera('rabbitmq_config_variables'),
 116       environment_variables   => hiera('rabbitmq_environment'),
 117     }
 118     rabbitmq_policy { 'ha-all@/':
 119       pattern    => '^(?!amq\.).*',
 120       definition => {
 121         'ha-mode' => 'all',
 122       },
 123     }
 124   } else {
 125     include ::rabbitmq
 126   }
 127
 128   # pre-install swift here so we can build rings
 129   include ::swift
 130
 131   $enable_ceph = hiera('ceph_storage_count', 0) > 0
 132
 133   if $enable_ceph {
 134     class { '::ceph::profile::params':
 135       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 136     }
 137     include ::ceph::profile::mon
 138   }
 139
 140   if str2bool(hiera('enable_ceph_storage', false)) {
 141     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 142       exec { 'set selinux to permissive on boot':
 143         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 144         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 145         path    => ['/usr/bin', '/usr/sbin'],
 146       }
 147
 148       exec { 'set selinux to permissive':
 149         command => 'setenforce 0',
 150         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 151         path    => ['/usr/bin', '/usr/sbin'],
 152       } -> Class['ceph::profile::osd']
 153     }
 154
 155     include ::ceph::profile::osd
 156   }
 157
 158   if str2bool(hiera('enable_external_ceph', false)) {
 159     include ::ceph::profile::client
 160   }
 161
 162 } #END STEP 2
 163
 164 if hiera('step') >= 3 {
 165
 166   include ::keystone
 167   include ::keystone::roles::admin
 168   include ::keystone::endpoint
 169
 170   #TODO: need a cleanup-keystone-tokens.sh solution here
 171   keystone_config {
 172     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 173   }
 174   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 175     ensure  => 'directory',
 176     owner   => 'keystone',
 177     group   => 'keystone',
 178     require => Package['keystone'],
 179   }
 180   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 181     content => hiera('keystone_signing_certificate'),
 182     owner   => 'keystone',
 183     group   => 'keystone',
 184     notify  => Service['keystone'],
 185     require => File['/etc/keystone/ssl/certs'],
 186   }
 187   file { '/etc/keystone/ssl/private/signing_key.pem':
 188     content => hiera('keystone_signing_key'),
 189     owner   => 'keystone',
 190     group   => 'keystone',
 191     notify  => Service['keystone'],
 192     require => File['/etc/keystone/ssl/private'],
 193   }
 194   file { '/etc/keystone/ssl/certs/ca.pem':
 195     content => hiera('keystone_ca_certificate'),
 196     owner   => 'keystone',
 197     group   => 'keystone',
 198     notify  => Service['keystone'],
 199     require => File['/etc/keystone/ssl/certs'],
 200   }
 201
 202   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 203   case $glance_backend {
 204       'swift': { $backend_store = 'glance.store.swift.Store' }
 205       'file': { $backend_store = 'glance.store.filesystem.Store' }
 206       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 207       default: { fail('Unrecognized glance_backend parameter.') }
 208   }
 209   $http_store = ['glance.store.http.Store']
 210   $glance_store = concat($http_store, $backend_store)
 211
 212   # TODO: notifications, scrubber, etc.
 213   include ::glance
 214   class { '::glance::api':
 215     known_stores => $glance_store,
 216   }
 217   include ::glance::registry
 218   include join(['::glance::backend::', $glance_backend])
 219
 220   class { '::nova' :
 221     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 222   }
 223   include ::nova::config
 224   include ::nova::api
 225   include ::nova::cert
 226   include ::nova::conductor
 227   include ::nova::consoleauth
 228   include ::nova::network::neutron
 229   include ::nova::vncproxy
 230   include ::nova::scheduler
 231   include ::nova::scheduler::filter
 232
 233   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 234
 235     # TODO(devvesa) provide non-controller ips for these services
 236     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 237     $cassandra_node_ips = hiera('neutron_api_node_ips')
 238
 239     # Run zookeeper in the controller if configured
 240     if hiera('enable_zookeeper_on_controller') {
 241       class {'::tripleo::cluster::zookeeper':
 242         zookeeper_server_ips => $zookeeper_node_ips,
 243         zookeeper_client_ip  => $ipaddress,
 244         zookeeper_hostnames  => hiera('controller_node_names')
 245       }
 246     }
 247
 248     # Run cassandra in the controller if configured
 249     if hiera('enable_cassandra_on_controller') {
 250       class {'::tripleo::cluster::cassandra':
 251         cassandra_servers => $cassandra_node_ips,
 252         cassandra_ip      => $ipaddress
 253       }
 254     }
 255
 256     class {'::tripleo::network::midonet::agent':
 257       zookeeper_servers => $zookeeper_node_ips,
 258       cassandra_seeds   => $cassandra_node_ips
 259     }
 260
 261     class {'::tripleo::network::midonet::api':
 262       zookeeper_servers    => $zookeeper_node_ips,
 263       vip                  => $ipaddress,
 264       keystone_ip          => $ipaddress,
 265       keystone_admin_token => hiera('keystone::admin_token'),
 266       bind_address         => $ipaddress,
 267       admin_password       => hiera('admin_password')
 268     }
 269
 270     # TODO: find a way to get an empty list from hiera
 271     class {'::neutron':
 272       service_plugins => []
 273     }
 274
 275   }
 276   else {
 277
 278     # ML2 plugin
 279     include ::neutron
 280   }
 281
 282   include ::neutron::server
 283   include ::neutron::server::notifications
 284
 285   # If the value of core plugin is set to 'nuage',
 286   # include nuage core plugin, and it does not
 287   # need the l3, dhcp and metadata agents
 288   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 289     include ::neutron::plugins::nuage
 290   } else {
 291     include ::neutron::agents::l3
 292     include ::neutron::agents::dhcp
 293     include ::neutron::agents::metadata
 294
 295     file { '/etc/neutron/dnsmasq-neutron.conf':
 296       content => hiera('neutron_dnsmasq_options'),
 297       owner   => 'neutron',
 298       group   => 'neutron',
 299       notify  => Service['neutron-dhcp-service'],
 300       require => Package['neutron'],
 301     }
 302
 303     # If the value of core plugin is set to 'midonet',
 304     # skip all the ML2 configuration
 305     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 306
 307       class {'::neutron::plugins::midonet':
 308         midonet_api_ip    => $ipaddress,
 309         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 310         keystone_password => hiera('neutron::server::auth_password')
 311       }
 312     } else {
 313
 314       include ::neutron::plugins::ml2
 315       include ::neutron::agents::ml2::ovs
 316
 317       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 318         include ::neutron::plugins::ml2::cisco::nexus1000v
 319
 320         class { '::neutron::agents::n1kv_vem':
 321           n1kv_source  => hiera('n1kv_vem_source', undef),
 322           n1kv_version => hiera('n1kv_vem_version', undef),
 323         }
 324
 325         class { '::n1k_vsm':
 326           n1kv_source       => hiera('n1kv_vsm_source', undef),
 327           n1kv_version      => hiera('n1kv_vsm_version', undef),
 328           pacemaker_control => false,
 329         }
 330       }
 331
 332       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 333         include ::neutron::plugins::ml2::cisco::ucsm
 334       }
 335       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 336         include ::neutron::plugins::ml2::cisco::nexus
 337         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 338       }
 339
 340       if hiera('neutron_enable_bigswitch_ml2', false) {
 341         include ::neutron::plugins::ml2::bigswitch::restproxy
 342       }
 343       neutron_l3_agent_config {
 344         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 345       }
 346       neutron_dhcp_agent_config {
 347         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 348       }
 349       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 350     }
 351
 352     Service['neutron-server'] -> Service['neutron-dhcp-service']
 353     Service['neutron-server'] -> Service['neutron-l3']
 354     Service['neutron-server'] -> Service['neutron-metadata']
 355   }
 356
 357   include ::cinder
 358   include ::cinder::api
 359   include ::cinder::glance
 360   include ::cinder::scheduler
 361   include ::cinder::volume
 362   class { '::cinder::setup_test_volume':
 363     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 364   }
 365
 366   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 367   if $cinder_enable_iscsi {
 368     $cinder_iscsi_backend = 'tripleo_iscsi'
 369
 370     cinder::backend::iscsi { $cinder_iscsi_backend :
 371       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 372       iscsi_helper     => hiera('cinder_iscsi_helper'),
 373     }
 374   }
 375
 376   if $enable_ceph {
 377
 378     $ceph_pools = hiera('ceph_pools')
 379     ceph::pool { $ceph_pools :
 380       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 381       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 382       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 383     }
 384
 385     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 386
 387   } else {
 388     $cinder_pool_requires = []
 389   }
 390
 391   if hiera('cinder_enable_rbd_backend', false) {
 392     $cinder_rbd_backend = 'tripleo_ceph'
 393
 394     cinder::backend::rbd { $cinder_rbd_backend :
 395       rbd_pool        => hiera('cinder_rbd_pool_name'),
 396       rbd_user        => hiera('ceph_client_user_name'),
 397       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 398       require         => $cinder_pool_requires,
 399     }
 400   }
 401
 402   if hiera('cinder_enable_netapp_backend', false) {
 403     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 404
 405     cinder_config {
 406       "${cinder_netapp_backend}/host": value => 'hostgroup';
 407     }
 408
 409     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 410       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 411     }
 412
 413     cinder::backend::netapp { $cinder_netapp_backend :
 414       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 415       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 416       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 417       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 418       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 419       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 420       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 421       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 422       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 423       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 424       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 425       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 426       nfs_shares                   => $cinder_netapp_nfs_shares,
 427       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 428       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 429       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 430       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 431       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 432       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 433       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 434     }
 435   }
 436
 437   if hiera('cinder_enable_nfs_backend', false) {
 438     $cinder_nfs_backend = 'tripleo_nfs'
 439
 440     if str2bool($::selinux) {
 441       selboolean { 'virt_use_nfs':
 442         value      => on,
 443         persistent => true,
 444       } -> Package['nfs-utils']
 445     }
 446
 447     package {'nfs-utils': } ->
 448     cinder::backend::nfs { $cinder_nfs_backend :
 449       nfs_servers       => hiera('cinder_nfs_servers'),
 450       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 451       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 452     }
 453   }
 454
 455   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 456   class { '::cinder::backends' :
 457     enabled_backends => $cinder_enabled_backends,
 458   }
 459
 460   # swift proxy
 461   include ::memcached
 462   include ::swift::proxy
 463   include ::swift::proxy::proxy_logging
 464   include ::swift::proxy::healthcheck
 465   include ::swift::proxy::cache
 466   include ::swift::proxy::keystone
 467   include ::swift::proxy::authtoken
 468   include ::swift::proxy::staticweb
 469   include ::swift::proxy::ratelimit
 470   include ::swift::proxy::catch_errors
 471   include ::swift::proxy::tempurl
 472   include ::swift::proxy::formpost
 473
 474   # swift storage
 475   if str2bool(hiera('enable_swift_storage', true)) {
 476     class { '::swift::storage::all':
 477       mount_check => str2bool(hiera('swift_mount_check')),
 478     }
 479     if(!defined(File['/srv/node'])) {
 480       file { '/srv/node':
 481         ensure  => directory,
 482         owner   => 'swift',
 483         group   => 'swift',
 484         require => Package['openstack-swift'],
 485       }
 486     }
 487     $swift_components = ['account', 'container', 'object']
 488     swift::storage::filter::recon { $swift_components : }
 489     swift::storage::filter::healthcheck { $swift_components : }
 490   }
 491
 492   # Ceilometer
 493   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 494   case $ceilometer_backend {
 495     /mysql/ : {
 496       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 497     }
 498     default : {
 499       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 500     }
 501   }
 502   include ::ceilometer
 503   include ::ceilometer::config
 504   include ::ceilometer::api
 505   include ::ceilometer::agent::notification
 506   include ::ceilometer::agent::central
 507   include ::ceilometer::expirer
 508   include ::ceilometer::collector
 509   include ::ceilometer::agent::auth
 510   class { '::ceilometer::db' :
 511     database_connection => $ceilometer_database_connection,
 512   }
 513
 514   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 515
 516   # Heat
 517   include ::heat
 518   include ::heat::api
 519   include ::heat::api_cfn
 520   include ::heat::api_cloudwatch
 521   include ::heat::engine
 522
 523   # Horizon
 524   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 525     $_profile_support = 'cisco'
 526   } else {
 527     $_profile_support = 'None'
 528   }
 529   $neutron_options   = {'profile_support' => $_profile_support }
 530
 531   class { '::horizon':
 532     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 533     neutron_options => $neutron_options,
 534   }
 535
 536   $snmpd_user = hiera('snmpd_readonly_user_name')
 537   snmp::snmpv3_user { $snmpd_user:
 538     authtype => 'MD5',
 539     authpass => hiera('snmpd_readonly_user_password'),
 540   }
 541   class { '::snmp':
 542     agentaddress => ['udp:161','udp6:[::1]:161'],
 543     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 544   }
 545
 546   hiera_include('controller_classes')
 547
 548 } #END STEP 3
 549
 550 if hiera('step') >= 4 {
 551   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 552
 553   include ::keystone::cron::token_flush
 554   if $nova_enable_db_purge {
 555     include ::nova::cron::archive_deleted_rows
 556   }
 557 } #END STEP 4
 558
 559 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 560 package_manifest{$package_manifest_name: ensure => present}