puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if hiera('step') >= 1 {
  28
  29   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  30
  31   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  32
  33   class { '::tripleo::loadbalancer' :
  34     controller_hosts => $controller_node_ips,
  35     manage_vip       => true,
  36   }
  37
  38 }
  39
  40 if hiera('step') >= 2 {
  41
  42   if count(hiera('ntp::servers')) > 0 {
  43     include ::ntp
  44   }
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49
  50     include ::mongodb::server
  51     $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
  52     $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
  53     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  54
  55     $mongodb_replset = hiera('mongodb::server::replset')
  56     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  57     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  58       mongodb_replset { $mongodb_replset :
  59         members => $mongo_node_ips_with_port,
  60       }
  61     }
  62   }
  63
  64   # Redis
  65   $redis_node_ips = split(hiera('redis_node_ips'), ',')
  66   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  67
  68   if $redis_master_hostname == $::hostname {
  69     $slaveof = undef
  70   } else {
  71     $slaveof = "${redis_master_hostname} 6379"
  72   }
  73   class {'::redis' :
  74     slaveof => $slaveof,
  75   }
  76
  77   if count($redis_node_ips) > 1 {
  78     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  79     include ::redis::sentinel
  80     class {'::tripleo::redis_notification' :
  81       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
  82     }
  83   }
  84
  85   if str2bool(hiera('enable_galera', 'true')) {
  86     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  87   } else {
  88     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  89   }
  90   # TODO Galara
  91   class { 'mysql::server':
  92     config_file => $mysql_config_file,
  93     override_options => {
  94       'mysqld' => {
  95         'bind-address' => hiera('controller_host'),
  96         'max_connections' => '1024',
  97         'open_files_limit' => '-1',
  98       },
  99     }
 100   }
 101
 102   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 103   # Create all the database schemas
 104   # Example DSN format: mysql://user:password@host/dbname
 105   $allowed_hosts = ['%',hiera('controller_host')]
 106   $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 107   class { 'keystone::db::mysql':
 108     user          => $keystone_dsn[3],
 109     password      => $keystone_dsn[4],
 110     host          => $keystone_dsn[5],
 111     dbname        => $keystone_dsn[6],
 112     allowed_hosts => $allowed_hosts,
 113   }
 114   $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 115   class { 'glance::db::mysql':
 116     user          => $glance_dsn[3],
 117     password      => $glance_dsn[4],
 118     host          => $glance_dsn[5],
 119     dbname        => $glance_dsn[6],
 120     allowed_hosts => $allowed_hosts,
 121   }
 122   $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 123   class { 'nova::db::mysql':
 124     user          => $nova_dsn[3],
 125     password      => $nova_dsn[4],
 126     host          => $nova_dsn[5],
 127     dbname        => $nova_dsn[6],
 128     allowed_hosts => $allowed_hosts,
 129   }
 130   $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 131   class { 'neutron::db::mysql':
 132     user          => $neutron_dsn[3],
 133     password      => $neutron_dsn[4],
 134     host          => $neutron_dsn[5],
 135     dbname        => $neutron_dsn[6],
 136     allowed_hosts => $allowed_hosts,
 137   }
 138   $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 139   class { 'cinder::db::mysql':
 140     user          => $cinder_dsn[3],
 141     password      => $cinder_dsn[4],
 142     host          => $cinder_dsn[5],
 143     dbname        => $cinder_dsn[6],
 144     allowed_hosts => $allowed_hosts,
 145   }
 146   $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 147   class { 'heat::db::mysql':
 148     user          => $heat_dsn[3],
 149     password      => $heat_dsn[4],
 150     host          => $heat_dsn[5],
 151     dbname        => $heat_dsn[6],
 152     allowed_hosts => $allowed_hosts,
 153   }
 154   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 155     $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 156     class { 'ceilometer::db::mysql':
 157       user          => $ceilometer_dsn[3],
 158       password      => $ceilometer_dsn[4],
 159       host          => $ceilometer_dsn[5],
 160       dbname        => $ceilometer_dsn[6],
 161       allowed_hosts => $allowed_hosts,
 162     }
 163   }
 164
 165   $rabbit_nodes = hiera('rabbit_node_ips')
 166   if count($rabbit_nodes) > 1 {
 167     class { '::rabbitmq':
 168       config_cluster          => true,
 169       cluster_nodes           => $rabbit_nodes,
 170       tcp_keepalive           => false,
 171       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 172       config_variables        => hiera('rabbitmq_config_variables'),
 173       environment_variables   => hiera('rabbitmq_environment'),
 174     }
 175     rabbitmq_policy { 'ha-all@/':
 176       pattern    => '^(?!amq\.).*',
 177       definition => {
 178         'ha-mode' => 'all',
 179       },
 180     }
 181   } else {
 182     include ::rabbitmq
 183   }
 184
 185   # pre-install swift here so we can build rings
 186   include ::swift
 187
 188   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 189   $enable_ceph = $cinder_enable_rbd_backend
 190
 191   if $enable_ceph {
 192     class { 'ceph::profile::params':
 193       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 194     }
 195     include ::ceph::profile::mon
 196   }
 197
 198   if str2bool(hiera('enable_ceph_storage', 'false')) {
 199     include ::ceph::profile::client
 200     include ::ceph::profile::osd
 201   }
 202
 203 } #END STEP 2
 204
 205 if hiera('step') >= 3 {
 206
 207   include ::keystone
 208
 209   #TODO: need a cleanup-keystone-tokens.sh solution here
 210   keystone_config {
 211     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 212   }
 213   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 214     ensure  => 'directory',
 215     owner   => 'keystone',
 216     group   => 'keystone',
 217     require => Package['keystone'],
 218   }
 219   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 220     content => hiera('keystone_signing_certificate'),
 221     owner   => 'keystone',
 222     group   => 'keystone',
 223     notify  => Service['keystone'],
 224     require => File['/etc/keystone/ssl/certs'],
 225   }
 226   file { '/etc/keystone/ssl/private/signing_key.pem':
 227     content => hiera('keystone_signing_key'),
 228     owner   => 'keystone',
 229     group   => 'keystone',
 230     notify  => Service['keystone'],
 231     require => File['/etc/keystone/ssl/private'],
 232   }
 233   file { '/etc/keystone/ssl/certs/ca.pem':
 234     content => hiera('keystone_ca_certificate'),
 235     owner   => 'keystone',
 236     group   => 'keystone',
 237     notify  => Service['keystone'],
 238     require => File['/etc/keystone/ssl/certs'],
 239   }
 240
 241   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 242   case $glance_backend {
 243       swift: { $glance_store = 'glance.store.swift.Store' }
 244       file: { $glance_store = 'glance.store.filesystem.Store' }
 245       rbd: { $glance_store = 'glance.store.rbd.Store' }
 246       default: { fail('Unrecognized glance_backend parameter.') }
 247   }
 248
 249   # TODO: notifications, scrubber, etc.
 250   include ::glance
 251   class { 'glance::api':
 252     known_stores => [$glance_store]
 253   }
 254   include ::glance::registry
 255   include join(['::glance::backend::', $glance_backend])
 256
 257   class { 'nova':
 258     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 259   }
 260
 261   include ::nova::api
 262   include ::nova::cert
 263   include ::nova::conductor
 264   include ::nova::consoleauth
 265   include ::nova::network::neutron
 266   include ::nova::vncproxy
 267   include ::nova::scheduler
 268
 269   include ::neutron
 270   include ::neutron::server
 271   include ::neutron::agents::dhcp
 272   include ::neutron::agents::l3
 273
 274   file { '/etc/neutron/dnsmasq-neutron.conf':
 275     content => hiera('neutron_dnsmasq_options'),
 276     owner   => 'neutron',
 277     group   => 'neutron',
 278     notify  => Service['neutron-dhcp-service'],
 279     require => Package['neutron'],
 280   }
 281
 282   class { 'neutron::plugins::ml2':
 283     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 284     tenant_network_types => [hiera('neutron_tenant_network_type')],
 285     type_drivers         => [hiera('neutron_tenant_network_type')],
 286   }
 287
 288   class { 'neutron::agents::ml2::ovs':
 289     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 290     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 291   }
 292
 293   class { 'neutron::agents::metadata':
 294     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 295   }
 296
 297   Service['neutron-server'] -> Service['neutron-dhcp-service']
 298   Service['neutron-server'] -> Service['neutron-l3']
 299   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 300   Service['neutron-server'] -> Service['neutron-metadata']
 301
 302   include ::cinder
 303   include ::cinder::api
 304   include ::cinder::glance
 305   include ::cinder::scheduler
 306   include ::cinder::volume
 307   class {'cinder::setup_test_volume':
 308     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 309   }
 310
 311   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 312   if $cinder_enable_iscsi {
 313     $cinder_iscsi_backend = 'tripleo_iscsi'
 314
 315     cinder::backend::iscsi { $cinder_iscsi_backend :
 316       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 317       iscsi_helper     => hiera('cinder_iscsi_helper'),
 318     }
 319   }
 320
 321   if $enable_ceph {
 322
 323     Ceph_pool {
 324       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 325       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 326       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 327     }
 328
 329     $ceph_pools = hiera('ceph_pools')
 330     ceph::pool { $ceph_pools : }
 331   }
 332
 333   if $cinder_enable_rbd_backend {
 334     $cinder_rbd_backend = 'tripleo_ceph'
 335
 336     cinder_config {
 337       "${cinder_rbd_backend}/host": value => 'hostgroup';
 338     }
 339
 340     cinder::backend::rbd { $cinder_rbd_backend :
 341       rbd_pool        => 'volumes',
 342       rbd_user        => 'openstack',
 343       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 344       require         => Ceph::Pool['volumes'],
 345     }
 346   }
 347
 348   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 349   class { '::cinder::backends' :
 350     enabled_backends => $cinder_enabled_backends,
 351   }
 352
 353   # swift proxy
 354   include ::memcached
 355   include ::swift::proxy
 356   include ::swift::proxy::proxy_logging
 357   include ::swift::proxy::healthcheck
 358   include ::swift::proxy::cache
 359   include ::swift::proxy::keystone
 360   include ::swift::proxy::authtoken
 361   include ::swift::proxy::staticweb
 362   include ::swift::proxy::ceilometer
 363   include ::swift::proxy::ratelimit
 364   include ::swift::proxy::catch_errors
 365   include ::swift::proxy::tempurl
 366   include ::swift::proxy::formpost
 367
 368   # swift storage
 369   if str2bool(hiera('enable_swift_storage', 'true')) {
 370     class {'swift::storage::all':
 371       mount_check => str2bool(hiera('swift_mount_check'))
 372     }
 373     if(!defined(File['/srv/node'])) {
 374       file { '/srv/node':
 375         ensure  => directory,
 376         owner   => 'swift',
 377         group   => 'swift',
 378         require => Package['openstack-swift'],
 379       }
 380     }
 381     $swift_components = ['account', 'container', 'object']
 382     swift::storage::filter::recon { $swift_components : }
 383     swift::storage::filter::healthcheck { $swift_components : }
 384   }
 385
 386   # Ceilometer
 387   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 388   case $ceilometer_backend {
 389     /mysql/ : {
 390       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 391     }
 392     default : {
 393       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 394     }
 395   }
 396   include ::ceilometer
 397   include ::ceilometer::api
 398   include ::ceilometer::agent::notification
 399   include ::ceilometer::agent::central
 400   include ::ceilometer::alarm::notifier
 401   include ::ceilometer::alarm::evaluator
 402   include ::ceilometer::expirer
 403   include ::ceilometer::collector
 404   class { '::ceilometer::db' :
 405     database_connection => $ceilometer_database_connection,
 406   }
 407   class { 'ceilometer::agent::auth':
 408     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 409   }
 410
 411   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 412
 413   # Heat
 414   include ::heat
 415   include ::heat::api
 416   include ::heat::api_cfn
 417   include ::heat::api_cloudwatch
 418   include ::heat::engine
 419
 420   # Horizon
 421   $vhost_params = { add_listen => false }
 422   class { 'horizon':
 423     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 424     vhost_extra_params => $vhost_params,
 425   }
 426
 427   $snmpd_user = hiera('snmpd_readonly_user_name')
 428   snmp::snmpv3_user { $snmpd_user:
 429     authtype => 'MD5',
 430     authpass => hiera('snmpd_readonly_user_password'),
 431   }
 432   class { 'snmp':
 433     agentaddress => ['udp:161','udp6:[::1]:161'],
 434     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 435   }
 436
 437 } #END STEP 3