puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if hiera('step') >= 1 {
  28
  29   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  30
  31   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  32
  33   class { '::tripleo::loadbalancer' :
  34     controller_hosts => $controller_node_ips,
  35     manage_vip       => true,
  36   }
  37
  38 }
  39
  40 if hiera('step') >= 2 {
  41
  42   if count(hiera('ntp::servers')) > 0 {
  43     include ::ntp
  44   }
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49
  50     include ::mongodb::server
  51     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  52     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  53
  54     $mongodb_replset = hiera('mongodb::server::replset')
  55     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  56     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  57       mongodb_replset { $mongodb_replset :
  58         members => $mongo_node_ips_with_port,
  59       }
  60     }
  61   }
  62
  63   # Redis
  64   $redis_node_ips = hiera('redis_node_ips')
  65   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  66
  67   if $redis_master_hostname == $::hostname {
  68     $slaveof = undef
  69   } else {
  70     $slaveof = "${redis_master_hostname} 6379"
  71   }
  72   class {'::redis' :
  73     slaveof => $slaveof,
  74   }
  75
  76   if count($redis_node_ips) > 1 {
  77     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  78     include ::redis::sentinel
  79     include ::tripleo::redis_notification
  80   }
  81
  82   if str2bool(hiera('enable_galera', 'true')) {
  83     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  84   } else {
  85     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  86   }
  87   # TODO Galara
  88   class { 'mysql::server':
  89     config_file => $mysql_config_file,
  90     override_options => {
  91       'mysqld' => {
  92         'bind-address' => hiera('mysql_bind_host'),
  93         'max_connections' => '1024',
  94         'open_files_limit' => '-1',
  95       },
  96     }
  97   }
  98
  99   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 100   # Create all the database schemas
 101   # Example DSN format: mysql://user:password@host/dbname
 102   $allowed_hosts = ['%',hiera('mysql_bind_host')]
 103   $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 104   class { 'keystone::db::mysql':
 105     user          => $keystone_dsn[3],
 106     password      => $keystone_dsn[4],
 107     host          => $keystone_dsn[5],
 108     dbname        => $keystone_dsn[6],
 109     allowed_hosts => $allowed_hosts,
 110   }
 111   $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 112   class { 'glance::db::mysql':
 113     user          => $glance_dsn[3],
 114     password      => $glance_dsn[4],
 115     host          => $glance_dsn[5],
 116     dbname        => $glance_dsn[6],
 117     allowed_hosts => $allowed_hosts,
 118   }
 119   $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 120   class { 'nova::db::mysql':
 121     user          => $nova_dsn[3],
 122     password      => $nova_dsn[4],
 123     host          => $nova_dsn[5],
 124     dbname        => $nova_dsn[6],
 125     allowed_hosts => $allowed_hosts,
 126   }
 127   $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 128   class { 'neutron::db::mysql':
 129     user          => $neutron_dsn[3],
 130     password      => $neutron_dsn[4],
 131     host          => $neutron_dsn[5],
 132     dbname        => $neutron_dsn[6],
 133     allowed_hosts => $allowed_hosts,
 134   }
 135   $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 136   class { 'cinder::db::mysql':
 137     user          => $cinder_dsn[3],
 138     password      => $cinder_dsn[4],
 139     host          => $cinder_dsn[5],
 140     dbname        => $cinder_dsn[6],
 141     allowed_hosts => $allowed_hosts,
 142   }
 143   $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 144   class { 'heat::db::mysql':
 145     user          => $heat_dsn[3],
 146     password      => $heat_dsn[4],
 147     host          => $heat_dsn[5],
 148     dbname        => $heat_dsn[6],
 149     allowed_hosts => $allowed_hosts,
 150   }
 151   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 152     $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 153     class { 'ceilometer::db::mysql':
 154       user          => $ceilometer_dsn[3],
 155       password      => $ceilometer_dsn[4],
 156       host          => $ceilometer_dsn[5],
 157       dbname        => $ceilometer_dsn[6],
 158       allowed_hosts => $allowed_hosts,
 159     }
 160   }
 161
 162   $rabbit_nodes = hiera('rabbit_node_ips')
 163   if count($rabbit_nodes) > 1 {
 164     class { '::rabbitmq':
 165       config_cluster          => true,
 166       cluster_nodes           => $rabbit_nodes,
 167       tcp_keepalive           => false,
 168       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 169       config_variables        => hiera('rabbitmq_config_variables'),
 170       environment_variables   => hiera('rabbitmq_environment'),
 171     }
 172     rabbitmq_policy { 'ha-all@/':
 173       pattern    => '^(?!amq\.).*',
 174       definition => {
 175         'ha-mode' => 'all',
 176       },
 177     }
 178   } else {
 179     include ::rabbitmq
 180   }
 181
 182   # pre-install swift here so we can build rings
 183   include ::swift
 184
 185   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 186   $enable_ceph = $cinder_enable_rbd_backend
 187
 188   if $enable_ceph {
 189     class { 'ceph::profile::params':
 190       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 191     }
 192     include ::ceph::profile::mon
 193   }
 194
 195   if str2bool(hiera('enable_ceph_storage', 'false')) {
 196     include ::ceph::profile::client
 197     include ::ceph::profile::osd
 198   }
 199
 200 } #END STEP 2
 201
 202 if hiera('step') >= 3 {
 203
 204   include ::keystone
 205
 206   #TODO: need a cleanup-keystone-tokens.sh solution here
 207   keystone_config {
 208     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 209   }
 210   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 211     ensure  => 'directory',
 212     owner   => 'keystone',
 213     group   => 'keystone',
 214     require => Package['keystone'],
 215   }
 216   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 217     content => hiera('keystone_signing_certificate'),
 218     owner   => 'keystone',
 219     group   => 'keystone',
 220     notify  => Service['keystone'],
 221     require => File['/etc/keystone/ssl/certs'],
 222   }
 223   file { '/etc/keystone/ssl/private/signing_key.pem':
 224     content => hiera('keystone_signing_key'),
 225     owner   => 'keystone',
 226     group   => 'keystone',
 227     notify  => Service['keystone'],
 228     require => File['/etc/keystone/ssl/private'],
 229   }
 230   file { '/etc/keystone/ssl/certs/ca.pem':
 231     content => hiera('keystone_ca_certificate'),
 232     owner   => 'keystone',
 233     group   => 'keystone',
 234     notify  => Service['keystone'],
 235     require => File['/etc/keystone/ssl/certs'],
 236   }
 237
 238   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 239   case $glance_backend {
 240       swift: { $glance_store = 'glance.store.swift.Store' }
 241       file: { $glance_store = 'glance.store.filesystem.Store' }
 242       rbd: { $glance_store = 'glance.store.rbd.Store' }
 243       default: { fail('Unrecognized glance_backend parameter.') }
 244   }
 245
 246   # TODO: notifications, scrubber, etc.
 247   include ::glance
 248   class { 'glance::api':
 249     known_stores => [$glance_store]
 250   }
 251   include ::glance::registry
 252   include join(['::glance::backend::', $glance_backend])
 253
 254   include ::nova
 255   include ::nova::api
 256   include ::nova::cert
 257   include ::nova::conductor
 258   include ::nova::consoleauth
 259   include ::nova::network::neutron
 260   include ::nova::vncproxy
 261   include ::nova::scheduler
 262
 263   include ::neutron
 264   include ::neutron::server
 265   include ::neutron::agents::l3
 266   include ::neutron::agents::dhcp
 267   include ::neutron::agents::metadata
 268
 269   file { '/etc/neutron/dnsmasq-neutron.conf':
 270     content => hiera('neutron_dnsmasq_options'),
 271     owner   => 'neutron',
 272     group   => 'neutron',
 273     notify  => Service['neutron-dhcp-service'],
 274     require => Package['neutron'],
 275   }
 276
 277   class { 'neutron::plugins::ml2':
 278     flat_networks => split(hiera('neutron_flat_networks'), ','),
 279     tenant_network_types => [hiera('neutron_tenant_network_type')],
 280   }
 281   class { 'neutron::agents::ml2::ovs':
 282     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 283     tunnel_types => split(hiera('neutron_tunnel_types'), ','),
 284   }
 285
 286   Service['neutron-server'] -> Service['neutron-dhcp-service']
 287   Service['neutron-server'] -> Service['neutron-l3']
 288   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 289   Service['neutron-server'] -> Service['neutron-metadata']
 290
 291   include ::cinder
 292   include ::cinder::api
 293   include ::cinder::glance
 294   include ::cinder::scheduler
 295   include ::cinder::volume
 296   class {'cinder::setup_test_volume':
 297     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 298   }
 299
 300   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 301   if $cinder_enable_iscsi {
 302     $cinder_iscsi_backend = 'tripleo_iscsi'
 303
 304     cinder::backend::iscsi { $cinder_iscsi_backend :
 305       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 306       iscsi_helper     => hiera('cinder_iscsi_helper'),
 307     }
 308   }
 309
 310   if $enable_ceph {
 311
 312     Ceph_pool {
 313       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 314       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 315       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 316     }
 317
 318     $ceph_pools = hiera('ceph_pools')
 319     ceph::pool { $ceph_pools : }
 320   }
 321
 322   if $cinder_enable_rbd_backend {
 323     $cinder_rbd_backend = 'tripleo_ceph'
 324
 325     cinder_config {
 326       "${cinder_rbd_backend}/host": value => 'hostgroup';
 327     }
 328
 329     cinder::backend::rbd { $cinder_rbd_backend :
 330       rbd_pool        => 'volumes',
 331       rbd_user        => 'openstack',
 332       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 333       require         => Ceph::Pool['volumes'],
 334     }
 335   }
 336
 337   if hiera('cinder_enable_netapp_backend', false) {
 338     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 339
 340     cinder_config {
 341       "${cinder_netapp_backend}/host": value => 'hostgroup';
 342     }
 343
 344     if hiera('cinder_netapp_nfs_shares', undef) {
 345       $cinder_netapp_nfs_shares = split(hiera('cinder_netapp_nfs_shares', undef), ',')
 346     }
 347
 348     cinder::backend::netapp { $cinder_netapp_backend :
 349       nfs_shares => $cinder_netapp_nfs_shares,
 350     }
 351   }
 352
 353   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend])
 354   class { '::cinder::backends' :
 355     enabled_backends => $cinder_enabled_backends,
 356   }
 357
 358   # swift proxy
 359   include ::memcached
 360   include ::swift::proxy
 361   include ::swift::proxy::proxy_logging
 362   include ::swift::proxy::healthcheck
 363   include ::swift::proxy::cache
 364   include ::swift::proxy::keystone
 365   include ::swift::proxy::authtoken
 366   include ::swift::proxy::staticweb
 367   include ::swift::proxy::ceilometer
 368   include ::swift::proxy::ratelimit
 369   include ::swift::proxy::catch_errors
 370   include ::swift::proxy::tempurl
 371   include ::swift::proxy::formpost
 372
 373   # swift storage
 374   if str2bool(hiera('enable_swift_storage', 'true')) {
 375     class {'swift::storage::all':
 376       mount_check => str2bool(hiera('swift_mount_check'))
 377     }
 378     if(!defined(File['/srv/node'])) {
 379       file { '/srv/node':
 380         ensure  => directory,
 381         owner   => 'swift',
 382         group   => 'swift',
 383         require => Package['openstack-swift'],
 384       }
 385     }
 386     $swift_components = ['account', 'container', 'object']
 387     swift::storage::filter::recon { $swift_components : }
 388     swift::storage::filter::healthcheck { $swift_components : }
 389   }
 390
 391   # Ceilometer
 392   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 393   case $ceilometer_backend {
 394     /mysql/ : {
 395       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 396     }
 397     default : {
 398       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 399     }
 400   }
 401   include ::ceilometer
 402   include ::ceilometer::api
 403   include ::ceilometer::agent::notification
 404   include ::ceilometer::agent::central
 405   include ::ceilometer::alarm::notifier
 406   include ::ceilometer::alarm::evaluator
 407   include ::ceilometer::expirer
 408   include ::ceilometer::collector
 409   include ceilometer::agent::auth
 410   class { '::ceilometer::db' :
 411     database_connection => $ceilometer_database_connection,
 412   }
 413
 414   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 415
 416   # Heat
 417   include ::heat
 418   include ::heat::api
 419   include ::heat::api_cfn
 420   include ::heat::api_cloudwatch
 421   include ::heat::engine
 422
 423   # Horizon
 424   $vhost_params = { add_listen => false }
 425   class { 'horizon':
 426     cache_server_ip    => hiera('memcache_node_ips', '127.0.0.1'),
 427     vhost_extra_params => $vhost_params,
 428   }
 429
 430   $snmpd_user = hiera('snmpd_readonly_user_name')
 431   snmp::snmpv3_user { $snmpd_user:
 432     authtype => 'MD5',
 433     authpass => hiera('snmpd_readonly_user_password'),
 434   }
 435   class { 'snmp':
 436     agentaddress => ['udp:161','udp6:[::1]:161'],
 437     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 438   }
 439
 440 } #END STEP 3