puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  28
  29   if $enable_load_balancer {
  30     class { '::tripleo::loadbalancer' :
  31       controller_hosts => $controller_node_ips,
  32       manage_vip       => true,
  33     }
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   include ::timezone
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49
  50     include ::mongodb::server
  51     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  52     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  53
  54     $mongodb_replset = hiera('mongodb::server::replset')
  55     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  56     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  57       mongodb_replset { $mongodb_replset :
  58         members => $mongo_node_ips_with_port,
  59       }
  60     }
  61   }
  62
  63   # Redis
  64   $redis_node_ips = hiera('redis_node_ips')
  65   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  66
  67   if $redis_master_hostname == $::hostname {
  68     $slaveof = undef
  69   } else {
  70     $slaveof = "${redis_master_hostname} 6379"
  71   }
  72   class {'::redis' :
  73     slaveof => $slaveof,
  74   }
  75
  76   if count($redis_node_ips) > 1 {
  77     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  78     include ::redis::sentinel
  79     include ::tripleo::redis_notification
  80   }
  81
  82   if str2bool(hiera('enable_galera', true)) {
  83     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  84   } else {
  85     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  86   }
  87   # TODO Galara
  88   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  89   # set bind-address to a hostname instead of an ip address; to move Mysql
  90   # from internal_api on another network we'll have to customize both
  91   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
  92   class { '::mysql::server':
  93     config_file             => $mysql_config_file,
  94     override_options        => {
  95       'mysqld' => {
  96         'bind-address'     => $::hostname,
  97         'max_connections'  => hiera('mysql_max_connections'),
  98         'open_files_limit' => '-1',
  99       },
 100     },
 101     remove_default_accounts => true,
 102   }
 103
 104   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 105   # Create all the database schemas
 106   include ::keystone::db::mysql
 107   include ::glance::db::mysql
 108   include ::nova::db::mysql
 109   include ::nova::db::mysql_api
 110   include ::neutron::db::mysql
 111   include ::cinder::db::mysql
 112   include ::heat::db::mysql
 113   include ::sahara::db::mysql
 114   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 115     include ::ceilometer::db::mysql
 116     include ::aodh::db::mysql
 117   }
 118
 119   $rabbit_nodes = hiera('rabbit_node_ips')
 120   if count($rabbit_nodes) > 1 {
 121     class { '::rabbitmq':
 122       config_cluster          => true,
 123       cluster_nodes           => $rabbit_nodes,
 124       tcp_keepalive           => false,
 125       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 126       config_variables        => hiera('rabbitmq_config_variables'),
 127       environment_variables   => hiera('rabbitmq_environment'),
 128     }
 129     rabbitmq_policy { 'ha-all@/':
 130       pattern    => '^(?!amq\.).*',
 131       definition => {
 132         'ha-mode' => 'all',
 133       },
 134     }
 135   } else {
 136     include ::rabbitmq
 137   }
 138
 139   # pre-install swift here so we can build rings
 140   include ::swift
 141
 142   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 143
 144   if $enable_ceph {
 145     class { '::ceph::profile::params':
 146       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 147     }
 148     include ::ceph::conf
 149     include ::ceph::profile::mon
 150   }
 151
 152   if str2bool(hiera('enable_ceph_storage', false)) {
 153     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 154       exec { 'set selinux to permissive on boot':
 155         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 156         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 157         path    => ['/usr/bin', '/usr/sbin'],
 158       }
 159
 160       exec { 'set selinux to permissive':
 161         command => 'setenforce 0',
 162         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 163         path    => ['/usr/bin', '/usr/sbin'],
 164       } -> Class['ceph::profile::osd']
 165     }
 166
 167     include ::ceph::conf
 168     include ::ceph::profile::osd
 169   }
 170
 171   if str2bool(hiera('enable_external_ceph', false)) {
 172     include ::ceph::conf
 173     include ::ceph::profile::client
 174   }
 175
 176 } #END STEP 2
 177
 178 if hiera('step') >= 3 {
 179
 180   include ::keystone
 181   include ::keystone::config
 182   include ::keystone::roles::admin
 183   include ::keystone::endpoint
 184   include ::keystone::wsgi::apache
 185
 186   #TODO: need a cleanup-keystone-tokens.sh solution here
 187
 188   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 189     ensure  => 'directory',
 190     owner   => 'keystone',
 191     group   => 'keystone',
 192     require => Package['keystone'],
 193   }
 194   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 195     content => hiera('keystone_signing_certificate'),
 196     owner   => 'keystone',
 197     group   => 'keystone',
 198     notify  => Service['keystone'],
 199     require => File['/etc/keystone/ssl/certs'],
 200   }
 201   file { '/etc/keystone/ssl/private/signing_key.pem':
 202     content => hiera('keystone_signing_key'),
 203     owner   => 'keystone',
 204     group   => 'keystone',
 205     notify  => Service['keystone'],
 206     require => File['/etc/keystone/ssl/private'],
 207   }
 208   file { '/etc/keystone/ssl/certs/ca.pem':
 209     content => hiera('keystone_ca_certificate'),
 210     owner   => 'keystone',
 211     group   => 'keystone',
 212     notify  => Service['keystone'],
 213     require => File['/etc/keystone/ssl/certs'],
 214   }
 215
 216   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 217   case $glance_backend {
 218       'swift': { $backend_store = 'glance.store.swift.Store' }
 219       'file': { $backend_store = 'glance.store.filesystem.Store' }
 220       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 221       default: { fail('Unrecognized glance_backend parameter.') }
 222   }
 223   $http_store = ['glance.store.http.Store']
 224   $glance_store = concat($http_store, $backend_store)
 225
 226   # TODO: scrubber and other additional optional features
 227   include ::glance
 228   include ::glance::config
 229   class { '::glance::api':
 230     known_stores => $glance_store,
 231   }
 232   include ::glance::registry
 233   include join(['::glance::backend::', $glance_backend])
 234   $rabbit_port = hiera('rabbitmq::port')
 235   class { '::glance::notify::rabbitmq':
 236     rabbit_hosts => suffix(hiera('rabbit_node_ips'), ":${rabbit_port}"),
 237   }
 238
 239   class { '::nova' :
 240     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 241   }
 242   include ::nova::config
 243   include ::nova::api
 244   include ::nova::cert
 245   include ::nova::conductor
 246   include ::nova::consoleauth
 247   include ::nova::network::neutron
 248   include ::nova::vncproxy
 249   include ::nova::scheduler
 250   include ::nova::scheduler::filter
 251
 252   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 253
 254     # TODO(devvesa) provide non-controller ips for these services
 255     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 256     $cassandra_node_ips = hiera('neutron_api_node_ips')
 257
 258     # Run zookeeper in the controller if configured
 259     if hiera('enable_zookeeper_on_controller') {
 260       class {'::tripleo::cluster::zookeeper':
 261         zookeeper_server_ips => $zookeeper_node_ips,
 262         # TODO: create a 'bind' hiera key for zookeeper
 263         zookeeper_client_ip  => hiera('neutron::bind_host'),
 264         zookeeper_hostnames  => hiera('controller_node_names')
 265       }
 266     }
 267
 268     # Run cassandra in the controller if configured
 269     if hiera('enable_cassandra_on_controller') {
 270       class {'::tripleo::cluster::cassandra':
 271         cassandra_servers => $cassandra_node_ips,
 272         # TODO: create a 'bind' hiera key for cassandra
 273         cassandra_ip      => hiera('neutron::bind_host'),
 274       }
 275     }
 276
 277     class {'::tripleo::network::midonet::agent':
 278       zookeeper_servers => $zookeeper_node_ips,
 279       cassandra_seeds   => $cassandra_node_ips
 280     }
 281
 282     class {'::tripleo::network::midonet::api':
 283       zookeeper_servers    => $zookeeper_node_ips,
 284       vip                  => hiera('tripleo::loadbalancer::public_virtual_ip'),
 285       keystone_ip          => hiera('tripleo::loadbalancer::public_virtual_ip'),
 286       keystone_admin_token => hiera('keystone::admin_token'),
 287       # TODO: create a 'bind' hiera key for api
 288       bind_address         => hiera('neutron::bind_host'),
 289       admin_password       => hiera('admin_password')
 290     }
 291
 292     # TODO: find a way to get an empty list from hiera
 293     class {'::neutron':
 294       service_plugins => []
 295     }
 296
 297   }
 298   else {
 299
 300     # ML2 plugin
 301     include ::neutron
 302   }
 303
 304   include ::neutron::config
 305   include ::neutron::server
 306   include ::neutron::server::notifications
 307
 308   # If the value of core plugin is set to 'nuage' or 'opencontrail',
 309   # include nuage or opencontrail core plugins, and it does not
 310   # need the l3, dhcp and metadata agents
 311   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 312     include ::neutron::plugins::nuage
 313   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 314     include ::neutron::plugins::opencontrail
 315   } else {
 316     include ::neutron::agents::l3
 317     include ::neutron::agents::dhcp
 318     include ::neutron::agents::metadata
 319
 320     file { '/etc/neutron/dnsmasq-neutron.conf':
 321       content => hiera('neutron_dnsmasq_options'),
 322       owner   => 'neutron',
 323       group   => 'neutron',
 324       notify  => Service['neutron-dhcp-service'],
 325       require => Package['neutron'],
 326     }
 327
 328     # If the value of core plugin is set to 'midonet',
 329     # skip all the ML2 configuration
 330     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 331
 332       class {'::neutron::plugins::midonet':
 333         midonet_api_ip    => hiera('tripleo::loadbalancer::public_virtual_ip'),
 334         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 335         keystone_password => hiera('neutron::server::auth_password')
 336       }
 337     } else {
 338
 339       include ::neutron::plugins::ml2
 340       include ::neutron::agents::ml2::ovs
 341
 342       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 343         include ::neutron::plugins::ml2::cisco::nexus1000v
 344
 345         class { '::neutron::agents::n1kv_vem':
 346           n1kv_source  => hiera('n1kv_vem_source', undef),
 347           n1kv_version => hiera('n1kv_vem_version', undef),
 348         }
 349
 350         class { '::n1k_vsm':
 351           n1kv_source       => hiera('n1kv_vsm_source', undef),
 352           n1kv_version      => hiera('n1kv_vsm_version', undef),
 353           pacemaker_control => false,
 354         }
 355       }
 356
 357       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 358         include ::neutron::plugins::ml2::cisco::ucsm
 359       }
 360       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 361         include ::neutron::plugins::ml2::cisco::nexus
 362         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 363       }
 364
 365       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 366         include ::neutron::plugins::ml2::bigswitch::restproxy
 367         include ::neutron::agents::bigswitch
 368       }
 369       neutron_l3_agent_config {
 370         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 371       }
 372       neutron_dhcp_agent_config {
 373         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 374       }
 375       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 376     }
 377
 378     Service['neutron-server'] -> Service['neutron-dhcp-service']
 379     Service['neutron-server'] -> Service['neutron-l3']
 380     Service['neutron-server'] -> Service['neutron-metadata']
 381   }
 382
 383   include ::cinder
 384   include ::cinder::config
 385   include ::tripleo::ssl::cinder_config
 386   include ::cinder::api
 387   include ::cinder::glance
 388   include ::cinder::scheduler
 389   include ::cinder::volume
 390   include ::cinder::ceilometer
 391   class { '::cinder::setup_test_volume':
 392     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 393   }
 394
 395   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 396   if $cinder_enable_iscsi {
 397     $cinder_iscsi_backend = 'tripleo_iscsi'
 398
 399     cinder::backend::iscsi { $cinder_iscsi_backend :
 400       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 401       iscsi_helper     => hiera('cinder_iscsi_helper'),
 402     }
 403   }
 404
 405   if $enable_ceph {
 406
 407     $ceph_pools = hiera('ceph_pools')
 408     ceph::pool { $ceph_pools :
 409       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 410       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 411       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 412     }
 413
 414     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 415
 416   } else {
 417     $cinder_pool_requires = []
 418   }
 419
 420   if hiera('cinder_enable_rbd_backend', false) {
 421     $cinder_rbd_backend = 'tripleo_ceph'
 422
 423     cinder::backend::rbd { $cinder_rbd_backend :
 424       rbd_pool        => hiera('cinder_rbd_pool_name'),
 425       rbd_user        => hiera('ceph_client_user_name'),
 426       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 427       require         => $cinder_pool_requires,
 428     }
 429   }
 430
 431   if hiera('cinder_enable_eqlx_backend', false) {
 432     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 433
 434     cinder::backend::eqlx { $cinder_eqlx_backend :
 435       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 436       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 437       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 438       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 439       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 440       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 441       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 442       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 443       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 444       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 445     }
 446   }
 447
 448   if hiera('cinder_enable_dellsc_backend', false) {
 449     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 450
 451     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 452       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 453       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 454       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 455       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 456       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 457       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 458       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 459       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 460       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 461       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 462     }
 463   }
 464
 465   if hiera('cinder_enable_netapp_backend', false) {
 466     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 467
 468     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 469       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 470     }
 471
 472     cinder::backend::netapp { $cinder_netapp_backend :
 473       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 474       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 475       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 476       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 477       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 478       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 479       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 480       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 481       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 482       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 483       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 484       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 485       nfs_shares                   => $cinder_netapp_nfs_shares,
 486       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 487       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 488       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 489       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 490       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 491       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 492       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 493     }
 494   }
 495
 496   if hiera('cinder_enable_nfs_backend', false) {
 497     $cinder_nfs_backend = 'tripleo_nfs'
 498
 499     if str2bool($::selinux) {
 500       selboolean { 'virt_use_nfs':
 501         value      => on,
 502         persistent => true,
 503       } -> Package['nfs-utils']
 504     }
 505
 506     package {'nfs-utils': } ->
 507     cinder::backend::nfs { $cinder_nfs_backend :
 508       nfs_servers       => hiera('cinder_nfs_servers'),
 509       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 510       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 511     }
 512   }
 513
 514   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 515   class { '::cinder::backends' :
 516     enabled_backends => $cinder_enabled_backends,
 517   }
 518
 519   # swift proxy
 520   include ::memcached
 521   include ::swift::proxy
 522   include ::swift::proxy::proxy_logging
 523   include ::swift::proxy::healthcheck
 524   include ::swift::proxy::cache
 525   include ::swift::proxy::keystone
 526   include ::swift::proxy::authtoken
 527   include ::swift::proxy::staticweb
 528   include ::swift::proxy::ratelimit
 529   include ::swift::proxy::catch_errors
 530   include ::swift::proxy::tempurl
 531   include ::swift::proxy::formpost
 532
 533   # swift storage
 534   if str2bool(hiera('enable_swift_storage', true)) {
 535     class { '::swift::storage::all':
 536       mount_check => str2bool(hiera('swift_mount_check')),
 537     }
 538     if(!defined(File['/srv/node'])) {
 539       file { '/srv/node':
 540         ensure  => directory,
 541         owner   => 'swift',
 542         group   => 'swift',
 543         require => Package['openstack-swift'],
 544       }
 545     }
 546     $swift_components = ['account', 'container', 'object']
 547     swift::storage::filter::recon { $swift_components : }
 548     swift::storage::filter::healthcheck { $swift_components : }
 549   }
 550
 551   # Ceilometer
 552   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 553   case $ceilometer_backend {
 554     /mysql/ : {
 555       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 556     }
 557     default : {
 558       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 559     }
 560   }
 561   include ::ceilometer
 562   include ::ceilometer::config
 563   include ::ceilometer::api
 564   include ::ceilometer::agent::notification
 565   include ::ceilometer::agent::central
 566   include ::ceilometer::expirer
 567   include ::ceilometer::collector
 568   include ::ceilometer::agent::auth
 569   class { '::ceilometer::db' :
 570     database_connection => $ceilometer_database_connection,
 571   }
 572
 573   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 574
 575   # Aodh
 576   class { '::aodh' :
 577     database_connection => $ceilometer_database_connection,
 578   }
 579   include ::aodh::db::sync
 580   # To manage the upgrade:
 581   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 582   include ::aodh::auth
 583   include ::aodh::api
 584   include ::aodh::wsgi::apache
 585   include ::aodh::evaluator
 586   include ::aodh::notifier
 587   include ::aodh::listener
 588   include ::aodh::client
 589
 590   # Heat
 591   class { '::heat' :
 592     notification_driver => 'messaging',
 593   }
 594   include ::heat::config
 595   include ::heat::api
 596   include ::heat::api_cfn
 597   include ::heat::api_cloudwatch
 598   include ::heat::engine
 599
 600   # Sahara
 601   include ::sahara
 602   include ::sahara::service::api
 603   include ::sahara::service::engine
 604
 605   # Horizon
 606   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 607     $_profile_support = 'cisco'
 608   } else {
 609     $_profile_support = 'None'
 610   }
 611   $neutron_options   = {'profile_support' => $_profile_support }
 612
 613   class { '::horizon':
 614     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 615     neutron_options => $neutron_options,
 616   }
 617
 618   $snmpd_user = hiera('snmpd_readonly_user_name')
 619   snmp::snmpv3_user { $snmpd_user:
 620     authtype => 'MD5',
 621     authpass => hiera('snmpd_readonly_user_password'),
 622   }
 623   class { '::snmp':
 624     agentaddress => ['udp:161','udp6:[::1]:161'],
 625     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 626   }
 627
 628   hiera_include('controller_classes')
 629
 630 } #END STEP 3
 631
 632 if hiera('step') >= 4 {
 633   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 634   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 635   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 636   $heat_enable_db_purge = hiera('heat_enable_db_purge', true)
 637
 638   if $keystone_enable_db_purge {
 639     include ::keystone::cron::token_flush
 640   }
 641   if $nova_enable_db_purge {
 642     include ::nova::cron::archive_deleted_rows
 643   }
 644   if $cinder_enable_db_purge {
 645     include ::cinder::cron::db_purge
 646   }
 647   if $heat_enable_db_purge {
 648     include ::heat::cron::purge_deleted
 649   }
 650 } #END STEP 4
 651
 652 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 653 package_manifest{$package_manifest_name: ensure => present}