puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include tripleo::packages
  17
  18 if hiera('step') >= 1 {
  19
  20   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  21
  22   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  23
  24   class { '::tripleo::loadbalancer' :
  25     controller_hosts => $controller_node_ips,
  26     manage_vip       => true,
  27   }
  28
  29 }
  30
  31 if hiera('step') >= 2 {
  32
  33   if count(hiera('ntp::servers')) > 0 {
  34     include ::ntp
  35   }
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40
  41     include ::mongodb::server
  42     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  43     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  44
  45     $mongodb_replset = hiera('mongodb::server::replset')
  46     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  47     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  48       mongodb_replset { $mongodb_replset :
  49         members => $mongo_node_ips_with_port,
  50       }
  51     }
  52   }
  53
  54   # Redis
  55   $redis_node_ips = hiera('redis_node_ips')
  56   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  57
  58   if $redis_master_hostname == $::hostname {
  59     $slaveof = undef
  60   } else {
  61     $slaveof = "${redis_master_hostname} 6379"
  62   }
  63   class {'::redis' :
  64     slaveof => $slaveof,
  65   }
  66
  67   if count($redis_node_ips) > 1 {
  68     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  69     include ::redis::sentinel
  70     include ::tripleo::redis_notification
  71   }
  72
  73   if str2bool(hiera('enable_galera', 'true')) {
  74     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  75   } else {
  76     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  77   }
  78   # TODO Galara
  79   class { 'mysql::server':
  80     config_file => $mysql_config_file,
  81     override_options => {
  82       'mysqld' => {
  83         'bind-address' => hiera('mysql_bind_host'),
  84         'max_connections' => hiera('mysql_max_connections'),
  85         'open_files_limit' => '-1',
  86       },
  87     }
  88   }
  89
  90   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  91   # Create all the database schemas
  92   # Example DSN format: mysql://user:password@host/dbname
  93   $allowed_hosts = ['%',hiera('mysql_bind_host')]
  94   $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
  95   class { 'keystone::db::mysql':
  96     user          => $keystone_dsn[3],
  97     password      => $keystone_dsn[4],
  98     host          => $keystone_dsn[5],
  99     dbname        => $keystone_dsn[6],
 100     allowed_hosts => $allowed_hosts,
 101   }
 102   $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 103   class { 'glance::db::mysql':
 104     user          => $glance_dsn[3],
 105     password      => $glance_dsn[4],
 106     host          => $glance_dsn[5],
 107     dbname        => $glance_dsn[6],
 108     allowed_hosts => $allowed_hosts,
 109   }
 110   $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 111   class { 'nova::db::mysql':
 112     user          => $nova_dsn[3],
 113     password      => $nova_dsn[4],
 114     host          => $nova_dsn[5],
 115     dbname        => $nova_dsn[6],
 116     allowed_hosts => $allowed_hosts,
 117   }
 118   $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 119   class { 'neutron::db::mysql':
 120     user          => $neutron_dsn[3],
 121     password      => $neutron_dsn[4],
 122     host          => $neutron_dsn[5],
 123     dbname        => $neutron_dsn[6],
 124     allowed_hosts => $allowed_hosts,
 125   }
 126   $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 127   class { 'cinder::db::mysql':
 128     user          => $cinder_dsn[3],
 129     password      => $cinder_dsn[4],
 130     host          => $cinder_dsn[5],
 131     dbname        => $cinder_dsn[6],
 132     allowed_hosts => $allowed_hosts,
 133   }
 134   $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 135   class { 'heat::db::mysql':
 136     user          => $heat_dsn[3],
 137     password      => $heat_dsn[4],
 138     host          => $heat_dsn[5],
 139     dbname        => $heat_dsn[6],
 140     allowed_hosts => $allowed_hosts,
 141   }
 142   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 143     $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 144     class { 'ceilometer::db::mysql':
 145       user          => $ceilometer_dsn[3],
 146       password      => $ceilometer_dsn[4],
 147       host          => $ceilometer_dsn[5],
 148       dbname        => $ceilometer_dsn[6],
 149       allowed_hosts => $allowed_hosts,
 150     }
 151   }
 152
 153   $rabbit_nodes = hiera('rabbit_node_ips')
 154   if count($rabbit_nodes) > 1 {
 155     class { '::rabbitmq':
 156       config_cluster          => true,
 157       cluster_nodes           => $rabbit_nodes,
 158       tcp_keepalive           => false,
 159       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 160       config_variables        => hiera('rabbitmq_config_variables'),
 161       environment_variables   => hiera('rabbitmq_environment'),
 162     }
 163     rabbitmq_policy { 'ha-all@/':
 164       pattern    => '^(?!amq\.).*',
 165       definition => {
 166         'ha-mode' => 'all',
 167       },
 168     }
 169   } else {
 170     include ::rabbitmq
 171   }
 172
 173   # pre-install swift here so we can build rings
 174   include ::swift
 175
 176   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 177   $enable_ceph = $cinder_enable_rbd_backend
 178
 179   if $enable_ceph {
 180     class { 'ceph::profile::params':
 181       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 182     }
 183     include ::ceph::profile::mon
 184   }
 185
 186   if str2bool(hiera('enable_ceph_storage', 'false')) {
 187     include ::ceph::profile::client
 188     include ::ceph::profile::osd
 189   }
 190
 191 } #END STEP 2
 192
 193 if hiera('step') >= 3 {
 194
 195   include ::keystone
 196
 197   #TODO: need a cleanup-keystone-tokens.sh solution here
 198   keystone_config {
 199     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 200   }
 201   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 202     ensure  => 'directory',
 203     owner   => 'keystone',
 204     group   => 'keystone',
 205     require => Package['keystone'],
 206   }
 207   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 208     content => hiera('keystone_signing_certificate'),
 209     owner   => 'keystone',
 210     group   => 'keystone',
 211     notify  => Service['keystone'],
 212     require => File['/etc/keystone/ssl/certs'],
 213   }
 214   file { '/etc/keystone/ssl/private/signing_key.pem':
 215     content => hiera('keystone_signing_key'),
 216     owner   => 'keystone',
 217     group   => 'keystone',
 218     notify  => Service['keystone'],
 219     require => File['/etc/keystone/ssl/private'],
 220   }
 221   file { '/etc/keystone/ssl/certs/ca.pem':
 222     content => hiera('keystone_ca_certificate'),
 223     owner   => 'keystone',
 224     group   => 'keystone',
 225     notify  => Service['keystone'],
 226     require => File['/etc/keystone/ssl/certs'],
 227   }
 228
 229   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 230   case $glance_backend {
 231       swift: { $backend_store = 'glance.store.swift.Store' }
 232       file: { $backend_store = 'glance.store.filesystem.Store' }
 233       rbd: { $backend_store = 'glance.store.rbd.Store' }
 234       default: { fail('Unrecognized glance_backend parameter.') }
 235   }
 236   $http_store = ['glance.store.http.Store']
 237   $glance_store = concat($http_store, $backend_store)
 238
 239   # TODO: notifications, scrubber, etc.
 240   include ::glance
 241   class { 'glance::api':
 242     known_stores => $glance_store
 243   }
 244   include ::glance::registry
 245   include join(['::glance::backend::', $glance_backend])
 246
 247   class { '::nova' :
 248     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 249   }
 250   include ::nova::config
 251   include ::nova::api
 252   include ::nova::cert
 253   include ::nova::conductor
 254   include ::nova::consoleauth
 255   include ::nova::network::neutron
 256   include ::nova::vncproxy
 257   include ::nova::scheduler
 258
 259   include ::neutron
 260   include ::neutron::server
 261   include ::neutron::agents::l3
 262   include ::neutron::agents::dhcp
 263   include ::neutron::agents::metadata
 264
 265   file { '/etc/neutron/dnsmasq-neutron.conf':
 266     content => hiera('neutron_dnsmasq_options'),
 267     owner   => 'neutron',
 268     group   => 'neutron',
 269     notify  => Service['neutron-dhcp-service'],
 270     require => Package['neutron'],
 271   }
 272
 273   class { 'neutron::plugins::ml2':
 274     flat_networks => split(hiera('neutron_flat_networks'), ','),
 275     tenant_network_types => [hiera('neutron_tenant_network_type')],
 276   }
 277   class { 'neutron::agents::ml2::ovs':
 278     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 279     tunnel_types => split(hiera('neutron_tunnel_types'), ','),
 280   }
 281
 282   Service['neutron-server'] -> Service['neutron-dhcp-service']
 283   Service['neutron-server'] -> Service['neutron-l3']
 284   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 285   Service['neutron-server'] -> Service['neutron-metadata']
 286
 287   include ::cinder
 288   include ::cinder::api
 289   include ::cinder::glance
 290   include ::cinder::scheduler
 291   include ::cinder::volume
 292   class {'cinder::setup_test_volume':
 293     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 294   }
 295
 296   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 297   if $cinder_enable_iscsi {
 298     $cinder_iscsi_backend = 'tripleo_iscsi'
 299
 300     cinder::backend::iscsi { $cinder_iscsi_backend :
 301       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 302       iscsi_helper     => hiera('cinder_iscsi_helper'),
 303     }
 304   }
 305
 306   if $enable_ceph {
 307
 308     Ceph_pool {
 309       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 310       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 311       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 312     }
 313
 314     $ceph_pools = hiera('ceph_pools')
 315     ceph::pool { $ceph_pools : }
 316   }
 317
 318   if $cinder_enable_rbd_backend {
 319     $cinder_rbd_backend = 'tripleo_ceph'
 320
 321     cinder_config {
 322       "${cinder_rbd_backend}/host": value => 'hostgroup';
 323     }
 324
 325     cinder::backend::rbd { $cinder_rbd_backend :
 326       rbd_pool        => 'volumes',
 327       rbd_user        => 'openstack',
 328       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 329       require         => Ceph::Pool['volumes'],
 330     }
 331   }
 332
 333   if hiera('cinder_enable_netapp_backend', false) {
 334     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 335
 336     cinder_config {
 337       "${cinder_netapp_backend}/host": value => 'hostgroup';
 338     }
 339
 340     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 341       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 342     }
 343
 344     cinder::backend::netapp { $cinder_netapp_backend :
 345       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 346       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 347       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 348       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 349       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 350       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 351       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 352       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 353       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 354       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 355       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 356       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 357       nfs_shares                   => $cinder_netapp_nfs_shares,
 358       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 359       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 360       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 361       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 362       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 363       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 364       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 365     }
 366   }
 367
 368   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend])
 369   class { '::cinder::backends' :
 370     enabled_backends => $cinder_enabled_backends,
 371   }
 372
 373   # swift proxy
 374   include ::memcached
 375   include ::swift::proxy
 376   include ::swift::proxy::proxy_logging
 377   include ::swift::proxy::healthcheck
 378   include ::swift::proxy::cache
 379   include ::swift::proxy::keystone
 380   include ::swift::proxy::authtoken
 381   include ::swift::proxy::staticweb
 382   include ::swift::proxy::ratelimit
 383   include ::swift::proxy::catch_errors
 384   include ::swift::proxy::tempurl
 385   include ::swift::proxy::formpost
 386
 387   # swift storage
 388   if str2bool(hiera('enable_swift_storage', 'true')) {
 389     class {'swift::storage::all':
 390       mount_check => str2bool(hiera('swift_mount_check'))
 391     }
 392     if(!defined(File['/srv/node'])) {
 393       file { '/srv/node':
 394         ensure  => directory,
 395         owner   => 'swift',
 396         group   => 'swift',
 397         require => Package['openstack-swift'],
 398       }
 399     }
 400     $swift_components = ['account', 'container', 'object']
 401     swift::storage::filter::recon { $swift_components : }
 402     swift::storage::filter::healthcheck { $swift_components : }
 403   }
 404
 405   # Ceilometer
 406   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 407   case $ceilometer_backend {
 408     /mysql/ : {
 409       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 410     }
 411     default : {
 412       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 413     }
 414   }
 415   include ::ceilometer
 416   include ::ceilometer::api
 417   include ::ceilometer::agent::notification
 418   include ::ceilometer::agent::central
 419   include ::ceilometer::alarm::notifier
 420   include ::ceilometer::alarm::evaluator
 421   include ::ceilometer::expirer
 422   include ::ceilometer::collector
 423   include ceilometer::agent::auth
 424   class { '::ceilometer::db' :
 425     database_connection => $ceilometer_database_connection,
 426   }
 427
 428   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 429
 430   # Heat
 431   include ::heat
 432   include ::heat::api
 433   include ::heat::api_cfn
 434   include ::heat::api_cloudwatch
 435   include ::heat::engine
 436
 437   # Horizon
 438   $vhost_params = { add_listen => false }
 439   class { 'horizon':
 440     cache_server_ip    => hiera('memcache_node_ips', '127.0.0.1'),
 441     vhost_extra_params => $vhost_params,
 442   }
 443
 444   $snmpd_user = hiera('snmpd_readonly_user_name')
 445   snmp::snmpv3_user { $snmpd_user:
 446     authtype => 'MD5',
 447     authpass => hiera('snmpd_readonly_user_password'),
 448   }
 449   class { 'snmp':
 450     agentaddress => ['udp:161','udp6:[::1]:161'],
 451     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 452   }
 453
 454   hiera_include('controller_classes')
 455
 456 } #END STEP 3